Debian Codegraph @

texmf-dist/fonts/source/public/punk/punkp.mf

raw
1 % Punk punctuation
2
3 beginpunkchar(".",5,1,2);
4 pd pp(.5w,0); % dot
5 endchar;
6
7 beginpunkchar(",",5,.5,.5);
8 z1=pp(.5w,0); z2=pp(w-u,-.1h); z3=pp(.5w,-.3h);
9 pd z1; pd z3; draw z1--z2--z3; % stroke
10 endchar;
11
12 beginpunkchar(":",5,1,.5);
13 pd pp(.5w,0); pd pp(.5w,.4h); % dots
14 endchar;
15
16 beginpunkchar(";",5,.5,.5);
17 z1=pp(.5w,0); z2=pp(w-u,-.1h); z3=pp(.5w,-.3h);
18 pd z1; pd z3; draw z1--z2--z3; % stroke
19 pd pp(.5w,.4h); % dot
20 endchar;
21
22 beginpunkchar("!",5,.5,.5);
23 pd pp(.5w,0); % dot
24 z1=pp(.5w,1.05h); z2=pp(.5w,.3h); pd z1; pd z2; draw z1--z2; % stem
25 endchar;
26 ligtable "!": "`" =: oct"016";
27
28 beginpunkchar(oct"016",5,.5,.5); % spanish inverted !
29 pd pp(.5w,.9h); % dot
30 z1=pp(.5w,-.1h); z2=pp(.5w,.6h); pd z1; pd z2; draw z1--z2; % stem
31 endchar;
32
33 beginpunkchar("?",9,1,.5);
34 z1=pp(1.5u,.8h); z2=pp(.5w,h); z3=pp(w-u,.8h); z4=pp(.5w,.3h);
35 pd z1; pd z4; draw z1..z2..z3..{down}z4; % arc and stem
36 pd pp(.5w,0); % dot
37 endchar;
38 ligtable "?": "`" =: oct"017";
39
40 beginpunkchar(oct"017",9,1,.5); % spanish inverted ?
41 z1=pp(1.5u,.1h); z2=pp(.5w,-.1h); z3=pp(w-u,.1h); z4=pp(.5w,.6h);
42 pd z1; pd z4; draw z1..z2..z3..{up}z4; % arc and stem
43 pd pp(.5w,.9h); % dot
44 endchar;
45
46 beginpunkchar("&",14,.5,.5);
47 z1=pp(w-2u,h); z2=pp(u,h); z3=pp(3u,0); z5=pp(w-u,.6h); z6=pp(w-2u,0);
48 pd z1; pd z5; draw z1--z2--z3--z5; % arms and stem
49 draw z1--.5[z2,z3]; pd z6; draw z6--.6[z3,z5]; % diagonals
50 endchar;
51
52 beginpunkchar("$",12,.5,.5);
53 z1=pp(w-1.5u,.7h); z2=pp(.5w,h); z3=pp(u,.7h); z4=.5[z3,z5];
54 z5=pp(w-u,.3h); z6=pp(.5w,0); z7=pp(u,.3h);
55 pd z1; pd z7; draw z1..z2..z3..z4..z5..z6..z7; % stroke
56 z8=z2+(0,.1h); pd z8; draw z8--z6; % stem
57 endchar;
58
59 beginpunkchar("%",18,.5,.5);
60 z1=pp(3.5u,1.1h); z2=pp(u,.8h); z3=pp(3.5u,.5h); z4=pp(6u,.8h);
61 z5=pp(w-3.5u,.5h); z6=pp(w-6u,.2h); z7=pp(w-3.5u,-.1h); z8=pp(w-u,.2h);
62 pd z1; draw z1..z2..z3..z4..z1; % upper bowl
63 pd z5; draw z5..z6..z7..z8..z5; % lower bowl
64 z9=pp(w-3u,1.1h); z0=pp(3u,-.1h); pd z0; draw z9--z0; % diagonal
65 draw z1{z5-z1}..z9; % link
66 endchar;
67
68 beginpunkchar("@",18,1,.5);
69 z1=pp(2u,0); z2=pp(1/3w,.7h); z3=pp(w-6u,0);
70 z4=pp(w,.3h); z5=pp(1/3w,h); z6=pp(u,.5h); z7=.7[z2,z3];
71 pd z1; pd z7; draw z1--z2--z3{right}..z4..z5..z6..z7; % diagonals and stroke
72 endchar;
73
74 beginpunkchar("-",7,.5,.5);
75 z1=pp(u,.4h); z2=pp(w-u,.5h); pd z1; pd z2; draw z1--z2; % bar
76 endchar;
77 ligtable "-": "-" =: oct"173";
78
79 beginpunkchar(oct"173",9,.5,.5); % --
80 z1=pp(0,.5h); z2=pp(w,.4h); pd z1; pd z2; draw z1--z2; % bar
81 endchar;
82 ligtable oct"173": "-" =: oct"174";
83
84 beginpunkchar(oct"174",18,.5,.5); % ---
85 z1=pp(0,.5h); z2=pp(w,.4h); pd z1; pd z2; draw z1--z2; % bar
86 endchar;
87
88 beginpunkchar("+",9,.5,1);
89 z1=pp(0,.5h); z2=pp(w,.5h); pd z1; pd z2; draw z1--z2; % bar
90 z3=pp(.5w,.1h); z4=pp(.5w,.9h); pd z3; pd z4; draw z3--z4; % stem
91 endchar;
92
93 beginpunkchar("*",13,.5,1);
94 z0=pp(.5w,1.1h); z1=pp(u,.9h); z2=pp(2u,.3h); z3=pp(w-u,.3h); z4=pp(w-u,.9h);
95 pd z0; draw z0--z2..1/3[.5[z2,z4],z0]..z4--z1--z3--z0; % star
96 endchar;
97
98 beginpunkchar("'",5,.3,.5);
99 z1=pp(1.5u,h); z2=pp(w-u,.85h); z3=pp(u,2/3h);
100 pd z1; pd z3; draw z1--z2--z3; % stroke
101 endchar;
102 ligtable "'": "'" =: oct"042";
103
104 beginpunkchar(oct"042",9,.3,.5); % ''
105 z1=pp(.5w-.5u,h); z2=pp(u,.6h); z3=pp(w-u,.95h);
106 pd z1; pd z3; draw z1--z2--z3; % stroke
107 endchar;
108
109 beginpunkchar("`",5,.3,.5);
110 z1=pp(w-1.5u,h); z2=pp(u,.85h); z3=pp(w-u,2/3h);
111 pd z1; pd z3; draw z1--z2--z3; % stroke
112 endchar;
113 ligtable "`": "`" =: oct"134";
114
115 beginpunkchar(oct"134",9,.3,.5); % ``
116 z1=pp(.5w+.5u,h); z2=pp(w-u,.6h); z3=pp(u,.95h);
117 pd z1; pd z3; draw z1--z2--z3; % stroke
118 endchar;
119
120 beginpunkchar(oct"015",9,.3,.5); % {\tt\char'15}
121 z1=pp(.5w,h); z2=pp(.5w,.6h); pd z1; pd z2; draw z1--z2; % stem
122 endchar;
123
124 beginpunkchar("(",7,.5,.5);
125 z1=pp(w-u,h); z2=pp(u,.5h); z3=pp(w-u,0);
126 pd z1; pd z3; draw z1..z2..z3; % stroke
127 endchar;
128
129 beginpunkchar(")",7,.5,.5);
130 z1=pp(u,h); z2=pp(w-u,.5h); z3=pp(u,0); pd z1; pd z3; draw z1..z2..z3; % stroke
131 endchar;
132
133 beginpunkchar("[",8,.5,.5);
134 z1=pp(w-u,h); z2=pp(.5w,h); z3=pp(.5w,0); z4=pp(w-u,0);
135 pd z1; pd z4; draw z1--z2--z3--z4; % bars and stem
136 endchar;
137
138 beginpunkchar("]",8,.5,.5);
139 z1=pp(u,h); z2=pp(.5w,h); z3=pp(.5w,0); z4=pp(u,0);
140 pd z1; pd z4; draw z1--z2--z3--z4; % bars and stem
141 endchar;
142
143 beginpunkchar("<",9,.5,.5);
144 z1=pp(w-u,.9h); z2=pp(u,.5h); z3=pp(w-u,.1h);
145 pd z1; pd z3; draw z1--z2--z3; % diagonals
146 endchar;
147
148 beginpunkchar(">",9,.5,.5);
149 z1=pp(u,.9h); z2=pp(w-u,.5h); z3=pp(u,.1h);
150 pd z1; pd z3; draw z1--z2--z3; % diagonals
151 endchar;
152
153 beginpunkchar("=",9,.5,.5);
154 z5=pp(u,2/3h); z6=pp(w-u,2/3h); pd z5; pd z6; draw z5--z6; % upper bar
155 z7=pp(u,1/3h); z8=pp(w-u,1/3h); pd z7; pd z8; draw z7--z8; % lower bar
156 endchar;
157
158 beginpunkchar("#",15,.5,.5);
159 z1=pp(.5w,h); z2=pp(3u,0); z3=pp(w-3u,h); z4=pp(.5w,0);
160 pd z2; pd z3; draw z3--z1--z2; draw z3--z4--z2; % diagonals (linked)
161 z5=pp(u,2/3h); z6=pp(w-u,2/3h); pd z5; pd z6; draw z5--z6; % upper bar
162 z7=pp(u,1/3h); z8=pp(w-u,1/3h); pd z7; pd z8; draw z7--z8; % lower bar
163 endchar;
164
165 beginpunkchar("/",9,1,1);
166 z1=pp(1.5u,-.05h); z2=pp(w-1.5u,1.05h); pd z1; pd z2; draw z1--z2; % diagonal
167 endchar;
168
169 beginpunkchar(oct"013",12,.5,.5); % {\tt\char'13}
170 z1=pp(u,.7h); z2=pp(.5w,h); z3=pp(w-u,.7h); z4=pp(.5w,0);
171 pd z1; pd z3; pd z4; draw z1--z2--z4; draw z3--z2; % stem and diagonals
172 endchar;
173
174 beginpunkchar(oct"014",12,.5,.5); % {\tt\char'14}
175 z1=pp(u,.3h); z2=pp(.5w,0); z3=pp(w-u,.3h); z4=pp(.5w,h);
176 pd z1; pd z3; pd z4; draw z1--z2--z4; draw z3--z2; % stem and diagonals
177 endchar;