| 1 |
% punk greek uppercase |
| 2 |
|
| 3 |
beginpunkchar(oct"000",11,1,2); % $\Gamma$ |
| 4 |
z1=pp(2u,0); z2=pp(2u,h); z3=pp(w-1.5u,h); |
| 5 |
pd z1; pd z3; draw z1--z2--z3; % stem and arm |
| 6 |
endchar; |
| 7 |
|
| 8 |
beginpunkchar(oct"001",15,1,2); % $\Delta$ |
| 9 |
z1=pp(u,0); z2=pp(.5w,h); z3=pp(w-u,0); |
| 10 |
pd z1; draw z1--z2..tension 5..z3..tension 5..z1; % triangle |
| 11 |
endchar; |
| 12 |
|
| 13 |
beginpunkchar(oct"002",15,.5,2); % $\Theta$ |
| 14 |
z1=pp(.5w,h); z2=pp(u,.6h); z3=pp(.5w,0); z4=pp(w-u,.6h); |
| 15 |
pd z1; draw z1..tension.8..z2..z3..z4..tension.8..z1; % bowl |
| 16 |
z5=pp(x2+2u,.4h); z6=pp(x4-2u,.4h); pd z5; pd z6; draw z5--z6; % bar |
| 17 |
endchar; |
| 18 |
|
| 19 |
beginpunkchar(oct"003",12,1,2); % $\Lambda$ |
| 20 |
z1=pp(u,0); z2=pp(.5w,h); z3=pp(w-u,0); |
| 21 |
pd z1; pd z3; draw z1--z2--z3; % diagonals |
| 22 |
endchar; |
| 23 |
|
| 24 |
beginpunkchar(oct"004",12,1,1); % $\Xi$ |
| 25 |
z1=pp(u,h); z2=pp(w-u,h); pd z1; pd z2; draw z1--z2; % upper arm |
| 26 |
z3=pp(2u,.55h); z4=pp(w-2u,.55h); pd z3; pd z4; draw z3--z4; % bar |
| 27 |
z5=pp(u,0); z6=pp(w-u,0); pd z5; pd z6; draw z5--z6; % lower arm |
| 28 |
endchar; |
| 29 |
|
| 30 |
beginpunkchar(oct"005",13,1,.5); % $\Pi$ |
| 31 |
z1=pp(1.5u,0); z2=pp(1.5u,h); z3=pp(w-1.5u,h); z4=pp(w-1.5u,0); |
| 32 |
pd z1; pd z4; draw z1--z2--z3--z4; % stems and bar |
| 33 |
endchar; |
| 34 |
|
| 35 |
beginpunkchar(oct"006",13,1,1); % $\Sigma$ |
| 36 |
z1=pp(w-u,h); z2=pp(u,h); z3=pp(.5w-u,.5h); z4=pp(u,0); z5=pp(w-u,0); |
| 37 |
pd z1; pd z5; draw z1--z2{.5[z4,z5]-z2}..z3--z4--z5; % arms and diagonals |
| 38 |
endchar; |
| 39 |
|
| 40 |
beginpunkchar(oct"007",15,1,.5); % $\Upsilon$ |
| 41 |
z1=pp(u,.8h); z2=pp(.3w,h); z3=pp(.5w,.5h); z4=pp(.5w,0); |
| 42 |
pd z1; pd z4; draw z1..z2..tension2..z3---z4; % left arc and stem |
| 43 |
z5=pp(w-u,.8h); z6=pp(.7w,h); |
| 44 |
pd z5; draw z5..z6..tension2..{z4-z3}z3; % right arc |
| 45 |
endchar; |
| 46 |
|
| 47 |
beginpunkchar(oct"010",13,1,2); % $\Phi$ |
| 48 |
z1=pp(.5w,h); z2=pp(.5w,0); pd z1; pd z2; draw z1--z2; % stem |
| 49 |
z3=pp(.5w,2/3h); z4=pp(u,.5h); z5=pp(.5w,1/4h); z6=pp(w-u,.5h); |
| 50 |
pd z3; draw z3..z4..z5..z6..z3; % bowl |
| 51 |
endchar; |
| 52 |
|
| 53 |
beginpunkchar(oct"011",14,1,1); % $\Psi$ |
| 54 |
z1=pp(.5w,h); z2=pp(.5w,0); pd z1; pd z2; draw z1--z2; % stem |
| 55 |
z3=pp(u,.8h); z4=pp(.5w,.2h); z5=pp(w-u,.8h); |
| 56 |
pd z3; pd z5; draw z3{.4[z1,z2]-z3}..z4{right}..{z5-.4[z1,z2]}z5; % stroke |
| 57 |
endchar; |
| 58 |
|
| 59 |
beginpunkchar(oct"012",13,1,2); % $\Omega$ |
| 60 |
z1=pp(u,0); z2=pp(1/3w,0); z3=pp(u,2/3h); z4=pp(.5w,h); |
| 61 |
z5=pp(w-u,2/3h); z6=pp(2/3w,0); z7=pp(w-u,0); |
| 62 |
pd z1; pd z7; draw z1--z2{up}..z3..z4..z5..{down}z6--z7; % bowl and arms |
| 63 |
endchar; |