Debian Codegraph @

packages/seacas/applications/mapvar/srchs.f

raw
1 C Copyright(C) 1999-2020 National Technology & Engineering Solutions
2 C of Sandia, LLC (NTESS). Under the terms of Contract DE-NA0003525 with
3 C NTESS, the U.S. Government retains certain rights in this software.
4 C
5 C See packages/seacas/LICENSE for details
6
7 SUBROUTINE SRCHS (
8 * NPSRF, NFSRF, LINKSRF, XYZSRF,
9 * NPTS, XYZPTS, TOLSRCH,
10 * NISR, NRSR, NISS, NRSS, ISRCHR, RSRCHR, LBLK,
11 * LIST, IND, IRNK, IRNK2, INDX, ILO, IUP,
12 * IDP, IDS, XMIN, XMAX, ISCR, RSCR, IERR )
13
14 C-----------------------------------------------------------------------
15
16 C DESCRIPTION:
17
18 C THIS SUBROUTINE CALCULATES THE CLOSEST POINT PROBLEM
19 C BETWEEN NPTS POINTS AND NFSRF SURFACES AND RETURNS RESULTS OF
20 C SEARCH IN ISRCHR,RSRCHR
21
22 C USED HERE FOR FINDING LOCATION OF EITHER NODE OR ELEMENT CENTROID
23 C FROM MESH-B IN SHELL ELEMENT OF MESH-A
24
25 C-----------------------------------------------------------------------
26
27 C FORMAL PARAMETERS
28
29 C MEMORY : P=PERMANENT, S=SCRATCH
30 C NAME : IMPLICIT A-H,O-Z REAL, I-N INTEGER
31 C TYPE : INPUT_STATUS/OUTPUT_STATUS (I=INPUT,O=OUTPUT,P=PASSED,
32 C U=UNMODIFIED,-=UNDEFINED)
33 C DESCRIPTION : DESCRIPTION OF VARIABLE
34
35 C-----------------------------------------------------------------------
36
37 C CALLING ARGUMENTS:
38
39 C MEMORY NAME TYPE DESCRIPTION
40 C --- ---- --- -----------
41 C P NPSRF I/U NUMBER OF POINTS THAT DEFINE THE SURFACE
42 C P NFSRF I/U NUMBER OF SURFACES
43 C P LINKSRF I/U CONNECTIVITY OF SURFACES OF SIZE (4*NFSRF),
44 C NUMBERS REFER TO LOCATIONS IN XYZSRF ARRAY
45 C P XYZSRF I/U XYZ COORDS OF POINTS DEFINING SURFACE
46 C P NPTS I/U NUMBER OF POINTS TO BE SEARCHED
47 C P XYZPTS I/U XYZ COORDS OF POINTS TO BE SEARCHED
48 C P TOLSRCH I/U PROXIMITY TOLERANCE FOR POINT-TO-SURFACE SEARCH
49 C P NISR I/U NUMBER OF INTEGER SEARCH RESULTS (>=1)
50 C P NRSR I/U NUMBER OF REAL SEARCH RESULTS (>=4)
51 C P NISS I/U NUMBER OF INTEGER SEARCH SCRATCH (=5)
52 C P NRSS I/U NUMBER OF REAL SEARCH SCRATCH (=10)
53 C P ISRCHR -/O INTEGER SEARCH RESULTS
54 C P RSRCHR -/O REAL SEARCH RESULTS
55 C P LBLK I/U VECTOR BLOCKING PARAMETER (RECOMMEND 512 ON CRAY)
56 C S LIST -/- LIST OF POTENTIAL CONTACTS FOR A SURFACE
57 C S IND -/- INDEX ARRAY INDICATING COORD. ORDER OF EACH POINT
58 C S IRNK -/- RANK ARRAY
59 C S IRNK2 -/- RANK ARRAY (INDIRECT)
60 C S INDX -/P INTERMEDIATE LIST OF POTENTIAL PAIRS (CONSTRUCTED
61 C AFTER THE INTERSECTION OF TWO OF THREE LISTS)
62 C S ILO -/- SEARCH BOX MINIMUM INDEX
63 C S IUP -/- SEARCH BOX MAXIMUM INDEX
64 C S XMIN -/- SEARCH BOX MINIMUM DIMENSION
65 C S XMAX -/- SEARCH BOX MAXIMUM DIMENSION
66 C S ISCR -/- INTEGER SCRATCH MEMORY
67 C S RSCR -/- REAL SCRATCH MEMORY
68 C P IERR -/O ERROR FLAG
69
70 C-----------------------------------------------------------------------
71
72 include 'tapes.blk'
73
74 C INPUT/OUTPUT ARRAYS
75
76 DIMENSION
77 * LINKSRF(4,NFSRF), XYZSRF(NPSRF,3),
78 * XYZPTS(NPTS,3),
79 * ISRCHR(NISR,NPTS), RSRCHR(NRSR,NPTS)
80 DIMENSION
81 * LIST(NPTS), IND(NPTS,3), IRNK(NPTS,3),
82 * IRNK2(NPTS,3,2), INDX(NPTS)
83 DIMENSION
84 * ILO(LBLK,3), IUP(LBLK,3), IDP(LBLK),
85 * IDS(LBLK)
86 DIMENSION
87 * XMIN(LBLK,3), XMAX(LBLK,3), ISCR(NISS*LBLK),
88 * RSCR(NRSS*LBLK)
89
90 C ISRCHR and RSRCHR must be initialized to zero
91
92 DO 1 I = 1, NPTS
93 DO 2 J = 1, NISR
94 ISRCHR(J,I) = 0
95 2 CONTINUE
96 DO 3 K = 1, NRSR
97 RSRCHR(K,I) = 0.
98 3 CONTINUE
99 1 CONTINUE
100
101 IF( NISR .LT. 1 .OR. NRSR .LT. 4 .OR. NISS .LT. 5 .OR.
102 * NRSS .LT. 10 )THEN
103 IERR = 1
104 RETURN
105 ENDIF
106 C DIMENSION OF COORDINATES
107 NDIM = 3
108 C ZERO SEARCH-PAIR COUNTER
109 KOUNTS = 0
110
111 C CALL SORTING ROUTINE TO MAKE RANK ARRAYS
112 CALL MKRNK( NPTS,NPTS,NDIM,XYZPTS,IND,IRNK,IRNK2 )
113
114 C LOOP OVER SURFACES AND SEARCH FOR POINTS WITHIN CAPTURE BOX
115 DO 100 IFSRF = 1, NFSRF, LBLK
116 NE = MIN(LBLK,NFSRF-IFSRF+1)
117 C CONSTRUCT THE BOUNDING BOX FOR NE SURFACES
118 DO 110 J = 1, NE
119 JFSRF = IFSRF + J - 1
120 NI = LINKSRF(1,JFSRF)
121 NJ = LINKSRF(2,JFSRF)
122 NK = LINKSRF(3,JFSRF)
123 NL = LINKSRF(4,JFSRF)
124
125 XMINMS = MIN(XYZSRF(NI,1),XYZSRF(NJ,1),
126 * XYZSRF(NK,1),XYZSRF(NL,1))
127 XMAXMS = MAX(XYZSRF(NI,1),XYZSRF(NJ,1),
128 * XYZSRF(NK,1),XYZSRF(NL,1))
129 YMINMS = MIN(XYZSRF(NI,2),XYZSRF(NJ,2),
130 * XYZSRF(NK,2),XYZSRF(NL,2))
131 YMAXMS = MAX(XYZSRF(NI,2),XYZSRF(NJ,2),
132 * XYZSRF(NK,2),XYZSRF(NL,2))
133 ZMINMS = MIN(XYZSRF(NI,3),XYZSRF(NJ,3),
134 * XYZSRF(NK,3),XYZSRF(NL,3))
135 ZMAXMS = MAX(XYZSRF(NI,3),XYZSRF(NJ,3),
136 * XYZSRF(NK,3),XYZSRF(NL,3))
137 XDEL = XMAXMS - XMINMS
138 YDEL = YMAXMS - YMINMS
139 ZDEL = ZMAXMS - ZMINMS
140 TOLER = TOLSRCH * MAX(XDEL,YDEL,ZDEL)
141 XMIN(J,1) = XMINMS - TOLER
142 XMAX(J,1) = XMAXMS + TOLER
143 XMIN(J,2) = YMINMS - TOLER
144 XMAX(J,2) = YMAXMS + TOLER
145 XMIN(J,3) = ZMINMS - TOLER
146 XMAX(J,3) = ZMAXMS + TOLER
147 110 CONTINUE
148
149 DO 120 IDIM = 1, NDIM
150 CALL GETBND( LBLK, NE, XYZPTS(1,IDIM), IND(1,IDIM),
151 * NPTS, XMIN(1,IDIM), XMAX(1,IDIM),
152 * NPTS, ILO(1,IDIM), IUP(1,IDIM),
153 * ISCR, RSCR )
154 120 CONTINUE
155
156 DO 130 J = 1, NE
157 JFSRF = IFSRF + J - 1
158 CALL MKLSTV(NPTS,IND,IRNK2,IUP,ILO,INDX,J,LIST,NLIST,
159 * LBLK,NDIM)
160
161 DO 140 K = 1, NLIST
162 LVAL = LIST(K)
163 CALL SHLSRC(
164 * NDIM, NPTS, NPSRF, NFSRF, NISR,
165 * NRSR, NRSS, XYZSRF, XYZPTS, LINKSRF,
166 * ISRCHR, RSRCHR, LVAL, JFSRF, TOLSRCH,
167 * IERR )
168
169 140 CONTINUE
170 130 CONTINUE
171 100 CONTINUE
172
173 RETURN
174 END