Debian Codegraph @

packages/seacas/applications/explore/explore.f

raw
1 C Copyright(C) 1999-2025 National Technology & Engineering Solutions
2 C of Sandia, LLC (NTESS). Under the terms of Contract DE-NA0003525 with
3 C NTESS, the U.S. Government retains certain rights in this software.
4 C
5 C See packages/seacas/LICENSE for details
6 C=======================================================================
7 PROGRAM EXPLORE
8 C=======================================================================
9
10 C *** EXPLORE 2.00 ***
11
12 C --*** EXPLORE *** (EXPLORE) GENESIS/EXODUS database examination program
13 C --
14 C --EXPLORE is a post-processing program to examine the output of a
15 C --finite element analysis, which is in the GENESIS or EXODUS database
16 C --format. EXPLORE allows the user to examine any values in the database.
17 C --The display can be directed to the CRT or to a print file.
18 C --
19 C --Expected input:
20 C -- o The commands on the standard input device.
21 C -- o The GENESIS/EXODUS database on unit 11.
22 C --
23 C --Output:
24 C -- o A listing of the input database information and any errors
25 C -- found on the standard output device.
26 C -- o A print file of requested information on unit 20.
27
28 C --Developed at Sandia National Laboratories.
29 C --
30 C --Source is in FORTRAN 77
31 C --
32 C --External software used:
33 C -- SUPES package (dynamic memory, free-field reader, FORTRAN extensions)
34 C --
35 C --Documentation:
36 C -- "User's Manual for EXPLORE"
37
38 include 'exodusII.inc'
39 include 'exp_progqa.blk'
40 include 'exp_outfil.blk'
41 include 'exp_dbase.blk'
42 include 'exp_dbtitl.blk'
43 include 'exp_dbnums.blk'
44 include 'argparse.inc'
45
46 C --A - the dynamic numeric memory base array
47 DIMENSION A(1)
48 INTEGER IA(1)
49 EQUIVALENCE (A(1), IA(1))
50 CHARACTER*1 C(1)
51
52 CHARACTER*2048 DBNAME
53 CHARACTER*2048 SCRATCH
54 C --DBNAME - the database name, needed because the database may be closed
55 character*256 option, value
56
57 LOGICAL EXODUS
58 C --EXODUS - true iff EXODUS file versus GENESIS file
59 LOGICAL MAPND, MAPEL
60
61 LOGICAL ISEOF
62 LOGICAL CHECK
63 CHARACTER*1 cdum
64
65 include 'exp_qainfo.blk'
66 CALL STRTUP (QAINFO)
67
68 C --Set up the print file
69
70 NCRT = -1
71 NOUT = NCRT
72 NPRT = 20
73 ANYPRT = .FALSE.
74
75 C --Print banner to CRT and print file
76
77 CALL BANNER (0, QAINFO,
78 & 'A GENESIS/EXODUS DATABASE EXPLORATION PROGRAM',
79 & ' ', ' ')
80
81 call cpyrgt (0, "2008")
82
83 C --Open the database
84
85 NDB = 11
86
87 CMPSIZ = 0
88 IOWS = 0
89 DBNAME = ' '
90
91 C .. Get filename from command line. If not specified, emit error message
92 NARG = argument_count()
93 if (narg .eq. 0) then
94 CALL PRTERR ('FATAL', 'Filename not specified.')
95 CALL PRTERR ('CMDSPEC',
96 * 'Syntax is: "explore [-[no]map node|element|all]' //
97 $ ' [-change_set #] filename"')
98 CALL PRTERR ('CMDSPEC',
99 * 'Documentation: https://sandialabs.github.io' //
100 $ '/seacas-docs/sphinx/html/index.html#explore')
101 GOTO 120
102 end if
103
104 CALL get_argument(narg,DBNAME, LNAM)
105 NDB = exopen(dbname(:lnam), EXREAD, CMPSIZ, IOWS, vers, IERR)
106 IF (IERR .NE. 0) THEN
107 SCRATCH = 'Database "'//DBNAME(:LNAM)//'" does not exist.'
108 CALL PRTERR ('FATAL', SCRATCH(:LENSTR(SCRATCH)))
109 GOTO 120
110 END IF
111
112 CALL EXOPTS(EXVRBS,IERR)
113
114 C ... By default, ultimately map both nodes and elements
115 C HOWEVER, in the transition time do not map either unless requested...
116 mapel = .false.
117 mapnd = .false.
118 check = .false.
119
120 if (narg .gt. 1) then
121 do i=1, narg-1, 2
122 CALL get_argument(i+0,option, lo)
123 CALL get_argument(i+1,value, lv)
124 if (option(:lo) .eq. '-nomap' .or.
125 * option(:lo) .eq. '--nomap') then
126 if (value(1:1) .eq. 'n' .or. value(1:1) .eq. 'N')
127 * mapnd = .false.
128 if (value(1:1) .eq. 'e' .or. value(1:1) .eq. 'E')
129 * mapel = .false.
130 if (value(1:1) .eq. 'a' .or. value(1:1) .eq. 'A') then
131 mapnd = .false.
132 mapel = .false.
133 end if
134 else if (option(:lo) .eq. '-map' .or.
135 * option(:lo) .eq. '--map') then
136 if (value(1:1) .eq. 'n' .or. value(1:1) .eq. 'N')
137 * mapnd = .true.
138 if (value(1:1) .eq. 'e' .or. value(1:1) .eq. 'E')
139 * mapel = .true.
140 if (value(1:1) .eq. 'a' .or. value(1:1) .eq. 'A') then
141 mapnd = .true.
142 mapel = .true.
143 end if
144 else if (option(:lo) .eq. '-check' .or.
145 * option(:lo) .eq. '--check') then
146 check = .TRUE.
147 else if (option(:lo) .eq. '-change_set' .or.
148 * option(:lo) .eq. '--change_set') then
149 C ... Convert `value` to an integer.
150 read (value(:lv), '(i10)') nchange
151 C ... Check that file contains at least that many change sets...
152 ndbr = iand(ndb, EX_FILE_ID_MASK)
153 call exinq(ndbr, EX_INQ_NUM_CHILD_GROUPS,
154 $ idum, rdum, cdum, ierr)
155 if (nchange .gt. idum) then
156 write (SCRATCH,*) 'Selected change set', nchange,
157 $ 'but there are only ', idum, ' change sets in file.'
158 call sqzstr(scratch, lscratch)
159 call PRTERR('CMDERR', SCRATCH(:LSCRATCH))
160 goto 110
161 else
162 ndb = ndbr + nchange
163 write (scratch,99) nchange
164 99 format(1x,'NOTE: Selecting change set ', i3)
165 call sqzstr(scratch, lscratch)
166 call PRTERR('CMDSPEC', scratch(:lscratch))
167 end if
168 end if
169 end do
170 end if
171
172 write (*,9999)
173 9999 FORMAT(/,
174 * 1x,'NOTE: This version has the option to use global',
175 * ' ids for both node and element ids.',/,
176 * 1x,' To see the mapping from local to global, use',
177 * ' the commands:',/,
178 * 1x,' "LIST MAP" (element map), or ',
179 * '"LIST NODEMAP" (node map)',/,
180 * 1x,' To disable the maps and use local ids, restart',
181 * ' explore with "-nomap node|element|all"',//,
182 * 1x,' To enable the maps and use global ids, restart',
183 * ' explore with "-map node|element|all"',//,
184 * 1x,' Notify [email protected] if bugs found')
185
186 if (mapel .and. mapnd) then
187 WRITE (*, 10010) 'Nodes and Elements using Global Ids'
188 else if (mapel) then
189 WRITE (*, 10010) 'Elements use Global Ids, Node Ids are Local'
190 else if (mapnd) then
191 WRITE (*, 10010) 'Element use Local Ids, Node Ids are Global'
192 else
193 WRITE (*, 10010) 'Nodes and Elements using Local Ids'
194 end if
195 10010 FORMAT (/, 1X, 5A)
196
197 C --Initialize dynamic memory
198 CALL MDINIT (A)
199 CALL MCINIT (C)
200 CALL MDSTAT (NERR, MEM)
201 IF (NERR .GT. 0) GOTO 100
202
203 C --Read the initial variables
204 call exgini(ndb, title, ndim, numnp, numel, nelblk,
205 * numnps, numess, ierr)
206 IF (IERR .NE. 0) GOTO 110
207 if (numnps .gt. 0) then
208 call exinq(ndb, EXNSNL, lnpsnl, rdum, cdum, ierr)
209 IF (IERR .NE. 0) GOTO 110
210 call exinq(ndb, EXNSDF, lnpsdf, rdum, cdum, ierr)
211 IF (IERR .NE. 0) GOTO 110
212 else
213 lnpsnl = 0
214 lnpsdf = 0
215 end if
216 if (numess .gt. 0) then
217 call exinq(ndb, EXSSNL, lessnl, rdum, cdum, ierr)
218 IF (IERR .NE. 0) GOTO 110
219 call exinq(ndb, EXSSEL, lessel, rdum, cdum, ierr)
220 IF (IERR .NE. 0) GOTO 110
221 call exinq(ndb, EXSSDF, lessdf, rdum, cdum, ierr)
222 IF (IERR .NE. 0) GOTO 110
223 else
224 lessnl = 0
225 lessel = 0
226 lessdf = 0
227 end if
228
229 call exinq(ndb, EXDBMXUSNM, namlen, rdum, cdum, ierr)
230 IF (IERR .NE. 0) GOTO 110
231 call exmxnm(ndb, namlen, ierr)
232 IF (IERR .NE. 0) GOTO 110
233
234 CALL PRINIT ('NTISC', NOUT, DBNAME, TITLE,
235 & NDIM, NUMNP, NUMEL, NELBLK,
236 & NUMNPS, LNPSNL, lnpsdf, NUMESS, LESSEL, LESSNL, LESSDF,
237 & NVARGL, NVARNP, NVAREL, NVARNS, NVARSS)
238
239 C ... See if there are any timesteps on the database (is EXODUS)
240 call exinq (ndb, EXTIMS, NSTEPS, rdum, cdum, ierr)
241 IF (IERR .NE. 0) GOTO 110
242 EXODUS = (NSTEPS .gt. 0)
243
244 if (EXODUS) THEN
245 CALL EXGVP (NDB,"G",NVARGL,IERR)
246 IF (IERR .NE. 0) GOTO 110
247 CALL EXGVP (NDB,"E",NVAREL,IERR)
248 IF (IERR .NE. 0) GOTO 110
249 CALL EXGVP (NDB,"N",NVARNP,IERR)
250 IF (IERR .NE. 0) GOTO 110
251 CALL EXGVP (NDB,"M",NVARNS,IERR)
252 IF (IERR .NE. 0) GOTO 110
253 CALL EXGVP (NDB,"S",NVARSS,IERR)
254 IF (IERR .NE. 0) GOTO 110
255
256 CALL PRINIT ('V', NOUT, DBNAME, TITLE,
257 & NDIM, NUMNP, NUMEL, NELBLK,
258 & NUMNPS, LNPSNL, lnpsdf, NUMESS, LESSEL, LESSNL, LESSDF,
259 & NVARGL, NVARNP, NVAREL, NVARNS, NVARSS)
260 END IF
261 CALL SETPRC(4,0)
262
263 C ... Read coordinate data
264 CALL MDRSRV ('CORD', KCORD, NUMNP * NDIM)
265 CALL MCRSRV ('NAMECO', KNMCO, NAMLEN*NDIM)
266 CALL MDSTAT (NERR, MEM)
267 IF (NERR .GT. 0) GOTO 100
268 CALL RDCORD (NDB, NDIM, NUMNP, A(KCORD), C(KNMCO), ISEOF, NAMLEN)
269
270 C ... Read element map
271 CALL MDRSRV ('MAPEL', KMAPEL, NUMEL)
272 if (mapel) then
273 kdbmapel = kmapel
274 else
275 call mdrsrv ('DBMAPEL', kdbmapel, numel)
276 endif
277 CALL MDSTAT (NERR, MEM)
278 IF (NERR .GT. 0) GOTO 100
279 if (mapel) then
280 CALL RDMAP (NDB, NUMEL, IA(KMAPEL), ISEOF)
281 else
282 CALL RDMAP (NDB, NUMEL, IA(KdbMAPEL), ISEOF)
283 call iniseq(numel, ia(kmapel))
284 end if
285
286 C ... Read node map
287 CALL MDRSRV ('MAPNO', KMAPNO, NUMNP)
288 if (mapnd) then
289 kdbmapno = kmapno
290 else
291 call mdrsrv ('DBMAPNO', kdbmapno, numnp)
292 endif
293 CALL MDSTAT (NERR, MEM)
294 IF (NERR .GT. 0) GOTO 100
295 if (mapnd) then
296 CALL RDNMAP (NDB, NUMNP, IA(KMAPNO), ISEOF)
297 else
298 CALL RDNMAP (NDB, NUMNP, IA(KDBMAPNO), ISEOF)
299 call iniseq(numnp, ia(kmapno))
300 end if
301
302 C ... Read element blocks
303 CALL MDRSRV ('IDELB', KIDELB, NELBLK)
304 CALL MDRSRV ('NUMELB', KNELB, NELBLK)
305 CALL MDRSRV ('NUMLNK', KNLNK, NELBLK)
306 CALL MDRSRV ('NUMATR', KNATR, NELBLK)
307 CALL MDRSRV ('LENE', KLENE, 1+NELBLK)
308 CALL MCRSRV ('EBTYPE', KNMLB, MXSTLN*NELBLK)
309 CALL MCRSRV ('EBNAME', KNMEB, NAMLEN*NELBLK)
310 CALL MDSTAT (NERR, MEM)
311 IF (NERR .GT. 0) GOTO 100
312 CALL RDELB (NDB, NELBLK,
313 & A(KIDELB), A(KNELB), A(KNLNK), A(KNATR),
314 & A, C, KLINK, KATRIB, KATRNM, ISEOF, C(KNMLB), C(KNMEB),
315 & NAMLEN)
316 CALL MDSTAT (NERR, MEM)
317 IF (NERR .GT. 0) GOTO 100
318
319 C ... If NELBLK .gt. 0 and NUMEL .eq. 0, then
320 C possible reading an experimental exodus file
321 C containing only results data...
322 C Calculate NUMEL based on NUMELB entries.
323 if (NELBLK .gt. 0 .and. NUMEL .eq. 0) then
324 do i=1, NELBLK
325 numel = numel + IA(KNELB+I-1)
326 end do
327 end if
328
329 C ... Read nodesets
330 CALL MDRSRV ('IDNPS', KIDNS, NUMNPS)
331 CALL MDRSRV ('NNNPS', KNNNS, NUMNPS)
332 CALL MDRSRV ('NDNPS', KNDNPS, NUMNPS)
333 CALL MDRSRV ('IXNNPS', KIXNNS, NUMNPS)
334 CALL MDRSRV ('IXDNPS', KIXDNS, NUMNPS)
335 CALL MDRSRV ('LTNNPS', KLTNNS, LNPSNL)
336 CALL MDRSRV ('FACNPS', KFACNS, LNPSNL)
337 CALL MCRSRV ('NSNAME', KNMNS, NAMLEN*NUMNPS)
338 CALL MDSTAT (NERR, MEM)
339 IF (NERR .GT. 0) GOTO 100
340 CALL RDNPS (NDB, NUMNPS, LNPSNL,
341 & A(KIDNS), A(KNNNS), A(KNDNPS), A(KIXNNS), A(KIXDNS),
342 & A(KLTNNS), A(KFACNS), C(KNMNS), ISEOF, NAMLEN)
343
344 C ... Read sidesets
345 CALL MDRSRV ('IDESS', KIDSS, NUMESS)
346 CALL MDRSRV ('NEESS', KNESS, NUMESS)
347 CALL MDRSRV ('NDESS', KNDSS, NUMESS)
348 CALL MDRSRV ('IXEESS', KIXESS, NUMESS)
349 CALL MDRSRV ('IXDESS', KIXNSS, NUMESS)
350 CALL MDRSRV ('LTEESS', KLTESS, LESSEL)
351 CALL MDRSRV ('LTSESS', KLTSSS, LESSEL)
352 CALL MDRSRV ('FACESS', KFACSS, LESSDF)
353 CALL MCRSRV ('SSNAME', KNMSS, NAMLEN*NUMESS)
354 CALL MDSTAT (NERR, MEM)
355 IF (NERR .GT. 0) GOTO 100
356
357 CALL RDESS (NDB, NUMESS, LESSEL, LESSDF,
358 & A(KIDSS), A(KNESS), A(KNDSS), A(KIXESS), A(KIXNSS),
359 & A(KLTESS), A(KLTSSS), A(KFACSS), C(KNMSS), ISEOF,
360 & NAMLEN)
361
362 C ... Read QA Information
363 CALL RDQA (NDB, NQAREC, NINFO, KQAREC, KINFO, C)
364
365 if (exodus) then
366 C ... Read variable names and truth table
367 CALL RDNAME (A, C, NDB, KVNAMI, KVNAMO,
368 & IXGV, IXNV, IXEV, IXNS, IXSS,
369 & KIEVOK, KNSVOK, KSSVOK)
370
371 C ... Read in the times for all the time steps from the database
372 call mdrsrv('TIMES', KTIMES, NSTEPS)
373 CALL RDTIMS (NDB, A(KTIMES))
374
375 WRITE (*, *)
376 IF (NSTEPS .GT. 0) THEN
377 WRITE (*, 10000, IOSTAT=IDUM) NSTEPS
378 10000 FORMAT (1X, 'Number of time steps on the database =', I12)
379 END IF
380
381 C ... Get the memory for the variables
382 CALL MDRSRV ('VARGL', KVARGL, NVARGL)
383 CALL MDRSRV ('VARNP', KVARNP, NVARNP * NUMNP)
384 CALL MDRSRV ('VAREL', KVAREL, NVAREL * NUMEL)
385 CALL MDRSRV ('VARNS', KVARNS, NVARNS * LNPSNL)
386 CALL MDRSRV ('VARSS', KVARSS, NVARSS * LESSEL)
387
388 ELSE
389 NSTEPS = 0
390 KVARGL = 1
391 KVARNP = 1
392 KVAREL = 1
393 KVARNS = 1
394 KVARSS = 1
395 END IF
396
397 C --Get the memory for the logical arrays
398
399 CALL MDRSRV ('LISNP', KLISNP, 1+NUMNP)
400 CALL MDRSRV ('NLISEL', KNLISE, 1+NELBLK)
401 CALL MDRSRV ('LISEL', KLISEL, 1+NUMEL)
402 CALL MDRSRV ('LISBEL', KLISBE, 1+NUMEL)
403 CALL MDRSRV ('LISNPS', KLISNS, 1+NUMNPS)
404 CALL MDRSRV ('LISESS', KLISSS, 1+NUMESS)
405 IF (EXODUS) THEN
406 CALL MDRSRV ('LISGV', KLISGV, 1+NVARGL)
407 CALL MDRSRV ('LISNV', KLISNV, 1+NVARNP)
408 CALL MDRSRV ('LISEV', KLISEV, 1+NVAREL)
409 CALL MDRSRV ('LISMV', KLISMV, 1+NVARNS)
410 CALL MDRSRV ('LISSV', KLISSV, 1+NVARSS)
411 ELSE
412 KLISGV = 1
413 KLISNV = 1
414 KLISEV = 1
415 KLISMV = 1
416 KLISSV = 1
417 END IF
418
419 CALL MDSTAT (NERR, MEM)
420 IF (NERR .GT. 0) GOTO 100
421
422 C --Process commands
423
424 CALL COMAND (A, IA, EXODUS, DBNAME, C(KQAREC), C(KINFO),
425 & C(KNMCO), C(KNMLB), C(KNMEB),C(KATRNM),
426 & C(KVNAMI+NAMLEN*(IXGV-1)), C(KVNAMI+NAMLEN*(IXNV-1)),
427 & C(KVNAMI+NAMLEN*(IXEV-1)), C(KVNAMI+NAMLEN*(IXNS-1)),
428 $ C(KVNAMI+NAMLEN*(IXSS-1)),
429 & C(KVNAMO+NAMLEN*(IXGV-1)), C(KVNAMO+NAMLEN*(IXNV-1)),
430 & C(KVNAMO+NAMLEN*(IXEV-1)), C(KVNAMO+NAMLEN*(IXNS-1)),
431 $ C(KVNAMO+NAMLEN*(IXSS-1)), A(KCORD),
432 * IA(KMAPEL), IA(KDBMAPEL), IA(KMAPNO), IA(KDBMAPNO),
433 * mapnd, mapel, check,
434 & A(KIDELB), A(KNELB), A(KLENE), A(KNLNK), A(KNATR),
435 & A(KLINK), A(KATRIB),
436 & A(KIDNS), A(KNNNS), A(KNDNPS), A(KIXNNS), A(KIXDNS),
437 $ A(KLTNNS), A(KFACNS), C(KNMNS),
438 & A(KIDSS), A(KNESS), A(KNDSS), A(KIXESS), A(KIXNSS),
439 & A(KLTESS), A(KLTSSS), A(KFACSS), C(KNMSS),
440 & A(KIEVOK), A(KNSVOK), A(KSSVOK), A(KTIMES),
441 & A(KVARGL), A(KVARNP), A(KVAREL), A(KVARNS), A(KVARSS),
442 & A(KLISNP), A(KNLISE), A(KLISEL), A(KLISNS), A(KLISSS),
443 & A(KLISGV), A(KLISNV), A(KLISEV), A(KLISMV), A(KLISSV))
444
445 CALL MDSTAT (NERR, MEM)
446 IF (NERR .GT. 0) GOTO 100
447
448
449 GOTO 110
450
451 100 CONTINUE
452 CALL MEMERR
453 GOTO 110
454
455 110 CONTINUE
456
457 call mdfree()
458 call exclos(ndb, ierr)
459
460 120 CONTINUE
461 IF (ANYPRT) CLOSE (NPRT, IOSTAT=IDUM)
462
463 call addlog (QAINFO(1)(:lenstr(QAINFO(1))))
464 CALL WRAPUP (QAINFO(1))
465
466 END