Debian Codegraph @

packages/seacas/applications/explore/exp_prelb.f

raw
1 C Copyright(C) 1999-2020 National Technology & Engineering Solutions
2 C of Sandia, LLC (NTESS). Under the terms of Contract DE-NA0003525 with
3 C NTESS, the U.S. Government retains certain rights in this software.
4 C
5 C See packages/seacas/LICENSE for details
6 C=======================================================================
7 SUBROUTINE PRELB (OPTION, NOUT, NELBLK, NLISEL, LISEL,
8 & IDELB, LENE, NUMLNK, NUMATR, LINK, ATRIB,
9 & EBTYPE, EBNAME, NVAREL, NAMEEV, ISEVOK, LISEV,
10 * ATNAME, MAPN, DOMAPN, MAPE, DOMAPE)
11 C=======================================================================
12
13 C --*** PRELB *** (BLOT) Display database element blocks
14 C --
15 C --PRELB displays the element blocks.
16 C --
17 C --Parameters:
18 C -- OPTION - IN - '*' to print all, else print options:
19 C -- ' ' to print block summary
20 C -- 'N' to print element block name
21 C -- 'V' to print element variable truth table
22 C -- 'C' to print connectivity
23 C -- 'A' to print attributes
24 C -- NOUT - IN - the output file, <=0 for standard
25 C -- NELBLK - IN - the number of element blocks
26 C -- NLISEL - IN - the number of selected elements by block
27 C -- LISEL - IN - the indices of the selected elements by block
28 C -- IDELB - IN - the element block ID for each block
29 C -- LENE - IN - the cumulative element counts by element block
30 C -- NUMLNK - IN - the number of nodes per element for each block
31 C -- NUMATR - IN - the number of attributes for each block
32 C -- LINK - IN - the connectivity array for all blocks
33 C -- ATRIB - IN - the attribute array for all blocks
34 C -- EBTYPE - IN - the names of the element block types
35 C -- NVAREL - IN - the number of element variables
36 C -- NAMEEV - IN - the names of the element variables
37 C -- ISEVOK - IN - the element block variable truth table;
38 C -- variable i of block j exists iff ISEVOK(i,j) is NOT 0
39 C -- LISEV - SCRATCH - size = NVAREL (if 'V' in OPTION)
40
41 include 'exodusII.inc'
42 CHARACTER*(*) OPTION
43 INTEGER NLISEL(0:NELBLK)
44 INTEGER LISEL(0:*)
45 INTEGER IDELB(*)
46 INTEGER LENE(0:NELBLK)
47 INTEGER NUMLNK(*)
48 INTEGER NUMATR(*)
49 INTEGER LINK(*)
50 REAL ATRIB(*)
51 CHARACTER*(MXSTLN) EBTYPE(*)
52 CHARACTER*(*) EBNAME(*)
53 CHARACTER*(*) NAMEEV(*)
54 CHARACTER*(*) ATNAME(*)
55 INTEGER ISEVOK(NVAREL,*)
56 INTEGER LISEV(*)
57 INTEGER MAPN(*), MAPE(*)
58 LOGICAL DOMAPN, DOMAPE
59 LOGICAL ISABRT
60 LOGICAL DONAM, DOVTBL, DOCONN, DOATR
61 LOGICAL BLK1
62 CHARACTER*40 STRA, STRB
63
64 DONAM = ((OPTION .EQ. '*') .OR. (INDEX (OPTION, 'N') .GT. 0))
65 DOVTBL = ((OPTION .EQ. '*') .OR. (INDEX (OPTION, 'V') .GT. 0))
66 DOCONN = ((OPTION .EQ. '*') .OR. (INDEX (OPTION, 'C') .GT. 0))
67 DOATR = ((OPTION .EQ. '*') .OR. (INDEX (OPTION, 'A') .GT. 0))
68
69 DONAM = .TRUE.
70 BLK1 = .TRUE.
71 IF (NOUT .GT. 0) THEN
72 IF (DOCONN .AND. DOATR) THEN
73 WRITE (NOUT, 10020) 'CONNECTIVITY and ATTRIBUTES'
74 ELSE IF (DOCONN) THEN
75 WRITE (NOUT, 10020) 'CONNECTIVITY'
76 ELSE IF (DOATR) THEN
77 WRITE (NOUT, 10020) 'ATTRIBUTES'
78 ELSE
79 WRITE (NOUT, 10020)
80 END IF
81 END IF
82
83 if (nout .gt. 0) then
84 if (domape) write (nout, 10060) 'Element'
85 if (domapn) write (nout, 10060) 'Nodal'
86 else
87 if (domape) write (*, 10060) 'Element'
88 if (domapn) write (*, 10060) 'Nodal'
89 end if
90
91 WRITE (STRA, 10000, IOSTAT=IDUM) NELBLK
92 10000 FORMAT ('(#', I12, ')')
93 CALL PCKSTR (1, STRA)
94 LSTRA = LENSTR (STRA)
95 WRITE (STRB, 10010, IOSTAT=IDUM) LENE(NELBLK), LENE(NELBLK)
96 10010 FORMAT ('(', I12, '..', I12, ')')
97 CALL PCKSTR (1, STRB)
98 LSTRB = LENSTR (STRB)
99
100 ISLNK = 1
101 ISATR = 1
102 ISATN = 1
103
104 DO 110 IELB = 1, NELBLK
105 NUME = LENE(IELB) - LENE(IELB-1)
106 if (ebtype(ielb) .eq. 'nsided' .or.
107 * ebtype(ielb) .eq. 'NSIDED') THEN
108 numnod = numlnk(ielb)
109 else
110 numnod = numlnk(ielb)*nume
111 end if
112 IF (ISABRT ()) RETURN
113 IF (NLISEL(IELB) .GT. 0) THEN
114 IEL = LENE(IELB-1)+1
115 LEL = LENE(IELB)
116
117 IF (BLK1 .OR. DOCONN .OR. DOATR) THEN
118 BLK1 = .FALSE.
119 IF (NOUT .GT. 0) THEN
120 WRITE (NOUT, *)
121 ELSE
122 WRITE (*, *)
123 END IF
124 END IF
125
126 WRITE (STRA, 10000, IOSTAT=IDUM) IELB
127 CALL PCKSTR (1, STRA)
128 WRITE (STRB, 10010, IOSTAT=IDUM) IEL, LEL
129 CALL PCKSTR (1, STRB)
130 IF (NOUT .GT. 0) THEN
131 WRITE (NOUT, 10030, IOSTAT=IDUM)
132 & IDELB(IELB), STRA(:LSTRA),
133 & NUME, STRB(:LSTRB), NUMLNK(IELB), NUMATR(IELB)
134 ELSE
135 WRITE (*, 10030, IOSTAT=IDUM)
136 & IDELB(IELB), STRA(:LSTRA),
137 & NUME, STRB(:LSTRB), NUMLNK(IELB), NUMATR(IELB)
138 END IF
139
140 IF (DONAM) THEN
141 LNAM = LENSTR(EBTYPE(IELB))
142 LNM = LENSTR(EBNAME(IELB))
143 IF (NOUT .GT. 0) THEN
144 WRITE (NOUT, 10040) EBNAME(IELB)(:LNM),
145 $ EBTYPE(IELB)(:LNAM)
146 ELSE
147 WRITE (*, 10040) EBNAME(IELB)(:LNM), EBTYPE(IELB)(:LNAM)
148 END IF
149 if (numatr(ielb) .gt. 0) then
150 mxnam = 0
151 DO I = 1, numatr(ielb)
152 LNAM = lenstr(atname(isatn+i-1))
153 mxnam = max(lnam, mxnam)
154 END DO
155 if (mxnam .gt. 1) then
156 IF (NOUT .GT. 0) THEN
157 WRITE (NOUT, 10090, IOSTAT=IDUM)
158 & (ATNAME(I)(:mxnam),
159 * I=ISATN,ISATN+NUMATR(IELB)-1)
160 ELSE
161 WRITE (*, 10090, IOSTAT=IDUM)
162 & (ATNAME(I)(:mxnam),
163 * I=ISATN,ISATN+NUMATR(IELB)-1)
164 END IF
165 end if
166 end if
167 END IF
168
169 IF (DOVTBL) THEN
170 NSEL = 0
171 mxnam = 0
172 DO 100 I = 1, NVAREL
173 IF (ISEVOK(I,IELB) .NE. 0) THEN
174 NSEL = NSEL + 1
175 LISEV(NSEL) = I
176 LNAM = lenstr(nameev(i))
177 mxnam = max(lnam, mxnam)
178 END IF
179 100 CONTINUE
180
181 IF (NOUT .GT. 0) THEN
182 if (mxnam .gt. 24) then
183 WRITE (NOUT, 10070, IOSTAT=IDUM)
184 & (NAMEEV(LISEV(I))(:mxnam), I=1,NSEL)
185 else
186 WRITE (NOUT, 10050, IOSTAT=IDUM)
187 & (NAMEEV(LISEV(I))(:mxnam), I=1,NSEL)
188 endif
189 write (nout, 10080)
190 ELSE
191 if (mxnam .gt. 24) then
192 WRITE (*, 10070, IOSTAT=IDUM)
193 & (NAMEEV(LISEV(I))(:mxnam), I=1,NSEL)
194 else
195 WRITE (*, 10050, IOSTAT=IDUM)
196 & (NAMEEV(LISEV(I))(:mxnam), I=1,NSEL)
197 endif
198 write (*, 10080)
199 END IF
200 END IF
201
202 IF (DOCONN .OR. DOATR) THEN
203 if (ebtype(ielb) .eq. 'nsided' .or.
204 * ebtype(ielb) .eq. 'NSIDED') THEN
205 CALL PREBN (OPTION, NOUT, IELB,
206 * nume, IDELB(IELB),
207 * IEL-1, NLISEL(IELB), LISEL(IEL),
208 * NUMATR(IELB),
209 & LINK(ISLNK), ATRIB(ISATR), max(1,numatr(ielb)),
210 * MAPN, DOMAPN, MAPE, DOMAPE)
211 else
212 CALL PREB1 (OPTION, NOUT, IEL-1,
213 & NLISEL(IELB), LISEL(IEL), NUMLNK(IELB), NUMATR(IELB),
214 & LINK(ISLNK), ATRIB(ISATR), max(1,numatr(ielb)),
215 * MAPN, DOMAPN, MAPE, DOMAPE)
216 end if
217 IF (ISABRT ()) RETURN
218 END IF
219 END IF
220
221 IF (DOCONN) ISLNK = ISLNK + numnod
222 IF (DOATR) ISATR = ISATR + NUME * NUMATR(IELB)
223 ISATN = ISATN + NUMATR(IELB)
224 110 CONTINUE
225
226 RETURN
227
228 10020 FORMAT (/, 1X, 'ELEMENT BLOCKS', :, ' - ', A)
229 C ... NOTE: Normal elements have a a mximum of <100 nodes, but superelements
230 C Or other "strange" elements may have lots of nodes; keep format high
231 10030 FORMAT (1X, 'Block', I12, 1X, A, ':',
232 & I12, ' elements', 1X, A,
233 & I6, '-node', I4, ' attributes')
234 10040 FORMAT (2X, 'Element block name = "',A
235 $ ,'", Element type = "', A, '"')
236 10050 FORMAT ((2x,4(2X, A)))
237 10060 FORMAT (1x, A, ' IDs are global')
238 10070 FORMAT ((2x,3(2X, A)))
239 10080 FORMAT (1X)
240 10090 FORMAT (2X, 'Attributes: ', 10(2X, A))
241 END