Debian Codegraph @

texmf-dist/fonts/source/public/oldlatin/oromanl.mf

raw
1 % THIS IS THE OLD LATIN SOURCE FILE oromanl.mf BY T. TERASHITA.
2 % IT MUST NOT BE MODIFIED IN ANY WAY UNLESS THE FILE NAME IS CHANGED!
3
4 % Old Latin Roman lower case
5 % based on Computer Modern Roman lower case
6 % (romanl.mf by D E Knuth):
7 % These letters were originally coded by D. E. Knuth in November, 1979,
8 % inspired by the Monotype faces used in {\sl The Art of Computer Programming}.
9 % Sans serif designs by Richard Southall were added in April, 1982.
10 % The programs were revised for the new \MF\ conventions in 1985.
11
12 % Character codes \0141 through \0172 are generated.
13
14 cmchar "The letter a";
15 beginchar("a",9u#,x_height#,0);
16 bh#:=min(bar_height#,1.14x_height#-bar_height#); define_pixels(bh);
17 italcorr 1/3[bh#,x_height#]*slant+.5stem#-serif_fit#-2u#;
18 adjust_fit(0,serif_fit# if serifs: if hair#+.5stem#>1.5u#:-.25u# fi\\fi);
19 pickup fine.nib; top y3r=h+vround 1.5oo;
20 if serifs: pos1(flare,180); pos2(hair,180);
21 pos3(vair,90); lft x1r=hround max(u,2.1u-.5flare); x3=.5w-.5u;
22 y1=min(bh+.5flare+2vair+2,.9[bh,h]-.5flare);
23 bulb(3,2,1); % bulb
24 else: pos1(5/7[vair,flare],95); x1l=good.x 1.5u; x1r:=good.x x1r;
25 pos3(1/8[vair,thin_join],90);
26 x3=.5w-.2u; top y1r=vround .82[bh,top y3r];
27 filldraw stroke term.e(3,1,left,.9,4); fi % terminal
28 pos4(stem,0); rt x4r=hround(w-2.5u+.5stem); y4=1/3[bh,h];
29 pos5(stem,0); x5=x4; y5=max(.55bh,2vair);
30 filldraw stroke super_arc.e(3,4)&z4e..z5e; % arc and stem
31 pos6(.3[thin_join,vair],90); x6=x4; bot y6=bh;
32 pos7(hround(curve-2stem_corr),180);
33 lft x7r=hround max(.5u,1.5u-.5curve); y7=1/3[top y8l,top y6r];
34 pos8(vair,270); x8l=.5w-.75u; bot y8r=-oo;
35 pos9(thin_join,360); z9l=z5l;
36 (x,y8r)=whatever[z8l,z9l]; x8r:=max(x,x8-u);
37 {{interim superness:=more_super;
38 filldraw stroke z9e{down}...z8e{left}...{up}z7e&super_arc.e(7,6)}}; % bowl
39 if serifs: numeric shaved_stem; shaved_stem=hround(stem-3stem_corr);
40 if hair#+.5stem#>1.5u#: pickup tiny.nib;
41 pos5'(shaved_stem,0); rt x5'r=fine.rt x5r; y5'=y5;
42 pos10(shaved_stem,0); x10=x5'; y10=.2[.5tiny,bh];
43 pos11(shaved_stem,0); rt x11r=hround(w-.25u); bot y11=0;
44 pos12(shaved_stem,0); x11=x12; top y12=slab+eps;
45 filldraw z5'l---z10l...z11l{right}--z11r
46 --z12r{left}...z10r+.75(z12-z11)---z5'r--cycle; % foot
47 else: pickup crisp.nib; pos5'(shaved_stem,0); rt x5'r=fine.rt x5r; y5'=y5;
48 pos10(shaved_stem,0); x10=x5'; y10=1/3bh;
49 pos11(.2[vair,stem],90); x11r=.5[x10r,x12r]; bot y11l=-vround .5oo;
50 pos12(hair,180); rt x12l=hround(w-.1u); y12=max(y10,y11+vair);
51 pos13(hair,180); x13=x12; top y13=max(vround .6bh,top y12);
52 (x',y11l)=whatever[z11r,z12r]; x11l:=max(x',x10);
53 filldraw stroke z5'e---z10e...z11e{right}...z12e---z13e; fi % hook
54 else: numeric shaved_stem; shaved_stem=hround(stem-stem_corr);
55 pickup tiny.nib; pos5'(shaved_stem,0); rt x5'r=fine.rt x5r; y5'=y5;
56 pos10(shaved_stem,0); x10=x5'; bot y10=0;
57 filldraw stroke z5'e--z10e; fi % base of stem
58 penlabels(1,2,3,4,5,6,7,8,9,10,11,12,13); endchar;
59
60 cmchar "The letter b";
61 beginchar("b",10u#+serif_fit#,asc_height#,0);
62 italcorr .5x_height#*slant+min(.5curve#-u#,-.25u#);
63 adjust_fit(serif_fit#,0);
64 pickup tiny.nib; pos1(stem',0); pos2(stem,0);
65 pos0'(stem',0); pos0(stem,0); z0l=z0'l; x0'=x1; x0=x2;
66 lft x1l=hround(2.5u-.5stem'); top y1=h;
67 numeric edge; edge=rt x2r;
68 pickup fine.nib; pos3(if hefty:thin_join else: hair fi,180);
69 pos4(vair,90); pos5(curve,0); pos6(vair,-90); penpos7(x3l-x3r,-180);
70 rt x3l=max(rt x3l-(lft x3r-tiny.lft x2l),1/3[rt x2,edge]);
71 y3=1/8[bar_height,x_height];
72 x4l=w-.5(w-serif_fit)+.5u; top y4r=x_height+oo;
73 rt x5r=hround min(w-1.35u+.5curve,w-.6u); y5=.5x_height;
74 x6l=x4l-.2u; bot y6r=-oo;
75 x7=x3; y7=min(y3,y6+y4-y3+.6vair);
76 (x,y4r)=whatever[z3l,z4l]; x4r:=min(x,.5[x4,x5r]);
77 (x',y6r)=whatever[z7l,z6l]; x6r:=min(x',.5[x6,x5r]);
78 filldraw stroke z3e{up}...pulled_arc.e(4,5)&pulled_arc.e(5,6)...{up}z7e; % bowl
79 y0=ypart(((edge,h)--(edge,0))intersectionpoint(z3l{up}...{right}z4l));
80 y2=ypart(((edge,h)--(edge,0))intersectionpoint(z6l{left}...{up}z7l));
81 pickup tiny.nib; filldraw stroke z1e--z0'e--z0e--z2e; % stem
82 pickup crisp.nib; pos8(hair,0); pos7'(stem,0);
83 z7'=z2; x8l=x7'l; bot y8=0;
84 filldraw stroke z7'e--z8e; % point
85 if serifs: sloped_serif.l(1,0',a,1/3,jut,serif_drop); fi % upper serif
86 penlabels(0,1,2,3,4,5,6,7,8); endchar;
87
88 cmchar "The letter c";
89 beginchar("c",8u#,x_height#,0);
90 italcorr x_height#*slant-.2u#;
91 adjust_fit(if monospace: .5u#,.5u# else: 0,0 fi);
92 pickup fine.nib; pos2(vair',90); pos4(vair',270);
93 x2=x4=.5(w+u); top y2r=vround(h+1.5oo); bot y4r=-oo;
94 pos3(curve,180); lft x3r=hround max(.6u,1.35u-.5curve); y3=.5h;
95 if serifs: pos1(hair,0); pos0(flare,0);
96 y1=min(bar_height+.5flare+2vair'+2,.9[bar_height,h]-.5flare);
97 rt x1r=hround(w-.7u); bulb(2,1,0); % bulb
98 pos5(hair,0); rt x5r=hround(w-.5u);
99 y5=max(good.y(.5bar_height-.9),y4l+vair');
100 (x,y4l)=whatever[z4r,z5l]; x4l:=min(x,x4l+.5u);
101 filldraw stroke pulled_super_arc.e(2,3)(.7superpull)
102 & pulled_super_arc.e(3,4)(.5superpull)
103 ..tension .9 and 1..{x5-x4,5(y5-y4)}z5e; % arc and lower terminal
104 else: pos1(4/7[vair',flare],80);
105 rt x1r=hround(w-.6u); top y1r=vround .82[bar_height,top y2r];
106 filldraw stroke term.e(2,1,right,.8,4); % upper terminal
107 pos5(.6[vair',flare],275); rt x5r=hround(w-.5u);
108 y5r=good.y(y5r+1/3bar_height-y5); y5l:=good.y y5l; x5l:=good.x x5l;
109 forsuffixes e=l,r: path p.e; p.e=z4e{right}..tension .9 and 1..z5e;
110 if angle direction 1 of p.e>75:
111 p.e:=z4e{right}..tension atleast.9 and 1..{dir 75}z5e; fi endfor
112 filldraw stroke pulled_super_arc.e(2,3)(.7superpull)
113 & pulled_super_arc.e(3,4)(.5superpull) & p.e; fi % arc and lower terminal
114 penlabels(0,1,2,3,4,5); endchar;
115
116 cmchar "The letter d";
117 beginchar("d",10u#+serif_fit#,asc_height#,0);
118 italcorr asc_height#*slant-serif_fit#+.5stem#-2u#;
119 adjust_fit(0,serif_fit#);
120 pickup tiny.nib; pos1(stem',0); pos2(stem,0);
121 pos0'(stem',0); pos0(stem,0); z0r=z0'r; x0'=x1; x0=x2;
122 rt x1r=hround(w-2.5u+.5stem'); top y1=h;
123 numeric edge; edge=lft x2l;
124 pickup fine.nib; pos3(if hefty:thin_join else: hair fi,0);
125 pos4(vair,90); pos5(curve,180); pos6(vair,270); penpos7(x3r-x3l,360);
126 lft x3l=min(lft x3l-(rt x3r-tiny.rt x2r),1/3[lft x2,edge]);
127 y3=1/8[bar_height,x_height];
128 x4l=.5(w-serif_fit)-.3u; top y4r=x_height+oo;
129 lft x5r=hround max(1.35u-.5curve,.6u); y5=.5x_height;
130 x6l=x4l-.2u; bot y6r=-oo;
131 x7=x3; y7=min(y3,y6+y4-y3+.6vair);
132 (x,y4r)=whatever[z3l,z4l]; x4r:=max(x,.5[x5r,x4]);
133 (x',y6r)=whatever[z7l,z6l]; x6r:=max(x',.5[x5r,x6]);
134 filldraw stroke z3e{up}...pulled_arc.e(4,5)
135 & pulled_arc.e(5,6)...{up}z7e; % bowl
136 y0=ypart(((edge,h)--(edge,0))intersectionpoint(z3l{up}...{left}z4l));
137 pickup tiny.nib; bot y2=if serifs:-min(oo,serif_drop) else: 0 fi;
138 filldraw stroke z1e--z0'e--z0e--z2e; % stem
139 if serifs: sloped_serif.l(1,0',a,1/3,jut,serif_drop); % upper serif
140 sloped_serif.r(2,0,b,1/3,jut,min(oo,serif_drop)); fi % lower serif
141 penlabels(0,1,2,3,4,5,6,7); endchar;
142
143 cmchar "The letter e";
144 beginchar("e",7.25u#+max(.75u#,.5curve#),x_height#,0);
145 italcorr .5[bar_height#,x_height#]*slant+.5min(curve#-1.5u#,0);
146 adjust_fit(if monospace: .25u#,.5u# else: 0,0 fi);
147 numeric left_curve,right_curve;
148 left_curve=right_curve+6stem_corr=curve if not serifs: -3stem_corr fi;
149 if right_curve<tiny.breadth: right_curve:=tiny.breadth; fi
150 if left_curve<tiny.breadth: left_curve:=tiny.breadth; fi
151 pickup tiny.nib; pos1(right_curve,0);
152 pos2(vair,90); pos3(left_curve,180);
153 y1=good.y bar_height; top y2r=h+vround 1.5oo; y0l=bot y1;
154 rt x1r=hround min(w-.5u,w-u+.5right_curve);
155 lft x3r=hround max(.5u,1.25u-.5left_curve); x2=.5w+.25u;
156 {{interim superness:=more_super;
157 filldraw stroke super_arc.e(1,2)}}; % right bowl
158 y3=.5[y2,y4]; bot y4r=-oo; x4=x2+.25u;
159 if serifs: pos4(vair',270); pos5(hair,360);
160 y5=max(good.y(.5bar_height-.9),y4l+vair); x5r=x1r;
161 (x,y4l)=whatever[z4r,z5]; x4l:=min(x,x4l+.5u);
162 filldraw stroke pulled_arc.e(2,3) & pulled_arc.e(3,4)
163 ...{x5-x4,5(y5-y4)}z5e; % left bowl, arc, and terminal
164 else: pos4(vair,270);
165 filldraw stroke super_arc.e(2,3) & super_arc.e(3,4); % left bowl and arc
166 pickup fine.nib; pos4'(vair,270); z4=z4';
167 pos5(.5[vair,flare],275); rt x5r=hround(w-.6u);
168 y5r=good.y(y5r+1/3bar_height-y5); y5l:=good.y y5l; x5l:=good.x x5l;
169 filldraw stroke term.e(4',5,right,1,4); fi % terminal
170 path testpath; testpath=super_arc.r(2,3) & super_arc.r(3,4);
171 y1'r=y0r=y0l+.6[thin_join,vair]; y1'l=y0l; x1'l=x1'r=x1;
172 forsuffixes $=l,r:
173 x0$=xpart(((0,y0$)--(x1,y0$)) intersectionpoint testpath); endfor
174 fill stroke z0e--z1'e; % crossbar
175 penlabels(0,1,2,3,4,5); endchar;
176
177 cmchar "The letter f";
178 beginchar("f",5.5u#,asc_height#,0);
179 italcorr asc_height#*slant+if serifs:flare#-.25u# else: 1.25u# fi;
180 adjust_fit(stem_shift#,if monospace: .5u# else:-stem_shift# fi);
181 pickup tiny.nib; pos1(stem',0); lft x1l=hround(2.5u-.5stem');
182 pickup fine.nib; numeric bulb_diam;
183 if serifs: bulb_diam=hround .8[stem,flare];
184 pos2(bulb_diam,0); y2+.5bulb_diam=.9[x_height,h+oo];
185 if monospace: rt x2r=hround(w-.5u)+1 else: lft x2l=hround(w-.75u+.5) fi;
186 else: pos2(5/7[vair,flare],90); top y2r=h;
187 rt x2=hround(if monospace:w-.5u else:w+.75u fi); fi
188 f_stroke(1,2,a,b,c,jut,if not monospace:1.25fi\\ jut); % stem, terminal, serif
189 pickup crisp.nib; top y3r=top y4r=x_height; lft x3=hround .5u-1;
190 pos3(bar,90); pos4(bar,90);
191 rt x4=hround(w-if monospace:.75u+1 else:1/3u fi);
192 filldraw stroke z3e--z4e; % bar
193 penlabels(1,2,3,4); endchar;
194
195 iff not variant_g: cmchar "The letter g";
196 beginchar("g",9u#,x_height#,desc_depth#);
197 italcorr x_height#*slant+.25u#;
198 adjust_fit(0,0);
199 numeric light_vair,light_curve,loop_top,loop_side;
200 light_vair=Vround(.5[thin_join,vair]+vair_corr);
201 light_curve=max(fine.breadth,hround(curve-3stem_corr));
202 loop_top=if serifs: Vround .77[vair,fudged.stem] else: vair fi;
203 loop_side=hround .64[vair,fudged.stem];
204 pickup fine.nib; pos1(light_vair,90);
205 pos2(light_curve,180); pos3(light_vair,270);
206 pos4(light_curve,360); pos11(loop_top,90);
207 y11r=good.y(y11r+.15bar_height-y11); x1=x3=.5[x2,x4]; y2=y4=.5[y1,y3];
208 lft x2r=hround(1.75u-.5light_curve); rt x4r=hround(w-2.75u+.5light_curve);
209 top y1r=h+oo; y3r=good.y(y3r+.27[top y11r,bot y1l]-y3);
210 filldraw stroke pulled_arc.e(1,2) & pulled_arc.e(2,3); % left half of bowl
211 filldraw stroke pulled_arc.e(3,4) & pulled_arc.e(4,1); % right half of bowl
212 x0=superness[x1r,x4r]; y0=superness[y4r,y1r]; % NE point on the super bowl
213 x8'=superness[x3r,x2r]; y8'=superness[y2r,y3r]; % SW point on the super bowl
214 x8''=superness[x3,x2]; y8''=superness[y2,y3];
215 pos0(thin_join,angle(z0-z8')+90);
216 pos8(thin_join,angle(z0-z8')-90); z8=.618[z8',z8''];
217 if serifs: pos5(vair,90);
218 pos6(hair,0); pos7(.5[hair,flare],0); x5=.75[x0,x6]; top y5r=h+o;
219 rt x6r=hround(w-.25u); y6+(.5[hair,flare])/2=.95[bar_height,h]+oo;
220 filldraw stroke z0e..{right}z5e; bulb(5,6,7); % ear
221 else: pos5(vair',100); top y5r=h+oo;
222 rt x5l=hround(w-.25u); y5l:=good.y y5l;
223 filldraw z0l{z5-z0}..z5l--z5r{left}..{curl 1}z0r--cycle; fi % ear
224 pos10(loop_top,90); x10=x8+.75u; y10=y11;
225 pos12(loop_side,0); pos13(light_vair,-90);
226 pos14(loop_side,-180); pos10'(.5[thin_join,vair],-270);
227 rt x12r=hround max(w-1.25u+.5loop_side,w-.5u); y12=y14=.5[y11,y13];
228 x11=x13=max(.5w,x10+eps); bot y13r=-d-oo-1; x14=w-x12; z10'l=z10l;
229 filldraw stroke z8e{z8-z0}..z10e---z11e; % link
230 filldraw stroke {{interim superness:=hein_super; super_arc.e(11,12)}}
231 & super_arc.e(12,13) & super_arc.e(13,14) & super_arc.e(14,10'); % loop
232 penlabels(0,1,2,3,4,5,6,7,8,10,11,12,13,14); labels(8',8''); endchar;
233
234 iff variant_g: cmchar "Variant letter g";
235 beginchar("g",10u#+serif_fit#,x_height#,desc_depth#);
236 italcorr x_height#*slant-serif_fit#+.5stem#-2u# if serifs:+.5u# fi;
237 adjust_fit(0,serif_fit# if serifs: -.5u# fi);
238 pickup tiny.nib; pos1(stem',0); pos2(stem,0);
239 pos0'(stem',0); pos0(stem,0); z0r=z0'r; x0'=x1; x0=x2;
240 rt x1r=hround(w-2.5u+.5stem');
241 numeric edge; edge=lft x2l;
242 path edge_path; edge_path=(edge,h)--(edge,0);
243 pickup fine.nib; pos3(if hefty:thin_join else: hair fi,0);
244 pos4(vair,90); pos5(curve,180); pos6(vair,270); penpos7(x3r-x3l,360);
245 lft x3l=min(lft x3l-(rt x3r-tiny.rt x2r),2/3[lft x2,edge]); y3=bar_height;
246 x4l=.5(w-serif_fit)-.3u; top y4r=x_height+oo;
247 lft x5r=hround max(1.35u-.5curve,.6u); y5=.5x_height;
248 x6l=x4l-.2u; bot y6r=vround 1/3vair;
249 lft x7l=edge; y7=min(y3,y6+y4-y3+.6vair);
250 (x,y4r)=whatever[z3l,z4l]; x4r:=max(x,.5[x5r,x4]);
251 (x',y6r)=whatever[z7l,z6l]; x6r:=max(x',.5[x5r,x6]);
252 filldraw stroke z3e{up}...{left}z4e&super_arc.e(4,5)
253 &super_arc.e(5,6)&z6e{right}...{up}z7e; % bowl
254 y1=ypart(edge_path intersectionpoint(z3l{up}...{left}z4l));
255 y0=ypart(edge_path intersectionpoint(z7l{down}...{left}z6l));
256 pickup tiny.nib; bot y2=if serifs: -.25d else: 0 fi;
257 filldraw stroke z1e--z0'e--z0e--z2e; % stem
258 pickup crisp.nib;
259 pos8(hround(hair-stem_corr),0); pos7'(stem',0);
260 z7'=z1; x8r=x7'r; top y8=h+oo;
261 filldraw stroke z7'e--z8e; % point
262 if serifs: pickup tiny.nib;
263 pos9(vair,-90); x9=.5[x2,x10]; bot y9r=-d-o-1;
264 pos10(hair,-180); lft x10r=hround u; y10=-.75d+.5flare;
265 pos11(flare,-180); z11r=z10r;
266 bulb(9,10,11); filldraw stroke super_arc.e(2,9); % tail
267 else: pickup fine.nib; pos2'(stem,0); z2'=z2;
268 z2''r=z2'r; z2''=z2'; z2''l=(x2'l,0);
269 pos9(vair,-90); x9=4.5u; bot y9r=-d-o-1;
270 pos10(.5[vair,flare],-90); lft x10=hround 1.25u;
271 y10r=good.y -5/6d; y10l:=good.y y10l;
272 filldraw stroke z2'e..z2''e&super_arc.e(2'',9)
273 & term.e(9,10,left,.9,4); fi % tail
274 penlabels(0,1,2,3,4,5,6,7,8,9,10,11); endchar;
275
276 cmchar "The letter h";
277 beginchar("h",10u#,asc_height#,0);
278 italcorr .5[bar_height#,x_height#]*slant-serif_fit#+.5stem#-2u#;
279 adjust_fit(serif_fit#+stem_shift#,serif_fit#-stem_shift#);
280 pickup tiny.nib; pos1(stem,0); pos2(stem,0);
281 pos1'(stem',0); pos2'(stem',0); pos3(stem,0);
282 lft x1l=hround(2.5u-.5stem); x1l=x1'l=x2l=x2'l; x3=w-x1;
283 top y1=h; bot y2=0; y1=y1'; y2=y2';
284 filldraw stroke z1'e--z2'e; % left stem
285 h_stroke(2,a,3,4); % arch and right stem
286 if serifs: sloped_serif.l(1',2',b,1/3,jut,serif_drop); % upper left serif
287 numeric inner_jut; pickup tiny.nib;
288 if rt x2r+jut+.5u+1<=lft x4l-jut: inner_jut=jut;
289 else: rt x2r+jut+.5u+1=lft x4l-inner_jut; fi
290 dish_serif(2,1,c,1/3,jut,d,1/3,jut); % lower left serif
291 dish_serif(4,3,e,1/3,inner_jut,f,1/3,jut); fi % lower right serif
292 penlabels(1,2,3,4); endchar;
293
294 cmchar "The letter i";
295 numeric dot_diam#; dot_diam#=max(dot_size#,cap_curve#);
296 beginchar("i",5u#,min(asc_height#,10/7x_height#+.5dot_diam#),0);
297 define_whole_blacker_pixels(dot_diam);
298 italcorr h#*slant-serif_fit# + .5dot_diam# -2u#;
299 adjust_fit(serif_fit#+stem_shift# if monospace:+.25u#fi,serif_fit#-stem_shift#);
300 pickup tiny.nib; pos1(stem',0); pos2(stem',0);
301 if odd(w-stem'): change_width; fi
302 lft x1l=hround(.5w-.5stem'); x1=x2;
303 top y1=x_height if serifs: +min(oo,serif_drop) fi; bot y2=0;
304 filldraw stroke z1e--z2e; % stem
305 pos3(dot_diam,0); pos4(dot_diam,90);
306 if serifs: x3r=max(x1r,hround(x1+.5dot_diam-.2jut)-.5tiny)
307 else: x3=x1-.5 fi;
308 top y4r=h+1;
309 if bot y4l-top y1<slab: y4l:=min(y4r-eps,y1+tiny+slab); fi
310 x3=x4; y3=.5[y4l,y4r]; dot(3,4); % dot
311 if serifs: sloped_serif.l(1,2,a,1/3,.95jut,serif_drop); % upper serif
312 dish_serif(2,1,b,1/3,jut,c,1/3,.9jut); fi % lower serif
313 penlabels(1,2,3,4); endchar;
314
315 cmchar "The letter j";
316 numeric dot_diam#; dot_diam#=max(dot_size#,cap_curve#);
317 beginchar("j",5.5u#,min(asc_height#,10/7x_height#+.5dot_diam#),desc_depth#);
318 define_whole_blacker_pixels(dot_diam);
319 italcorr h#*slant-serif_fit#+.5stem#-2u#;
320 adjust_fit(serif_fit#+2stem_shift# if monospace:+\\.5u# fi,
321 serif_fit#-2stem_shift# if monospace:-.5u# fi);
322 pickup tiny.nib; pos1(stem',0); pos2(stem',0);
323 rt x1r=hround(.5w+.25u+.5stem'); x1=x2;
324 top y1=x_height if serifs: +min(oo,serif_drop) fi; bot y2=-1/3d;
325 filldraw stroke z1e--z2e; % stem
326 pos3(dot_diam,0); pos4(dot_diam,90);
327 x3r=x1r; top y4r=h+1;
328 if bot y4l-top y1<slab: y4l:=min(y4r-eps,y1+tiny+slab); fi
329 x3=x4; y3=.5[y4l,y4r]; dot(3,4); % dot
330 if serifs: sloped_serif.l(1,2,a,1/3,1.1jut,serif_drop); % upper serif
331 pickup tiny.nib; pos5(vair,-90); pos6(hair,-180); pos7(flare,-180);
332 x5=.5[x2,x6r]; bot y5r=-d-oo; y6-.5flare=-.88d;
333 if monospace: lft x6r=0 else: z6r=z7r; rt x7l=floor .75u fi;
334 (x,y5r)=whatever[z5l,z2l]; x5r:=max(x,.5[x6r,x5]);
335 filldraw stroke z2e{down}...z5e{left}; bulb(5,6,7); % arc and bulb
336 else: pickup fine.nib; pos2'(stem',0); z2'=z2;
337 pos6(.2[vair,stem'],-90); pos7(vair,-90);
338 lft x7r=hround -.75u; bot y7r=vround 5/6(-d-oo);
339 (x,y7l)=whatever[z7r,z3]; x7l:=x;
340 z5r=z2'r; (x2'l,y5l)=whatever[z7l,z5r]; x5l=x2'l; y5=y5r;
341 x6r=.5[x7r,x5r]; x6l:=.5[x7l,x5l]; bot y6r=-d-oo;
342 filldraw stroke z2'e..{down}z5e & super_arc.e(5,6)
343 & z6e{left}..z7e; fi % arc and terminal
344 penlabels(1,2,3,4,5,6,7); endchar;
345
346 cmchar "The letter k";
347 beginchar("k",9.5u#,asc_height#,0);
348 italcorr x_height#*slant-.2u#;
349 adjust_fit(serif_fit#,serif_fit#); pickup tiny.nib;
350 numeric right_jut,stem[],alpha[];
351 stem1=max(tiny.breadth,hround(fudged.stem-stem_corr));
352 stem2=max(tiny.breadth,hround(fudged.stem-2stem_corr));
353 stem3=max(tiny.breadth,hround(fudged.hair if hefty:-\\4stem_corr fi));
354 stem4=max(tiny.breadth,hround(fudged.stem-3stem_corr));
355 if serifs: right_jut=.6jut; else: right_jut=.4tiny; fi
356 pos1(stem1,0); pos2(stem2,0); top y1=h; bot y2=0;
357 lft x1l=lft x2l=hround(2.5u-.5stem1);
358 top y3=x_height; rt x3r=hround(r-letter_fit-.7u-right_jut)+eps;
359 bot y6=0; rt x6r=hround(r-letter_fit-.3u-right_jut)+eps;
360 x4=x11=x1; y4=.7bar_height; y11=y3;
361 alpha1=diag_ratio(1,.5(stem3-tiny),y3-y4,x3r-x4);
362 alpha2=diag_ratio(1,.5(stem4-tiny),y11-y6,x6r-x1);
363 penpos3(alpha1*(stem3-tiny),0); penpos4(whatever,-90);
364 z5=.5[z5l,z5r]; penpos6(alpha2*(stem4-tiny),0);
365 forsuffixes $=l,r: y3'$=x_height; y6'$=0; z4$=z3'$+whatever*(z3-z4);
366 z5$=z6'$+whatever*(z11-z6)=whatever[z3,z4]; endfor
367 z3'r=z3r+penoffset z3-z4 of currentpen+whatever*(z3-z4);
368 % we have also |z3'l=z3l+penoffset z4-z3 of currentpen+whatever*(z3-z4)|;\]
369 z6'r=z6r+penoffset z11-z6 of currentpen+whatever*(z11-z6);
370 z6'l=z6l+penoffset z6-z11 of currentpen+whatever*(z11-z6);
371 fill z4r--diag_end(4r,3'r,1,.5,3'l,4l)--z4l--cycle; % upper diagonal
372 fill z5l--diag_end(5l,6'l,.5,1,6'r,5r)--z5r--cycle; % lower diagonal
373 pos0(stem1,0); pos0'(stem2,0); y0=y0'; x0=x1; x0'=x2;
374 rt z0r=whatever[z3,z4]; filldraw stroke z1e..z0e--z0'e..z2e; % stem
375 if serifs: numeric inner_jut;
376 if rt x2r+jut+.5u+1<=lft x6l-jut: inner_jut=jut;
377 else: rt x2r+inner_jut+.5u+1=lft x6l-inner_jut; fi
378 sloped_serif.l(1,0,a,1/3,jut,serif_drop); % upper stem serif
379 dish_serif(2,0',b,1/3,jut,c,1/3,inner_jut); % lower stem serif
380 dish_serif(3,4,d,2/3,1.4jut,e,1/2,right_jut)(dark); % upper diagonal serif
381 dish_serif(6,5,f,1/2,inner_jut,g,1/3,right_jut)(dark);fi % lower diagonal serif
382 penlabels(0,1,2,3,4,5,6,11); endchar;
383
384 cmchar "The letter l";
385 beginchar("l",5u#,asc_height#,0); l_width#:=5u#+2serif_fit#;
386 italcorr asc_height#*slant-serif_fit#+.5stem#-2u#;
387 adjust_fit(serif_fit#+stem_shift#,serif_fit#-stem_shift#);
388 pickup tiny.nib; pos1(stem',0); pos2(stem',0);
389 if odd(w-stem'): change_width; fi
390 lft x1l=hround(.5w-.5stem'); x1=x2; top y1=h; bot y2=0;
391 filldraw stroke z1e--z2e; % stem
392 if serifs: sloped_serif.l(1,2,a,1/3,jut,serif_drop); % upper serif
393 dish_serif(2,1,b,1/3,jut,c,1/3,jut); fi % lower serif
394 penlabels(1,2); endchar;
395
396 cmchar "The letter m";
397 beginchar("m",15u#,x_height#,0);
398 italcorr .5[bar_height#,x_height#]*slant-serif_fit#+.5stem#-2u#;
399 adjust_fit(serif_fit#+stem_shift#,serif_fit#-stem_shift#);
400 numeric shaved_stem; shaved_stem=hround(mfudged.stem-2stem_corr);
401 pickup tiny.nib; pos1(mfudged.stem,0); pos2(mfudged.stem,0);
402 pos1'(shaved_stem,0); pos2'(shaved_stem,0);
403 pos3(mfudged.stem,0); pos5(mfudged.stem,0);
404 lft x1l=hround(2.5u-.5stem); x1l=x1'l=x2l=x2'l; % stem, sic
405 lft x3l=hround(.5w-.5mfudged.stem); x5-x3=x3-x1;
406 if not monospace: r:=hround(x5+x1)+r-w; fi % change width for better fit
407 top y1=h+min(oo,serif_drop); bot y2=0; y1=y1'; y2=y2';
408 filldraw stroke z1'e--z2'e; % left stem
409 h_stroke(2,a,3,4); % left arch and middle stem
410 h_stroke(4,b,5,6); % right arch and right stem
411 if serifs: sloped_serif.l(1',2',c,1/3,jut,serif_drop); % upper left serif
412 numeric inner_jut; pickup tiny.nib;
413 if rt x2r+jut+.5u+1<=lft x4l-jut: inner_jut=jut;
414 else: rt x2r+jut+.5u+1=lft x4l-inner_jut; fi
415 dish_serif(2,1,d,1/3,jut,e,1/3,jut); % lower left serif
416 dish_serif(4,3,f,1/3,inner_jut,g,1/3,jut); % lower middle serif
417 dish_serif(6,5,h,1/3,inner_jut,i,1/3,jut); fi % lower right serif
418 penlabels(1,2,3,4,5,6); endchar;
419
420 cmchar "The letter n";
421 beginchar("n",10u#,x_height#,0);
422 italcorr .5[bar_height#,x_height#]*slant-serif_fit#+.5stem#-2u#;
423 adjust_fit(serif_fit#+stem_shift#,serif_fit#-stem_shift#);
424 pickup tiny.nib; pos1(stem,0); pos2(stem,0);
425 numeric shaved_stem; shaved_stem=hround(stem-2stem_corr);
426 pos1'(shaved_stem,0); pos2'(shaved_stem,0); pos3(stem,0);
427 lft x1l=hround(2.5u-.5stem); x1l=x1'l=x2l=x2'l; x3=w-x1;
428 top y1=h+min(oo,serif_drop); bot y2=0; y1=y1'; y2=y2';
429 filldraw stroke z1'e--z2'e; % left stem
430 h_stroke(2,a,3,4); % arch and right stem
431 if serifs: sloped_serif.l(1',2',b,1/3,jut,serif_drop); % upper left serif
432 numeric inner_jut; pickup tiny.nib;
433 if rt x2r+jut+.5u+1<=lft x4l-jut: inner_jut=jut;
434 else: rt x2r+jut+.5u+1=lft x4l-inner_jut; fi
435 dish_serif(2,1,c,1/3,jut,d,1/3,jut); % lower left serif
436 dish_serif(4,3,e,1/3,inner_jut,f,1/3,jut); fi % lower right serif
437 penlabels(1,2,3,4); endchar;
438
439 cmchar "The letter o";
440 beginchar("o",9u#,x_height#,0);
441 italcorr .7x_height#*slant;
442 adjust_fit(if monospace: .5u#,.5u# else: 0,0 fi);
443 penpos1(vair,90); penpos3(vair',-90);
444 penpos2(curve,180); penpos4(curve,0);
445 x2r=hround max(.5u,1.25u-.5curve);
446 x4r=w-x2r; x1=x3=.5w; y1r=h+vround 1.5oo; y3r=-oo;
447 y2=y4=.5h-vair_corr; y2l:=y4l:=.52h;
448 penstroke pulled_arc.e(1,2) & pulled_arc.e(2,3)
449 & pulled_arc.e(3,4) & pulled_arc.e(4,1) & cycle; % bowl
450 penlabels(1,2,3,4); endchar;
451
452 cmchar "The letter p";
453 beginchar("p",10u#+serif_fit#,x_height#,desc_depth#);
454 italcorr .5x_height#*slant+min(.5curve#-.85u#,-.1u#);
455 adjust_fit(serif_fit#,0);
456 pickup tiny.nib; pos1(stem',0); pos2(stem,0);
457 pos0'(stem',0); pos0(stem,0); z0l=z0'l; x0'=x1; x0=x2;
458 lft x1l=hround(2.5u-.5stem'); top y1=h if serifs: +min(oo,serif_drop) fi;
459 numeric edge; edge=rt x2r;
460 pickup fine.nib; pos3(if hefty:thin_join else: hair fi,180);
461 pos4(vair',90); pos5(curve,0); pos6(vair,-90); penpos7(x3l-x3r,-180);
462 rt x3l=max(rt x3l-(lft x3r-tiny.lft x2l), 1/3[rt x2,edge]);
463 y3=1/8[bar_height,x_height];
464 x4l=w-.5(w-serif_fit)+.5u; top y4r=x_height+oo;
465 rt x5r=hround min(w-1.35u+.5curve,w-.6u); y5=.5x_height;
466 x6l=x4l-.2u; bot y6r=-oo;
467 x7=x3; y7=min(y3,y6+y4-y3+.6vair);
468 (x,y4r)=whatever[z3l,z4l]; x4r:=min(x,.5[x5r,x4]);
469 (x',y6r)=whatever[z7l,z6l]; x6r:=min(x',.5[x5r,x6]);
470 filldraw stroke z3e{up}...{right}z4e&super_arc.e(4,5)
471 &super_arc.e(5,6)&z6e{left}...{up}z7e; % bowl
472 y0=ypart(((edge,h)--(edge,0))intersectionpoint(z3l{up}...{right}z4l));
473 pickup tiny.nib; bot y2=-d;
474 filldraw stroke z1e--z0'e--z0e--z2e; % stem
475 pickup crisp.nib; pos8(hair,0); pos7'(stem,0);
476 z7'=z2; x8l=x7'l; bot y8=0;
477 filldraw stroke z7'e--z8e; % point
478 if serifs: sloped_serif.l(1,0',a,1/3,jut,serif_drop); % upper serif
479 dish_serif(2,0,b,1/3,jut,c,1/3,jut); fi % lower serif
480 penlabels(0,1,2,3,4,5,6,7,8); endchar;
481
482 cmchar "The letter q";
483 beginchar("q",10u#+serif_fit#,x_height#,desc_depth#);
484 italcorr x_height#*slant-serif_fit#+.5stem#-2u# if serifs:+.5u# fi;
485 adjust_fit(0,serif_fit# if serifs: -.5u# fi);
486 pickup tiny.nib; pos1(stem',0); pos2(stem,0);
487 pos0'(stem',0); pos0(stem,0); z0r=z0'r; x0'=x1; x0=x2;
488 rt x1r=hround(w-2.5u+.5stem');
489 numeric edge; edge=lft x2l;
490 pickup fine.nib; pos3(if hefty:thin_join else: hair fi,0);
491 pos4(vair',90); pos5(curve,180); pos6(vair,270); penpos7(x3r-x3l,360);
492 lft x3l=min(lft x3l-(rt x3r-tiny.rt x2r),2/3[lft x2,edge]); y3=bar_height;
493 x4l=.5(w-serif_fit)-.3u; top y4r=x_height+oo;
494 lft x5r=hround max(1.35u-.5curve,.6u); y5=.5x_height;
495 x6l=x4l-.2u; bot y6r=-oo; y7=min(y3,y6+y4-y3+.6vair);
496 lft x7l=min(lft x7l-(rt x7r-tiny.rt x2r),1/3[lft x2,edge]);
497 (x,y4r)=whatever[z3l,z4l]; x4r:=max(x,.5[x5r,x4]);
498 (x',y6r)=whatever[z7l,z6l]; x6r:=max(x',.5[x5r,x6]);
499 filldraw stroke z3e{up}...{left}z4e&super_arc.e(4,5)
500 &super_arc.e(5,6)&z6e{right}...{up}z7e; % bowl
501 y1=ypart(((edge,h)--(edge,0))intersectionpoint(z3l{up}...{left}z4l));
502 y0=ypart(((edge,h)--(edge,0))intersectionpoint(z6l{right}...{up}z7l));
503 pickup tiny.nib; bot y2=-d;
504 filldraw stroke z1e--z0'e--z0e--z2e; % stem
505 pickup crisp.nib;
506 pos8(hround(hair-stem_corr),0); pos7'(stem',0);
507 z7'=z1; x8r=x7'r; top y8=h+oo;
508 filldraw stroke z7'e--z8e; % point
509 if serifs: dish_serif(2,0,b,1/3,jut,c,1/3,jut); fi % lower serif
510 penlabels(0,1,2,3,4,5,6,7,8); endchar;
511
512 cmchar "The letter r";
513 numeric r_flare#; r_flare#=.75[if serifs: stem# else: vair# fi,flare#];
514 define_whole_blacker_pixels(r_flare);
515 beginchar("r",if serifs:max(7u#,5.5u#+r_flare#) else:6.5u# fi,x_height#,0);
516 italcorr x_height#*slant if not serifs: +.25u# fi;
517 adjust_fit(serif_fit#,0);
518 pickup fine.nib; top y4r=h+oo;
519 if serifs: pos4(vair,90); pos5(hair,0);
520 x4=w-max(1.75u,.25u+r_flare);
521 rt x5r=hround(w-.5u+.5); y5+.5r_flare=.9[bar_height,h]+oo;
522 pos6(r_flare,0); bulb(4,5,6); % bulb
523 else: pos4(r_flare,90); rt x4=hround(w-.25u); fi
524 pos3(thin_join,180); rt x3l=hround(2.5u-.5stem')+stem'; top y3=bar_height;
525 filldraw stroke z3e{up}...{right}z4e; % arc
526 pickup tiny.nib; pos0(stem',0); pos2(stem',0);
527 pos1(hround(stem-3stem_corr),0); top y1=h+min(oo,serif_drop);
528 pos0'(hround(stem-3stem_corr),0); y0=y0'=y3; x1l=x0l=x0'l=x2l;
529 lft x1l=hround(2.5u-.5stem'); bot y2=0;
530 filldraw stroke z1e--z0'e--z0e--z2e; % stem
531 if serifs: sloped_serif.l(1,0',a,1/3,jut,serif_drop); % upper serif
532 dish_serif(2,0,b,1/3,jut,c,1/3,1.25jut); fi % lower serif
533 penlabels(1,2,3,4,5,6); endchar;
534
535 cmchar "The letter langes Es";
536 beginchar("s",5.5u#,asc_height#,0);
537 italcorr asc_height#*slant+if serifs:flare#-.25u# else: 1.25u# fi;
538 adjust_fit(stem_shift#,if monospace: .5u# else:-stem_shift# fi);
539 pickup tiny.nib; pos1(stem',0); lft x1l=hround(2.5u-.5stem');
540 pickup fine.nib; numeric bulb_diam;
541 if serifs: bulb_diam=hround .8[stem,flare];
542 pos2(bulb_diam,0); y2+.5bulb_diam=.9[x_height,h+oo];
543 if monospace: rt x2r=hround(w-.5u)+1 else: lft x2l=hround(w-.75u+.5) fi;
544 else: pos2(5/7[vair,flare],90); top y2r=h;
545 rt x2=hround(if monospace:w-.5u else:w+.75u fi); fi
546 f_stroke(1,2,a,b,c,jut,if not monospace:1.25fi\\ jut); % stem, terminal, serif
547 pickup crisp.nib; top y3r=top y4r=x_height; lft x3=hround .5u-1;
548 pos3(bar,90); pos4(bar,90);
549 rt x4=x1;
550 filldraw stroke z3e--z4e; % bar
551 penlabels(1,2,3,4); endchar;
552
553 cmchar "The letter kurzes Es";
554 beginchar(oct"363",7.1u#,x_height#,0);
555 italcorr x_height#*slant-if serifs:.55u# else:.3u# fi;
556 adjust_fit(if monospace: .5u#,.4u# else: 0,if serifs:0 else:-.2u# fi fi);
557 numeric theta; theta=90-angle(40u,h); slope:=-h/40u; % angle at middle
558 numeric s_slab; s_slab=if serifs:vair else:Vround .1[vair,stem] fi;
559 numeric ess'; ess'=max(fine.breadth,ess);
560 pickup fine.nib; pos2(max(fine.breadth,s_slab-vround vair_corr),-100);
561 pos0(ess',theta); pos7(s_slab,-90); x2l=x0=x7=.5w;
562 top y2l=h+vround 1.5oo; bot y7r=-oo;
563 y0-.5ess'=y7l+if serifs:.54 else: .52 fi\\(y2r-y7l-ess');
564 lft x3l=hround .6u; rt x6r=hround(w-.6u);
565 x3r-x3l=x6r-x6l=hround .5[s_slab,ess']-fine;
566 ellipse_set(2l,3l,4l,0l); ellipse_set(2r,3r,4r,0r); y3=y3r;
567 ellipse_set(7l,6l,5l,0l); ellipse_set(7r,6r,5r,0r); y6=y6r;
568 interim superness:=more_super;
569 filldraw stroke super_arc.e(2,3) & z3e{down}
570 ..z4e---z5e..z6e{down} & super_arc.e(6,7); % main stroke
571 if serifs: pos1(hair,180); pos8(hair,180);
572 rt x1l=hround(w-1.05u); lft x8r=hround .6u;
573 bot y1=min(bot y2r,vround 1/5[top y5r,h]);
574 top y8=max(top y7l,vround 5/6 bot y4l);
575 filldraw stroke z1e{up}....{left}z2e; % upper arc
576 filldraw stroke z7e{left}....{x8-x7,5(y8-y7)}z8e; % lower arc
577 path upper_arc, lower_arc;
578 upper_arc=z1{up}....{left}z2; lower_arc=z7{left}....{x8-x7,5(y8-y7)}z8;
579 pos10(.3[fine.breadth,cap_hair],0); pos9(.3[fine.breadth,cap_hair],0);
580 x10r=x1l; top y10=top y2l; x9l=x8r; bot y9=bot y7r;
581 x1l-x1'=x8'-x8r=1.6cap_curve-fine; y1'=y1; y8'=y8;
582 numeric t; t=xpart(upper_arc intersectiontimes(z10l--z1'));
583 filldraw z1l--z10r--z10l--subpath(t,0) of upper_arc--cycle; % upper barb
584 t:=xpart(lower_arc intersectiontimes(z9r--z8'));
585 filldraw z8r--z9l--z9r--subpath(t,1) of lower_arc--cycle; % lower barb
586 else: pos1(4/7[s_slab,flare],-100); pos8(flare,-100);
587 x1l=good.x(x1l+w-u-rt x1); lft x8r=hround .5u;
588 top y1l=vround(.93h+1.5oo); bot y8r=vround .1h-oo;
589 filldraw stroke term.e(2,1,right,.9,4); % upper arc and terminal
590 filldraw stroke term.e(7,8,left,1,4); fi % lower arc and terminal
591 penlabels(0,1,1',2,3,4,5,6,7,8,8',9,10); endchar;
592
593 cmchar "The letter t";
594 beginchar("t",6u#+max(u#,.5stem#),
595 min(asc_height#,if hefty:9/7 else:10/7 fi\\ x_height#),0);
596 italcorr x_height#*slant if serifs: -.9u# else: -.4u# fi;
597 adjust_fit(0,if serifs: 0 else: -.5u# fi);
598 numeric shaved_stem; shaved_stem=hround(stem if hefty:-\\2stem_corr fi);
599 pickup fine.nib; pos2(shaved_stem,180);pos3(shaved_stem,180);
600 lft x2r=lft x3r=hround(2.5u-.5shaved_stem);
601 y2=y8; y3=max(.5bar_height,2vair);
602 pickup crisp.nib; pos8(bar,90);
603 rt x8=hround(w-1.3u); top y8r=x_height; lft x7=hround 1/3u; y7l=y8l;
604 if hefty: pos7(bar,90);
605 filldraw stroke z7e--z8e; % crossbar
606 pickup tiny.nib; pos1(hround(shaved_stem-stem_corr),0);
607 rt x1r=fine.rt x2l; top y1=h;
608 penpos2'(x1r-x1l,0); x2'=x1; y2'=y2;
609 filldraw stroke z1e--z2'e; % upper terminal
610 else: pos7(vair,90); pos1(hair,0);
611 rt x1r=fine.rt x2l; top y1=h;
612 filldraw z1l{down}...{left}z7r--z7l--z8l
613 --z8r--(x1r,y8r)--z1r--cycle; fi % upper terminal and crossbar
614 pickup fine.nib; interim superness:=more_super;
615 pos4(vair',-90); bot y4r=-oo; rt x5r=hround(w-u);
616 if serifs: pos5(hair,0); y5=y3; x4l=.5[x3l,x5l];
617 (x,y4r)=whatever[z4l,z5l]; x4r:=max(x,.5[x3r,x4]);
618 filldraw stroke z2e..super_arc.e(3,4)...{up}z5e; % stem and hook
619 pickup crisp.nib; pos6(hair,0); pos5'(hair,0);
620 x6=x5=x5'; top y6=max(vround .75bar_height,top y5); y5=y5';
621 filldraw stroke z5'e--z6e; % terminal
622 else: pos5(vair,-75); top y5l=vround .2[top y4l,bar_height];
623 x5l:=good.x x5l; x4l=1/3[x3l,x5l]; x4r:=1/3[x3r,x5r]; y3l:=y3l+.2vair;
624 filldraw stroke z2e..super_arc.e(3,4); % stem and hook
625 path p; p=stroke z4e{right}..tension .9 and atleast 1..z5e; % terminal
626 if (xpart(z5l-precontrol 1 of p)<0) or (xpart(z5r-postcontrol 2 of p)<0):
627 filldraw stroke z4e{right}...{up}z5e;
628 else: filldraw p; fi fi;
629 penlabels(1,2,3,4,5,6,7,8); endchar;
630
631 cmchar "The letter u";
632 beginchar("u",10u#,x_height#,0);
633 italcorr x_height#*slant-serif_fit#+.5stem#-2u#;
634 adjust_fit(serif_fit#+stem_shift#,serif_fit#-stem_shift#);
635 numeric light_vair; light_vair=vair if hefty: -vround 2vair_corr fi;
636 if light_vair<fine.breadth: light_vair:=fine.breadth; fi
637 pickup tiny.nib; pos1(stem,0); pos2(stem,0);
638 pos3(stem,0); pos4(stem',0);
639 lft x1l=hround(2.5u-.5stem); x1=x2; x3=w-x1; x3r=x4r;
640 if serifs: top y1=h+min(oo,serif_drop); bot y4=-min(oo,serif_drop);
641 else: top y1=h; bot y4=0; fi
642 pos0(stem,0); pos0'(stem',0); x0=x3; x0'=x4; y0=y0';
643 penpos2'(stem-fine,-180); z2'=z2; y3=y1; y2=.5bar_height;
644 penpos5(max(eps,light_vair-fine),-90); penpos6(thin_join-fine,0);
645 y6=y0=2/3bar_height;
646 filldraw stroke z1e--z2e; % left stem
647 filldraw stroke z3e..z0e--z0'e..z4e; % right stem
648 pickup fine.nib; bot y5r=-oo; x5l=.5w-.25u; lft x6l=tiny.lft x0l;
649 (x,y5r)=whatever[z5l,z6l]; x5r:=max(x,.5[x5,x2'r]);
650 filldraw stroke {{interim superness:=hein_super;
651 pulled_arc.e(2',5)}} & z5e{right}...{up}z6e; % arc
652 if serifs: sloped_serif.l(1,2,a,1/3,jut,serif_drop); % upper left serif
653 sloped_serif.l(3,0,b,1/3,jut,serif_drop); % upper right serif
654 sloped_serif.r(4,0',c,1/3,jut,min(oo,serif_drop)); fi % lower right serif
655 penlabels(1,2,3,4,5); labels(6); endchar;
656
657 cmchar "The letter v";
658 beginchar("v",if serifs: 9.5u# else:9u# fi,x_height#,0);
659 italcorr x_height#*slant+.25u#;
660 adjust_fit(serif_fit# if monospace:+\\.5u#,.5u#+ else:,fi\\ serif_fit#);
661 numeric left_stem,right_stem,outer_jut,alpha;
662 left_stem=fudged.stem-stem_corr;
663 right_stem=min(fudged.hair if hefty:-2stem_corr fi,left_stem);
664 outer_jut=.75jut; x1l=w-x4r=l+letter_fit+outer_jut+.25u; y1=y4=h;
665 x2-x1=x4-x3; x2l+apex_corr=x3l; y2=y3=-apex_oo;
666 alpha=diag_ratio(2,right_stem,y1-y2,x4r-x1l-apex_corr);
667 penpos1(alpha*left_stem,0); penpos2(alpha*left_stem,0);
668 penpos3(alpha*right_stem,0); penpos4(alpha*right_stem,0);
669 z0=whatever[z1r,z2r]=whatever[z3l,z4l];
670 if y0>notch_cut: y0:=notch_cut;
671 fill z0+.5right{up}...{z4-z3}diag_end(3l,4l,1,1,4r,3r)
672 --diag_end(4r,3r,1,1,2l,1l)--diag_end(2l,1l,1,1,1r,2r){z2-z1}
673 ...{down}z0+.5left--cycle; % left and right diagonals
674 else: fill z0--diag_end(0,4l,1,1,4r,3r)--diag_end(4r,3r,1,1,2l,1l)
675 --diag_end(2l,1l,1,1,1r,0)--cycle; fi % left and right diagonals
676 if serifs: numeric inner_jut; pickup tiny.nib;
677 prime_points_inside(1,2); prime_points_inside(4,3);
678 if rt x1'r+jut+.5u+1<=lft x4'l-jut: inner_jut=jut;
679 else: rt x1'r+inner_jut+.5u+1=lft x4'l-inner_jut; fi
680 dish_serif(1',2,a,1/3,outer_jut,b,1/2,inner_jut); % left serif
681 dish_serif(4',3,c,.6,inner_jut,d,1/2,outer_jut)(dark); fi % right serif
682 penlabels(0,1,2,3,4); endchar;
683
684 cmchar "The letter w";
685 beginchar("w",13u#,x_height#,0);
686 italcorr x_height#*slant+.25u#;
687 adjust_fit(serif_fit#,serif_fit#);
688 numeric stem[],outer_jut,upper_notch,alpha,mid_corr;
689 outer_jut=.7jut; x1l=w-x8r=l+letter_fit+outer_jut+.25u;
690 stem1=fudged.stem-stem_corr;
691 stem4=min(fudged.hair if hefty:-2stem_corr fi,stem1);
692 stem2=if hefty:.1[vair,stem4] else: stem4 fi;
693 stem3=max(stem2,stem1-3stem_corr);
694 x2-x1=x4-x3=x6-x5=x8-x7; x2l+apex_corr=x3l; x6l+apex_corr=x7l;
695 y1=y8=h; y2=y3=y6=y7=-apex_oo;
696 y4=y5=if monospace: vround .6 fi\\ h; upper_notch=y4-notch_cut;
697 mid_corr=if monospace or hefty:-.3apex_corr else: .5jut fi;
698 alpha=diag_ratio(4,stem2-stem3+stem4,y1-y2,x8r-x1l+mid_corr-2apex_corr);
699 penpos1(alpha*stem1,0); penpos2(alpha*stem1,0);
700 penpos3(alpha*stem2,0); penpos4(alpha*stem2,0);
701 penpos5(alpha*stem3,0); penpos6(alpha*stem3,0);
702 penpos7(alpha*stem4,0); penpos8(alpha*stem4,0);
703 x4l-x1l=floor(x4l-x1l+.5(x5r+mid_corr-x4r)); % |x5r| $\approx$ |x4r+mid_corr|
704 z23=whatever[z1r,z2r]=whatever[z3l,z4l];
705 z45=whatever[z3r,z4r]=whatever[z5l,z6l];
706 z67=whatever[z5r,z6r]=whatever[z7l,z8l];
707 fill diag_end(1l,2l,1,1,3r,4r){z4-z3}
708 ...if y45<upper_notch:(x45,upper_notch)+.5left{up}
709 --(x45,upper_notch)+.5right{down} else: z45&z45 fi
710 ...{z6-z5}diag_end(5l,6l,1,1,7r,8r)--diag_end(7r,8r,1,1,8l,7l){z7-z8}
711 ...if y67>notch_cut:(x67,notch_cut)+.5right{down}
712 --(x67,notch_cut)+.5left{up} else: z67&z67 fi
713 ...{z5-z6}special_diag_end(6,5,4,3){z3-z4}
714 ...if y23>notch_cut:(x23,notch_cut)+.5right{down}
715 --(x23,notch_cut)+.5left{up} else: z23&z23 fi
716 ...{z1-z2}diag_end(2r,1r,1,1,1l,2l)--cycle; % diagonals
717 if serifs: numeric inner_jut[]; pickup tiny.nib;
718 prime_points_inside(1,2); prime_points_inside(5,6); prime_points_inside(8,7);
719 if monospace: inner_jut1=inner_jut4=1.5jut;
720 elseif hefty: inner_jut1=inner_jut4=jut;
721 else: fill diag_end(6r,5r,1,1,5l,6l)--.9[z5l,z6l]
722 ..{z5-z6}.1[z5r,z6r]--cycle; % middle stem
723 inner_jut2=.7inner_jut1; inner_jut4=1.1inner_jut3;
724 if rt x1'r+jut+.5u+1<=lft x5'l-.7jut: inner_jut1=jut;
725 else: rt x1'r+inner_jut1+.5u+1=lft x5'l-inner_jut2; fi
726 if rt x5'r+jut+.5u+1<=lft x8'l-1.1jut: inner_jut3=jut;
727 else: rt x5'r+inner_jut3+.5u+1=lft x8'l-inner_jut4; fi
728 dish_serif(5',6,e,1/3,inner_jut2,f,1/2,inner_jut3); fi % middle serif
729 dish_serif(1',2,a,1/3,outer_jut,b,1/2,inner_jut1); % left serif
730 dish_serif(8',7,c,.6,inner_jut4,d,1/2,outer_jut)(dark); fi % right serif
731 penlabels(0,1,2,3,4,5,6,7,8,23,45,67); endchar;
732
733 cmchar "The letter x";
734 beginchar("x",if serifs:9.5u# else:9u# fi,x_height#,0);
735 italcorr x_height#*slant-.05u#;
736 adjust_fit(serif_fit# if monospace:+\\.5u#,.5u#+ else:,fi\\ serif_fit#);
737 numeric stem[],outer_jut,xjut,alpha[];
738 stem1=fudged.stem-4stem_corr; stem2=min(fudged.hair,stem1);
739 outer_jut=.75jut; xjut= if serifs: (stem1-stem2)/4 else: 0 fi;
740 x1l=l+letter_fit+.1u+outer_jut; x2r=r-letter_fit-.3u-outer_jut-xjut;
741 x3l=l+letter_fit+outer_jut+xjut; x4r=r-letter_fit-outer_jut;
742 y1=y2=h; y3=y4=0;
743 alpha1=diag_ratio(1,stem1,h,x4r-x1l);
744 alpha2=diag_ratio(1,stem2,h,x2r-x3l);
745 penpos1(alpha1*stem1,0); penpos2(alpha2*stem2,0);
746 penpos3(alpha2*stem2,0); penpos4(alpha1*stem1,0);
747 if hefty: z0=whatever[z1,z4]=whatever[z2,z3];
748 x12=x34=x0; y13=y24=y0;
749 z12=whatever[z2l,z3l]; z13=whatever[z2l,z3l];
750 z24=whatever[z2r,z3r]; z34=whatever[z2r,z3r];
751 forsuffixes $=13,24,34: z$'=.2[z$,z0]; endfor
752 fill diag_end(12,1r,.5,1,1l,13')--z13'--diag_end(13',3l,1,.5,3r,34')--z34'
753 --diag_end(34',4l,.5,1,4r,24')--z24'
754 --diag_end(24',2r,1,.5,2l,12)--z12--cycle; % diagonals
755 else: fill diag_end(4r,1r,.5,1,1l,4l)
756 --diag_end(1l,4l,.5,1,4r,1r)--cycle; % left diagonal
757 fill diag_end(2l,3l,.5,1,3r,2r)
758 --diag_end(3r,2r,.5,1,2l,3l)--cycle; fi % right diagonal
759 if serifs: numeric inner_jut[]; pickup tiny.nib;
760 prime_points_inside(1,4); prime_points_inside(2,3);
761 prime_points_inside(3,2); prime_points_inside(4,1);
762 if rt x1'r+jut+.5u+1<=lft x2'l-jut-xjut: inner_jut1=jut;
763 else: rt x1'r+inner_jut1+.5u+1=lft x2'l-inner_jut1-xjut; fi
764 if rt x3'r+jut+.5u+1<=lft x4'l-jut-xjut: inner_jut2=jut;
765 else: rt x3'r+inner_jut2+.5u+1=lft x4'l-inner_jut2-xjut; fi
766 dish_serif(1',4,a,1/3,outer_jut,b,2/3,inner_jut1); % upper left serif
767 dish_serif(4',1,c,2/3,inner_jut2,d,1/3,outer_jut); % lower right serif
768 dish_serif(2',3,e,2/3,inner_jut1+xjut,
769 f,1/2,outer_jut+xjut)(dark); % upper right serif
770 dish_serif(3',2,g,1/2,outer_jut+xjut,
771 h,2/3,inner_jut2+xjut)(dark); fi % lower left serif
772 penlabels(0,1,2,3,4,12,13,24,34); endchar;
773
774 cmchar "The letter y";
775 beginchar("y",if serifs:9.5u# else:9u# fi,x_height#,desc_depth#);
776 italcorr x_height#*slant+.25u#;
777 adjust_fit(serif_fit# if monospace:+\\.5u#,.5u#+ else:,fi\\ serif_fit#);
778 numeric left_stem,right_stem,bot_stem,bot_vair,outer_jut;
779 left_stem=fudged.stem-stem_corr;
780 right_stem=fudged.hair if hefty:-2stem_corr fi;
781 bot_stem=fudged.hair if hefty:-8stem_corr fi;
782 bot_vair=Vround(if serifs: vair else:.5[vair,bot_stem] fi);
783 outer_jut=.75jut;
784 x1l=w-x4r=l+letter_fit+outer_jut+.25u; y1=y4r=h; y2=y3=0; x2l=x3l;
785 numeric alpha,alpha[]; x9=3u; y9=bot_vair-d-oo;
786 alpha1=diag_ratio(2,bot_stem,y1-y3,x4r-x1l-apex_corr);
787 alpha2=diag_ratio(1,bot_stem,y1-y9,x4r-x9);
788 if alpha1<alpha2: x2l-x1l=x4r-x3r+apex_corr; alpha=alpha1;
789 else: alpha=alpha2; z3l=whatever[z9,z4r-(alpha*bot_stem,0)]; fi
790 penpos3(alpha*bot_stem,0); penpos4(alpha*right_stem,0);
791 alpha3=(y1++(x2l-x1l))/y1;
792 penpos1(alpha3*left_stem,0); penpos2(alpha3*left_stem,0);
793 z0=whatever[z1r,z2r]=z4l+whatever*(z3r-z4r);
794 if y0>notch_cut: y0:=notch_cut;
795 fill z0+.5right{up}...{z4r-z3r}diag_end(0,4l,1,1,4r,3r)
796 --z3r--z2l--diag_end(2l,1l,1,1,1r,2r){z2-z1}
797 ...{down}z0+.5left--cycle; % left and right diagonals
798 else: fill z0--diag_end(0,4l,1,1,4r,3r)--z3r--z2l
799 --diag_end(2l,1l,1,1,1r,0)--cycle; fi % left and right diagonals
800 penpos5(alpha*bot_stem,0); z5r=whatever[z3r,z4r]; y5-.5vair=-.5d;
801 if serifs: numeric light_bulb; light_bulb=hround 7/8[hair,flare]; clearpen;
802 penpos6(vair,-90); penpos7(hair,-180); penpos8(light_bulb,-180);
803 x6=2u; y6r=-d-oo; y8-.5light_bulb=-.85d; x8r=hround .35u;
804 fill stroke z3e---z5e...{left}z6e; bulb(6,7,8); % arc and bulb
805 numeric inner_jut; pickup tiny.nib;
806 prime_points_inside(1,2); prime_points_inside(4,3);
807 if rt x1'r+jut+.5u+1<=lft x4'l-jut: inner_jut=jut;
808 else: rt x1'r+inner_jut+.5u+1=lft x4'l-inner_jut; fi
809 dish_serif(1',2,a,1/3,outer_jut,b,1/2,inner_jut); % left serif
810 dish_serif(4',3,c,.6,inner_jut,d,1/2,outer_jut)(dark); % right serif
811 else: penpos6(bot_vair,-90); x6=2.5u; y6r=-d-oo;
812 fill stroke z3e---z5e...{left}z6e; % arc
813 pickup fine.nib; pos6'(bot_vair,-90); z6'=z6;
814 pos7(2/3[bot_vair,flare],-85);
815 lft x7l=hround u; bot y7r=vround-.96d-oo; y7l:=good.y y7l;
816 filldraw stroke term.e(6',7,left,1,4); fi % arc and terminal
817 penlabels(0,1,2,3,4,5,6,7,8,9); endchar;
818
819 cmchar "The letter z";
820 beginchar("z",8u#,x_height#,0);
821 italcorr x_height#*slant-.5serif_fit#-.3u#;
822 adjust_fit(0,.5serif_fit#);
823 numeric arm_thickness[],z_stem;
824 if hefty: arm_thickness1=Vround(vair-vair_corr); arm_thickness2=vair;
825 z_stem=.6[vair,stem];
826 else: arm_thickness1=vair; arm_thickness2=vair'; z_stem=.9[vair,stem]; fi
827 pickup tiny.nib; rt x1r=rt x2r=hround(w-.8u); lft x3l=lft x4l=hround .5u;
828 top y1=h; y2=min(y1,h-2/3arm_thickness1);
829 bot y4=0; y3=max(y4,2/3arm_thickness2);
830 numeric alpha; alpha=diag_ratio(1,z_stem-tiny,y2-y3,x2r-x3l-slant*(y2-y3));
831 penpos1(alpha*(z_stem-tiny),0); penpos2(alpha*(z_stem-tiny),0);
832 penpos3(alpha*(z_stem-tiny),0); penpos4(alpha*(z_stem-tiny),0);
833 pair delta; delta=penoffset z3-z2 of currentpen;
834 fill top lft z1l--z2l+delta---z3l+delta..lft z3l---lft z4l..bot z4l
835 ---bot rt z4r--z3r-delta---z2r-delta..rt z2r---rt z1r..top z1r
836 ---cycle; % diagonal
837 pickup crisp.nib; pos5(arm_thickness1,90); pos6(hair,180);
838 top y5r=h; x5=x1; lft x6r=hround .75u; y6=good.y(y5l-beak/1.4)-eps;
839 arm(5,6,a,beak_darkness,-.4beak_jut); % upper arm and beak
840 pos7(arm_thickness2,-90); pos8(hair,0);
841 bot y7r=0; x7=x4; rt x8r=hround(w-.75u); y8=good.y(y7l+beak/1.2)+eps;
842 arm(7,8,b,beak_darkness,.6beak_jut); % lower arm and beak
843 penlabels(1,2,3,4,5,6,7,8); endchar;