Debian Codegraph @

packages/seacas/applications/mapvar/srchq.f

raw
1 C Copyright(C) 1999-2020 National Technology & Engineering Solutions
2 C of Sandia, LLC (NTESS). Under the terms of Contract DE-NA0003525 with
3 C NTESS, the U.S. Government retains certain rights in this software.
4 C
5 C See packages/seacas/LICENSE for details
6
7 SUBROUTINE SRCHQ (
8 * NPSRF, NFSRF, LINKSRF, XYZSRF,
9 * NPTS, XYZPTS, TOLSRCH,
10 * NISR, NRSR, NISS, NRSS, ISRCHR, RSRCHR, LBLK,
11 * LIST, IND, IRNK, IRNK2, INDX, ILO, IUP,
12 * IDP, IDS, XMIN, XMAX, ISCR, RSCR, IERR )
13
14 C-----------------------------------------------------------------------
15
16 C DESCRIPTION:
17
18 C THIS SUBROUTINE CALCULATES THE CLOSEST POINT PROBLEM
19 C BETWEEN NPTS POINTS AND NFSRF SURFACES AND RETURNS RESULTS OF
20 C SEARCH IN ISRCHR,RSRCHR
21
22 C USED HERE FOR FINDING LOCATION OF EITHER NODE OR ELEMENT CENTROID
23 C FROM MESH-B IN QUAD-4 ELEMENT OF MESH-A
24
25 C-----------------------------------------------------------------------
26
27 C FORMAL PARAMETERS
28
29 C MEMORY : P=PERMANENT, S=SCRATCH
30 C NAME : IMPLICIT A-H,O-Z REAL, I-N INTEGER
31 C TYPE : INPUT_STATUS/OUTPUT_STATUS (I=INPUT,O=OUTPUT,P=PASSED,
32 C U=UNMODIFIED,-=UNDEFINED)
33 C DESCRIPTION : DESCRIPTION OF VARIABLE
34
35 C-----------------------------------------------------------------------
36
37 C CALLING ARGUMENTS:
38
39 C MEMORY NAME TYPE DESCRIPTION
40 C --- ---- --- -----------
41 C P NPSRF I/U NUMBER OF POINTS THAT DEFINE THE SURFACE
42 C P NFSRF I/U NUMBER OF SURFACES
43 C P LINKSRF I/U CONNECTIVITY OF SURFACES OF SIZE (4*NFSRF),
44 C NUMBERS REFER TO LOCATIONS IN XYZSRF ARRAY
45 C P XYZSRF I/U XYZ COORDS OF POINTS DEFINING SURFACE
46 C P NPTS I/U NUMBER OF POINTS TO BE SEARCHED
47 C P XYZPTS I/U XYZ COORDS OF POINTS TO BE SEARCHED
48 C P TOLSRCH I/U PROXIMITY TOLERANCE FOR POINT-TO-SURFACE SEARCH
49 C P NISR I/U NUMBER OF INTEGER SEARCH RESULTS (>=1)
50 C P NRSR I/U NUMBER OF REAL SEARCH RESULTS (>=4)
51 C P NISS I/U NUMBER OF INTEGER SEARCH SCRATCH (=5)
52 C P NRSS I/U NUMBER OF REAL SEARCH SCRATCH (=10)
53 C P ISRCHR -/O INTEGER SEARCH RESULTS
54 C P RSRCHR -/O REAL SEARCH RESULTS
55 C P LBLK I/U VECTOR BLOCKING PARAMETER (RECOMMEND 512 ON CRAY)
56 C S LIST -/- LIST OF POTENTIAL CONTACTS FOR A SURFACE
57 C S IND -/- INDEX ARRAY INDICATING COORD. ORDER OF EACH POINT
58 C S IRNK -/- RANK ARRAY
59 C S IRNK2 -/- RANK ARRAY (INDIRECT)
60 C S INDX -/P INTERMEDIATE LIST OF POTENTIAL PAIRS (CONSTRUCTED
61 C AFTER THE INTERSECTION OF TWO OF THREE LISTS)
62 C S ILO -/- SEARCH BOX MINIMUM INDEX
63 C S IUP -/- SEARCH BOX MAXIMUM INDEX
64 C S XMIN -/- SEARCH BOX MINIMUM DIMENSION
65 C S XMAX -/- SEARCH BOX MAXIMUM DIMENSION
66 C S ISCR -/- INTEGER SCRATCH MEMORY
67 C S RSCR -/- REAL SCRATCH MEMORY
68 C P IERR -/O ERROR FLAG
69
70 C-----------------------------------------------------------------------
71
72 include 'amesh.blk'
73 include 'tapes.blk'
74
75 C INPUT/OUTPUT ARRAYS
76
77 DIMENSION
78 * LINKSRF(NELNDA,NFSRF), XYZSRF(NPSRF,3),
79 * XYZPTS(NPTS,3),
80 * ISRCHR(NISR,NPTS), RSRCHR(NRSR,NPTS)
81 DIMENSION
82 * LIST(NPTS), IND(NPTS,3), IRNK(NPTS,3),
83 * IRNK2(NPTS,3,2), INDX(NPTS)
84 DIMENSION
85 * ILO(LBLK,3), IUP(LBLK,3), IDP(LBLK),
86 * IDS(LBLK)
87 DIMENSION
88 * XMIN(LBLK,3), XMAX(LBLK,3), ISCR(NISS*LBLK),
89 * RSCR(NRSS*LBLK)
90
91 C ISRCHR and RSRCHR must be initialized to zero
92
93 DO 1 I = 1, NPTS
94 DO 2 J = 1, NISR
95 ISRCHR(J,I) = 0
96 2 CONTINUE
97 DO 3 K = 1, NRSR
98 RSRCHR(K,I) = 0.
99 3 CONTINUE
100 1 CONTINUE
101
102 IF( NISR .LT. 1 .OR. NRSR .LT. 2 .OR. NISS .LT. 5 .OR.
103 * NRSS .LT. 10 )THEN
104 IERR = 1
105 RETURN
106 ENDIF
107 C DIMENSION OF COORDINATES
108 NDIM = 2
109
110 C CALL SORTING ROUTINE TO MAKE RANK ARRAYS
111 CALL MKRNK( NPTS,NPTS,NDIM,XYZPTS,IND,IRNK,IRNK2 )
112
113 C LOOP OVER SURFACES AND SEARCH FOR POINTS WITHIN CAPTURE BOX
114 DO 100 IFSRF = 1, NFSRF, LBLK
115 NE = MIN(LBLK,NFSRF-IFSRF+1)
116 C CONSTRUCT THE BOUNDING BOX FOR NE SURFACES
117 DO 110 J = 1, NE
118 JFSRF = IFSRF + J - 1
119 NI = LINKSRF(1,JFSRF)
120 NJ = LINKSRF(2,JFSRF)
121 NK = LINKSRF(3,JFSRF)
122 NL = LINKSRF(4,JFSRF)
123
124 XMINMS = MIN(XYZSRF(NI,1),XYZSRF(NJ,1),
125 * XYZSRF(NK,1),XYZSRF(NL,1))
126 XMAXMS = MAX(XYZSRF(NI,1),XYZSRF(NJ,1),
127 * XYZSRF(NK,1),XYZSRF(NL,1))
128 YMINMS = MIN(XYZSRF(NI,2),XYZSRF(NJ,2),
129 * XYZSRF(NK,2),XYZSRF(NL,2))
130 YMAXMS = MAX(XYZSRF(NI,2),XYZSRF(NJ,2),
131 * XYZSRF(NK,2),XYZSRF(NL,2))
132 ZMINMS = MIN(XYZSRF(NI,3),XYZSRF(NJ,3),
133 * XYZSRF(NK,3),XYZSRF(NL,3))
134 ZMAXMS = MAX(XYZSRF(NI,3),XYZSRF(NJ,3),
135 * XYZSRF(NK,3),XYZSRF(NL,3))
136 TOLER = TOLSRCH * (XMAXMS - XMINMS)
137 XMIN(J,1) = XMINMS - TOLER
138 XMAX(J,1) = XMAXMS + TOLER
139 TOLER = TOLSRCH * (YMAXMS - YMINMS)
140 XMIN(J,2) = YMINMS - TOLER
141 XMAX(J,2) = YMAXMS + TOLER
142 TOLER = TOLSRCH * (ZMAXMS - ZMINMS)
143 XMIN(J,3) = ZMINMS - TOLER
144 XMAX(J,3) = ZMAXMS + TOLER
145 110 CONTINUE
146
147 DO 120 IDIM = 1, NDIM
148 CALL GETBND( LBLK, NE, XYZPTS(1,IDIM), IND(1,IDIM),
149 * NPTS, XMIN(1,IDIM), XMAX(1,IDIM),
150 * NPTS, ILO(1,IDIM), IUP(1,IDIM),
151 * ISCR, RSCR )
152 120 CONTINUE
153
154 DO 130 J = 1, NE
155 JFSRF = IFSRF + J - 1
156 CALL MKLSTV(NPTS,IND,IRNK2,IUP,ILO,INDX,J,LIST,NLIST,
157 * LBLK,NDIM)
158
159 DO 140 K = 1, NLIST
160 lval = list(k)
161 CALL QADSRC(
162 * NDIM, NPTS, NPSRF, NFSRF, NISR,
163 * NRSR, NRSS, XYZSRF, XYZPTS, LINKSRF,
164 * ISRCHR, RSRCHR, LVAL, JFSRF, IERR )
165 140 CONTINUE
166 130 CONTINUE
167 100 CONTINUE
168 RETURN
169 END