Debian Codegraph @

texmf-dist/fonts/source/public/oldlatin/oromlig.mf

raw
1 % THIS IS THE OLD LATIN SOURCE FILE oromlig.mf BY T. TERASHITA.
2 % IT MUST NOT BE MODIFIED IN ANY WAY UNLESS THE FILE NAME IS CHANGED!
3
4 % Old Latin ligatures part 1 (part 2 is oromligs.mf)
5 % based on romlig.mf by D E Knuth.
6 % This file describes five roman ligatures that begin with `f'
7 % and puts them in code positions \0013--\0017.
8
9 numeric itc#; % modified italic correction on `f' and `ff'
10 itc#=if serifs: max(0,flare#-.25u#) else: 1.25u# fi;
11
12 ligtable "f": "i"=:oct"014", "f"=:oct"013", "l"=:oct"015",
13 "'" kern itc#, "?" kern itc#, "!" kern itc#, ")" kern itc#, "]" kern itc#;
14 ligtable oct"013": "i"=:oct"016", "l"=:oct"017",
15 "'" kern itc#, "?" kern itc#, "!" kern itc#, ")" kern itc#, "]" kern itc#;
16
17 cmchar "The ligature ff";
18 beginchar(oct"013",10.5u#+2letter_fit#,asc_height#,0);
19 italcorr asc_height#*slant+if serifs:flare#-.25u# else: 1.25u# fi;
20 adjust_fit(0,0);
21 pickup tiny.nib; pos1(stem',0); lft x1l=hround(2.5u-.5stem');
22 pos11(stem',0); rt x11r=hround(w-3u+.5stem');
23 pickup fine.nib; numeric bulb_diam, inner_jut;
24 if serifs: bulb_diam=hround .8[stem,flare];
25 pos2(bulb_diam,0); pos12(bulb_diam,0);
26 rt x2r=hround(rt x11r-stem_corr); lft x12l=hround(w-.75u+.5);
27 y2+.5bulb_diam=.85[x_height,h+oo]; y12+.5bulb_diam=.9[x_height,h+oo];
28 if rt x1r+jut+.5u+2<=lft x11l-jut: inner_jut=jut;
29 else: rt x1r+inner_jut+.5u+2=lft x11l-inner_jut; fi
30 else: pos2(5/7[vair,flare],90); top y2r=h; rt x2=hround 6.25u;
31 pos12(5/7[vair,flare],90); y12=y2; rt x12=hround(w+.75u); fi
32 f_stroke(1,2,a,b,c,jut,inner_jut); % left stem, arc, terminal, serif
33 f_stroke(11,12,d,e,f,inner_jut,1.25jut); % right stem, arc, terminal, serif
34 pickup crisp.nib; top y3r=top y4r=x_height; lft x3=hround .5u-1;
35 pos3(bar,90); pos4(bar,90);
36 rt x4=hround(w-1/3u);
37 if hefty: pos3'(bar,90); x3'-x1=x4-x11; y3'=y3;
38 pos4'(bar,90); x4'=x11; y4'=y4;
39 filldraw stroke z3e--z3'e; filldraw stroke z4'e--z4e; % bars
40 else: filldraw stroke z3e--z4e; fi % bar
41 penlabels(1,2,3,4,11,12); endchar;
42
43 cmchar "The ligature fi";
44 beginchar(oct"014",10u#+2letter_fit#,asc_height#,0);
45 italcorr asc_height#*slant-serif_fit#+.5if serifs:stem# else:dot_size# fi-2u#;
46 adjust_fit(0,serif_fit#);
47 pickup tiny.nib; pos1(stem',0); lft x1l=hround(2.5u-.5stem');
48 pos11(stem',0); rt x11r=hround(w-2.5u+.5stem');
49 pos12(stem',0); x11=x12; bot y12=0;
50 pickup fine.nib; numeric bulb_diam, inner_jut;
51 if serifs: bulb_diam=hround 1/4[.8[stem,flare],dot_size];
52 pos2(bulb_diam,0); x2r=x12r;
53 y2+.5bulb_diam=.8[x_height,h+oo]; top y11=x_height+min(oo,serif_drop);
54 if rt x1r+jut+.5u+2<=lft x11l-jut: inner_jut=jut;
55 else: rt x1r+inner_jut+.5u+2=lft x11l-inner_jut; fi
56 else: bulb_diam=max(stem,dot_size);
57 pos2(6/7[vair,flare],90); top y2r=h; rt x2=hround 5.3u;
58 pickup tiny.nib; pos13(bulb_diam,0); pos14(bulb_diam,90);
59 x13=x11-.5; top y14r=min(10/7x_height+.5bulb_diam,h)+1; top y11=x_height;
60 if bot y14l-x_height<tiny: y14l:=min(y14r-eps,y11+2tiny); fi
61 x13=x14; y13=.5[y14l,y14r]; dot(13,14); % dot
62 fi; % this is the ligature we're drawing
63 f_stroke(1,2,a,b,c,jut,inner_jut); % left stem, arc, terminal, serif
64 pickup tiny.nib; filldraw stroke z11e--z12e; % right stem
65 pickup crisp.nib; top y3r=top y4r=x_height; lft x3=hround .5u-1;
66 pos3(bar,90); pos4(bar,90);
67 if serifs: x4=x11; % bar will overlap upper right serif
68 sloped_serif.l(11,12,d,1/3,jut,min(oo,serif_drop)); % upper right serif
69 dish_serif(12,11,e,1/3,inner_jut,f,1/3,jut); % lower right serif
70 else: rt x4= hround 5.3u; fi
71 pickup crisp.nib; filldraw stroke z3e--z4e; % bar
72 penlabels(1,2,3,4,11,12,13,14); endchar;
73
74 cmchar "The ligature fl";
75 beginchar(oct"015",10u#+2letter_fit#,asc_height#,0);
76 italcorr asc_height#*slant-serif_fit#+.5stem#-2u#;
77 adjust_fit(0,serif_fit#);
78 pickup tiny.nib; pos1(stem',0); lft x1l=hround(2.5u-.5stem');
79 pos11(stem',0); rt x11r=hround(w-2.5u+.5stem');
80 pos12(stem',0); x11=x12; bot y12=0; top y11=h;
81 filldraw stroke z11e--z12e; % right stem
82 pickup fine.nib; numeric bulb_diam, inner_jut;
83 if serifs: bulb_diam=hround .8[stem,flare];
84 pos2(bulb_diam,0); x2r=x11r-stem_corr;
85 y2+.5bulb_diam=.9[x_height,h+oo];
86 sloped_serif.l(11,12,d,1/3,eps,max(serif_drop,oo)); % erase excess at top
87 if rt x1r+jut+.5u+2<=lft x11l-jut: inner_jut=jut;
88 else: rt x1r+inner_jut+.5u+2=lft x11l-inner_jut; fi
89 else: pos2(5/7[vair,flare],90); top y2r=h; rt x2=hround 5.3u; fi
90 f_stroke(1,2,a,b,c,jut,inner_jut); % left stem, arc, terminal, serif
91 pickup crisp.nib; top y3r=top y4r=x_height; lft x3=hround .5u-1;
92 pos3(bar,90); pos4(bar,90);
93 if serifs: x4=x11;
94 dish_serif(12,11,e,1/3,inner_jut,f,1/3,jut); % lower right serif
95 else: rt x4= hround 5.3u; fi
96 pickup crisp.nib; filldraw stroke z3e--z4e; % bar
97 penlabels(1,2,3,4,11,12); endchar;
98
99 cmchar "The ligature ffi";
100 beginchar(oct"016",15u#+4letter_fit#,asc_height#,0);
101 italcorr asc_height#*slant-serif_fit#+.5if serifs:stem# else:dot_size# fi-2u#;
102 adjust_fit(0,serif_fit#);
103 pickup tiny.nib; pos1(stem',0); lft x1l=hround(2.5u-.5stem');
104 pos11(stem',0); lft x11l=hround(.5w-.5stem');
105 pos21(stem',0); rt x21r=hround(w-2.5u+.5stem');
106 pos22(stem',0); x21=x22; bot y22=0;
107 pickup fine.nib; numeric bulb_diam, inner_jut;
108 if serifs: bulb_diam=hround 1/4[.8[stem,flare],dot_size];
109 pos2(bulb_diam,0); x2r=x11r-stem_corr;
110 pos12(bulb_diam,0); x12r=x21r;
111 top y21=x_height+min(oo,serif_drop);
112 y2+.5bulb_diam=.8[x_height,h+oo]; y12=y2;
113 if rt x1r+jut+.5u+2<=lft x11l-jut: inner_jut=jut;
114 else: rt x1r+inner_jut+.5u+2=lft x11l-inner_jut; fi
115 else: bulb_diam=max(stem,dot_size);
116 pos2(5/7[vair,flare],90); top y2r=h; rt x2=hround 5.75u;
117 pos12(6/7[vair,flare],90); y12=y2; rt x12=hround(.5w+2.8u);
118 pickup tiny.nib; pos23(bulb_diam,0); pos24(bulb_diam,90);
119 x23=x21-.5; top y24r=min(10/7x_height+.5bulb_diam,h)+1; top y21=x_height;
120 if bot y24l-x_height<tiny: y24l:=min(y24r-eps,y21+2tiny); fi
121 x23=x24; y23=.5[y24l,y24r]; dot(23,24); fi % dot
122 f_stroke(1,2,a,b,c,jut,inner_jut); % left stem, arc, terminal, serif
123 f_stroke(11,12,d,e,f,inner_jut,inner_jut); % middle ditto
124 pickup tiny.nib; filldraw stroke z21e--z22e; % right stem
125 pickup crisp.nib; top y3r=top y4r=x_height; lft x3=hround.5u-1;
126 pos3(bar,90); pos4(bar,90);
127 if serifs: x4=x21; % bar will overlap upper right serif
128 sloped_serif.l(21,22,g,1/3,jut,min(oo,serif_drop)); % upper right serif
129 dish_serif(22,21,h,1/3,inner_jut,i,1/3,jut); % lower right serif
130 else: rt x4=hround(.5w+2.8u); fi
131 pickup crisp.nib;
132 if hefty: pos3'(bar,90); x3'-x1=x4-x11; y3'=y3;
133 pos4'(bar,90); x4'=x11; y4'=y4;
134 filldraw stroke z3e--z3'e; filldraw stroke z4'e--z4e; % bars
135 else: filldraw stroke z3e--z4e; fi % bar
136 penlabels(1,2,3,4,11,12,21,22,23,24); endchar;
137
138 cmchar "The ligature ffl";
139 beginchar(oct"017",15u#+4letter_fit#,asc_height#,0);
140 italcorr asc_height#*slant-serif_fit#+.5stem#-2u#;
141 adjust_fit(0,serif_fit#);
142 pickup tiny.nib; pos1(stem',0); lft x1l=hround(2.5u-.5stem');
143 pos11(stem',0); lft x11l=hround(.5w-.5stem');
144 pos21(stem',0); rt x21r=hround(w-2.5u+.5stem');
145 pos22(stem',0); x21=x22; bot y22=0; top y21=h;
146 filldraw stroke z21e--z22e; % right stem
147 pickup fine.nib; numeric bulb_diam, inner_jut;
148 if serifs: bulb_diam=hround .8[stem,flare];
149 pos2(bulb_diam,0); x2r=x11r-stem_corr;
150 pos12(bulb_diam,0); x12r=x21r-stem_corr;
151 y2+.5bulb_diam=.85[x_height,h+oo]; y12+.5bulb_diam=.9[x_height,h+oo];
152 sloped_serif.l(21,22,g,1/3,eps,max(serif_drop,oo)); % erase excess at top
153 if rt x1r+jut+.5u+2<=lft x11l-jut: inner_jut=jut;
154 else: rt x1r+inner_jut+.5u+2=lft x11l-inner_jut; fi
155 else: pos2(5/7[vair,flare],90); top y2r=h; rt x2=hround 5.75u;
156 pos12(5/7[vair,flare],90); y12=y2; rt x12=hround(.5w+2.8u); fi
157 f_stroke(1,2,a,b,c,jut,inner_jut); % left stem, arc, terminal, serif
158 f_stroke(11,12,d,e,f,inner_jut,inner_jut); % middle ditto
159 pickup crisp.nib; top y3r=top y4r=x_height; lft x3=hround.5u-1;
160 pos3(bar,90); pos4(bar,90);
161 if serifs: dish_serif(22,21,h,1/3,inner_jut,i,1/3,jut); % lower right serif
162 pickup crisp.nib; x4=x21;
163 else: rt x4=hround(.5w+2.8u); fi
164 if hefty: pos3'(bar,90); x3'-x1=x4-x11; y3'=y3;
165 pos4'(bar,90); x4'=x11; y4'=y4;
166 filldraw stroke z3e--z3'e; filldraw stroke z4'e--z4e; % bars
167 else: filldraw stroke z3e--z4e; fi % bar
168 penlabels(1,2,3,4,11,12,21,22); endchar;