Debian Codegraph @

cmake/tribits/core/package_arch/TribitsListHelpers.cmake

raw
1 # @HEADER
2 # *****************************************************************************
3 # TriBITS: Tribal Build, Integrate, and Test System
4 #
5 # Copyright 2013-2016 NTESS and the TriBITS contributors.
6 # SPDX-License-Identifier: BSD-3-Clause
7 # *****************************************************************************
8 # @HEADER
9
10
11 include(TribitsHostType)
12 include(TribitsDeprecatedHelpers)
13
14
15 #
16 # This module defines the datastructure for the list of packages
17 # ${PROJECT_NAME}_PACKAGES_AND_DIRS_AND_CLASSIFICATIONS which has the form:
18 #
19 # Package0_name Package0_dir Package0_classification
20 # Package1_name Package1_dir Package1_classification
21 # ...
22 #
23 # There are 3 fields per row all stored in a flat array.
24 #
25
26
27 set(PLH_NUM_FIELDS_PER_PACKAGE 3)
28 set(PLH_NUM_PACKAGE_DIR_OFFSET 1)
29 set(PLH_NUM_PACKAGE_CLASSIFICATION_OFFSET 2)
30
31
32 macro(tribits_set_package_to_ex PACKAGE_NAME)
33 list(FIND ${PROJECT_NAME}_PACKAGES_AND_DIRS_AND_CLASSIFICATIONS
34 ${PACKAGE_NAME} PACKAGE_NAME_IDX)
35 if (PACKAGE_NAME_IDX EQUAL -1)
36 message(
37 "\n***"
38 "\n*** NOTE: Package ${PACKAGE_NAME} not found in list of packages!"
39 "\n***\n"
40 )
41 else()
42 math(EXPR PACKAGE_CLASSIFICATION_IDX
43 "${PACKAGE_NAME_IDX}+${PLH_NUM_PACKAGE_CLASSIFICATION_OFFSET}")
44 list(INSERT ${PROJECT_NAME}_PACKAGES_AND_DIRS_AND_CLASSIFICATIONS
45 ${PACKAGE_CLASSIFICATION_IDX} EX )
46 math(EXPR PACKAGE_CLASSIFICATION_IDX_PLUS_1
47 "${PACKAGE_CLASSIFICATION_IDX}+1")
48 list(REMOVE_AT ${PROJECT_NAME}_PACKAGES_AND_DIRS_AND_CLASSIFICATIONS
49 ${PACKAGE_CLASSIFICATION_IDX_PLUS_1} )
50 endif()
51
52 endmacro()
53
54
55 # @MACRO: tribits_disable_package_on_platforms()
56 #
57 # Disable a package automatically for a list of platforms.
58 #
59 # Usage::
60 #
61 # tribits_disable_package_on_platforms( <packageName>
62 # <hosttype0> <hosttype1> ...)
63 #
64 # If any of the host-type arguments ``<hosttypei>`` matches the
65 # ``${PROJECT_NAME}_HOSTTYPE`` variable for the current platform, then package
66 # ``<packageName>`` test group classification is changed to ``EX``. Changing
67 # the package test group classification to ``EX`` results in the package being
68 # disabled by default (see `EX packages disabled by default`_). However,
69 # an explicit enable can still enable the package.
70 #
71 macro( tribits_disable_package_on_platforms PACKAGE_NAME )
72 #message("TRIBITS_DISABLE_PACKAGE_ON_PLATFORMS: ${PACKAGE_NAME}")
73 #print_var(${PROJECT_NAME}_HOSTTYPE)
74 foreach(HOSTTYPE ${ARGN})
75 #print_var(HOSTTYPE)
76 if (${PROJECT_NAME}_HOSTTYPE STREQUAL ${HOSTTYPE})
77 #message("${${PROJECT_NAME}_HOSTTYPE} == ${HOSTTYPE}")
78 tribits_set_package_to_ex(${PACKAGE_NAME})
79 #print_var(${PROJECT_NAME}_PACKAGES_AND_DIRS_AND_CLASSIFICATIONS)
80 if (${PROJECT_NAME}_ENABLE_${PACKAGE_NAME})
81 message(
82 "\n***"
83 "\n*** NOTE: User has set ${PROJECT_NAME}_ENABLE_${PACKAGE_NAME}=ON but the"
84 "\n*** package ${PACKAGE_NAME} is not supported on this platform type '${HOSTTYPE}'!"
85 "\n***\n"
86 )
87 endif()
88 endif()
89 endforeach()
90 endmacro()
91
92
93 macro( package_disable_on_platforms PACKAGE_NAME_IN_ )
94 tribits_deprecated_command(package_disable_on_platforms
95 MESSAGE "Use tribits_disable_package_on_platforms() instead!")
96 tribits_disable_package_on_platforms(${PACKAGE_NAME_IN_} ${ARGN})
97 endmacro()
98
99
100
101 function(tribits_update_ps_pt_ss_st THING_TYPE THING_NAME TESTGROUP_VAR)
102
103 #message("TRIBITS_UPDATE_PS_PT_SS_ST: ${THING_TYPE} ${THING_NAME} ${TESTGROUP_VAR}")
104
105 set(TESTGROUP_IN ${${TESTGROUP_VAR}})
106 #print_var(TESTGROUP_IN)
107
108 if (TESTGROUP_IN STREQUAL PS)
109 if (${PROJECT_NAME}_VERBOSE_CONFIGURE)
110 tribits_deprecated("${THING_TYPE} ${THING_NAME} TESTGROUP 'PS' is deprecated."
111 " Use 'PT' instead!")
112 endif()
113 set(TESTGROUP_OUT PT)
114 elseif (TESTGROUP_IN STREQUAL SS)
115 if (${PROJECT_NAME}_VERBOSE_CONFIGURE)
116 tribits_deprecated("${THING_TYPE} ${THING_NAME} TESTGROUP 'SS' is deprecated."
117 " Use 'ST' instead!")
118 endif()
119 set(TESTGROUP_OUT ST)
120 elseif (TESTGROUP_IN STREQUAL TS)
121 if (${PROJECT_NAME}_VERBOSE_CONFIGURE)
122 tribits_deprecated("${THING_TYPE} ${THING_NAME} TESTGROUP 'TS' is deprecated."
123 " Use 'TT' instead!")
124 endif()
125 set(TESTGROUP_OUT TT)
126 else()
127 set(TESTGROUP_OUT ${TESTGROUP_IN})
128 endif()
129 #print_var(TESTGROUP_OUT)
130
131 set(${TESTGROUP_VAR} ${TESTGROUP_OUT} PARENT_SCOPE)
132
133 endfunction()