Debian Codegraph @

texmf-dist/fonts/source/public/pacioli/cpcpunct.mf

raw
1 %%
2 %% This is file `cpcpunct.mf',
3 %% generated with the docstrip utility.
4 %%
5 %% The original source files were:
6 %%
7 %% pacioli.dtx (with options: `punct')
8 %%
9 %% Copyright 1999 Peter R. Wilson
10 %%
11 %% This program is provided under the terms of the
12 %% LaTeX Project Public License distributed from CTAN
13 %% archives in directory macros/latex/base/lppl.txt.
14 %%
15 %% Author: Peter Wilson (CUA and NIST)
16 %% now at: [email protected]
17 %%
18
19
20 cmchar "Exclamation point";
21 beginchar("!",5u#+width_adj#,asc_height#,0);
22 italcorr asc_height#*slant-2u#-.5width_adj#+.5dot_size#;
23 adjust_fit(0,0);
24 pickup tiny.nib; pos3(dot_size,0); pos4(dot_size,90);
25 lft x3l=hround(.5w-.5dot_size); bot y4l=0; z3=z4; dot(3,4); % dot
26 numeric bot_width;
27 bot_width=if hefty:max(hround .8dot_size,fine.breadth) else: hair fi;
28 pickup fine.nib; pos1(dot_size,0); pos2(bot_width,0);
29 x1=x2=x3; bot y2=.25[top y4r,x_height]+1;
30 if square_dots: top y1=h;
31 filldraw stroke z1e--z2e; % stem
32 else: top z0=(x1,h+o); y1+.5dot_size=h+o;
33 filldraw z1r...z0...z1l---z2l--z2r---cycle; fi % stem and bulb
34 penlabels(0,1,2,3,4); endchar;
35
36
37 cmchar "Apostrophe";
38 beginchar("'",5u#,asc_height#,0);
39 italcorr asc_height#*slant+.5dot_size#-2u#;
40 adjust_fit(0,0);
41 x1-.5dot_size=hround(.5w-.5dot_size); y1+.5dot_size=h;
42 if monospace: comma(1,a,dot_size,.28u,vround 1.5comma_depth); % large comma
43 else: comma(1,a,dot_size,.25u,comma_depth); fi % comma with increased jut
44 penlabels(1); endchar;
45
46
47 cmchar "Left parenthesis";
48 beginchar("(",7u# if monospace: -u# fi,body_height#,paren_depth#);
49 italcorr body_height#*slant-.5u#;
50 adjust_fit(0,0); pickup fine.nib;
51 pos1(vair,0); pos2(.75[hair,stem],0); pos3(vair,0);
52 rt x1r=rt x3r=hround(w-u); lft x2l=hround(x1-4u if monospace: +4/3u fi);
53 top y1=h; y2=.5[y1,y3]=math_axis;
54 filldraw stroke z1e{3(x2e-x1e),y2-y1}...z2e
55 ...{3(x3e-x2e),y3-y2}z3e; % arc
56 penlabels(1,2,3); endchar;
57
58
59 cmchar "Right parenthesis";
60 beginchar(")",7u# if monospace: -u# fi,body_height#,paren_depth#);
61 italcorr math_axis#*slant-.5u#;
62 adjust_fit(0,0); pickup fine.nib;
63 pos1(vair,0); pos2(.75[hair,stem],0); pos3(vair,0);
64 lft x1l=lft x3l=hround u; rt x2r=hround(x1+4u if monospace: -4/3u fi);
65 top y1=h; y2=.5[y1,y3]=math_axis;
66 filldraw stroke z1e{3(x2e-x1e),y2-y1}...z2e
67 ...{3(x3e-x2e),y3-y2}z3e; % arc
68 penlabels(1,2,3); endchar;
69
70
71 cmchar "Comma";
72 numeric dot_diam#; dot_diam#=if monospace: 5/4 fi\\ dot_size#;
73 define_whole_blacker_pixels(dot_diam);
74 beginchar(",",5u#,dot_diam#,comma_depth#);
75 adjust_fit(0,0);
76 x1-.5dot_diam=hround(.5w-.5dot_diam); y1-.5dot_diam=0;
77 comma(1,a,dot_diam,.2u,comma_depth); % dot and tail
78 penlabels(1); endchar;
79
80
81 cmchar "Period";
82 numeric dot_diam#; dot_diam#=if monospace: 5/4 fi\\ dot_size#;
83 define_whole_blacker_pixels(dot_diam);
84 beginchar(".",5u#,dot_diam#,0);
85 adjust_fit(0,0); pickup fine.nib;
86 pos1(dot_diam,0); pos2(dot_diam,90);
87 lft x1l=hround(.5w-.5dot_diam); bot y2l=0; z1=z2; dot(1,2); % dot
88 penlabels(1,2); endchar;
89
90
91 cmchar "Virgule (slash)";
92 beginchar("/",9u#,body_height#,paren_depth#);
93 italcorr body_height#*slant-.5u#;
94 adjust_fit(0,0); pickup rule.nib;
95 rt x1=hround(w-u)+eps; top y1=h+eps;
96 lft x2=hround u-eps; bot y2=-d-eps;
97 draw z1--z2; % diagonal
98 penlabels(1,2); endchar;
99
100
101 cmchar "Colon";
102 numeric dot_diam#; dot_diam#=if monospace: 5/4 fi\\ dot_size#;
103 define_whole_blacker_pixels(dot_diam);
104 beginchar(":",5u#,x_height#,0);
105 italcorr x_height#*slant+.5dot_diam#-2u#;
106 adjust_fit(0,0); pickup fine.nib;
107 pos1(dot_diam,0); pos2(dot_diam,90);
108 lft x1l=hround(.5w-.5dot_diam); top y2r=h; z1=z2; dot(1,2); % upper dot
109 pos3(dot_diam,0); pos4(dot_diam,90);
110 x3=x1; bot y4l=0; z3=z4; dot(3,4); % lower dot
111 penlabels(1,2,3,4); endchar;
112
113
114 cmchar "Semicolon";
115 numeric dot_diam#; dot_diam#=if monospace: 5/4 fi\\ dot_size#;
116 define_whole_blacker_pixels(dot_diam);
117 beginchar(";",5u#,x_height#,comma_depth#);
118 italcorr x_height#*slant+.5dot_diam#-2u#;
119 adjust_fit(0,0); pickup fine.nib;
120 pos1(dot_diam,0); pos2(dot_diam,90);
121 lft x1l=hround(.5w-.5dot_diam); top y2r=h; z1=z2; dot(1,2); % upper dot
122 x3-.5dot_diam=hround(.5w-.5dot_diam); y3-.5dot_diam=0;
123 comma(3,a,dot_diam,.05u,comma_depth); % lower dot and tail
124 penlabels(1,2,3); endchar;
125
126
127 cmchar "Left bracket";
128 numeric wd#; wd#=max(5u#,4.5u#+.5if hefty:stem# else:rule_thickness# fi);
129 beginchar("[",wd#,body_height#,paren_depth#);
130 italcorr body_height#*slant;
131 adjust_fit(0,0);
132 numeric top_thickness,side_thickness;
133 if hefty: top_thickness=vair;
134 side_thickness=max(crisp.breadth,stem-2stem_corr);
135 else: top_thickness=side_thickness=rule_thickness; fi;
136 pickup crisp.nib; pos1(side_thickness,0); pos2(side_thickness,0);
137 top y1=h; bot y2=-d; lft x1l=lft x2l=hround(2.5u-.5side_thickness)-1-eps;
138 filldraw stroke z1e--z2e; % stem
139 pos3(top_thickness,90); pos4(top_thickness,90);
140 pos5(top_thickness,90); pos6(top_thickness,90);
141 x3=x5=x1l; rt x4=rt x6=ceiling(w-.4u)+eps; y3r=y4r=y1; y5l=y6l=y2;
142 filldraw stroke z3e--z4e; % upper bar
143 filldraw stroke z5e--z6e; % lower bar
144 penlabels(1,2,3,4,5,6); endchar;
145
146
147 cmchar "Right bracket";
148 numeric wd#; wd#=max(5u#,4.5u#+.5if hefty:stem# else:rule_thickness# fi);
149 beginchar("]",wd#,body_height#,paren_depth#);
150 italcorr body_height#*slant-2u#+.5if hefty:stem# else:rule_thickness# fi;
151 adjust_fit(0,0);
152 numeric top_thickness,side_thickness;
153 if hefty: top_thickness=vair;
154 side_thickness=max(crisp.breadth,stem-2stem_corr);
155 else: top_thickness=side_thickness=rule_thickness; fi;
156 pickup crisp.nib; pos1(side_thickness,0); pos2(side_thickness,0);
157 top y1=h; bot y2=-d; rt x1r=rt x2r=hround(w-2.5u+.5side_thickness)+1+eps;
158 filldraw stroke z1e--z2e; % stem
159 pos3(top_thickness,90); pos4(top_thickness,90);
160 pos5(top_thickness,90); pos6(top_thickness,90);
161 x3=x5=x1r; lft x4=lft x6=floor .4u-eps; y3r=y4r=y1; y5l=y6l=y2;
162 filldraw stroke z3e--z4e; % upper bar
163 filldraw stroke z5e--z6e; % lower bar
164 penlabels(1,2,3,4,5,6); endchar;
165
166
167 cmchar "Reverse apostrophe";
168 beginchar("`",5u#,asc_height#,0);
169 italcorr asc_height#*slant+.5dot_size#-2u#;
170 adjust_fit(0,0);
171 x1-.5dot_size=hround(.5w-.5dot_size); y1+.5dot_size=h-comma_depth;
172 if monospace: ammoc(1,a,dot_size,.28u,vround 1.5comma_depth); % large ammoc
173 else: ammoc(1,a,dot_size,.25u,comma_depth); fi % normal ammoc
174 penlabels(1); endchar;
175