| 1 |
# @HEADER |
| 2 |
# ***************************************************************************** |
| 3 |
# TriBITS: Tribal Build, Integrate, and Test System |
| 4 |
# |
| 5 |
# Copyright 2013-2016 NTESS and the TriBITS contributors. |
| 6 |
# SPDX-License-Identifier: BSD-3-Clause |
| 7 |
# ***************************************************************************** |
| 8 |
# @HEADER |
| 9 |
|
| 10 |
|
| 11 |
# Standard TriBITS system includes |
| 12 |
include("${CMAKE_CURRENT_LIST_DIR}/../common/TribitsConstants.cmake") |
| 13 |
include(TribitsProcessExtraRepositoriesList) |
| 14 |
include(TribitsProcessPackagesAndDirsLists) |
| 15 |
include(TribitsProcessTplsLists) |
| 16 |
include(TribitsReadDepsFilesCreateDepsGraph) |
| 17 |
include(TribitsConfigureTiming) |
| 18 |
|
| 19 |
# Standard TriBITS utilities includes |
| 20 |
include(TimingUtils) |
| 21 |
|
| 22 |
|
| 23 |
# @MACRO: tribits_read_all_project_deps_files_create_deps_graph() |
| 24 |
# |
| 25 |
# Usage:: |
| 26 |
# |
| 27 |
# tribits_read_all_project_deps_files_create_deps_graph() |
| 28 |
# |
| 29 |
# Macro run at the top project-level scope that reads the lists of packages |
| 30 |
# and TPLs and creates the packages dependency graph. |
| 31 |
# |
| 32 |
# On output, this creates all of the package lists and dependency |
| 33 |
# data-structures described in the section `TriBITS System Data Structures`_ |
| 34 |
# and more specifically the sections: |
| 35 |
# |
| 36 |
# * `Lists of external and internal packages`_ |
| 37 |
# * `Variables defining the package dependencies graph`_ |
| 38 |
# * `TriBITS Package Top-Level Local Variables`_ |
| 39 |
# * `TriBITS Subpackage Top-Level Local Variables`_ |
| 40 |
# * `TriBITS Package Cache Variables`_ |
| 41 |
# |
| 42 |
# See `Function call tree for constructing package dependency graph`_. |
| 43 |
# |
| 44 |
macro(tribits_read_all_project_deps_files_create_deps_graph) |
| 45 |
|
| 46 |
tribits_config_code_start_timer(SET_UP_DEPENDENCIES_TIME_START_SECONDS) |
| 47 |
|
| 48 |
tribits_read_defined_external_and_internal_toplevel_packages_lists() |
| 49 |
|
| 50 |
tribits_read_deps_files_create_deps_graph() |
| 51 |
|
| 52 |
# ${PROJECT_NAME}_DEFINED_PACKAGES |
| 53 |
set(${PROJECT_NAME}_DEFINED_PACKAGES |
| 54 |
${${PROJECT_NAME}_DEFINED_TPLS} |
| 55 |
${${PROJECT_NAME}_DEFINED_INTERNAL_PACKAGES}) |
| 56 |
list(LENGTH ${PROJECT_NAME}_DEFINED_PACKAGES |
| 57 |
${PROJECT_NAME}_NUM_DEFINED_PACKAGES) |
| 58 |
|
| 59 |
tribits_config_code_stop_timer(SET_UP_DEPENDENCIES_TIME_START_SECONDS |
| 60 |
"\nTotal time to read in all dependencies files and build dependencies graph") |
| 61 |
|
| 62 |
endmacro() |
| 63 |
|
| 64 |
|
| 65 |
# @MACRO: tribits_read_defined_external_and_internal_toplevel_packages_lists() |
| 66 |
# |
| 67 |
# Usage:: |
| 68 |
# |
| 69 |
# tribits_read_defined_external_and_internal_toplevel_packages_lists() |
| 70 |
# |
| 71 |
# Macro run at the top project-level scope that reads in the contents of all |
| 72 |
# of the `<repoDir>/TPLsList.cmake`_ and `<repoDir>/PackagesList.cmake`_ files |
| 73 |
# to get the list of defined external packages (TPLs) and internal top-level |
| 74 |
# (TriBITS) packages. |
| 75 |
# |
| 76 |
# On output, this produces the local variables: |
| 77 |
# |
| 78 |
# * `${PROJECT_NAME}_DEFINED_TPLS`_ |
| 79 |
# * `${PROJECT_NAME}_DEFINED_INTERNAL_TOPLEVEL_PACKAGES`_ |
| 80 |
# * `${PROJECT_NAME}_DEFINED_TOPLEVEL_PACKAGES`_ |
| 81 |
# |
| 82 |
# and the length vars for these: |
| 83 |
# |
| 84 |
# * `${PROJECT_NAME}_NUM_DEFINED_TPLS`_ |
| 85 |
# * `${PROJECT_NAME}_NUM_DEFINED_INTERNAL_TOPLEVEL_PACKAGES`_ |
| 86 |
# * `${PROJECT_NAME}_NUM_DEFINED_TOPLEVEL_PACKAGES`_ |
| 87 |
# |
| 88 |
# This includes the files: |
| 89 |
# |
| 90 |
# * `<repoDir>/TPLsList.cmake`_ |
| 91 |
# * `<repoDir>/PackagesList.cmake`_ |
| 92 |
# |
| 93 |
# and calls the macros: |
| 94 |
# |
| 95 |
# * `tribits_process_tpls_lists()`_ |
| 96 |
# * `tribits_process_packages_and_dirs_lists()`_ |
| 97 |
# |
| 98 |
# which set their variables. |
| 99 |
# |
| 100 |
# See `Function call tree for constructing package dependency graph`_ |
| 101 |
# |
| 102 |
macro(tribits_read_defined_external_and_internal_toplevel_packages_lists) |
| 103 |
|
| 104 |
tribits_set_all_extra_repositories() |
| 105 |
|
| 106 |
# Set package list vars to empty |
| 107 |
set(${PROJECT_NAME}_DEFINED_TPLS "") |
| 108 |
set(${PROJECT_NAME}_DEFINED_INTERNAL_TOPLEVEL_PACKAGES "") |
| 109 |
|
| 110 |
# |
| 111 |
# A) Read list of external packages/TPLs and top-level internal packages |
| 112 |
# from 'PRE' extra repos |
| 113 |
# |
| 114 |
|
| 115 |
set(READ_PRE_OR_POST_EXRAREPOS PRE) |
| 116 |
tribits_read_extra_repositories_lists() |
| 117 |
|
| 118 |
# |
| 119 |
# B) Read list of external packages/TPLs and top-level internal packages |
| 120 |
# from the native repos |
| 121 |
# |
| 122 |
|
| 123 |
foreach(NATIVE_REPO ${${PROJECT_NAME}_NATIVE_REPOSITORIES}) |
| 124 |
|
| 125 |
tribits_get_repo_name_dir(${NATIVE_REPO} NATIVE_REPO_NAME NATIVE_REPO_DIR) |
| 126 |
#print_var(NATIVE_REPO_NAME) |
| 127 |
#print_var(NATIVE_REPO_DIR) |
| 128 |
|
| 129 |
# Need to make sure this gets set because logic in Dependencies.cmake files |
| 130 |
# looks for the presents of this variable. |
| 131 |
tribits_set_base_repo_dir(${PROJECT_SOURCE_DIR} ${NATIVE_REPO_DIR} |
| 132 |
${NATIVE_REPO_NAME}_SOURCE_DIR) |
| 133 |
#print_var(${NATIVE_REPO_NAME}_SOURCE_DIR) |
| 134 |
|
| 135 |
if (NATIVE_REPO STREQUAL ".") |
| 136 |
set(REPOSITORY_NAME ${PROJECT_NAME}) |
| 137 |
else() |
| 138 |
set(REPOSITORY_NAME ${NATIVE_REPO_NAME}) |
| 139 |
endif() |
| 140 |
|
| 141 |
# |
| 142 |
# B.1) Define the lists of all ${NATIVE_REPO_NAME} native packages and TPLs |
| 143 |
# |
| 144 |
|
| 145 |
# B.1.a) Read in the list of TPLs for this repo |
| 146 |
|
| 147 |
if (${NATIVE_REPO_NAME}_TPLS_FILE_OVERRIDE) |
| 148 |
if (IS_ABSOLUTE "${${NATIVE_REPO_NAME}_TPLS_FILE_OVERRIDE}") |
| 149 |
set(${NATIVE_REPO_NAME}_TPLS_FILE |
| 150 |
"${${NATIVE_REPO_NAME}_TPLS_FILE_OVERRIDE}") |
| 151 |
else() |
| 152 |
set(${NATIVE_REPO_NAME}_TPLS_FILE |
| 153 |
"${${NATIVE_REPO_NAME}_SOURCE_DIR}/${${NATIVE_REPO_NAME}_TPLS_FILE_OVERRIDE}") |
| 154 |
endif() |
| 155 |
else() |
| 156 |
set(${NATIVE_REPO_NAME}_TPLS_FILE |
| 157 |
"${${NATIVE_REPO_NAME}_SOURCE_DIR}/${${PROJECT_NAME}_TPLS_FILE_NAME}") |
| 158 |
endif() |
| 159 |
|
| 160 |
message("") |
| 161 |
message("Reading list of native TPLs from ${${NATIVE_REPO_NAME}_TPLS_FILE}") |
| 162 |
message("") |
| 163 |
|
| 164 |
tribits_trace_file_processing(REPOSITORY INCLUDE |
| 165 |
"${${NATIVE_REPO_NAME}_TPLS_FILE}") |
| 166 |
include(${${NATIVE_REPO_NAME}_TPLS_FILE}) |
| 167 |
tribits_process_tpls_lists(${NATIVE_REPO_NAME} ${NATIVE_REPO_DIR}) |
| 168 |
|
| 169 |
# B.1.b) Read in list of packages for this repo |
| 170 |
|
| 171 |
if (${NATIVE_REPO_NAME}_PACKAGES_FILE_OVERRIDE) |
| 172 |
if (IS_ABSOLUTE "${${NATIVE_REPO_NAME}_PACKAGES_FILE_OVERRIDE}") |
| 173 |
set(${NATIVE_REPO_NAME}_PACKAGES_FILE |
| 174 |
"${${NATIVE_REPO_NAME}_PACKAGES_FILE_OVERRIDE}") |
| 175 |
else() |
| 176 |
set(${NATIVE_REPO_NAME}_PACKAGES_FILE |
| 177 |
"${${NATIVE_REPO_NAME}_SOURCE_DIR}/${${NATIVE_REPO_NAME}_PACKAGES_FILE_OVERRIDE}") |
| 178 |
endif() |
| 179 |
else() |
| 180 |
set(${NATIVE_REPO_NAME}_PACKAGES_FILE |
| 181 |
"${${NATIVE_REPO_NAME}_SOURCE_DIR}/${${PROJECT_NAME}_PACKAGES_FILE_NAME}") |
| 182 |
endif() |
| 183 |
|
| 184 |
message("") |
| 185 |
message("Reading list of native packages from ${${NATIVE_REPO_NAME}_PACKAGES_FILE}") |
| 186 |
message("") |
| 187 |
|
| 188 |
tribits_trace_file_processing(REPOSITORY INCLUDE |
| 189 |
"${${NATIVE_REPO_NAME}_PACKAGES_FILE}") |
| 190 |
include(${${NATIVE_REPO_NAME}_PACKAGES_FILE}) |
| 191 |
|
| 192 |
tribits_process_packages_and_dirs_lists(${NATIVE_REPO_NAME} ${NATIVE_REPO_DIR}) |
| 193 |
|
| 194 |
endforeach() |
| 195 |
|
| 196 |
# |
| 197 |
# C) Read list of external packages/TPLs and top-level internal packages |
| 198 |
# from 'POST' extra repos |
| 199 |
# |
| 200 |
|
| 201 |
set(READ_PRE_OR_POST_EXRAREPOS POST) |
| 202 |
tribits_read_extra_repositories_lists() |
| 203 |
|
| 204 |
# |
| 205 |
# D) Compute lengths and other combined quantities |
| 206 |
# |
| 207 |
|
| 208 |
# ${PROJECT_NAME}_NUM_DEFINED_TPLS |
| 209 |
list(LENGTH ${PROJECT_NAME}_DEFINED_TPLS ${PROJECT_NAME}_NUM_DEFINED_TPLS) |
| 210 |
|
| 211 |
# ${PROJECT_NAME}_DEFINED_TOPLEVEL_PACKAGES |
| 212 |
set(${PROJECT_NAME}_DEFINED_TOPLEVEL_PACKAGES |
| 213 |
${${PROJECT_NAME}_DEFINED_TPLS} |
| 214 |
${${PROJECT_NAME}_DEFINED_INTERNAL_TOPLEVEL_PACKAGES}) |
| 215 |
list(LENGTH ${PROJECT_NAME}_DEFINED_TOPLEVEL_PACKAGES |
| 216 |
${PROJECT_NAME}_NUM_DEFINED_TOPLEVEL_PACKAGES) |
| 217 |
|
| 218 |
endmacro() |
| 219 |
|
| 220 |
|
| 221 |
# @FUNCTION: tribits_write_xml_dependency_files_if_supported() |
| 222 |
# |
| 223 |
# Usage:: |
| 224 |
# |
| 225 |
# tribits_write_xml_dependency_files_if_supported() |
| 226 |
# |
| 227 |
# Function that writes XML dependency files if support for that exists in this |
| 228 |
# instance of TriBITs. |
| 229 |
# |
| 230 |
# See `Function call tree for constructing package dependency graph`_ |
| 231 |
# |
| 232 |
function(tribits_write_xml_dependency_files_if_supported) |
| 233 |
set(TRIBITS_PROJECT_CI_SUPPORT_DIR |
| 234 |
"${${PROJECT_NAME}_TRIBITS_DIR}/${TRIBITS_CI_SUPPORT_DIR}") |
| 235 |
set(TRIBITS_DUMP_XML_DEPS_MODULE |
| 236 |
"${TRIBITS_PROJECT_CI_SUPPORT_DIR}/TribitsWriteXmlDependenciesFiles.cmake") |
| 237 |
if (EXISTS "${TRIBITS_DUMP_XML_DEPS_MODULE}") |
| 238 |
include(${TRIBITS_DUMP_XML_DEPS_MODULE}) |
| 239 |
tribits_write_xml_dependency_files() |
| 240 |
endif() |
| 241 |
endfunction() |
| 242 |
|
| 243 |
|
| 244 |
# Macro that sets ${PROJECT_NAME}_ALL_REPOSITORIES from |
| 245 |
# ${PROJECT_NAME}_PRE_REPOSITORIES and ${PROJECT_NAME}_EXTRA_REPOSITORIES if |
| 246 |
# it is not already set. Also, it replaces ',' with ';' in the latter. |
| 247 |
# |
| 248 |
# This function is needed in use cases where extra repos are used where the |
| 249 |
# extra repos are not read in through an ExtraRepositoriesList.cmake file and |
| 250 |
# instead are directly passed in by the user. |
| 251 |
# |
| 252 |
macro(tribits_set_all_extra_repositories) |
| 253 |
if ("${${PROJECT_NAME}_ALL_EXTRA_REPOSITORIES}" STREQUAL "") |
| 254 |
# Allow list to be separated by ',' instead of just by ';'. This is needed |
| 255 |
# by the unit test driver code |
| 256 |
split("${${PROJECT_NAME}_PRE_REPOSITORIES}" "," |
| 257 |
${PROJECT_NAME}_PRE_REPOSITORIES) |
| 258 |
split("${${PROJECT_NAME}_EXTRA_REPOSITORIES}" "," |
| 259 |
${PROJECT_NAME}_EXTRA_REPOSITORIES) |
| 260 |
set(${PROJECT_NAME}_ALL_EXTRA_REPOSITORIES |
| 261 |
${${PROJECT_NAME}_PRE_REPOSITORIES} ${${PROJECT_NAME}_EXTRA_REPOSITORIES}) |
| 262 |
endif() |
| 263 |
endmacro() |
| 264 |
|
| 265 |
|
| 266 |
# Macro that processes the list of package and TPLs for the set of 'PRE' or |
| 267 |
# 'POST' extra repos. |
| 268 |
# |
| 269 |
macro(tribits_read_extra_repositories_lists) |
| 270 |
|
| 271 |
list(LENGTH ${PROJECT_NAME}_PRE_REPOSITORIES PRE_EXTRAREPOS_LEN) |
| 272 |
list(LENGTH ${PROJECT_NAME}_EXTRA_REPOSITORIES POST_EXTRAREPOS_LEN) |
| 273 |
math(EXPR ALL_EXTRAREPOS_LEN "${PRE_EXTRAREPOS_LEN} + ${POST_EXTRAREPOS_LEN}") |
| 274 |
|
| 275 |
# See if processing 'PRE' or 'POST' extra repos |
| 276 |
if (READ_PRE_OR_POST_EXRAREPOS STREQUAL "PRE") |
| 277 |
set(EXTRAREPO_IDX_START 0) |
| 278 |
set(EXTRAREPO_IDX_END ${PRE_EXTRAREPOS_LEN}) |
| 279 |
elseif (READ_PRE_OR_POST_EXRAREPOS STREQUAL "POST") |
| 280 |
set(EXTRAREPO_IDX_START ${PRE_EXTRAREPOS_LEN}) |
| 281 |
set(EXTRAREPO_IDX_END ${ALL_EXTRAREPOS_LEN}) |
| 282 |
else() |
| 283 |
message(FATAL_ERROR "Invalid value for READ_PRE_OR_POST_EXRAREPOS='${READ_PRE_OR_POST_EXRAREPOS}' ") |
| 284 |
endif() |
| 285 |
# NOTE: For some reason, we can't pass this argument to the function and |
| 286 |
# have it read. Instead, we have to pass it a local variable. I will never |
| 287 |
# understand CMake. |
| 288 |
|
| 289 |
set(EXTRAREPO_IDX ${EXTRAREPO_IDX_START}) |
| 290 |
while(EXTRAREPO_IDX LESS EXTRAREPO_IDX_END) |
| 291 |
|
| 292 |
list(GET ${PROJECT_NAME}_ALL_EXTRA_REPOSITORIES ${EXTRAREPO_IDX} EXTRA_REPO ) |
| 293 |
set(REPOSITORY_NAME ${EXTRA_REPO}) |
| 294 |
|
| 295 |
#print_var(EXTRA_REPO) |
| 296 |
#print_var(EXTRAREPO_IDX) |
| 297 |
#print_var(${PROJECT_NAME}_ALL_EXTRA_REPOSITORIES_HASPKGS) |
| 298 |
|
| 299 |
# Need to make sure this gets set because logic in Dependencies.cmake files |
| 300 |
# looks for the presents of this variable. |
| 301 |
set(${EXTRA_REPO}_SOURCE_DIR "${PROJECT_SOURCE_DIR}/${EXTRA_REPO}") |
| 302 |
if (${PROJECT_NAME}_VERBOSE_CONFIGURE) |
| 303 |
print_var(${EXTRA_REPO}_SOURCE_DIR) |
| 304 |
endif() |
| 305 |
# ToDo: TriBITS:73: Get ${EXTRA_REPO}_SOURCE_DIR from |
| 306 |
# ${PROJECT_NAME}_ALL_EXTRA_REPOSITORIES_DIR when it exists. |
| 307 |
|
| 308 |
set(EXTRAREPO_PACKSTAT "") |
| 309 |
if (${PROJECT_NAME}_ALL_EXTRA_REPOSITORIES_HASPKGS) |
| 310 |
list(GET ${PROJECT_NAME}_ALL_EXTRA_REPOSITORIES_HASPKGS ${EXTRAREPO_IDX} |
| 311 |
EXTRAREPO_PACKSTAT ) |
| 312 |
endif() |
| 313 |
|
| 314 |
if (EXTRAREPO_PACKSTAT STREQUAL NOPACKAGES) |
| 315 |
|
| 316 |
message("") |
| 317 |
message("Skipping reading packages and TPLs for ${READ_PRE_OR_POST_EXRAREPOS} extra repo ${EXTRA_REPO} because marked NOPACKAGES ... ") |
| 318 |
message("") |
| 319 |
# ToDo: TriBITS:73: Don't print the above message by default. It is |
| 320 |
# just clutter. |
| 321 |
|
| 322 |
else() |
| 323 |
|
| 324 |
# Read in the add-on TPLs from the extra repo |
| 325 |
|
| 326 |
set(${EXTRA_REPO}_TPLS_FILE |
| 327 |
"${${EXTRA_REPO}_SOURCE_DIR}/${${PROJECT_NAME}_EXTRA_TPLS_FILE_NAME}") |
| 328 |
print_var(${EXTRA_REPO}_SOURCE_DIR) |
| 329 |
print_var(${PROJECT_NAME}_EXTRA_TPLS_FILE_NAME) |
| 330 |
print_var(${EXTRA_REPO}_TPLS_FILE) |
| 331 |
|
| 332 |
message("") |
| 333 |
message("Reading list of ${READ_PRE_OR_POST_EXRAREPOS} extra TPLs from ${${EXTRA_REPO}_TPLS_FILE} ... ") |
| 334 |
message("") |
| 335 |
|
| 336 |
if (NOT EXISTS "${${EXTRA_REPO}_TPLS_FILE}") |
| 337 |
if (${PROJECT_NAME}_IGNORE_MISSING_EXTRA_REPOSITORIES) |
| 338 |
message("-- " |
| 339 |
"NOTE: Ignoring missing ${READ_PRE_OR_POST_EXRAREPOS} extra repo '${EXTRA_REPO}' TPLs list file '${${EXTRA_REPO}_TPLS_FILE}' on request!" ) |
| 340 |
else() |
| 341 |
message( SEND_ERROR |
| 342 |
"ERROR: Skipping missing ${READ_PRE_OR_POST_EXRAREPOS} extra repo '${EXTRA_REPO}' TPLs list file '${${EXTRA_REPO}_TPLS_FILE}'!") |
| 343 |
endif() |
| 344 |
else() |
| 345 |
tribits_trace_file_processing(REPOSITORY INCLUDE "${${EXTRA_REPO}_TPLS_FILE}") |
| 346 |
include("${${EXTRA_REPO}_TPLS_FILE}") |
| 347 |
set(APPEND_TO_TPLS_LIST TRUE) |
| 348 |
tribits_process_tpls_lists(${EXTRA_REPO} ${EXTRA_REPO}) |
| 349 |
endif() |
| 350 |
|
| 351 |
# Read in the add-on packages from the extra repo |
| 352 |
|
| 353 |
#print_var(${EXTRA_REPO}_PACKAGES_LIST_FILE) |
| 354 |
if (${EXTRA_REPO}_PACKAGES_LIST_FILE) |
| 355 |
set(EXTRAREPO_PACKAGES_FILE |
| 356 |
"${PROJECT_SOURCE_DIR}/${${EXTRA_REPO}_PACKAGES_LIST_FILE}") |
| 357 |
else() |
| 358 |
set(EXTRAREPO_PACKAGES_FILE |
| 359 |
"${${EXTRA_REPO}_SOURCE_DIR}/${${PROJECT_NAME}_EXTRA_PACKAGES_FILE_NAME}") |
| 360 |
endif() |
| 361 |
|
| 362 |
message("") |
| 363 |
message("Reading list of ${READ_PRE_OR_POST_EXRAREPOS} extra packages from ${EXTRAREPO_PACKAGES_FILE} ... ") |
| 364 |
message("") |
| 365 |
|
| 366 |
if (NOT EXISTS "${EXTRAREPO_PACKAGES_FILE}") |
| 367 |
if (${PROJECT_NAME}_IGNORE_MISSING_EXTRA_REPOSITORIES) |
| 368 |
message("-- " |
| 369 |
"NOTE: Ignoring missing ${READ_PRE_OR_POST_EXRAREPOS} extra repo '${EXTRA_REPO}' packages list file '${EXTRAREPO_PACKAGES_FILE}' on request!") |
| 370 |
else() |
| 371 |
message( SEND_ERROR |
| 372 |
"ERROR: Skipping missing ${READ_PRE_OR_POST_EXRAREPOS} extra repo '${EXTRA_REPO}' packages list file '${EXTRAREPO_PACKAGES_FILE}'!") |
| 373 |
# ToDo: TriBITS:73: Change to FATAL_ERROR to abort early |
| 374 |
endif() |
| 375 |
else() |
| 376 |
tribits_trace_file_processing(REPOSITORY INCLUDE "${EXTRAREPO_PACKAGES_FILE}") |
| 377 |
include("${EXTRAREPO_PACKAGES_FILE}") |
| 378 |
set(APPEND_TO_PACKAGES_LIST TRUE) |
| 379 |
tribits_process_packages_and_dirs_lists(${EXTRA_REPO} ${EXTRA_REPO}) |
| 380 |
endif() |
| 381 |
|
| 382 |
endif() |
| 383 |
|
| 384 |
math(EXPR EXTRAREPO_IDX "${EXTRAREPO_IDX}+1") |
| 385 |
|
| 386 |
endwhile() |
| 387 |
|
| 388 |
endmacro() |