Debian Codegraph @

packages/seacas/applications/genshell/gs_splxyz.f

raw
1 C Copyright(C) 1999-2020 National Technology & Engineering Solutions
2 C of Sandia, LLC (NTESS). Under the terms of Contract DE-NA0003525 with
3 C NTESS, the U.S. Government retains certain rights in this software.
4 C
5 C See packages/seacas/LICENSE for details
6
7 C -*- Mode: fortran -*-
8 C=======================================================================
9 SUBROUTINE SPLXYZ (XN, YN, XN3, YN3, ZN3, ATRIB,
10 & NSPL1, RSA, ZSA, ZS2A, DISTA, SCRA,
11 & SLLFT, SLRGT, RDTHET, SWEEP, NOSCAL )
12 C=======================================================================
13
14 C --*** SPLXYZ *** (GEN3D) Calculate 3D coordinates for Double-surface
15 C Spline projection
16 C -- Written by Greg Sjaardema - 01/08/90
17 C --
18 C --SPLXYZ calculates the coordinate array for the 3D spline translations.
19 C --
20 C --Parameters:
21 C -- XN, YN - IN - the 2D coordinates, destroyed
22 C -- XN3, YN3, ZN3 - OUT - the 3D coordinates
23 C -- IXNP - IN - the new index for each node
24 C -- NRNP - IN - the number of new nodes generated for each node
25 C -- ZCORD - SCRATCH - size = NNREPL, holds z coordinate for transformations
26 C --
27 C --Common Variables:
28 C -- Uses NDIM, NUMNP of /DBNUMS/
29 C -- Uses NDIM3, NUMNP3 of /DBNUM3/
30 C -- Uses DOTRAN, NNREPL, DIM3, NRTRAN, D3TRAN, ZGRAD,
31 C -- CENTER, NUMCOL, NUMROW of /PARAMS/
32
33 INCLUDE 'gs_dbnums.blk'
34 INCLUDE 'gs_dbnum3.blk'
35 INCLUDE 'gs_params.blk'
36
37 PARAMETER (BINGO = 1.0E38)
38 PARAMETER (TOLER = 1.0E-8)
39
40 INTEGER XSWEEP, YSWEEP, SPHERI, SWEEP
41 PARAMETER (XSWEEP = 10)
42 PARAMETER (YSWEEP = 1)
43 PARAMETER (SPHERI = 11)
44
45 REAL XN(NUMNP), YN(NUMNP),
46 & XN3(NUMNP3), YN3(NUMNP3), ZN3(NUMNP3)
47 REAL ATRIB(NUMEL)
48 REAL RSA(NSPL1), ZSA(NSPL1), ZS2A(NSPL1), DISTA(NSPL1),
49 & SCRA(NSPL1)
50 C ... NOTE: Only sllft(1) and slrgt(1) are used, (2) left for comp. with gen3d
51 REAL SLLFT(2), SLRGT(2)
52
53 LOGICAL RDTHET, NOSCAL
54
55 rad = 0.0
56 xt = 0.0
57 yt = 0.0
58
59 PI = ATAN2(0.0, -1.0)
60
61 C ... Check for valid options...
62 IF (RDTHET .AND. NOSCAL) THEN
63 CALL PRTERR('ERROR', 'Cannot use NOSCALE with ANGULAR spline')
64 RETURN
65 END IF
66
67 C ... Convert angles from degrees to radians
68 IF (RDTHET) THEN
69 DO 10 IPT = 1, NSPL1
70 RSA(IPT) = RSA(IPT) * PI / 180.0
71 10 CONTINUE
72 END IF
73
74 CALL SPLINE (RSA, ZSA, NSPL1, SLLFT(1), SLRGT(1), ZS2A, SCRA)
75
76 C ... Calculate approximate distance along curve. Distance is computed
77 C as the straight line distance of the segments. Accurate for
78 C smooth curves; bad for non-smooth curves.
79 C ... If 'NOSCALE' is set, then the spline must be linear and
80 C we use the input RSA values for the distance.
81
82 IF (NOSCAL) THEN
83 DO 20 IPT = 1, NSPL1
84 DISTA(IPT) = RSA(IPT)
85 20 CONTINUE
86 ELSE
87 IF (RDTHET) THEN
88 DISTA(1) = ZSA(1) * SIN(RSA(1))
89 DO 30 IPT = 2, NSPL1
90 DISTA(IPT) = DISTA(IPT-1) + SQRT(
91 & (ZSA(IPT) * SIN(RSA(IPT)) -
92 & ZSA(IPT-1) * SIN(RSA(IPT-1)))**2 +
93 & (ZSA(IPT) * COS(RSA(IPT)) -
94 & ZSA(IPT-1) * COS(RSA(IPT-1)))**2)
95 30 CONTINUE
96 ELSE
97 DISTA(1) = RSA(1)
98 DO 50 IPT = 2, NSPL1
99 DISTA(IPT) = SQRT( (RSA(IPT-1) - RSA(IPT))**2 +
100 & (ZSA(IPT-1) - ZSA(IPT))**2 ) + DISTA(IPT-1)
101 50 CONTINUE
102 END IF
103 END IF
104 C... Determine maximum radius of mesh
105
106 RMAX = 0.0
107 RMIN = BINGO
108 IF (SWEEP .EQ. SPHERI) THEN
109 DO 80 INP = 1, NUMNP
110 DX = XN(INP)
111 DY = YN(INP)
112 RMIN = MIN (RMIN, (DX**2 + DY**2))
113 RMAX = MAX (RMAX, (DX**2 + DY**2))
114 80 CONTINUE
115 RMIN = SQRT(RMIN)
116 RMAX = SQRT(RMAX)
117 ELSE IF (SWEEP .EQ. XSWEEP) THEN
118 DO 82 INP = 1, NUMNP
119 DY = YN(INP)
120 RMIN = MIN (RMIN, DY)
121 RMAX = MAX (RMAX, DY)
122 82 CONTINUE
123 ELSE IF (SWEEP .EQ. YSWEEP) THEN
124 DO 84 INP = 1, NUMNP
125 DX = XN(INP)
126 RMIN = MIN (RMIN, DX)
127 RMAX = MAX (RMAX, DX)
128 84 CONTINUE
129 END IF
130
131 C... If there is not a node at 0,0 - RMIN will not equal zero, therefore,
132 C we assume that if the spline starts at zero, the mesh also starts
133 C at zero.
134 IF (DISTA(1) .EQ. 0.0) THEN
135 RMIN = 0.0
136 END IF
137
138 IF (NOSCAL) THEN
139 PROPA = 1.0
140 ELSE
141 PROPA = (DISTA(NSPL1) - DISTA(1)) / (RMAX - RMIN)
142 END IF
143
144 C ... Echo spline data
145
146 WRITE (*,*) ' '
147 WRITE (*,70) 'top spline', DISTA(NSPL1), PROPA
148 70 FORMAT (' Total length of ',A,T32,' = ',1PE12.5,
149 & ', Proportion = ',1PE12.5)
150
151 KLOA = 1
152 DO 100 INP = 1, NUMNP
153 DX = XN(INP)
154 DY = YN(INP)
155 IF (SWEEP .EQ. SPHERI) THEN
156 RAD = SQRT (DX**2 + DY**2)
157 ELSE IF (SWEEP .EQ. XSWEEP) THEN
158 RAD = DY
159 ELSE IF (SWEEP .EQ. YSWEEP) THEN
160 RAD = DX
161 END IF
162 RADA = DISTA(1) + PROPA * (RAD - RMIN)
163
164 C ... Determine segment containing point and proportion within segment
165
166 CALL HUNT (DISTA, NSPL1, RADA, KLOA)
167 KLOA = MIN(NSPL1-1, MAX(1, KLOA))
168
169 C ... We want to map the X-Y plane onto the spline surface without
170 C stretching. Therefore, calculate a new radius RNEW which is
171 C the distance from the Z axis to the point on the spline such
172 C that the arc length from R=0 to R=RAD is the distance RNEW.
173 C The new X and Y coordinates corresponding to RNEW are calculated
174 C as the proportion of RNEW / RAD. FIXR is added to RAD in case
175 C RAD is 0; FIXR = 1 iff RAD = 0, else FIXR = 0
176
177 C --- On IEEE Machines, at least on Ultrix 4.0 IEEE, the SIGN
178 C trick does not work since it defines a signed 0.0
179
180 IF (RAD .EQ. 0.0) THEN
181 FIXR = 1.0
182 ELSE
183 FIXR = 0.0
184 END IF
185 C FIXR = SIGN(0.5, RAD) + SIGN(0.5, -RAD)
186
187 PROP = (RADA - DISTA(KLOA)) / (DISTA(KLOA+1) - DISTA(KLOA))
188 RNEWA = RSA(KLOA) + PROP * (RSA(KLOA+1) - RSA(KLOA))
189
190 H = RSA(KLOA+1) - RSA(KLOA)
191 A = (RSA(KLOA+1)-RNEWA) / H
192 B = (RNEWA-RSA(KLOA)) / H
193
194 ZT = A * ZSA(KLOA) + B * ZSA(KLOA+1) +
195 * ((A**3-A) * ZS2A(KLOA)+(B**3-B) * ZS2A(KLOA+1)) * (H**2)/6.
196
197 IF (RDTHET) THEN
198 RSAV = RNEWA
199 ZSAV = ZT
200 ZT = ZSAV * COS(RSAV)
201 RNEWA = ZSAV * SIN(RSAV)
202 END IF
203
204 IF (SWEEP .EQ. SPHERI) THEN
205 C ... Spherical Sweep of Spline Surface
206 XT = RNEWA * DX / (RAD + FIXR)
207 YT = RNEWA * DY / (RAD + FIXR)
208
209 ELSE IF (SWEEP .EQ. XSWEEP) THEN
210 C ... Sweep spline along the X axis
211 XT = DX
212 YT = RNEWA * DY / (RAD + FIXR)
213
214 ELSE IF (SWEEP .EQ. YSWEEP) THEN
215 C ... Sweep spline along the X axis
216 XT = RNEWA * DX / (RAD + FIXR)
217 YT = DY
218
219 END IF
220
221 C$$$$ write (*,*) inp, xn(inp), yn(inp), xt, yt, zt
222 ZN3(INP) = ZT
223 YN3(INP) = YT
224 XN3(INP) = XT
225 100 CONTINUE
226
227 C ... Now do the attributes for all of the elements
228
229 DO 370 IEL = 1, NUMEL
230 ATRIB(IEL) = DIM3
231 370 CONTINUE
232
233 RETURN
234 END