Debian Codegraph @

packages/seacas/applications/genshell/genshell.f

raw
1 C Copyright(C) 1999-2020, 2022 National Technology & Engineering Solutions
2 C of Sandia, LLC (NTESS). Under the terms of Contract DE-NA0003525 with
3 C NTESS, the U.S. Government retains certain rights in this software.
4 C
5 C See packages/seacas/LICENSE for details
6
7 C=======================================================================
8 PROGRAM GENSHL
9 C=======================================================================
10 C --*** GENSHL *** (GENSHL) GENESIS 2D to 3D Shell Program
11 C --
12 C --GENSHL inputs a 2D GENESIS database and outputs a 3D GENESIS database.
13 C --
14 C --Expected input:
15 C -- o The commands on the standard input device.
16 C -- o The 2D GENESIS database on unit 9
17 C -- (must have 4 nodes per element,
18 C -- cannot have more than 2048 element blocks).
19 C --
20 C --Output:
21 C -- o A listing of the input database information and any errors
22 C -- found on the standard output device.
23 C -- o The 3D GENESIS Shell database on unit 10.
24
25 C --Developed at Sandia National Laboratories.
26 C --
27 C --Current author and code sponsor: Gregory D. Sjaardema
28 C --
29 C --Revision History:
30 C -- 04/86 GEN3D Created (Amy Gilkey)
31 C -- 01/91 GENSHL Created (Greg Sjaardema)
32 C --
33 C --Source is in FORTRAN 77
34 C --
35 C --External software used:
36 C -- SUPES package (dynamic memory, free-field reader, FORTRAN extensions)
37 C -- SUPLIB package (EXODUS file manipulation and other routines)
38 C --
39
40 C --Documentation:
41 C -- --NONE--
42
43 include 'exodusII.inc'
44 INCLUDE 'gs_progqa.blk'
45 INCLUDE 'gs_dbase.blk'
46 INCLUDE 'gs_dbtitl.blk'
47 INCLUDE 'gs_dbnums.blk'
48 INCLUDE 'gs_dbnum3.blk'
49 INCLUDE 'gs_params.blk'
50 INCLUDE 'gs_xyzoff.blk'
51 INCLUDE 'gs_xyzrot.blk'
52 INCLUDE 'gs_xyzmir.blk'
53 INCLUDE 'argparse.inc'
54
55 CHARACTER*2048 FILIN, FILOUT, SCRATCH
56
57 CHARACTER*(MXSTLN) NAMECO(6)
58 CHARACTER*(MXSTLN) NAMELB(2048)
59 C --NAMECO - the coordinate names
60 C --NAMELB - the element block names
61
62 CHARACTER CDUM
63
64 DIMENSION A(1)
65 INTEGER IA(1)
66 EQUIVALENCE (A(1), IA(1))
67 CHARACTER*1 C(1)
68 C --A - the dynamic numeric memory base array
69
70 INTEGER IDNSET(0:10,2)
71 INTEGER IDESET(0:10,2)
72
73 INCLUDE 'gs_qainfo.blk'
74
75 CALL STRTUP (QAINFO)
76
77 CALL BANNER (0, QAINFO,
78 & 'A GENESIS DATABASE 2D TO 3D SHELL CONVERSION PROGRAM',
79 & ' ', ' ')
80 call cpyrgt (0, '1991')
81
82 CALL MDINIT (A)
83 CALL MCINIT (C)
84 CALL MDSTAT (NERR, MEM)
85 IF (NERR .GT. 0) GOTO 40
86
87 C .. Get filename from command line. If not specified, emit error message
88 NARG = argument_count()
89 if (narg .lt. 2) then
90 CALL PRTERR ('FATAL', 'Filenames not specified.')
91 CALL PRTERR ('CMDSPEC',
92 * 'Syntax is: "genshell 2dfilename 3dfilename"')
93 CALL PRTERR ('CMDSPEC',
94 * 'Documentation: https://sandialabs.github.io' //
95 $ '/seacas-docs/sphinx/html/index.html#genshell')
96 GOTO 60
97 else if (narg .gt. 2) then
98 CALL PRTERR ('FATAL', 'Too many arguments specified.')
99 CALL PRTERR ('CMDSPEC',
100 * 'Syntax is: "genshell 2dfilename 3dfilename"')
101 CALL PRTERR ('CMDSPEC',
102 * 'Documentation: https://sandialabs.github.io' //
103 $ '/seacas-docs/sphinx/html/index.html#genshell')
104 GOTO 60
105 end if
106
107 C --Open the input database and read the initial variables
108
109 NDBIN = 9
110 NDBOUT = 10
111
112 CMPSIZ = 0
113 IOWS = 0
114
115 FILIN = ' '
116 CALL get_argument(1,FILIN, LNAM)
117 NDBIN = exopen(filin(:lnam), EXREAD, CMPSIZ, IOWS, vers, IERR)
118 IF (IERR .NE. 0) THEN
119 SCRATCH = 'Database "'//FILIN(:LNAM)//'" does not exist.'
120 CALL PRTERR ('FATAL', SCRATCH(:LENSTR(SCRATCH)))
121 GOTO 60
122 END IF
123
124 call exgini(ndbin, title, ndim, numnp, numel, nelblk,
125 * numnps, numess, ierr)
126 if (nelblk .gt. 2048) then
127 CALL PRTERR ('PROGRAM', 'Too many element blocks. 2048 MAX')
128 GOTO 60
129 end if
130 if (numnps .gt. 0) then
131 call exinq(ndbin, EXNSNL, lnpsnl, rdum, cdum, ierr)
132 call exinq(ndbin, EXNSDF, lnpsdf, rdum, cdum, ierr)
133 else
134 lnpsnl = 0
135 lnpsdf = 0
136 end if
137 if (numess .gt. 0) then
138 call exinq(ndbin, EXSSNL, lessnl, rdum, cdum, ierr)
139 call exinq(ndbin, EXSSEL, lessel, rdum, cdum, ierr)
140 call exinq(ndbin, EXSSDF, lessdf, rdum, cdum, ierr)
141 else
142 lessnl = 0
143 lessel = 0
144 lessdf = 0
145 end if
146
147 CALL DBPINI ('NTIS', NDBIN, TITLE, NDIM, NUMNP, NUMEL, NELBLK,
148 & NUMNPS, LNPSNL, LNPSDF, NUMESS, LESSEL, LESSNL,
149 & LESSDF, IDUM, IDUM, IDUM)
150
151 IF (NDIM .NE. 2) THEN
152 CALL PRTERR ('FATAL', 'Number of dimensions must be 2')
153 GOTO 60
154 END IF
155
156 C --Reserve memory for the 2D information
157
158 CALL MDRSRV ('XN', KXN, NUMNP)
159 CALL MDRSRV ('YN', KYN, NUMNP)
160 KZN = 1
161
162 CALL MDRSRV ('MAPEL', KMAPEL, NUMEL)
163
164 CALL MDRSRV ('IDELB', KIDELB, NELBLK)
165 CALL MDRSRV ('NUMELB', KNELB, NELBLK)
166 CALL MDRSRV ('NUMLNK', KNLNK, NELBLK)
167 CALL MDRSRV ('NUMATR', KNATR, NELBLK)
168 CALL MDRSRV ('LINK', KLINK, 0)
169 CALL MDRSRV ('ATRIB', KATRIB, 0)
170
171 CALL MDRSRV ('IDNPS', KIDNS, NUMNPS)
172 CALL MDRSRV ('NNNPS', KNNNS, NUMNPS)
173 CALL MDRSRV ('NDNPS', KNDNPS, NUMNPS)
174 CALL MDRSRV ('IXNNPS', KIXNNS, NUMNPS)
175 CALL MDRSRV ('IXDNPS', KIXDNS, NUMNPS)
176 CALL MDRSRV ('LTNNPS', KLTNNS, LNPSNL)
177 CALL MDRSRV ('FACNPS', KFACNS, LNPSNL)
178
179 CALL MDRSRV ('IDESS', KIDSS, NUMESS)
180 CALL MDRSRV ('NEESS', KNESS, NUMESS)
181 CALL MDRSRV ('NNESS', KNNSS, NUMESS)
182 CALL MDRSRV ('NDESS', KNDSS, NUMESS)
183 CALL MDRSRV ('IXEESS', KIXESS, NUMESS)
184 CALL MDRSRV ('IXNESS', KIXNSS, NUMESS)
185 CALL MDRSRV ('IXDESS', KIXDSS, NUMESS)
186 CALL MDRSRV ('LTNNSS', KLTNNN, LESSEL)
187 CALL MDRSRV ('LTEESS', KLTESS, LESSEL)
188 CALL MDRSRV ('LTNESS', KLTNSS, LESSNL)
189 CALL MDRSRV ('LTSESS', KLTSSS, LESSEL)
190 CALL MDRSRV ('FACESS', KFACSS, LESSNL)
191
192 CALL MDSTAT (NERR, MEM)
193 IF (NERR .GT. 0) GOTO 40
194
195 C --Read 2D information from the database and close file
196
197 call exgcor (ndbin, a(kxn), a(kyn), a(kzn), ierr)
198 call exgmap (ndbin, ia(kmapel), ierr)
199
200 CALL INISTR (NDIM, ' ', NAMECO)
201 call exgcon (ndbin, nameco, ierr)
202
203 CALL INISTR (2048, ' ', NAMELB)
204 CALL DBIELB (NDBIN, '*', 1, NELBLK,
205 * IA(KIDELB), IA(KNELB), IA(KNLNK), IA(KNATR),
206 * A, IA, KLINK, KATRIB, NAMELB, *60)
207 CALL MDSTAT (NERR, MEM)
208 IF (NERR .GT. 0) GOTO 40
209
210 C ... At the current time, only handle all 4-node or 8-node hexes per model.
211 NLNK = IA(KNLNK)
212 DO 5 IEL = 2, NELBLK
213 if (NLNK .NE. IA(KNLNK+IEL-1)) THEN
214 CALL PRTERR ('FATAL',
215 * 'Mesh must be ALL 4-node or ALL 8-node quads')
216 STOP
217 END IF
218 5 CONTINUE
219
220 if (numnps .gt. 0) then
221 call exgcns(ndbin, a(kidns), a(knnns), a(kndnps), a(kixnns),
222 * a(kixdns), a(kltnns), a(kfacns), ierr)
223 end if
224
225 if (numess .gt. 0) then
226 call exgcss(ndbin, a(kidss), a(kness), a(kndss), a(kixess),
227 * a(kixdss), A(KLTeSS), a(kltsss), a(kfacss), ierr)
228 end if
229
230 call exinq(ndbin, EXQA, nqarec, rdum, cdum, ierr)
231 call exinq(ndbin, EXINFO, ninfo, rdum, cdum, ierr)
232 call mcrsrv('QAREC', kqarec, (nqarec+1) * 4 * MXSTLN)
233 call mcrsrv('INFREC', kinfo, (ninfo+1) * MXLNLN)
234 CALL MCSTAT (NERR, MEM)
235 IF (NERR .GT. 0) GOTO 40
236 if (nqarec .gt. 0) then
237 C ... Wrapper to get strings the right length
238 call exgqaw(ndbin, c(kqarec), ierr)
239 end if
240 if (ninfo .gt. 0) then
241 C ... Wrapper to get info record the right length
242 call exginw(ndbin, c(kinfo), ierr)
243 end if
244
245 IF ((NQAREC .GT. 0) .OR. (NINFO .GT. 0)) THEN
246 CALL DBPQA ('*', NQAREC, c(kqarec), NINFO, c(kinfo))
247 END IF
248
249 C -- This assumes only max of 7 attributes per element block
250 CALL MDRSRV ('ATRIBNW', KATRIBN, 0)
251 CALL MDRSRV ('ELATTR', KELATT, NELBLK*7)
252 CALL MDSTAT (NERR, MEM)
253 IF (NERR .GT. 0) GOTO 40
254
255 C --Read in runtime parameters
256
257 CALL COMAND (IA(KIDNS), IA(KIDSS), IDNSET, IDESET,
258 & IA(KIDELB), IA(KNELB), IA(KNLNK), NAMELB, A(KELATT),
259 & A(KXN), A(KYN), A, *60)
260
261 C --Get the new numbers for the elements and nodes
262
263 LNPSNO = LNPSNL
264
265 C --Get the node sets
266
267 CONTINUE
268
269 C --Get the side sets, and the front and back side sets
270
271 NSSET = IDESET(0,1)+IDESET(0,2)
272 IF (NSSET .GT. 0) THEN
273 CALL MDRSRV ('ISSFRO', KISFRO, NUMEL)
274 CALL MDRSRV ('ISSBCK', KISBCK, NUMEL)
275 CALL MDRSRV ('NSSFRO', KNSFRO, NLNK*NUMEL)
276 CALL MDRSRV ('NSSBCK', KNSBCK, NLNK*NUMEL)
277 ELSE
278 KISFRO = 1
279 KISBCK = 1
280 KNSFRO = 1
281 KNSBCK = 1
282 END IF
283
284 LESSEO = INTADD (NUMESS, IA(KNESS))
285 LESSNO = INTADD (NUMESS, IA(KNDSS))
286
287 CALL NEWESS
288 & (IDESET(0,1), IDESET(0,2), NSSUR, NLNK,
289 & IA(KLINK), IA(KISFRO), IA(KISBCK), IA(KNSFRO), IA(KNSBCK))
290
291 IF (NSSET .GT. 0) THEN
292 CALL MDLONG ('NSSFRO', KNSFRO, NSSUR)
293 CALL MDLONG ('NSSBCK', KNSBCK, NSSUR)
294 END IF
295 CALL MDSTAT (NERR, MEM)
296 IF (NERR .GT. 0) GOTO 40
297
298 C --Open the output database
299 FILOUT = ' '
300 CALL get_argument(2,FILOUT, LFIL)
301 CMPSIZ = 0
302 IOWS = iowdsz()
303 ndbout = excre(filout(:lfil), EXCLOB, CMPSIZ, IOWS, IERR)
304 if (ierr .lt. 0) then
305 call exopts (EXVRBS, ierr)
306 call exerr('grepos', 'Error from excre', ierr)
307 go to 50
308 endif
309
310 C --Write the initial variables
311
312 CALL NEWINI (IDNSET(0,1)+IDNSET(0,2), IDESET(0,1)+IDESET(0,2),
313 & NSSUR, IA(KNATR))
314 call expini (ndbout, title, ndim3, numnp3, numel3, nelbl3,
315 & nnps3, ness3, ierr)
316
317 CALL DBPINI ('NTIS', NDBOUT, TITLE, NDIM3, NUMNP3, NUMEL3, NELBL3,
318 & NNPS3, LNPSN3, LNPSN3, NESS3, LESSE3, LESSN3, LESSN3,
319 & IDUM, IDUM, IDUM)
320
321 C --Write the coordinates
322
323 CALL MDRSRV ('XN3', KXN3, NUMNP3)
324 CALL MDRSRV ('YN3', KYN3, NUMNP3)
325 CALL MDRSRV ('ZN3', KZN3, NUMNP3)
326
327 C -- Since we only read quads, NUMATR should be 0. For a shell, we
328 C have 1 attribute (thickness)
329
330 CALL MDLONG ('ATRIB', KATRIB, NUMEL3)
331
332 CALL MDSTAT (NERR, MEM)
333 IF (NERR .GT. 0) GOTO 40
334
335 CALL NEWXYZ (A(KXN), A(KYN), A(KXN3), A(KYN3), A(KZN3),
336 $ A(KATRIB), A )
337 call expcor (ndbout, a(kxn3), a(kyn3), a(kzn3), ierr)
338
339 NAMECO(1) = 'X'
340 NAMECO(2) = 'Y'
341 NAMECO(3) = 'Z'
342 call expcon(ndbout, nameco, ierr)
343
344 CALL MDDEL ('XN')
345 CALL MDDEL ('YN')
346 CALL MDDEL ('XN3')
347 CALL MDDEL ('YN3')
348 CALL MDDEL ('ZN3')
349 CALL MDSTAT (NERR, MEM)
350 IF (NERR .GT. 0) GOTO 40
351
352 C --Write the element order map - NOTE: New map is same as old map
353 call expmap (ndbout, ia(kmapel), ierr)
354 CALL MDDEL ('MAPEL')
355
356 C --Fixup connectivity if mirrored
357 IF (XMIRR * YMIRR * ZMIRR .LT. 0.0) THEN
358 CALL DBMIRR (1, NELBLK, IA(KIDELB), IA(KNELB),
359 $ IA(KNLNK), IA(KLINK))
360 END IF
361 C --Write the element block
362
363 ILOFF = 0
364 IAOFF = 0
365 DO 30 I = 1, NELBLK
366 C ... Calculate these here since values may change if BEAM...
367 II = I - 1
368 ILINC = IA(KNELB+II) * IA(KNLNK+II)
369 IAINC = IA(KNELB+II) * IA(KNATR+II)
370 IF (NAMELB(I)(:4) .EQ. 'QUAD' .OR. NAMELB(I) .EQ. ' ') THEN
371 NAMELB(I) = 'SHELL'
372 ELSE IF (NAMELB(I)(:4) .EQ. 'BEAM') THEN
373 IA(KNATR+I-1) = 7
374 ELSE
375 CALL PRTERR ('CMDWARN',
376 $ 'Invalid Element Block Type')
377 END IF
378 CALL DBOELB (A, NDBOUT, IA(KIDELB+II), IA(KNELB+II),
379 $ IA(KNLNK+II), IA(KNATR+II), IA(KLINK+ILOFF),
380 * NAMELB(I), A(KATRIB), A(KELATT+(II*7)))
381 ILOFF = ILOFF + ILINC
382 IAOFF = IAOFF + IAINC
383
384 30 CONTINUE
385
386 CALL MDDEL ('LINK')
387 CALL MDDEL ('ATRIB')
388 CALL MDSTAT (NERR, MEM)
389 IF (NERR .GT. 0) GOTO 40
390
391 C --Write the node sets
392
393 CALL WRNPS (A, IA, IDNSET(0,1), IDNSET(0,2), IA(KIDNS),
394 & IA(KNNNS), IA(KIXNNS), IA(KLTNNS), A(KFACNS), *40)
395
396 C --Fixup sides sets if mirrored
397 c$$$ IF (XMIRR * YMIRR * ZMIRR .LT. 0.0) THEN
398 c$$$ CALL MIRSS (IDESET(0,1), IDESET(0,2), NLNK,
399 c$$$ & NSSUR, IA(KNSFRO), IA(KNSBCK), IA(KLTSSS))
400 c$$$ END IF
401 C --Write the side sets
402
403 CALL WRESS (A, IA, IDESET(0,1), IDESET(0,2),
404 & IA(KISFRO), IA(KISBCK), NSSUR, IA(KNSFRO), IA(KNSBCK),
405 & IA(KIDSS), IA(KNESS), IA(KNDSS), IA(KIXESS), IA(KIXDSS),
406 & IA(KLTESS), IA(KLTSSS), A(KFACSS), *40)
407
408 IF (NSSET .GT. 0) THEN
409 CALL MDDEL ('ISSFRO')
410 CALL MDDEL ('ISSBCK')
411 CALL MDDEL ('NSSFRO')
412 CALL MDDEL ('NSSBCK')
413 END IF
414 CALL MDSTAT (NERR, MEM)
415 IF (NERR .GT. 0) GOTO 40
416
417 C --Write the QA records
418 CALL DBOQA (NDBOUT, QAINFO, NQAREC, c(kqarec),
419 & NINFO, c(kinfo), ' GenShell: ', FILIN)
420
421 GOTO 50
422
423 40 CONTINUE
424 CALL MEMERR
425 GOTO 50
426
427 50 CONTINUE
428 call mdfree()
429 call exclos(ndbin, ierr)
430 call exclos(ndbout, ierr)
431
432 60 CONTINUE
433 call addlog (QAINFO(1)(:lenstr(QAINFO(1))))
434 CALL WRAPUP (QAINFO(1))
435
436 END
437
438 subroutine exgqaw(ndb, qarec, ierr)
439 include 'exodusII.inc'
440 character*(mxstln) qarec(4, *)
441 call exgqa(ndb, qarec, ierr)
442 return
443 end
444
445 subroutine exginw(ndb, info, ierr)
446 include 'exodusII.inc'
447 character*(mxlnln) info(*)
448 call exginf(ndb, info, ierr)
449 return
450 end