Debian Codegraph @

texmf-dist/fonts/source/public/pacioli/cpcromanu.mf

raw
1 %%
2 %% This is file `cpcromanu.mf',
3 %% generated with the docstrip utility.
4 %%
5 %% The original source files were:
6 %%
7 %% pacioli.dtx (with options: `maj')
8 %%
9 %% Copyright 1999 Peter R. Wilson
10 %%
11 %% This program is provided under the terms of the
12 %% LaTeX Project Public License distributed from CTAN
13 %% archives in directory macros/latex/base/lppl.txt.
14 %%
15 %% Author: Peter Wilson (CUA and NIST)
16 %% now at: [email protected]
17 %%
18
19 def checkthin=
20 if thin-currentbreadth<eps: thin:=currentbreadth+eps; fi;
21 if thin-currentbreadth<eps: thin:=currentbreadth+eps; fi enddef;
22
23 numeric P_width#; P_width#=cap_jut#+3thick#+1/4side#-thin#;
24 define_pixels(P_width);
25
26 pair xeps, yeps; xeps=(eps,0); yeps=(0,eps);
27 numeric tail_corr; tail_corr=1/8;
28 numeric cap_jut_factor; cap_jut_factor=8/7;
29
30 numeric pcshiftx#; % x value of LHS of Pacioli box wrt origin of char box
31 define_pixels(pcshiftx);
32
33
34 cmchar "Pacioli's letter A";
35 beginchar("A", 2u#+side#, cap_height#, 0);
36 adjust_fit(cap_serif_fit#, cap_serif_fit#);
37 pcshiftx := u;
38 top y3= top y2=h + 2cap_jut;
39 % for left leg
40 numeric alpha[]; alpha1=(h++(0.5side - cap_jut - 0.5thin))/(side);
41 penpos1(alpha1*medium,0); penpos2(alpha1*medium,0);
42 % and for the right leg
43 alpha2=(h++(0.5side-0.5thick))/(side);
44 penpos3(alpha2*thick,0); penpos4(alpha2*thick,0);
45 lft x1l=cap_jut_factor*lrad+.5u; rt x4r=pcshiftx + side;
46 bot y1=bot y4=0 if monospace: +1/2 crisp fi;
47 x3r=x2l = 0.5side + pcshiftx;
48 z0=whatever[z1r,z2r]=whatever[z3l,z4l];
49 fill z0--diag_end(0,4l,1,1,4r,3r)--z3r..z2l--diag_end(2l,1l,1,1,1r,0)
50 --z0..cycle; % diagonals
51 top y5r=top y6r=hround(h/2); top y5r-bot y5l=top y6r-bot y6l=thin;
52 penpos5(whatever, angle(z2-z1)); penpos6(whatever, angle(z3-z4));
53 z5=whatever[z1,z2]; z6=whatever[z3,z4];
54 penstroke z5e--z6e; % bar line
55 pickup tiny.nib;
56 numeric top_bar; top_bar=top y5r-bot y6l;
57 if monospace: pickup pencircle scaled 0pt;
58 pos11(top_bar,90); pos12(top_bar,90);
59 top y11r=top y12r=h; w/2=.5[x11,x12]; x12-x11=apex_corr+2cap_jut;
60 fill z11l--z12l{right}..tension atleast.95..{left}z12r--z11r{left}..
61 tension atleast.95..{right}cycle;
62 penlabels(11,12); fi
63 if serifs: bracket:=10/7 bracket; cap_jut:=cap_jut_factor*cap_jut;
64 pickup tiny.nib; numeric jut_factor;
65 if monospace: jut_factor:=1; else: jut_factor:=3/4; fi
66 serif(1,2,a,.8serif_darkness,-cap_jut);serif(4,3,d,.8serif_darkness, cap_jut);
67 bracket:=jut_factor*bracket; if monospace: jut_factor:=.6; fi
68 serif(1,2,b,7/8 serif_darkness,jut_factor*cap_jut);
69 serif(4,3,c,7/8 serif_darkness,-jut_factor*cap_jut);
70 fi
71 x20 = x2l - 0.5lrad; y20 = side+lrad;
72 erase filldraw fullcircle scaled 2lrad shifted (x20,y20);
73 proofpcbb(1, lrad+0.5medium, 0);
74 penlabels(0,1,2,3,4,5,6,20); endchar;
75
76
77 cmchar "Pacioli's letter B";
78 beginchar("B",u#+cap_jut#+0.64side#, cap_height#, 0);
79 adjust_fit(cap_serif_fit#,0); pickup tiny.nib;
80 pcshiftx := 0.5u;
81 pos1(thick,0); pos2(thick,0); lft x1l=lft x2l=pcshiftx+cap_jut;
82 bot y2=0; top y1=h; filldraw stroke z1e--z2e; % vertical stem
83 pos3(thin,-90); pos5(thick,0); pos7(medium,90);
84 z3r=z2; y4l=y3l; x4l=x3l+thick; y4r=y3r; x4r=x4l+thick-1/2thin; z4=.5[z4l,z4r];
85 y7=h/2; x7=x1; y6l=y7l; x6l=x4l; top y6r-bot y6l=medium; x6r=x4r;
86 z6=.5[z6r,z6l];
87 x5=hround(x1+0.64side-thick); y5=0.25side;
88 filldraw stroke z3e--z4e..pulled_arc.e(4,5)&pulled_arc.e(5,6)..z6e--z7e;
89 % bottom lobe
90 pos7'(thin,-90); pos8(thick,0); pos10(medium,90);
91 z7'=z7; z6'=z6; x6'r=x4r; x6'l=x4l; y6'r=y7'r; y6'l=y7'l;
92 z10r=z1; x9r=x6'r; x9l=x6'l; y9r=y10r; top y9r-bot y9l=medium; z9=.5[z9r,z9l];
93 x8=hround(x1+0.53side-thick); y8=.75side;
94 filldraw stroke z7'e--z6'e..pulled_arc.e(6',8)&pulled_arc.e(8,9)
95 ..z9e--z10e; % upper lobe
96 if serifs: serif(1,2,a, serif_darkness,-cap_jut);
97 serif(2,1,b,serif_darkness,-cap_jut);
98 numeric tempa_, tempb_; tempa_=slab; tempb_=bracket;
99 slab:=thin; bracket:=2/3cap_jut; serif(2,1,c,serif_darkness,2/3cap_jut);
100 slab:=tempa_; bracket:=tempb_; fi
101 proofpcbb(2, cap_jut+0.5thick, 0);
102 penlabels(1,2,3,4,5,6,7,8,9,10,11,12);
103 penlabels(6',7'); endchar;
104
105
106 cmchar "Pacioli's original letter C";
107 beginchar("c",2u#+.95side#, cap_height#, 0);
108 adjust_fit(0, 0); if monospace: pickup fine.nib; else: pickup tiny.nib;fi
109 pcshiftx := u;
110 numeric alpha; alpha=w-u-thick;
111 pos2(thin, 90); x2=.5[x3r,x0r]; top y2r=h;% topmost pen position
112 pos3(thick,180); lft z3r=(u,h/2);
113 pos4(thin, 270); x4=x2; bot y4r=0; % bottommost pen position
114 pos0(thick,0); lft z0l=(w+thick-u,h/2);
115 path p, p', line.u, line.b; line.u=(alpha,1.5h)--(alpha,h/2);
116 line.b=(.5[alpha,x0],0)--(.5[alpha,x0],h/2);
117 p=pulled_arc.r(0,2)&pulled_arc.r(2,3)&pulled_arc.r(3,4)
118 &pulled_arc.r(4,0)&cycle;
119 p'=pulled_arc.l(0,2)&pulled_arc.l(2,3)&pulled_arc.l(3,4)
120 &pulled_arc.l(4,0)&cycle;
121 z'1l=line.u intersectionpoint p'; z'1r=line.u intersectionpoint p;
122 bot rt z1l=z'1l; top rt z1r=z'1r; z1=.5[z1l,z1r];
123 z'5l=line.b intersectionpoint p'; z'5r=line.b intersectionpoint p;
124 z5r = (side+pcshiftx-3/4thick, 3/4thick); z5l = (x5r+o, y5r+1.5thick); z5=.5[z5r,z5l];
125 if not monospace:
126 x1l:=x1l+.6thin; y1l:=y1r-1.0thick-2tiny;
127 y5l:=2thick+y5r-2tiny; fi
128 if monospace: x1:=x1l:=x1r:=x5; y1:=y1-thin; y1l:=y1l-thin; y1r:=y1r-.6thin; fi
129 % readjust to have a better opening in CDTT
130 numeric slope_factor; if monospace:slope_factor=4/3; else:slope_factor=3/4; fi
131 filldraw
132 z1r{-1,slope_factor}...{left}z2r..pulled_arc.r(2,3)&
133 pulled_arc.r(3,4)..{right}z4r..tension 0.9..z5r--
134 reverse
135 (z1l..tension 0.9..{left}z2l..pulled_arc.l(2,3)&pulled_arc.l(3,4)..{right}z4l
136 ..tension 0.9..z5l)
137 ..(z1l+(eps,0))--(z1r+(eps,0))..cycle;
138 proofpcbb(3, 0.5thick, 0.5side);
139 penlabels(0,1,2,3,4,5); endchar;
140
141
142 cmchar "Pacioli's letter C";
143 beginchar("C",2u#+.95side#, cap_height#, 0);
144 adjust_fit(0, 0); if monospace: pickup fine.nib; else: pickup tiny.nib;fi
145 pcshiftx := u;
146 numeric alpha; alpha=w-u-thick;
147 pos2(thin, 90); x2=.5[x3r,x0r]; top y2r=h+o;% topmost pen position
148 pos3(thick,180); lft z3r=(u,h/2);
149 pos4(thin, 270); x4=x2; bot y4r=-o; % bottommost pen position
150 pos0(thick,0); lft z0l=(w+thick-u,h/2);
151 path p, p', line.u, line.b; line.u=(alpha,1.5h)--(alpha,h/2);
152 line.b=(.5[alpha,x0],0)--(.5[alpha,x0],h/2);
153 p=pulled_arc.r(0,2)&pulled_arc.r(2,3)&pulled_arc.r(3,4)
154 &pulled_arc.r(4,0)&cycle;
155 p'=pulled_arc.l(0,2)&pulled_arc.l(2,3)&pulled_arc.l(3,4)
156 &pulled_arc.l(4,0)&cycle;
157 z'1l=line.u intersectionpoint p'; z'1r=line.u intersectionpoint p;
158 bot rt z1l=z'1l; top rt z1r=z'1r; z1=.5[z1l,z1r];
159 z'5l=line.b intersectionpoint p'; z'5r=line.b intersectionpoint p;
160 z5r = (side+pcshiftx-3/4thick, 3/4thick); z5l = (x5r+o, y5r+1.5thick); z5=.5[z5r,z5l];
161 if not monospace:
162 x1l:=x1l+.6thin; y1l:=y1r-1.0thick-2tiny;
163 y5l:=2thick+y5r-2tiny; fi
164 if monospace: x1:=x1l:=x1r:=x5; y1:=y1-thin; y1l:=y1l-thin; y1r:=y1r-.6thin; fi
165 % readjust to have a better opening in CDTT
166 numeric slope_factor; if monospace:slope_factor=4/3; else:slope_factor=3/4; fi
167 filldraw
168 z1r{-1,slope_factor}...{left}z2r..pulled_arc.r(2,3)&
169 pulled_arc.r(3,4)..{right}z4r..tension 0.9..z5r--
170 reverse
171 (z1l..tension 0.9..{left}z2l..pulled_arc.l(2,3)&pulled_arc.l(3,4)..{right}z4l
172 ..tension 0.9..z5l)
173 ..(z1l+(eps,0))--(z1r+(eps,0))..cycle;
174 proofpcbb(3, 0.5thick, 0.5side);
175 penlabels(0,1,2,3,4,5); endchar;
176
177
178 cmchar "Pacioli's letter D";
179 beginchar("D", cap_jut#+.95side#+u#, cap_height#, 0);
180 adjust_fit(cap_serif_fit#,0);
181 pickup tiny.nib; pos1(cap_stem,0); pos2(cap_stem,0);
182 lft x1l=.5u+cap_jut; x2=x1; bot y2=0; top y1=h;
183 filldraw stroke z1e--z2e; % stem
184 pos3(thin, 90); pos5(thick, 0); pos7(5/4thin, -90);
185 x3=x7=x1; top y3r=h; bot y7r=0;
186 y5=good.y h/2; x5=h-3/2thick+x1;
187 if not monospace: x4r=x6r=hround(w/2); top y4r=h; bot y6r=0;
188 bot y4l=vround(h-thin); top y6l=vround 5/4thin;
189 x4l=x6l; 2(lft x5l-x4l)=y4l-y6l;
190 z4=.5[z4l, z4r]; z6=.5[z6l, z6r];
191 else: pos4(thin,90); pos6(thin,-90); x4=x6=hround w/2; top y4r=h; bot y6r=0;
192 fi
193 filldraw stroke z3e{right}...pulled_super_arc.e(4,5,eta)&
194 pulled_super_arc.e(5,6,eta)...{left}z7e; % lobe
195 if serifs: serif(1, 2, a, serif_darkness, -cap_jut);
196 serif(2, 1, b, serif_darkness, -cap_jut);
197 if not monospace: numeric temp_; temp_=slab; slab:=5/4thin;
198 serif(2, 1, c, serif_darkness, cap_jut); slab:=temp_; fi fi
199 proofpcbb(2, cap_jut+0.5thick, 0);
200 penlabels(1,2,3,4,5,6,7); endchar;
201
202
203 cmchar "Pacioli's letter E";
204 numeric topbar_; topbar_=1/2; % half the square for Pacioli
205 numeric middlebar_; middlebar_=10/31; % as measured
206 beginchar("E", u#+cap_jut#+5.25thick#, cap_height#,0);
207 adjust_fit(cap_serif_fit#,0);
208 pcshiftx := 0.5u;
209 pickup tiny.nib; pos1(cap_stem,0); pos2(cap_stem,0);
210 lft x1l=lft x2l=.5u+cap_jut; top y1=h; bot y2=0;
211 filldraw stroke z1e--z2e; % stem
212 pickup crisp.nib; % prepare for arms and serifs
213 pos3(medium,90); pos4(dslab,0);
214 x1=x3; top y3r=h; rt x4l=x2l+topbar_*side;
215 bot y4=vround(h-if monospace: 2 fi vstretch*thick);
216 arm(3,4,d,serif_darkness,0); % top arm and beak
217 pos5(thin,-90); pos0(thin,90); pos6(dslab,0); pos7(dslab,0);
218 x5=x0=x1; y5=y0=hround(h/2); rt x6r=rt x7r= x1r+middlebar_*side;
219 top y6-bot y7= thin+3/4thick; y5=.5[y6,y7];
220 arm(5,6,e,eta,0); arm(0,7,f,eta,0); % middle arms and beaks
221 pos8(medium,-90); pos9(dslab,0); x8=x2; bot y8r=0; rt x9r=hround(x2l+5.25thick);
222 y9=y8r+thick;
223 foot(8,9,g,serif_darkness,0.25thick); % lower arm
224 if serifs: serif(1,2,a,serif_darkness,-cap_jut);
225 serif(2,1,b,serif_darkness,-cap_jut);
226 if not monospace: temp_:=slab; slab:=medium; tmp_:=bracket; bracket:=cap_jut+medium;
227 serif(2,1,c,serif_darkness,cap_jut);
228 slab:=temp_; bracket:=tmp_; fi fi
229 proofpcbb(2, cap_jut+0.5thick, 0);
230 penlabels(0,1,2,3,4,5,6,7,8,9); endchar; % end of "E"
231
232
233 cmchar "Pacioli's letter F";
234 numeric topbar_; topbar_=1/2; % half the square for Pacioli
235 numeric middlebar_; middlebar_=10/31; % as measured
236 beginchar("F", u#+1/2side#+cap_jut#, cap_height#,0);
237 adjust_fit(cap_serif_fit#,0);
238 pcshiftx := 0.5u;
239 pickup tiny.nib; pos1(cap_stem,0); pos2(cap_stem,0);
240 lft x1l=lft x2l=.5u+cap_jut; top y1=h; bot y2=0;
241 filldraw stroke z1e--z2e; % stem
242 pickup crisp.nib; % prepare for arms and serifs
243 pos3(medium,90); pos4(dslab,0);
244 x1=x3; top y3r=h; rt x4l= x2l+topbar_*side;
245 bot y4=vround(h-if monospace: 2 fi vstretch*thick);
246 arm(3,4,d,serif_darkness,0); % top arm and beak
247 pos5(thin,-90); pos0(thin,90); pos6(dslab,0); pos7(dslab,0);
248 x5=x0=x1; y5=y0=hround(h/2); rt x6r=rt x7r= x1r+middlebar_*side;
249 top y6-bot y7= thin + 3/4thick; y5=.5[y6,y7];
250 arm(5,6,e,eta,0); arm(0,7,f,eta,0); % middle arms and beaks
251 if serifs: serif(1,2,a,serif_darkness,-cap_jut);
252 serif(2,1,b,serif_darkness,-cap_jut); serif(2,1,c,serif_darkness, cap_jut);
253 fi
254 proofpcbb(2, cap_jut+0.5thick, 0);
255 penlabels(0,1,2,3,4,5,6,7); endchar; % end of "F"
256
257
258 cmchar "Pacioli's original letter G";
259 beginchar("g",2u#+.925side#, cap_height#, 0);
260 adjust_fit(0, cap_serif_fit#);
261 pcshiftx := u;
262 if monospace: pickup fine.nib; else: pickup tiny.nib;fi
263 numeric alpha; alpha=w-u-thick;
264 pos2(thin, 90); x2=.5[x3r,x0r]; top y2r=h;% topmost pen position
265 pos3(thick,180); lft z3r=(u,h/2);
266 pos4(thin, 270); x4=x2; bot y4r=0;
267 pos0(thick,0); lft z0l=(w+thick-u,h/2);
268 path p, p', line.u, line.b; line.u=(alpha,1.5h)--(alpha,h/2);
269 line.b=(.5[alpha,x0],0)--(.5[alpha,x0],h/2);
270 p=pulled_arc.r(0,2)&pulled_arc.r(2,3)&pulled_arc.r(3,4)
271 &pulled_arc.r(4,0)&cycle;
272 p'=pulled_arc.l(0,2)&pulled_arc.l(2,3)&pulled_arc.l(3,4)
273 &pulled_arc.l(4,0)&cycle;
274 z'1l=line.u intersectionpoint p'; z'1r=line.u intersectionpoint p;
275 bot rt z1l=z'1l; top rt z1r=z'1r; z1=.5[z1l,z1r];
276 z'5l=line.b intersectionpoint p'; z'5r=line.b intersectionpoint p;
277 z5r = (side+pcshiftx-3/4thick, 3/4thick); z5l = (x5r+o, y5r+1.5thick); z5=.5[z5r, z5l];
278 if not monospace:
279 x1l:=x1l+.6thin; y1l:=y1r-1.0thick-2tiny;
280 y5l:=2thick+y5r-2tiny; fi
281 if monospace: x1:=x1l:=x1r:=x5; y1:=y1-thin; y1l:=y1l-thin; y1r:=y1r-.6thin; fi
282 % readjust to have a better opening in CDTT
283 numeric slope_factor; if monospace:slope_factor=4/3; else:slope_factor=3/4; fi
284 path p,p',line.o, line.i;
285 p=z1r{-1,slope_factor}..{left}pulled_arc.r(2,3)&
286 pulled_arc.r(3,4){right}..tension 0.9..z5r;
287 p'= reverse
288 (z1l..tension 0.9..{left}pulled_arc.l(2,3)&pulled_arc.l(3,4){right}
289 ..tension 0.9..z5l);
290 pos7(thick,0);
291 top z7=(x1r,7/2thick);
292 numeric counter; counter=0;
293 forever:
294 counter:=counter+1;
295 line.o:=z7r--(x7r,-2o); line.i:=(z7r-(thick,0))--(x7r-thick,-2o);
296 numeric t[],tt[];
297 (t1,tt1)=p intersectiontimes line.o; (t2,tt2)=p' intersectiontimes line.i;
298 exitif t1*t2>0; forsuffixes $$=l, r: x7$$:=x7$$-.1u; endfor
299 x7:=x7-.1u; endfor
300 x6r=x7r; x6l=x7l; bot y6r=ypart point t1 of p; bot y6l=ypart point t2 of p';
301 z6=.5[z6r,z6l];
302 p:= subpath(0,t1) of p..(z6r-xeps+yeps)--(z6l+xeps+yeps)..
303 subpath(t2,infinity) of p'..(z1l+xeps)--cycle;
304 filldraw p;
305 filldraw z6l--z7l--z7r--z6r--cycle;
306 if serifs: serif(7,6,a,serif_darkness,-srad);
307 serif(7,6,b,serif_darkness, srad); fi
308 proofpcbb(3, 0.5thick, 0.5side);
309 penlabels(0,1,2,3,4,5,6,7); endchar;
310
311
312 cmchar "Pacioli's letter G";
313 beginchar("G",2u#+.925side#, cap_height#, 0);
314 adjust_fit(0, cap_serif_fit#);
315 pcshiftx := u;
316 if monospace: pickup fine.nib; else: pickup tiny.nib;fi
317 numeric alpha; alpha=w-u-thick;
318 pos2(thin, 90); x2=.5[x3r,x0r]; top y2r=h+o;% topmost pen position
319 pos3(thick,180); lft z3r=(u,h/2);
320 pos4(thin, 270); x4=x2; bot y4r=-o;
321 pos0(thick,0); lft z0l=(w+thick-u,h/2);
322 path p, p', line.u, line.b; line.u=(alpha,1.5h)--(alpha,h/2);
323 line.b=(.5[alpha,x0],0)--(.5[alpha,x0],h/2);
324 p=pulled_arc.r(0,2)&pulled_arc.r(2,3)&pulled_arc.r(3,4)
325 &pulled_arc.r(4,0)&cycle;
326 p'=pulled_arc.l(0,2)&pulled_arc.l(2,3)&pulled_arc.l(3,4)
327 &pulled_arc.l(4,0)&cycle;
328 z'1l=line.u intersectionpoint p'; z'1r=line.u intersectionpoint p;
329 bot rt z1l=z'1l; top rt z1r=z'1r; z1=.5[z1l,z1r];
330 z'5l=line.b intersectionpoint p'; z'5r=line.b intersectionpoint p;
331 z5r = (side+pcshiftx-3/4thick, 3/4thick); z5l = (x5r+o, y5r+1.5thick); z5=.5[z5r, z5l];
332 if not monospace:
333 x1l:=x1l+.6thin; y1l:=y1r-1.0thick-2tiny;
334 y5l:=2thick+y5r-2tiny; fi
335 if monospace: x1:=x1l:=x1r:=x5; y1:=y1-thin; y1l:=y1l-thin; y1r:=y1r-.6thin; fi
336 % readjust to have a better opening in CDTT
337 numeric slope_factor; if monospace:slope_factor=4/3; else:slope_factor=3/4; fi
338 path p,p',line.o, line.i;
339 p=z1r{-1,slope_factor}..{left}pulled_arc.r(2,3)&
340 pulled_arc.r(3,4){right}..tension 0.9..z5r;
341 p'= reverse
342 (z1l..tension 0.9..{left}pulled_arc.l(2,3)&pulled_arc.l(3,4){right}
343 ..tension 0.9..z5l);
344 pos7(thick,0);
345 top z7=(x1r,7/2thick);
346 numeric counter; counter=0;
347 forever:
348 counter:=counter+1;
349 line.o:=z7r--(x7r,-2o); line.i:=(z7r-(thick,0))--(x7r-thick,-2o);
350 numeric t[],tt[];
351 (t1,tt1)=p intersectiontimes line.o; (t2,tt2)=p' intersectiontimes line.i;
352 exitif t1*t2>0; forsuffixes $$=l, r: x7$$:=x7$$-.1u; endfor
353 x7:=x7-.1u; endfor
354 x6r=x7r; x6l=x7l; bot y6r=ypart point t1 of p; bot y6l=ypart point t2 of p';
355 z6=.5[z6r,z6l];
356 p:= subpath(0,t1) of p..(z6r-xeps+yeps)--(z6l+xeps+yeps)..
357 subpath(t2,infinity) of p'..(z1l+xeps)--cycle;
358 filldraw p;
359 filldraw z6l--z7l--z7r--z6r--cycle;
360 if serifs: serif(7,6,a,serif_darkness,-srad);
361 serif(7,6,b,serif_darkness, srad); fi
362 proofpcbb(3, 0.5thick, 0.5side);
363 penlabels(0,1,2,3,4,5,6,7); endchar;
364
365
366 cmchar "Pacioli's letter H";
367 beginchar("H", u#+side#, cap_height#,0);
368 adjust_fit(cap_serif_fit#, cap_serif_fit#); pickup tiny.nib;
369 forsuffixes t=1,2,3,4: pos.t(thick,0); endfor
370 lft x1l=lft x2l=.5u+cap_jut; bot y2=0; top y1=h;
371 filldraw stroke z1e--z2e; % left vertical stem
372 x3=x4=w-x1; y3=y1; y4=y2;
373 filldraw stroke z3e--z4e; % right vertical stem
374 pos5(thin, 90); pos6(thin,90);
375 x5=.5[x1r,x1l]; x6=w-x5; top y5r=top y6r=h/2;
376 filldraw stroke z5e--z6e; % horizontal crossbar
377 if serifs:
378 serif(1,2,a,serif_darkness,-cap_jut); serif(1,2,b,serif_darkness,cap_jut);
379 serif(2,1,c,serif_darkness,-cap_jut); serif(2,1,d,serif_darkness,cap_jut);
380 serif(3,4,e,serif_darkness,-cap_jut); serif(3,4,f,serif_darkness,cap_jut);
381 serif(4,3,g,serif_darkness,-cap_jut); serif(4,3,h,serif_darkness,cap_jut); fi
382 proofpcbb(2, cap_jut+0.5thick, 0);
383 labels(1,2,3,4,5,6); endchar;
384
385
386 cmchar "Pacioli's letter I";
387 beginchar("I", .5u#+2cap_jut#+cap_stem#+.5u#, cap_height#,0);
388 adjust_fit(cap_serif_fit#, cap_serif_fit#);
389 pickup tiny.nib; checkthin; pos1(cap_stem,0); pos2(cap_stem,0);
390 x1=x2=hround(w/2); top y1=h; bot y2=0;
391 filldraw stroke z1e--z2e; % vertical stem
392 if serifs:
393 serif(1, 2, a, serif_darkness, -cap_jut);
394 serif(1, 2, b, serif_darkness, cap_jut); % top lft,rt
395 serif(2, 1, c, serif_darkness, -cap_jut);
396 serif(2, 1, d, serif_darkness, cap_jut); % bot lft,rt
397 fi
398 proofpcbb(2, 0.5side, 0);
399 penlabels(1, 2); endchar;
400
401
402 cmchar "Pacioli's letter J";
403 %% Pacioli didn't have a J, so use Durer's.
404 beginchar("J",u#+3thick#+cap_jut#,cap_height#, 1/4 cap_height#);
405 adjust_fit(0, cap_serif_fit#); pickup tiny.nib;
406 pos1(thick,0); pos2(thick,0); pos3(thin, -90);
407 top y1=h; rt x1r=w-.5u-cap_jut; x2=x1; bot y2=0; lft x3=.5u; bot y3r=-d;
408 filldraw stroke z1e--z2e{down}..{left}z3e;
409 if serifs: serif(1,2,a,serif_darkness,-cap_jut);
410 serif(1,2,b,serif_darkness,cap_jut); fi
411 proofpcbb(2, 0.5side, 0);
412 penlabels(1,2,3); endchar;
413
414
415 cmchar "Pacioli's letter K";
416 beginchar("K", 3/2u#+side#, cap_height#,0);
417 adjust_fit(cap_serif_fit#,0); pickup tiny.nib;
418 pcshiftx := 3/4u;
419 pair durer[]; % represent Pacioli's corner points
420 durer1=(pcshiftx,side); durer2=(pcshiftx+side,side); durer3=(xpart durer1,0);
421 durer4=(xpart durer2,0);
422 numeric diag_angle[];
423 diag_angle1=angle(durer2-durer3);
424 diag_angle2=angle(durer1-durer4);
425 numeric alpha;
426 alpha=((xpart durer2 - xpart durer1)++h)/h;
427 pos1(thick,0); pos2(thick,0);
428 lft x1l=lft x2l=pcshiftx+cap_jut;
429 top y1=h; bot y2=0; filldraw stroke z1e--z2e; % left stem
430 pos3(alpha*medium,0); pos4(alpha*medium,0); z4l = (x2,h/2);
431 top y3=h; z3r-z4r=whatever*(durer2-durer3);
432 z0=whatever[z1r,z2r]=whatever[z3l,z4l];
433 filldraw z4l--z3l--z3r--z4r--cycle; % upper diagonal stroke
434 pos5(alpha*thick,0); pos6(alpha*thick,0);
435 z5l = z4l;
436 bot y6=0; z5r-z6r=whatever*(durer1-durer4);
437 z10 = whatever[z3r,z4r]=whatever[z6r,z5r];
438 filldraw z6l--z5l--z10--z6r--cycle; % bottom leg
439 if serifs:
440 serif(1,2,a,serif_darkness,-cap_jut); serif(1,2,b,serif_darkness,cap_jut);
441 serif(2,1,c,serif_darkness,-cap_jut); serif(2,1,d,serif_darkness,cap_jut);
442 numeric old_jut, old_brack; old_jut=cap_jut; old_brack=bracket;
443 bracket:=.5old_brack;cap_jut:=.5old_jut;
444 if not monospace: serif(3,4,e,serif_darkness,-cap_jut); fi
445 bracket:=2old_brack; cap_jut:=2old_jut;
446 serif(3,4,f,.6serif_darkness,if monospace:.7 fi cap_jut);
447 bracket:=.5old_brack;cap_jut:=.5old_jut;
448 if not monospace: serif(6,5,g,serif_darkness,-cap_jut); fi
449 bracket:=2old_brack; cap_jut:=2old_jut;
450 serif(6,5,h,.6serif_darkness,if monospace:.7 fi cap_jut);
451 cap_jut:=old_jut; bracket:=old_brack;
452 fi
453 proofpcbb(2, pcshiftx+cap_jut+0.5thick, 0);
454 penlabels(0,1,2,3,4,5,6,7); endchar;
455
456
457 cmchar "Pacioli's letter L";
458 numeric topbar_; if monospace: topbar_=11/15;
459 else: topbar_=17/30; fi % Duerer's wierd value
460 beginchar("L", u#+cap_jut#+5.75thick#, cap_height#,0);
461 adjust_fit(cap_serif_fit#,0);
462 pcshiftx := 0.5u;
463 pickup tiny.nib; pos1(cap_stem,0); pos2(cap_stem,0);
464 lft x1l=lft x2l=.5u+cap_jut; top y1=h; bot y2=0;
465 filldraw stroke z1e--z2e; % stem
466 pickup crisp.nib; % prepare for arms and serifs
467 pos3(thin,90);
468 pos8(medium,-90); pos9(dslab,0); x8=x2; bot y8r=0; rt x9r=hround(x2l+5.75thick);
469 y9=y8r+1.5thick; foot(8,9,g,serif_darkness,0.75thick);
470 % lower arm
471 if serifs: serif(1,2,a,serif_darkness,-cap_jut);
472 serif(2,1,b,serif_darkness,-cap_jut); serif(1,2,d,serif_darkness,cap_jut);
473 if not monospace: temp_:=slab; slab:=medium; tmp_:=bracket; bracket:=thick+medium;
474 serif(2,1,c,serif_darkness,thick);
475 slab:=temp_; bracket:=tmp_; fi fi
476 proofpcbb(2, cap_jut+0.5thick, 0);
477 penlabels(0,1,2,3,4,5,6,7,8,9); endchar; % end of "L"
478
479
480 cmchar"Pacioli's letter M";
481 beginchar("M", u#+cap_jut#+side#, cap_height#, 0);
482 adjust_fit(cap_serif_fit#, cap_serif_fit#); pickup tiny.nib;
483 pcshiftx := 0.5u;
484 pos1(medium,0); pos2(medium,0);
485 lft x2l=pcshiftx+cap_jut; top y1=h; bot y2=0;
486 lft x1l = lft x2l + side*sind(1); % left leg has 1 degree angle
487 pos3(thick,0); pos4(thick,0);
488 x4r=pcshiftx+side; top y3=h; bot y4=0;
489 x3r=x4r-side*sind(3); % right leg has 3 degree angle
490 numeric long, short, hypot, alpha; long=side; short=1/2side;
491 hypot=long++short; alpha=hypot/long;
492 pos5(alpha*thick,0); pos6(alpha*thick,0); % left inner
493 z5l=(2pcshiftx,side); bot lft z6l=(pcshiftx+1/2side,0);
494 pos7(alpha*medium,0); pos8(alpha*medium,0); % right inner
495 z7r=z6l; z8r=z3r; z0=whatever[z5r,z6r]=whatever[z7l,z8l];
496 z10=whatever[z5l,z6l]=whatever[z1r,z2r];
497 z11=whatever[z7r,z8r]=whatever[z3l,z4l];
498 filldraw z5r--z0--z8l--z3r--z4r--z4l--z11--z6l--z10--z2r--z2l--z1l--cycle;
499 if serifs:
500 serif(2,1,a,serif_darkness,-cap_jut); serif(1,2,b,serif_darkness,-lrad);
501 serif(3,4,c,serif_darkness, lrad); serif(4,3,d,serif_darkness, lrad);
502 serif(2,1,e,serif_darkness,cap_jut); serif(4,3,f,serif_darkness,-cap_jut);
503 % lower, inner serifs
504 fi
505 proofpcbb(2, cap_jut+0.5medium, 0);
506 penlabels(0,1,2,3,4,5,6,7,8,10,11); endchar;
507
508
509 cmchar "Pacioli's letter N";
510 beginchar("N", u#+2cap_jut#+.8side#, cap_height#,0);
511 adjust_fit(cap_serif_fit#, cap_serif_fit#); pickup tiny.nib;
512 numeric long, short, hypot, alpha; long=h; short=side-2cap_jut;
513 hypot=long++short; alpha=hypot/long;
514 pos1(medium,0); pos2(medium,0); lft x1l=lft x2l=.5u+cap_jut; top y1=h; bot y2=0;
515 pos3(medium,0); pos4(medium,0); x3=x4; x3=x2+side-2cap_jut-medium; y3=y1; y4=y2;
516 pos 5(alpha*thick,0); pos6(alpha*thick,0);
517 z5r=z1r; z6l=z4r; z0=whatever[z1r,z2r]=whatever[z5l,z6l]; % under notch point
518 z0'=whatever[z5r,z6r]=whatever[z3l,z4l];
519 filldraw z1r--z1l--z2l--z2r--z0--z6l--z3r--z3l--z0'--cycle;
520 if serifs:
521 serif(2,1,b,serif_darkness,-cap_jut); serif(2,1,c,serif_darkness,cap_jut);
522 % bottom, left serifs
523 serif(3,4,d,serif_darkness,-cap_jut);serif(3,4,e,serif_darkness,cap_jut);
524 % top right serifs
525 z.a=(x1l-1.5cap_jut,y1); pickup tiny.nib; filldraw
526 z0{z0-z4r}..{left}(z.a-(0,eps))..z.a--z1r--cycle;
527 % top left serif
528 serif(1,2,a,serif_darkness,-lrad);
529 fi
530 proofpcbb(2, cap_jut+0.5medium, 0);
531 penlabels(0,0',1,2,3,4,5,6); endchar;
532
533
534 cmchar "Pacioli's original letter O";
535 beginchar("o", 2u#+side#+2o#, cap_height#, 0);
536 adjust_fit(0,0); pair durer[];
537 pcshiftx := u;
538 x2r=pcshiftx-o; x4r=w-pcshiftx+o; y1r=h; y3r=0; z0=(w/2,h/2);
539 z0=.5[z5,z6]; numeric axis_angle;
540 durer1=(x2r,y1r-o); durer2=(x4r, ypart durer1);
541 durer3=(xpart durer1, y3r+o); durer4=(xpart durer2, ypart durer3);
542 axis_angle=angle(durer2-durer3);
543 z5-z6=(thick,0)rotated axis_angle;
544 y2r=y6; y4r=y5; x1r=x5; x3r=x6;
545 forsuffixes $=1,2,3,4: z$=.5[z$l,z$r]; endfor
546 x1l=x3r; y1l-y6=y6-y3r; x5-x2l=x4r-x5; y2l=y4r;
547 x3l=x1r; y1r-y5=y5-y3l; x4l-x6=x6-x2r; y4l=y2r;
548 path p,p';
549 p=pulled_arc.r(1,2)&reverse pulled_arc.r(3,2)&
550 pulled_arc.r(3,4)&reverse pulled_arc.r(1,4)&cycle;
551 path anti_diag; anti_diag=z0--durer1;
552 z21r=p intersectionpoint anti_diag; penpos21(thin, axis_angle+90);
553 x43r=w-x21r; y43r=h-y21r; penpos43(thin, axis_angle+270);
554 path diag; diag=z0--durer2;
555 z41r=diag intersectionpoint p; penpos41(thick, axis_angle);
556 x32r=w-x41r; y32r=h-y41r; penpos32(thick, axis_angle+180);
557 if not monospace: p'=
558 z1l{left}..z21l..z2l{down}..z32l..
559 z3l{right}..z43l..
560 z4l{up}..z41l..{left}cycle;
561 else:p'=z1l..z21l..z32l..z3l..z43l..z41l..cycle; fi
562 fill p; unfill p';
563 proofpcbb(0, 0.5side, 0.5side);
564 penlabels(0,1,2,3,4,5,6,21,32,43,41); endchar;
565
566
567 cmchar "Pacioli's letter O";
568 beginchar("O", 2u#+side#+2o#, cap_height#, 0);
569 adjust_fit(0,0); pair durer[];
570 pcshiftx := u;
571 x2r=pcshiftx-o; x4r=w-pcshiftx+o; y1r=h+o; y3r=-o; z0=(w/2,h/2);
572 z0=.5[z5,z6]; numeric axis_angle;
573 durer1=(x2r,y1r-o); durer2=(x4r, ypart durer1);
574 durer3=(xpart durer1, y3r+o); durer4=(xpart durer2, ypart durer3);
575 axis_angle=angle(durer2-durer3);
576 z5-z6=(thick,0)rotated axis_angle;
577 y2r=y6; y4r=y5; x1r=x5; x3r=x6;
578 forsuffixes $=1,2,3,4: z$=.5[z$l,z$r]; endfor
579 x1l=x3r; y1l-y6=y6-y3r; x5-x2l=x4r-x5; y2l=y4r;
580 x3l=x1r; y1r-y5=y5-y3l; x4l-x6=x6-x2r; y4l=y2r;
581 path p,p';
582 p=pulled_arc.r(1,2)&reverse pulled_arc.r(3,2)&
583 pulled_arc.r(3,4)&reverse pulled_arc.r(1,4)&cycle;
584 path anti_diag; anti_diag=z0--durer1;
585 z21r=p intersectionpoint anti_diag; penpos21(thin, axis_angle+90);
586 x43r=w-x21r; y43r=h-y21r; penpos43(thin, axis_angle+270);
587 path diag; diag=z0--durer2;
588 z41r=diag intersectionpoint p; penpos41(thick, axis_angle);
589 x32r=w-x41r; y32r=h-y41r; penpos32(thick, axis_angle+180);
590 if not monospace: p'=
591 z1l{left}..z21l..z2l{down}..z32l..
592 z3l{right}..z43l..
593 z4l{up}..z41l..{left}cycle;
594 else:p'=z1l..z21l..z32l..z3l..z43l..z41l..cycle; fi
595 fill p; unfill p';
596 proofpcbb(0, 0.5side, 0.5side);
597 penlabels(0,1,2,3,4,5,6,21,32,43,41); endchar;
598
599
600 cmchar "Pacioli's letter P";
601 beginchar("P", 1.5u#+P_width#, cap_height#, 0);
602 adjust_fit(cap_serif_fit#, 0);
603 pickup tiny.nib; pos1(thick,0); pos2(thick,0);
604 top lft z1l=(.5u+cap_jut,h); bot lft z2l=(.5u+cap_jut,0);
605 filldraw stroke z1e--z2e; % vertical stem
606 pos3(medium,90); pos4(medium,90); pos5(thick,0);
607 pos6(if not monospace and serifs: .5thin else:thin fi,-90);
608 top y3r=top y4r=h; x3=x1; x4=x1r+thick; filldraw stroke z3e--z4e;
609 x6=x4; y6=hround(h/2 -medium); rt x5r=hround(x2+0.65side-cap_jut-0.5medium); y5=.75side;
610 y7=y6; if serifs: x7=.5[rt x1r, x6]; else: x7=x3; fi
611 pos7(if not monospace and serifs:.5thin else:thin fi,-90);
612 filldraw stroke pulled_super_arc.e(4,5,eta)&pulled_super_arc.e(5,6,eta)
613 ..z7e; % lobe
614 if serifs: serif(1,2,a,serif_darkness,-cap_jut);
615 serif(2,1,b,serif_darkness,-cap_jut);
616 serif(2,1,c,serif_darkness,cap_jut); fi
617 proofpcbb(2, cap_jut+0.5thick, 0);
618 penlabels(1,2,3,4,5,6,7); endchar;
619
620
621 cmchar "Pacioli's original letter Q";
622 beginchar("q", 2u#+side#+2o#, cap_height#, 0);
623 adjust_fit(0,0); pair durer[];
624 pcshiftx := u;
625 x2r=pcshiftx-o; x4r=w-pcshiftx+o; y1r=h; y3r=0; z0=(w/2,h/2);
626 z0=.5[z5,z6]; numeric axis_angle;
627 durer1=(x2r,y1r-o); durer2=(x4r, ypart durer1);
628 durer3=(xpart durer1, y3r+o); durer4=(xpart durer2, ypart durer3);
629 axis_angle=angle(durer2-durer3);
630 z5-z6=(thick,0)rotated axis_angle;
631 y2r=y6; y4r=y5; x1r=x5; x3r=x6;
632 forsuffixes $=1,2,3,4: z$=.5[z$l,z$r]; endfor
633 x1l=x3r; y1l-y6=y6-y3r; x5-x2l=x4r-x5; y2l=y4r;
634 x3l=x1r; y1r-y5=y5-y3l; x4l-x6=x6-x2r; y4l=y2r;
635 path p,p';
636 p=pulled_arc.r(1,2)&reverse pulled_arc.r(3,2)&
637 pulled_arc.r(3,4)&reverse pulled_arc.r(1,4)&cycle;
638 path anti_diag; anti_diag=z0--durer1;
639 z21r=p intersectionpoint anti_diag; penpos21(thin, axis_angle+90);
640 x43r=w-x21r; y43r=h-y21r; penpos43(thin, axis_angle+270);
641 path diag; diag=z0--durer2;
642 z41r=diag intersectionpoint p; penpos41(thick, axis_angle);
643 x32r=w-x41r; y32r=h-y41r; penpos32(thick, axis_angle+180);
644 if not monospace: p'=
645 z1l{left}..z21l..z2l{down}..z32l..
646 z3l{right}..z43l..
647 z4l{up}..z41l..{left}cycle;
648 else:p'=z1l..z21l..z32l..z3l..z43l..z41l..cycle; fi
649 fill p; unfill p';
650 z10r=z3l; z10l=z3r;
651 z11r=(pcshiftx+side,-0.25side); z11l=z11r-(0,thick);
652 z12l=z11l+(0.5side+medium,-thick); z12r=z12l+(0,0.5thin);
653 filldraw z10r..z11r..z12r--z12l..z11l..z10l--cycle;
654 proofpcbb(0, 0.5side, 0.5side);
655 penlabels(0,1,2,3,4,5,6,10,11,12,13,14,15); endchar;
656
657
658 cmchar "Pacioli's letter Q";
659 beginchar("Q", 2u#+side#+2o#, cap_height#, 0);
660 adjust_fit(0,0); pair durer[];
661 pcshiftx := u;
662 x2r=pcshiftx-o; x4r=w-pcshiftx+o; y1r=h+o; y3r=-o; z0=(w/2,h/2);
663 z0=.5[z5,z6]; numeric axis_angle;
664 durer1=(x2r,y1r-o); durer2=(x4r, ypart durer1);
665 durer3=(xpart durer1, y3r+o); durer4=(xpart durer2, ypart durer3);
666 axis_angle=angle(durer2-durer3);
667 z5-z6=(thick,0)rotated axis_angle;
668 y2r=y6; y4r=y5; x1r=x5; x3r=x6;
669 forsuffixes $=1,2,3,4: z$=.5[z$l,z$r]; endfor
670 x1l=x3r; y1l-y6=y6-y3r; x5-x2l=x4r-x5; y2l=y4r;
671 x3l=x1r; y1r-y5=y5-y3l; x4l-x6=x6-x2r; y4l=y2r;
672 path p,p';
673 p=pulled_arc.r(1,2)&reverse pulled_arc.r(3,2)&
674 pulled_arc.r(3,4)&reverse pulled_arc.r(1,4)&cycle;
675 path anti_diag; anti_diag=z0--durer1;
676 z21r=p intersectionpoint anti_diag; penpos21(thin, axis_angle+90);
677 x43r=w-x21r; y43r=h-y21r; penpos43(thin, axis_angle+270);
678 path diag; diag=z0--durer2;
679 z41r=diag intersectionpoint p; penpos41(thick, axis_angle);
680 x32r=w-x41r; y32r=h-y41r; penpos32(thick, axis_angle+180);
681 if not monospace: p'=
682 z1l{left}..z21l..z2l{down}..z32l..
683 z3l{right}..z43l..
684 z4l{up}..z41l..{left}cycle;
685 else:p'=z1l..z21l..z32l..z3l..z43l..z41l..cycle; fi
686 fill p; unfill p';
687 z10r=z3l; z10l=z3r;
688 z11r=(pcshiftx+side,-0.25side); z11l=z11r-(0,thick);
689 z12l=z11l+(0.5side+medium,-thick); z12r=z12l+(0,0.5thin);
690 filldraw z10r..z11r..z12r--z12l..z11l..z10l--cycle;
691 proofpcbb(0, 0.5side, 0.5side);
692 penlabels(0,1,2,3,4,5,6,10,11,12,13,14,15); endchar;
693
694
695 cmchar "Pacioli's letter R";
696 beginchar("R", u#+side#, cap_height#,0);
697 adjust_fit(cap_serif_fit#,0);
698 pickup tiny.nib; pos1(thick,0); pos2(thick,0);
699 top lft z1l=(.5u+cap_jut,h); bot lft z2l=(.5u+cap_jut,0);
700 filldraw stroke z1e--z2e; % vertical stem
701 pos3(thin,90); pos4(thin,90); pos5(thick,0);
702 pos6(thin, -90);
703 top y3r=top y4r=h; x3=x1; x4=x1r+thick;
704 x6=x4; y6=hround h/2; rt x5r=hround(.5u+P_width if not monospace:
705 +1/2thin fi); y5=.5[y4,y6];
706 y7=y6; x7=x3; pos7(thin, -90);
707 filldraw stroke z3e--pulled_super_arc.e(4,5,eta)&
708 pulled_super_arc.e(5,6,eta)..z7e; % lobe
709 numeric half_letter_width; 2half_letter_width+1/2u=w;
710 if serifs: half_letter_width:=half_letter_width+1/2u;
711 else: half_letter_width:=half_letter_width-1.6thin; fi
712 path p; p=pulled_super_arc.r(5,6,eta)..z7r;
713 z0r=p intersectionpoint ((half_letter_width,0)--(half_letter_width,h));
714 path circ_; circ_= (((halfcircle scaled 2thick) rotated 180) shifted z0r);
715 z0l= p intersectionpoint circ_;
716 if not monospace: z0'=(.45[half_letter_width,w],0);
717 else: z0'=(.42[half_letter_width,w],0); fi
718 numeric tail_angle; tail_angle=angle(z0l-z0');
719 penpos8(thick, tail_angle-90); z8l=whatever[z0', z0l];
720 x8=1/5[half_letter_width,w];
721 penpos9(2/3thick,tail_angle-90); z9r=whatever[z0r, z8r];
722 x9r=.5[half_letter_width, w];
723 penpos10(if monospace:1/2 dslab else: .5thin fi,90); z10l=(w,0);
724 fill z0l--z8l...{right}z10l--z10r{-w,1/4h}..z9r--z0r--cycle; % tail
725 if serifs: serif(1,2,a,serif_darkness,-cap_jut);
726 serif(2,1,b,serif_darkness,-cap_jut);
727 serif(2,1,c,serif_darkness,cap_jut); fi
728 proofpcbb(2, 1.5cap_jut+0.5thick, 0);
729 penlabels(0,1,2,3,4,5,6,7,8,9,10); labels(0'); endchar;
730
731
732 cmchar "The Knuthian S";
733 beginchar("S", 2u#+1/2 side# if not monospace:+thick# fi, cap_height#, 0);
734 adjust_fit(0,0); pickup tiny.nib;
735 pair durer[]; % points to contain corner coords of Durer square
736 ypart durer3=ypart durer4=0; xpart durer4-xpart durer1=side;
737 xpart durer1=u-1.5thick;
738 durer1=(xpart durer3, h); durer2=(xpart durer 4, ypart durer1);
739 numeric slope, diag_angle; diag_angle=angle(durer2-durer3);
740 slope=-if not monospace: 3/4 else: 1/2 fi h/(xpart durer4-xpart durer3);
741 pos0(thick,diag_angle); x0=.52[xpart durer1, xpart durer2];
742 y0=h/2;
743 lft x3l=u if not monospace:+2/3thick fi; rt x3r=lft x3l+5/6thick;
744 pos2(thin,-diag_angle); top y2l=h;
745 if x0-x3r>thick: x2l=x0 if monospace:+.4thin fi; else:
746 x2l=x0r; slope:=-1/2; fi
747 ellipse_set(2l,3l,4l,0l); ellipse_set(2r,3r,4r,0r);
748 pos7(thin,-diag_angle); x7r=x0; bot y7r=0; rt x6r=w-if monospace:.75 fi u;
749 lft x6l=rt x6r-thick;
750 ellipse_set(7l,6l,5l,0l); ellipse_set(7r,6r,5r,0r);
751 pos1(max(currentbreadth+eps,5/6 thick),-90);
752 top y1l=h-thin; rt x1=x0+2thick+o;
753 pos8(1.5thick,-80);lft x8r=u; bot y8r=medium;
754 if not monospace:
755 filldraw z1l..z2l{left}..{down}z3l..z4l--z5l..{down}z6l..{left}z7l..z8l
756 --z8r..{right}z7r..{up}z6r..z5r--z4r..{up}z3r..{right}z2r..z1r--cycle;
757 else: draw z1l..z2l{left}..{down}z3l..z4l--z5l..{down}z6l..{left}z7l..z8l;
758 draw z8r..{right}z7r..{up}z6r..z5r--z4r..{up}z3r..{right}z2r..z1r;
759 fi
760 proofpcbb(0, 0.5side, 0.5side);
761 penlabels(0,1,2,3,4,5,6,7,8); endchar;
762
763
764 cmchar "Pacioli's letter T";
765 beginchar("T",2u#+side#-2medium#, cap_height#,0);
766 adjust_fit(0,0); pickup tiny.nib;
767 pos1(thick,0); pos2(thick,0); .5[x1r,x1l]=w/2; .5[x2r,x2l]=w/2;
768 top y1=h; bot y2=0; filldraw stroke z1e--z2e; % central stem
769 numeric top_bar; top_bar=0.5side-medium; % half length of top bar
770 pos3(medium,90); pos4(dslab,0);
771 x1=x3; top y3r=h; rt x4l=x1+top_bar;
772 bot y4=vround(h-if monospace: 2 fi vstretch*(medium+cap_jut));
773 arm(3,4,c,serif_darkness,0);
774 pos5(dslab,180);
775 lft x5r=x1-top_bar;
776 bot y5= bot y4;
777 arm(3,5,d,serif_darkness,0);
778 if serifs:
779 serif(2,1,a,serif_darkness,-cap_jut);serif(2,1,b,serif_darkness,cap_jut);
780 fi
781 proofpcbb(2, 0.5side, 0);
782 penlabels(1,2,3,4); endchar;
783
784
785 cmchar "Pacioli's letter U";
786 beginchar("U", u#+2cap_jut#+.8side#, cap_height#,0);
787 adjust_fit(cap_serif_fit#, cap_serif_fit#);
788 pickup tiny.nib; pos1(thick,0); pos2(thick,0); pos2'(thick,180);
789 pos3(medium,-90); pos4(medium,0); pos5(medium,0);
790 x1=x2; x3=.5[x1,x5]; x4=x5; x1l=w-x5r;
791 top y1=top y5=h; y2=y4=1/3h; bot y3r=0; z2'=z2;
792 lft x1l=hround .5u+cap_jut;
793 filldraw stroke z1e--z2e; % left stem
794 filldraw stroke pulled_super_arc.e(2',3,eta)
795 & pulled_super_arc.e(3,4,eta)&z4e--z5e;
796 if serifs: serif(1,2,a,serif_darkness,-cap_jut);
797 serif(1,2,b,serif_darkness,cap_jut);
798 serif(5,4,c,serif_darkness,-cap_jut); serif(5,4,d,serif_darkness,cap_jut); fi
799 penlabels(1,2,3,4,5); endchar;
800
801
802 cmchar "Pacioli's letter V";
803 beginchar("V",u#+side#, cap_height#, 0);
804 adjust_fit(cap_serif_fit#, cap_serif_fit#); pickup tiny.nib;
805 pcshiftx := 0.5u;
806 z10 = (pcshiftx+0.5side,0);
807 numeric alpha; alpha=((0.5h-cap_jut)++(h))/(h);
808 pos1(alpha*thick,0); pos2(alpha*thick,0);
809 pos3(alpha*medium,0); pos4(alpha*medium,0);
810 top y1=top y4=h; lft x1l=pcshiftx+cap_jut; x4r=x1l+side-2cap_jut;
811 lft x2l=hround(pcshiftx+0.5side); x3r=x2l; bot y2=bot y3=0;
812 z0=whatever[z1r,z2r]=whatever[z3l,z4l]; % notch point
813 filldraw z0--diag_end(0,4l,1,1,4r,3r)--z2l
814 --diag_end(2l,1l,1,1,1r,0)--cycle;
815 if serifs: bracket:=cap_jut_factor*bracket; cap_jut:=cap_jut_factor*cap_jut;
816 pickup tiny.nib; numeric jut_factor;
817 if monospace: jut_factor=1; else: jut_factor=3/4; fi
818 serif(1,2,a,.8serif_darkness,-Lrad);
819 serif(4,3,d,.8serif_darkness,lrad);
820 bracket:=jut_factor*bracket;
821 serif(1,2,b,7/8 serif_darkness, jut_factor*cap_jut);
822 serif(4,3,c,7/8 serif_darkness,-jut_factor*cap_jut); fi
823 proofpcbb(10, 0.5side, 0);
824 penlabels(0,1,2,3,4); endchar;
825
826
827 cmchar "Pacioli's letter W";
828 numeric alpha;
829 alpha=((cap_height#+cap_jut#)++(.4side#+cap_jut_factor*cap_jut#))/
830 (cap_height#+cap_jut#);
831 beginchar("W", 2cap_jut_factor*cap_jut#+1.6side#-alpha*thick#, cap_height#, 0);
832 adjust_fit(.5cap_serif_fit#, cap_serif_fit#); pickup tiny.nib;
833 mid_corr=if monospace: -apex_corr else: 1/3jut fi;
834 pos1(alpha*thick,0); pos2(alpha*thick,0);
835 pos3(alpha*medium,0); pos4(alpha*medium,0);
836 pos5(alpha*thick,0); pos6(alpha*thick,0);
837 pos7(alpha*medium,0); pos8(alpha*medium,0);
838 numeric V_width; V_width=2cap_jut_factor*cap_jut+4/5side;
839 if not monospace:
840 top y1=top y4=h; lft x1l=cap_jut_factor*cap_jut; x4r=V_width-x1l;
841 lft x2l=hround V_width/2; x3r=x2l; bot y2=bot y3=0;
842 pair shift_amt; ypart shift_amt=0;
843 xpart shift_amt=V_width-2cap_jut_factor*cap_jut-alpha*(thick);
844 z0=whatever[z1r,z2r]=whatever[z3l,z4l]; % notch point
845 path p; p=z0--diag_end(0,4l,1,1,4r,3r)--z2l
846 --diag_end(2l,1l,1,1,1r,0)--cycle;
847 filldraw p; filldraw (p shifted shift_amt); % the 2 V's
848 forsuffixes t=1,2,3,4: z[t+4]=z.t shifted shift_amt; endfor
849 else: top y1=h; lft x1l=cap_jut_factor*cap_jut; bot y2=bot y3=0;
850 x2l+apex_corr=x3l;
851 x8=w-x1; y8=y1; x2-x1=x4-x3=x6-x5=x8-x7;
852 x6l+apex_corr=x7l; y6=y7=y2;
853 y4:=vround .6h; y5=y4;
854 x5=x4;
855 y4l:=y4r:=y4; % ??
856 z0 =whatever[z1r,z2r];
857 z0'=whatever[z7l,z8l]; y0=y0'=h/9;
858 z45=whatever[z3r,z4r]=whatever[z5l,z6l];
859 filldraw z0--diag_end(0,4l,1,1,4r,3r)--z2l--diag_end(2l,1l,1,1,1r,0)--cycle;
860 filldraw z0'--diag_end(0',8l,1,1,8r,7r)--z7l--diag_end(7l,5l,1,1,5r,0')
861 --cycle; fi
862 if serifs: bracket:=cap_jut_factor*bracket; cap_jut:=cap_jut_factor*cap_jut;
863 pickup tiny.nib; numeric jut_factor;
864 if monospace: jut_factor=1.8; else: jut_factor=3/4; fi
865 serif(1,2,a,.8serif_darkness,-cap_jut);
866 serif(8,7,f,.8serif_darkness,cap_jut);
867 if not monospace: serif(5,6,d,.8serif_darkness,cap_jut);
868 serif(5,6,c,.8serif_darkness,-cap_jut); fi
869 bracket:=jut_factor*bracket;
870 serif(1,2,b,7/8 serif_darkness, jut_factor*cap_jut);
871 serif(8,7,e,7/8 serif_darkness,-jut_factor*cap_jut);
872 fi
873 penlabels(0,0',1,2,3,4,5,6,7,8,45); endchar;
874
875
876 cmchar "Pacioli's letter X";
877 beginchar("X", u#+side#, cap_height#, 0);
878 adjust_fit(cap_serif_fit#, cap_serif_fit#);
879 pcshiftx := 0.5u;
880 z10=(pcshiftx+0.5side, 0.5side); % center of the square
881 numeric alpha; alpha=(h++(h-2thick))/h;
882 penpos1(alpha*thick,0); penpos4(alpha*thick,0);
883 penpos2(alpha*medium,0); penpos3(alpha*medium,0);
884 lft x3l = pcshiftx+thick; y3=0; y2=side;
885 0.5[z3l,z2l]=z10;
886 y4 = 0; y1 = side;
887 lft x1l = pcshiftx+1.5thick;
888 0.5[z4l,z1l]=z10;
889 filldraw z1l--z1r--z4r--z4l--cycle; % draw the thick limb
890 filldraw z2l--z2r--z3r--z3l--cycle; % draw the other limb
891 if serifs: bracket:=cap_jut_factor*bracket; cap_jut:=cap_jut_factor*cap_jut;
892 pickup tiny.nib; numeric jut_factor;
893 if monospace: cap_jut:=.5cap_jut; jut_factor=1; else: jut_factor=3/4; fi
894 serif(1,4,a,.8serif_darkness,-Lrad);
895 serif(4,1,d,.8serif_darkness,cap_jut);
896 serif(2,3,f,.8serif_darkness,cap_jut);
897 serif(3,2,g,.8serif_darkness,-lrad);
898 bracket:=jut_factor*bracket;
899 serif(1,4,b,7/8 serif_darkness,.75cap_jut);
900 serif(4,1,c,7/8 serif_darkness,-.75cap_jut);
901 serif(2,3,e,7/8 serif_darkness,-.75cap_jut);
902 serif(3,2,h,7/8 serif_darkness,.75cap_jut); fi
903 proofpcbb(10, 0.5side, 0.5side);
904 penlabels(1,2,3,4); endchar;
905
906
907 cmchar "Pacioli's letter Y";
908 beginchar("Y", u#+side#, cap_height#, 0);
909 adjust_fit(cap_serif_fit#, cap_serif_fit#); pickup pencircle scaled 0pt;
910 pcshiftx := 0.5u;
911 z100 = (pcshiftx+0.5side,0.5side); % center of the square
912 numeric alpha, long, short, hypot; long=h/2;
913 short=0.5side-thick;
914 hypot=long++short; alpha=hypot/long;
915 penpos1(alpha*thick,0);
916 lft x1l=pcshiftx+thick;
917 top y1=h;
918 penpos4(alpha*medium,0); y4=y1; x4r=x1l+side-2thick;
919 penpos2(alpha*thick,0); penpos3(alpha*medium,0);
920 y2 = y3 = 0.5side;
921 penpos5(thick,0); penpos6(thick,0);
922 z2l = z3r = z100;
923 z6 = (pcshiftx+0.5side,0);
924 z5 = (x6,side);
925 z0=whatever[z1r, z2r]=whatever[z3l,z4l]; % notch point
926 z7=whatever[z6l,z5l] = whatever[z2l,z1l]; % left stem and V
927 z8=whatever[z6r,z5r] = whatever[z3r,z4r]; % right stem and V
928 filldraw z1r--z0--z4l--z4r--z8--z6r--z6l--z7--z1l--cycle;
929 if serifs: numeric jut_factor;
930 serif(6,5,e,serif_darkness,-cap_jut); serif(6,5,f,serif_darkness,cap_jut);
931 bracket:=cap_jut_factor*bracket; cap_jut:=cap_jut_factor*cap_jut;
932 if monospace: cap_jut:=.5cap_jut; jut_factor=1; else: jut_factor=3/4; fi
933 % top outer serifs
934 serif(1,2,a,serif_darkness,-lrad);serif(4,3,d,serif_darkness,lrad);
935 bracket:=jut_factor*bracket;
936 if monospace: cap_jut:=1.5cap_jut; fi
937 % top inner serifs
938 serif(1,2,b,7/8 serif_darkness,.6cap_jut);
939 serif(4,3,c,7/8 serif_darkness,-.6cap_jut);
940 fi
941 proofpcbb(100, 0.5side, 0.5side);
942 penlabels(0,1,2,3,4,5,6); endchar; % End of "Y"
943
944
945 cmchar "Pacioli's letter Z";
946 beginchar("Z", 2u#+.8side#, cap_height#,0);
947 adjust_fit(0, 0); pickup tiny.nib;
948 pcshiftx := u;
949 numeric alpha, long, short, hypot;
950 long=h; short=w-2u-thick; hypot=long++short;
951 alpha=hypot/long;
952 pos1(medium,90); pos2(medium,90); pos3(alpha*thick, 0);
953 pos4(alpha*thick, 0); pos5(medium,-90); pos6(medium,-90);
954 rt x3r=w-u; top y3=h; x4l=w-x3r; bot y4=0;
955 top y1r=h; lft x1=u; y2=y1; rt x2=x3;
956 bot y5r=bot y6r=0; lft x5=x4; rt x6=w-u;
957 filldraw stroke z1e--z2e; % top bar
958 filldraw stroke z3e--z4e; % diagonal
959 filldraw stroke z5e--z6e; % bottom bar
960 z100 = (0.5(x1+x3r),0.5side); % center of square
961 if serifs: pickup crisp.nib; % prepare for arms and serifs
962 pos7(medium, 90); pos8(dslab,180); z7=z2; lft x8r=u;
963 bot y8=h-if monospace:2 fi vstretch*thick;
964 arm(7,8,a,serif_darkness,0); % upper dropped serif
965 pos9(medium,-90); z9=z5; pos10(dslab,0); rt x10r=w-u;
966 top y10=if monospace: 2.5 fi vstretch*thick;
967 arm(9,10,b,serif_darkness,0); fi
968 proofpcbb(100, 0.5side, 0.5side);
969 penlabels(1,2,3,4,5,6,7,8,9,10); endchar;
970