Debian Codegraph @

texmf-dist/fonts/source/public/mdsymbol/mdgeometric.mf

raw
1 %
2 % Copyright (c) 2011, 2012, Sebastian Schubert <[email protected]>
3 %
4 % This Font Software is licensed under the SIL Open Font License,
5 % Version 1.1. This license is in the accompanying file OFL.txt, and
6 % is also available with a FAQ at: http://scripts.sil.org/OFL
7 %
8
9 beginsymbol(2dot_size# + 2side_bearing#, vcentre(2dot_size#)); "centre dot";
10 fill dot((w/2, (h-d)/2), dot_size);
11 endchar;
12
13 for alpha = 0, 90, 45, 135:
14 beginsymbol((4dot_size# + equal_spread#) * abs (cosd alpha) + 2dot_size# * abs (sind alpha) + 2side_bearing#, vcentre(2dot_size# * abs (cosd alpha) + (4dot_size# + equal_spread#) * abs (sind alpha))); "colon (" & decimal alpha & ")";
15 pair centre;
16 centre := (w/2, (h-d)/2);
17
18 z1 - z0 = (2dot_size + equal_spread) * dir alpha;
19 1/2[z0,z1] = centre;
20
21 fill dot(z0, dot_size);
22 fill dot(z1, dot_size);
23 endchar;
24 endfor;
25
26 for alpha = 0, 90, 45, 135:
27 beginsymbol((6dot_size# + 2equal_spread#) * abs (cosd alpha) + 2dot_size# * abs (sind alpha) + 2side_bearing#, vcentre(2dot_size# * abs (cosd alpha) + (6dot_size# + 2equal_spread#) * abs (sind alpha))); "triple colon (" & decimal alpha & ")";
28 pair centre;
29 centre := (w/2, (h-d)/2);
30
31 z1 - z0 = (2dot_size + equal_spread) * dir alpha;
32 z2 - z1 = (2dot_size + equal_spread) * dir alpha;
33 z1 = centre;
34
35 fill dot(z0, dot_size);
36 fill dot(z1, dot_size);
37 fill dot(z2, dot_size);
38 endchar;
39 endfor;
40
41 for alpha = 0, 90, 180, 270:
42 beginoperator(plus_size#, 1); "therefore (" & decimal alpha & ")";
43 r := 1/2plus_size - dot_size;
44 r := r * 1/3[1, sqrt 2];
45
46 z1 = z0 + r * dir alpha;
47 z2 = z0 + r * dir (alpha + 120);
48 z3 = z0 + r * dir (alpha + 240);
49
50 1/2[z1,1/2[z2,z3]] = centre;
51
52 fill dot(z1, dot_size);
53 fill dot(z2, dot_size);
54 fill dot(z3, dot_size);
55 endchar;
56 endfor;
57
58 beginoperator(plus_size#, 1); "double colon";
59 r := (1/2plus_size - dot_size) * sqrt(2);
60
61 fill dot(centre + r * dir 45, dot_size);
62 fill dot(centre + r * dir 135, dot_size);
63 fill dot(centre + r * dir 225, dot_size);
64 fill dot(centre + r * dir 315, dot_size);
65 endchar;
66
67 beginoperator(plus_size#, 1); "minus";
68 draw_line(centre + radius * right, centre + radius * left, true);
69 endchar;
70
71 beginoperator(plus_size#, 1); "medium slash";
72 draw_line(centre + 4/3radius * dir 45, centre + 4/3radius * dir 225, true);
73 endchar;
74
75 beginoperator(plus_size#, 1); "medium backslash";
76 draw_line(centre + 4/3radius * dir 135, centre + 4/3radius * dir 315, true);
77 endchar;
78
79 beginoperator(plus_size#, 1); "plus";
80 draw_line(centre + radius * right, centre + radius * left, true);
81 draw_line(centre + radius * up, centre + radius * down, true);
82 endchar;
83
84 beginoperator(plus_size#, 1); "times";
85 r := 4/3radius;
86
87 draw_line(centre + r * dir 45, centre + r * dir 225, true);
88 draw_line(centre + r * dir 135, centre + r * dir 315, true);
89 endchar;
90
91 for angle = 0, 180:
92 beginoperator(plus_size#, 1); "dot minus (" & decimal angle & ")";
93 draw_line(centre - radius * dir angle, centre + radius * dir angle, true);
94 fill dot(centre + equal_spread * dir (angle + 90), 3/4dot_size);
95 endchar;
96 endfor;
97
98 beginoperator(plus_size#, 1); "divide";
99 draw_line(centre + radius * right, centre + radius * left, true);
100 fill dot(centre + equal_spread * up, 3/4dot_size);
101 fill dot(centre + equal_spread * down, 3/4dot_size);
102 endchar;
103
104 for sign = 1, -1:
105 beginoperator(plus_size#, 1); "minus with two dots";
106 draw_line(centre + radius * right, centre + radius * left, true);
107 fill dot(centre + sign * (radius - 3/4dot_size) * left + equal_spread * up, 3/4dot_size);
108 fill dot(centre + sign * (radius - 3/4dot_size) * right + equal_spread * down, 3/4dot_size);
109 endchar;
110 endfor;
111
112 beginoperator(plus_size#, 1); "minus with four dots";
113 draw_line(centre + radius * right, centre + radius * left, true);
114 fill dot(centre + (radius - 3/4dot_size) * left + equal_spread * up, 3/4dot_size);
115 fill dot(centre + (radius - 3/4dot_size) * right + equal_spread * up, 3/4dot_size);
116 fill dot(centre + (radius - 3/4dot_size) * left + equal_spread * down, 3/4dot_size);
117 fill dot(centre + (radius - 3/4dot_size) * right + equal_spread * down, 3/4dot_size);
118 endchar;
119
120 for angle = 0, 180:
121 beginoperator(plus_size#, 1.25); "plus minus (" & decimal angle & ")";
122 centre := centre + 0.125plus_size * dir (angle + 90);
123 pair bt;
124 bt := centre + (radius + 0.25plus_size) * dir (angle - 90);
125
126 draw_line(centre + radius * right, centre + radius * left, true);
127 draw_line(centre + radius * up, centre + radius * down, true);
128 draw_line(bt + radius * right, bt + radius * left, true);
129 endchar;
130 endfor;
131
132 for angle = 0, 180:
133 beginoperator(plus_size#, 1.25); "dot plus (" & decimal angle & ")";
134 centre := centre + 0.125plus_size * dir (angle - 90);
135 pair tp;
136 tp := centre + (radius + 0.25plus_size) * dir (angle + 90);
137
138 draw_line(centre + radius * right, centre + radius * left, true);
139 draw_line(centre + radius * up, centre + radius * down, true);
140 fill dot(tp, 3/4dot_size);
141 endchar;
142 endfor;
143
144 beginoperator(plus_size#, 1.25); "dot times";
145 centre := centre + 0.125plus_size * down;
146 pair tp;
147 tp := centre + (radius + 0.2plus_size) * up;
148 r := 4/3radius;
149
150 draw_line(centre + r * dir 45, centre + r * dir 225, true);
151 draw_line(centre + r * dir 135, centre + r * dir 315, true);
152 fill dot(tp, 3/4dot_size);
153 endchar;
154
155 beginoperator(plus_size#, 1.25); "times bar";
156 centre := centre + 0.125plus_size * up;
157 pair bt;
158 bt := centre + (radius + 0.25plus_size) * down;
159 r := 4/3radius;
160
161 draw_line(centre + r * dir 45, centre + r * dir 225, true);
162 draw_line(centre + r * dir 135, centre + r * dir 315, true);
163 draw_line(bt + radius * right, bt + radius * left, true);
164 endchar;
165
166 beginoperator(plus_size#, 1); "divide on times";
167 r := 4/3radius;
168
169 draw_line(centre + radius * right, centre + radius * left, true);
170 draw_line(centre + r * dir 45, centre + r * dir 225, true);
171 draw_line(centre + r * dir 135, centre + r * dir 315, true);
172 fill dot(centre + equal_spread * up, 3/4dot_size);
173 fill dot(centre + equal_spread * down, 3/4dot_size);
174 endchar;
175
176 for sign = 1, -1:
177 beginoperator(plus_size#, 1); "logical not";
178 draw_line(centre + radius * left, centre + radius * right, true);
179 draw_line(centre + sign * radius * right, centre + sign * radius * right + equal_spread * down, true);
180 endchar;
181 endfor;
182
183 for sign = 1, -1:
184 beginoperator(plus_size#, 1); "upside down logical not";
185 draw_line(centre + radius * left, centre + radius * right, true);
186 draw_line(centre + sign * radius * right, centre + sign * radius * right + equal_spread * up, true);
187 endchar;
188 endfor;
189
190 for sign = -1, 1:
191 beginoperator(plus_size#, 1); "three times";
192 r := 4/3radius;
193
194 z0 = centre + r * dir (sign * 45);
195 z1 = centre + r * dir (sign * 225);
196 z2 = centre + r * dir (270 + sign * 45);
197 z3 = centre + 1/4line_thickness * dir (270 + sign * 45);
198
199 draw_line(z0, z1, true);
200 draw_line(z3, z2, true);
201 endchar;
202 endfor;
203
204 for alpha = 0, 90, 180, 270:
205 beginoperator(plus_size#, 1); "closed times (" & decimal alpha & ")";
206 thick := line_thickness;
207 r := 4/3radius;
208
209 z0 = centre + (r + 1/2line_thickness) * dir (alpha + 45);
210 z1 = centre + r * dir (alpha + 315);
211 z2 = centre + r * dir (alpha + 225);
212 z3 = centre + (r + 1/2line_thickness) * dir (alpha + 135);
213
214 penpos0(thick,alpha + 315);
215 penpos1(thick,alpha + 45);
216 penpos2(thick,alpha + 315);
217 penpos3(thick,alpha + 45);
218
219 z5 = z1r + whatever * dir (270 + alpha - 15);
220 z6 = z2l + whatever * dir (270 + alpha + 15);
221 z5 = whatever[z1r + thick * dir (270 + alpha), z2l + thick * dir (270 + alpha)];
222 z6 = whatever[z1r + thick * dir (270 + alpha), z2l + thick * dir (270 + alpha)];
223
224 fill stroke z0e -- z2e;
225 fill stroke z1e -- z3e;
226 fill z1r -- z5 -- z6 -- z2l -- cycle;
227
228 penlabels(0,1,2,3,5,6);
229 endchar;
230 endfor;
231
232 for alpha = 0, 90:
233 beginoperator(plus_size#, 1); "bowtie (" & decimal alpha & ")";
234 thick := line_thickness;
235 r := 4/3radius;
236
237 z0 = centre + r * dir (alpha + 135);
238 z1 = centre + r * dir (alpha + 45);
239 z2 = centre + r * dir (alpha + 315);
240 z3 = centre + r * dir (alpha + 225);
241
242 penpos0(thick,alpha + 45);
243 penpos1(thick,alpha + 135);
244 penpos2(thick,alpha + 45);
245 penpos3(thick,alpha + 135);
246
247 z4 = z0r + whatever * dir (180 + alpha + 15);
248 z5 = z1r + whatever * dir (alpha - 15);
249 z6 = z2l + whatever * dir (alpha + 15);
250 z7 = z3l + whatever * dir (180 + alpha - 15);
251 z4 = whatever[z0r + thick * dir (180 + alpha), z3l + thick * dir (180 + alpha)];
252 z5 = whatever[z1r + thick * dir alpha, z2l + thick * dir alpha];
253 z6 = whatever[z1r + thick * dir alpha, z2l + thick * dir alpha];
254 z7 = whatever[z0r + thick * dir (180 + alpha), z3l + thick * dir (180 + alpha)];
255
256 fill stroke z0e -- z2e;
257 fill stroke z1e -- z3e;
258 fill z1r -- z5 -- z6 -- z2l -- cycle;
259 fill z0r -- z4 -- z7 -- z3l -- cycle;
260
261 penlabels(0,1,2,3,4,5,6,7);
262 endchar;
263 endfor;
264
265 for alpha = 0, 90, 180, 270:
266 beginoperator(plus_size#, 1); "Y (" & decimal alpha & ")";
267 s := 1/15plus_size;
268
269 draw_line(centre - s * dir alpha, centre + radius * dir alpha, true);
270 draw_line(centre - s * dir alpha, centre - s * dir alpha + (radius + s) * dir (alpha + 135), true);
271 draw_line(centre - s * dir alpha, centre - s * dir alpha + (radius + s) * dir (alpha + 225), true);
272 endchar;
273 endfor;
274
275 % operators
276
277 for sign = 1, -1:
278 beginoperator(plus_size#, 1); "wedge";
279 draw_less(a, centre + sign * plus_size/2 * up, centre - sign * plus_size/2 * up, 2radius, line_thickness, false, true);
280 endchar;
281 endfor;
282
283 for sign = 1, -1:
284 beginoperator(plus_size#, 1); "wedge dot";
285 draw_less(a, centre + sign * plus_size/2 * up, centre - sign * plus_size/2 * up, 2radius, line_thickness, false, true);
286 fill dot(centre - sign * 1/3plus_size * up, 3/4dot_size);
287 endchar;
288 endfor;
289
290 for sign = 1, -1:
291 beginsymbol(13/9plus_size# + 2side_bearing#, vcentre(plus_size#)); "double wedge";
292 1/2[z0,z1] = (w/2, (h-d)/2);
293 z1 - z0 = 4/9plus_size * right;
294
295 draw_less(a, z0 + sign * plus_size/2 * up, z0 - sign * plus_size/2 * up, 2radius, line_thickness, false, true);
296 draw_less(b, z1 + sign * plus_size/2 * up, z1 - sign * plus_size/2 * up, 2radius, line_thickness, false, true);
297 endchar;
298 endfor;
299
300 for sign = 1, -1:
301 beginoperator(plus_size#, 1); "curly wedge";
302 draw_prec(a, centre + sign * plus_size/2 * up, centre - sign * plus_size/2 * up, 2radius, line_thickness, false);
303 endchar;
304 endfor;
305
306 for sign = 1, -1:
307 beginoperator(plus_size#, 1.25); "bar wedge";
308 centre := centre - sign * 0.125plus_size * up;
309 pair tp;
310 tp := centre + sign * (radius + 0.25plus_size) * up;
311
312 draw_less(a, centre + sign * plus_size/2 * up, centre - sign * plus_size/2 * up, 2radius, line_thickness, false, true);
313 draw_line(tp + radius * left, tp + radius * right, true);
314 endchar;
315 endfor;
316
317 for sign = 1, -1:
318 beginoperator(plus_size#, 1.5); "double bar wedge";
319 centre := centre - sign * 0.25plus_size * up;
320 pair tpa, tpb;
321 tpa := centre + sign * (radius + 0.25plus_size) * up;
322 tpb := centre + sign * (radius + 0.5plus_size) * up;
323
324 draw_less(a, centre + sign * plus_size/2 * up, centre - sign * plus_size/2 * up, 2radius, line_thickness, false, true);
325 draw_line(tpa + radius * left, tpa + radius * right, true);
326 draw_line(tpb + radius * left, tpb + radius * right, true);
327 endchar;
328 endfor;
329
330 for sign = 1, -1:
331 beginoperator(plus_size#, 1); "union";
332 draw_subset(a,centre - sign * plus_size/2 * up, centre + sign * plus_size/2 * up, 2radius, line_thickness);
333 endchar;
334 endfor;
335
336 for sign = 1, -1:
337 beginoperator(4/3plus_size#, 1); "double union";
338 draw_subset(a, centre - sign * 5/18plus_size * up, centre + sign * 2/3plus_size * up, 5/6radius, line_thickness);
339 draw_subset(b, centre - sign * 2/3plus_size * up, centre + sign * 2/3plus_size * up, 2radius, line_thickness);
340 endchar;
341 endfor;
342
343 for sign = 1, -1:
344 beginoperator(plus_size#, 1); "union dot";
345 draw_subset(a, centre - sign * plus_size/2 * up, centre + sign * plus_size/2 * up, 2radius, line_thickness);
346 fill dot(centre + sign * 1/6plus_size * up, 3/4dot_size);
347 endchar;
348 endfor;
349
350 for sign = 1, -1:
351 beginoperator(plus_size#, 1); "union plus";
352 draw_subset(a, centre - sign * plus_size/2 * up, centre + sign * plus_size/2 * up, 2radius, line_thickness);
353
354 r := 1/6plus_size;
355
356 draw_line(centre + sign * 1/6plus_size * up + r * right, centre + sign * 1/6plus_size * up + r * left, true);
357 draw_line(centre + (r + sign * 1/6plus_size) * up, centre + (r - sign * 1/6plus_size) * down, true);
358 endchar;
359 endfor;
360
361 for sign = 1, -1:
362 beginoperator(plus_size#, 1); "square union";
363 z3 - z0 = z2 - z1 = 2radius * right;
364 z0 - z1 = sign * 2radius * up;
365 1/2[1/2[z0,z1], 1/2[z2,z3]] = centre;
366
367 draw_line(z0, z1, true);
368 draw_line(z1, z2, false);
369 draw_line(z2, z3, true);
370 endchar;
371 endfor;
372
373 for sign = 1, -1:
374 beginoperator(4/3plus_size#, 1); "double square union";
375 z3a - z0a = z2a - z1a = 2radius * right;
376 z0a - z1a = sign * 2radius * up;
377 1/2[1/2[z0a,z1a], 1/2[z2a,z3a]] = centre;
378 z3b - z0b = z2b - z1b = 5/9plus_size * right;
379 z0b - z1b = sign * 17/12radius * up;
380 y0b = y0a;
381 1/2[x0b, x3b] = xpart centre;
382
383 draw_line(z0a, z1a, true);
384 draw_line(z1a, z2a, false);
385 draw_line(z2a, z3a, true);
386 draw_line(z0b, z1b, true);
387 draw_line(z1b, z2b, false);
388 draw_line(z2b, z3b, true);
389 endchar;
390 endfor;
391
392 for sign = 1, -1:
393 beginoperator(plus_size#, 1); "square union dot";
394 z3 - z0 = z2 - z1 = 2radius * right;
395 z0 - z1 = sign * 2radius * up;
396 1/2[1/2[z0,z1], 1/2[z2,z3]] = centre;
397
398 draw_line(z0, z1, true);
399 draw_line(z1, z2, false);
400 draw_line(z2, z3, true);
401 fill dot(centre + sign * 1/6plus_size * up, 3/4dot_size);
402 endchar;
403 endfor;
404
405 for sign = 1, -1:
406 beginoperator(plus_size#, 1); "square union plus";
407 z3 - z0 = z2 - z1 = 2radius * right;
408 z0 - z1 = sign * 2radius * up;
409 1/2[1/2[z0,z1], 1/2[z2,z3]] = centre;
410
411 draw_line(z0, z1, true);
412 draw_line(z1, z2, false);
413 draw_line(z2, z3, true);
414
415 r := 1/6plus_size;
416
417 draw_line(centre + sign * 1/6plus_size * up + r * right, centre + sign * 1/6plus_size * up + r * left, true);
418 draw_line(centre + (r + sign * 1/6plus_size) * up, centre + (r - sign * 1/6plus_size) * down, true);
419 endchar;
420 endfor;
421
422 for alpha = 0, 180:
423 beginoperator(plus_size#, 1); "corner with dot";
424 z3 - z0 = z2 - z1 = 2radius * dir alpha;
425 z0 - z1 = 2radius * dir (alpha + 90);
426 1/2[1/2[z0,z1], 1/2[z2,z3]] = centre;
427
428 draw_line(z1, z2, true);
429 draw_line(z2, z3, true);
430 fill dot(centre, 3/4dot_size);
431 endchar;
432 endfor;
433
434 % triangles
435
436 for alpha = 0, 90, 180, 270:
437 beginsymbol((3/4small_op_size# + 3/2line_thickness#) * abs(cosd alpha) + sqrt(3) * (small_op_size#/2 + line_thickness#) * abs(sind alpha) + 2side_bearing#, vcentre(sqrt(3) * (small_op_size#/2 + line_thickness#) * abs(cosd alpha) + (3/4small_op_size# + 3/2line_thickness#) * abs(sind alpha))); "small triangle (" & decimal alpha & ")";
438 thick := line_thickness;
439 radius := small_op_size/2;
440 centre := (w/2, (h - d)/2) - 1/4(radius + thick) * dir alpha;
441
442 draw_triangle(a, centre, radius, alpha, thick);
443 endchar;
444 endfor;
445
446 for alpha = 0, 90, 180, 270:
447 beginsymbol((3/4small_op_size# + 3/2line_thickness#) * abs(cosd alpha) + sqrt(3) * (small_op_size#/2 + line_thickness#) * abs(sind alpha) + 2side_bearing#, vcentre(sqrt(3) * (small_op_size#/2 + line_thickness#) * abs(cosd alpha) + (3/4small_op_size# + 3/2line_thickness#) * abs(sind alpha))); "small filled triangle (" & decimal alpha & ")";
448 thick := line_thickness;
449 radius := small_op_size/2;
450 centre := (w/2, (h - d)/2) - 1/4(radius + thick) * dir alpha;
451
452 filldraw_triangle(a, centre, radius, alpha, thick);
453 endchar;
454 endfor;
455
456 for alpha = 0, 90, 180, 270:
457 beginsymbol((3/4med_op_size# + 3/2line_thickness#) * abs(cosd alpha) + sqrt(3) * (med_op_size#/2 + line_thickness#) * abs(sind alpha) + 2side_bearing#, vcentre(sqrt(3) * (med_op_size#/2 + line_thickness#) * abs(cosd alpha) + (3/4med_op_size# + 3/2line_thickness#) * abs(sind alpha))); "medium triangle (" & decimal alpha & ")";
458 thick := line_thickness;
459 radius := med_op_size/2;
460 centre := (w/2, (h - d)/2) - 1/4(radius + thick) * dir alpha;
461
462 draw_triangle(a, centre, radius, alpha, thick);
463 endchar;
464 endfor;
465
466 for alpha = 0, 90, 180, 270:
467 beginsymbol((3/4med_op_size# + 3/2line_thickness#) * abs(cosd alpha) + sqrt(3) * (med_op_size#/2 + line_thickness#) * abs(sind alpha) + 2side_bearing#, vcentre(sqrt(3) * (med_op_size#/2 + line_thickness#) * abs(cosd alpha) + (3/4med_op_size# + 3/2line_thickness#) * abs(sind alpha))); "medium filled triangle (" & decimal alpha & ")";
468 thick := line_thickness;
469 radius := med_op_size/2;
470 centre := (w/2, (h - d)/2) - 1/4(radius + thick) * dir alpha;
471
472 filldraw_triangle(a, centre, radius, alpha, thick);
473 endchar;
474 endfor;
475
476 for alpha = 90, 270:
477 beginsymbol(sqrt(3) * (large_op_size#/2 + line_thickness#) + 2side_bearing#, vcentre(3/4large_op_size# + 3/2line_thickness#)); "large triangle (" & decimal alpha & ")";
478 thick := line_thickness;
479 radius := large_op_size/2;
480 centre := (w/2, (h - d)/2) - 1/4(radius + thick) * dir alpha;
481
482 draw_triangle(a, centre, radius, alpha, thick);
483 endchar;
484 endfor;
485
486 % circles
487
488 beginoperator(4/5small_op_size#, 1); "small circle";
489 draw_circle(centre, radius, line_thickness);
490 endchar;
491
492 beginoperator(4/5small_op_size#, 1); "small filled circle";
493 filldraw_circle(centre, radius, line_thickness);
494 endchar;
495
496 beginoperator(4/5med_op_size#, 1); "medium circle";
497 draw_circle(centre, radius, line_thickness);
498 endchar;
499
500 beginoperator(4/5med_op_size#, 1); "medium filled circle";
501 filldraw_circle(centre, radius, line_thickness);
502 endchar;
503
504 beginoperator(4/5med_op_size#, 1); "medium circle minus";
505 draw_circle(centre, radius, line_thickness);
506 draw_line(centre + radius * left, centre + radius * right, false);
507 endchar;
508
509 beginoperator(4/5med_op_size#, 1); "medium circle bar";
510 draw_circle(centre, radius, line_thickness);
511 draw_line(centre + radius * up, centre + radius * down, false);
512 endchar;
513
514 beginoperator(4/5med_op_size#, 1); "medium circle slash";
515 draw_circle(centre, radius, line_thickness);
516 draw_line(centre + radius * dir 45, centre + radius * dir 225, false);
517 endchar;
518
519 beginoperator(4/5med_op_size#, 1); "medium circle backslash";
520 draw_circle(centre, radius, line_thickness);
521 draw_line(centre + radius * dir 135, centre + radius * dir 315, false);
522 endchar;
523
524 beginoperator(4/5med_op_size#, 1); "medium circle plus";
525 draw_circle(centre, radius, line_thickness);
526 draw_line(centre + radius * left, centre + radius * right, false);
527 draw_line(centre + radius * up, centre + radius * down, false);
528 endchar;
529
530 beginoperator(4/5med_op_size#, 1); "medium circle times";
531 draw_circle(centre, radius, line_thickness);
532 draw_line(centre + radius * dir 45, centre + radius * dir 225, false);
533 draw_line(centre + radius * dir 135, centre + radius * dir 315, false);
534 endchar;
535
536 beginoperator(4/5med_op_size#, 1); "medium circle dot";
537 draw_circle(centre, radius, line_thickness);
538 fill dot(centre, dot_size);
539 endchar;
540
541 beginoperator(4/5med_op_size#, 1); "medium circle circle";
542 draw_circle(centre, radius, line_thickness);
543 draw_circle(centre, 2/5radius, line_thickness);
544 endchar;
545
546 beginoperator(4/5med_op_size#, 1); "medium circle asterisk";
547 thick := line_thickness;
548
549 draw_circle(centre, radius, thick);
550
551 penpos a0(4/3thick, 0);
552 penpos a1(4/3thick, 60);
553 penpos a2(4/3thick, 120);
554 penpos a3(4/3thick, 180);
555 penpos a4(4/3thick, 240);
556 penpos a5(4/3thick, 300);
557
558 penpos b0(2/3thick, 0);
559 penpos b1(2/3thick, 60);
560 penpos b2(2/3thick, 120);
561 penpos b3(2/3thick, 180);
562 penpos b4(2/3thick, 240);
563 penpos b5(2/3thick, 300);
564
565 reg_poly_points(a)(6, centre, radius, 90);
566
567 z.b0 = z.b1 = z.b2 = z.b3 = z.b4 = z.b5 = centre;
568
569 fill stroke z.a0e -- z.b0e;
570 fill stroke z.a1e -- z.b1e;
571 fill stroke z.a2e -- z.b2e;
572 fill stroke z.a3e -- z.b3e;
573 fill stroke z.a4e -- z.b4e;
574 fill stroke z.a5e -- z.b5e;
575 endchar;
576
577 beginoperator(4/5med_op_size#, 1); "medium circle dash";
578 draw_circle(centre, radius, line_thickness);
579 draw_line(centre + 2/3radius * left, centre + 2/3radius * right, false);
580 endchar;
581
582 beginoperator(4/5med_op_size#, 1); "medium circle equal";
583 draw_circle(centre, radius, line_thickness);
584 draw_line(centre + 2/5equal_spread * up + 2/3radius * left, centre + 2/5equal_spread * up + 2/3radius * right, false);
585 draw_line(centre + 2/5equal_spread * down + 2/3radius * left, centre + 2/5equal_spread * down + 2/3radius * right, false);
586 endchar;
587
588 for sign = 1,-1:
589 beginoperator(4/5med_op_size#, 1); "negated medium circle";
590 r := 4/3radius;
591
592 draw_circle(centre, radius, line_thickness);
593 draw_line(centre + r * dir (sign * 45), centre + r * dir (sign * 225), true);
594 endchar;
595 endfor;
596
597 beginoperator(4/5large_op_size#, 1); "large circle";
598 draw_circle(centre, radius, line_thickness);
599 endchar;
600
601 beginoperator(4/5large_op_size#, 1); "large filled circle";
602 filldraw_circle(centre, radius, line_thickness);
603 endchar;
604
605 % squares
606
607 beginoperator(small_op_size#/sqrt(2), 1); "small square";
608 draw_square(centre, radius, 0, line_thickness);
609 endchar;
610
611 beginoperator(small_op_size#/sqrt(2), 1); "small filled square";
612 filldraw_square(centre, radius, 0, line_thickness);
613 endchar;
614
615 beginoperator(med_op_size#/sqrt(2), 1); "medium square";
616 draw_square(centre, radius, 0, line_thickness);
617 endchar;
618
619 beginoperator(med_op_size#/sqrt(2), 1); "medium filled square";
620 filldraw_square(centre, radius, 0, line_thickness);
621 endchar;
622
623 beginoperator(med_op_size#/sqrt(2), 1); "medium square minus";
624 draw_square(centre, radius, 0, line_thickness);
625 draw_line(centre + radius * right, centre + radius * left, false);
626 endchar;
627
628 beginoperator(med_op_size#/sqrt(2), 1); "medium square vert";
629 draw_square(centre, radius, 0, line_thickness);
630 draw_line(centre + radius * up, centre + radius * down, false);
631 endchar;
632
633 beginoperator(med_op_size#/sqrt(2), 1); "medium square slash";
634 r := radius * sqrt(2);
635
636 draw_square(centre, radius, 0, line_thickness);
637 draw_line(centre + r * dir 45, centre + r * dir 225, false);
638 endchar;
639
640 beginoperator(med_op_size#/sqrt(2), 1); "medium square backslash";
641 r := radius * sqrt(2);
642
643 draw_square(centre, radius, 0, line_thickness);
644 draw_line(centre + r * dir 135, centre + r * dir 315, false);
645 endchar;
646
647 beginoperator(med_op_size#/sqrt(2), 1); "medium square plus";
648 draw_square(centre, radius, 0, line_thickness);
649 draw_line(centre + radius * right, centre + radius * left, false);
650 draw_line(centre + radius * up, centre + radius * down, false);
651 endchar;
652
653 beginoperator(med_op_size#/sqrt(2), 1); "medium square times";
654 r := radius * sqrt(2);
655
656 draw_square(centre, radius, 0, line_thickness);
657 draw_line(centre + r * dir 45, centre + r * dir 225, false);
658 draw_line(centre + r * dir 135, centre + r * dir 315, false);
659 endchar;
660
661 beginoperator(med_op_size#/sqrt(2), 1); "medium square dot";
662 draw_square(centre, radius, 0, line_thickness);
663 fill dot(centre, dot_size);
664 endchar;
665
666 beginoperator(med_op_size#/sqrt(2), 1); "medium square square";
667 draw_square(centre, radius, 0, line_thickness);
668 draw_square(centre, 2/5radius, 0, 4/5line_thickness);
669 endchar;
670
671 beginoperator(large_op_size#/sqrt(2), 1); "large square";
672 draw_square(centre, radius, 0, line_thickness);
673 endchar;
674
675 beginoperator(large_op_size#/sqrt(2), 1); "large filled square";
676 filldraw_square(centre, radius, 0, line_thickness);
677 endchar;
678
679 beginoperator(small_op_size#, 1); "small diamond";
680 draw_square(centre, radius / sqrt(2), 45, line_thickness);
681 endchar;
682
683 beginoperator(small_op_size#, 1); "small filled diamond";
684 filldraw_square(centre, radius / sqrt(2), 45, line_thickness);
685 endchar;
686
687 beginoperator(med_op_size#, 1); "medium diamond";
688 draw_square(centre, radius / sqrt(2), 45, line_thickness);
689 endchar;
690
691 beginoperator(med_op_size#, 1); "medium filled diamond";
692 filldraw_square(centre, radius / sqrt(2), 45, line_thickness);
693 endchar;
694
695 beginoperator(med_op_size#, 1); "medium diamond minus";
696 draw_square(centre, radius / sqrt(2), 45, line_thickness);
697 draw_line(centre + radius * right, centre + radius * left, false);
698 endchar;
699
700 beginoperator(med_op_size#, 1); "medium diamond vert";
701 draw_square(centre, radius / sqrt(2), 45, line_thickness);
702 draw_line(centre + radius * up, centre + radius * down, false);
703 endchar;
704
705 beginoperator(med_op_size#, 1); "medium diamond slash";
706 r := radius / sqrt(2);
707
708 draw_square(centre, r, 45, line_thickness);
709 draw_line(centre + r * dir 45, centre + r * dir 225, false);
710 endchar;
711
712 beginoperator(med_op_size#, 1); "medium diamond backslash";
713 r := radius / sqrt(2);
714
715 draw_square(centre, r, 45, line_thickness);
716 draw_line(centre + r * dir 135, centre + r * dir 315, false);
717 endchar;
718
719 beginoperator(med_op_size#, 1); "medium diamond plus";
720 draw_square(centre, radius / sqrt(2), 45, line_thickness);
721 draw_line(centre + radius * right, centre + radius * left, false);
722 draw_line(centre + radius * up, centre + radius * down, false);
723 endchar;
724
725 beginoperator(med_op_size#, 1); "medium diamond times";
726 r := radius / sqrt(2);
727
728 draw_square(centre, r, 45, line_thickness);
729 draw_line(centre + r * dir 45, centre + r * dir 225, false);
730 draw_line(centre + r * dir 135, centre + r * dir 315, false);
731 endchar;
732
733 beginoperator(med_op_size#, 1); "medium diamond dot";
734 draw_square(centre, radius / sqrt(2), 45, line_thickness);
735 fill dot(centre, dot_size);
736 endchar;
737
738 beginoperator(med_op_size#, 1); "medium diamond diamond";
739 draw_square(centre, radius / sqrt(2), 45, line_thickness);
740 draw_square(centre, 2/5radius / sqrt(2), 45, 4/5line_thickness);
741 endchar;
742
743 beginoperator(5/6small_op_size#, 8/5); "small lozenge";
744 x0 = w - x2 = side_bearing;
745 y0 = y2 = ypart centre;
746 x1 = x3 = xpart centre;
747 y1 = h;
748 y3 = -d;
749
750 theta := angle(z1 - z0);
751
752 x0' = x0 + line_thickness / sind theta;
753 x2' = x2 - line_thickness / sind theta;
754 y0' = y2' = y0;
755 y1' = y1 - line_thickness / cosd theta;
756 y3' = y3 + line_thickness / cosd theta;
757 x1' = x3' = x1;
758
759 fill z0 -- z1 -- z2 -- z3 -- cycle;
760 unfill z0' -- z1' -- z2' -- z3' -- cycle;
761 endchar;
762
763 beginoperator(5/6small_op_size#, 8/5); "small filled lozenge";
764 x0 = w - x2 = side_bearing;
765 y0 = y2 = ypart centre;
766 x1 = x3 = xpart centre;
767 y1 = h;
768 y3 = -d;
769
770 fill z0 -- z1 -- z2 -- z3 -- cycle;
771 endchar;
772
773 beginoperator(1/sqrt(2)*med_op_size#, 8/5); "medium lozenge";
774 x0 = w - x2 = side_bearing;
775 y0 = y2 = ypart centre;
776 x1 = x3 = xpart centre;
777 y1 = h;
778 y3 = -d;
779
780 theta := angle(z1 - z0);
781
782 x0' = x0 + line_thickness / sind theta;
783 x2' = x2 - line_thickness / sind theta;
784 y0' = y2' = y0;
785 y1' = y1 - line_thickness / cosd theta;
786 y3' = y3 + line_thickness / cosd theta;
787 x1' = x3' = x1;
788
789 fill z0 -- z1 -- z2 -- z3 -- cycle;
790 unfill z0' -- z1' -- z2' -- z3' -- cycle;
791 endchar;
792
793 beginoperator(1/sqrt(2)*med_op_size#, 8/5); "medium filled lozenge";
794 x0 = w - x2 = side_bearing;
795 y0 = y2 = ypart centre;
796 x1 = x3 = xpart centre;
797 y1 = h;
798 y3 = -d;
799
800 fill z0 -- z1 -- z2 -- z3 -- cycle;
801 endchar;
802
803 beginoperator(1/sqrt(2)*med_op_size#, 8/5); "medium lozenge minus";
804 thick := line_thickness;
805
806 x0 = w - x2 = side_bearing;
807 y0 = y2 = ypart centre;
808 x1 = x3 = xpart centre;
809 y1 = h;
810 y3 = -d;
811
812 theta := angle(z1 - z0);
813
814 x0' = x0 + thick / sind theta;
815 x2' = x2 - thick / sind theta;
816 y0' = y2' = y0;
817 y1' = y1 - thick / cosd theta;
818 y3' = y3 + thick / cosd theta;
819 x1' = x3' = x1;
820
821 fill z0 -- z1 -- z2 -- z3 -- cycle;
822 unfill z0' -- z1' -- z2' -- z3' -- cycle;
823 draw_line(z0', z2', true);
824 endchar;
825
826 beginoperator(5/4small_op_size#, 1); "small star";
827 r := radius + line_thickness;
828 t := 1/11r;
829
830 reg_poly_points(a)(5, centre - t * up, r, 90);
831 reg_poly_points(b)(5, centre - t * up, .4r, 126);
832
833 s := r - 4/5line_thickness / sind (270 - angle (z.b0 - z.a0));
834
835 reg_poly_points(c)(5, centre - t * up, s, 90);
836 reg_poly_points(d)(5, centre - t * up, .4s, 126);
837
838 fill z.a0 -- z.b0 -- z.a1 -- z.b1 -- z.a2 -- z.b2 -- z.a3 -- z.b3 -- z.a4 -- z.b4 -- cycle;
839 unfill z.c0 -- z.d0 -- z.c1 -- z.d1 -- z.c2 -- z.d2 -- z.c3 -- z.d3 -- z.c4 -- z.d4 -- cycle;
840 endchar;
841
842 beginoperator(small_op_size#, 1); "small filled star";
843 r := radius + line_thickness;
844 t := 1/11r;
845
846 reg_poly_points(a)(5, centre - t * up, r, 90);
847 reg_poly_points(b)(5, centre - t * up, .4r, 126);
848
849 fill z.a0 -- z.b0 -- z.a1 -- z.b1 -- z.a2 -- z.b2 -- z.a3 -- z.b3 -- z.a4 -- z.b4 -- cycle;
850 endchar;
851
852 beginoperator(med_op_size#, 1); "medium star";
853 r := radius + line_thickness;
854 t := 1/11r;
855
856 reg_poly_points(a)(5, centre - t * up, r, 90);
857 reg_poly_points(b)(5, centre - t * up, .4r, 126);
858
859 s := r - line_thickness / sind (270 - angle (z.b0 - z.a0));
860
861 reg_poly_points(c)(5, centre - t * up, s, 90);
862 reg_poly_points(d)(5, centre - t * up, .4s, 126);
863
864 fill z.a0 -- z.b0 -- z.a1 -- z.b1 -- z.a2 -- z.b2 -- z.a3 -- z.b3 -- z.a4 -- z.b4 -- cycle;
865 unfill z.c0 -- z.d0 -- z.c1 -- z.d1 -- z.c2 -- z.d2 -- z.c3 -- z.d3 -- z.c4 -- z.d4 -- cycle;
866 endchar;
867
868 beginoperator(med_op_size#, 1); "medium filled star";
869 r := radius + line_thickness;
870 t := 1/11r;
871
872 reg_poly_points(a)(5, centre - t * up, r, 90);
873 reg_poly_points(b)(5, centre - t * up, .4r, 126);
874
875 fill z.a0 -- z.b0 -- z.a1 -- z.b1 -- z.a2 -- z.b2 -- z.a3 -- z.b3 -- z.a4 -- z.b4 -- cycle;
876 endchar;
877
878 beginoperator(large_op_size#, 1); "large star";
879 r := radius + line_thickness;
880 t := 1/11r;
881
882 reg_poly_points(a)(5, centre - t * up, r, 90);
883 reg_poly_points(b)(5, centre - t * up, .4r, 126);
884
885 s := r - line_thickness / sind (270 - angle (z.b0 - z.a0));
886
887 reg_poly_points(c)(5, centre - t * up, s, 90);
888 reg_poly_points(d)(5, centre - t * up, .4s, 126);
889
890 fill z.a0 -- z.b0 -- z.a1 -- z.b1 -- z.a2 -- z.b2 -- z.a3 -- z.b3 -- z.a4 -- z.b4 -- cycle;
891 unfill z.c0 -- z.d0 -- z.c1 -- z.d1 -- z.c2 -- z.d2 -- z.c3 -- z.d3 -- z.c4 -- z.d4 -- cycle;
892 endchar;
893
894 beginoperator(large_op_size#, 1); "large filled star";
895 r := radius + line_thickness;
896 t := 1/11r;
897
898 reg_poly_points(a)(5, centre - t * up, r, 90);
899 reg_poly_points(b)(5, centre - t * up, .4r, 126);
900
901 fill z.a0 -- z.b0 -- z.a1 -- z.b1 -- z.a2 -- z.b2 -- z.a3 -- z.b3 -- z.a4 -- z.b4 -- cycle;
902 endchar;
903
904 beginoperator(small_op_size#, 1); "asterisk";
905 r := w/2 - side_bearing;
906
907 penpos a0(4/3line_thickness, 0);
908 penpos a1(4/3line_thickness, 60);
909 penpos a2(4/3line_thickness, 120);
910 penpos a3(4/3line_thickness, 180);
911 penpos a4(4/3line_thickness, 240);
912 penpos a5(4/3line_thickness, 300);
913
914 penpos b0(2/3line_thickness, 0);
915 penpos b1(2/3line_thickness, 60);
916 penpos b2(2/3line_thickness, 120);
917 penpos b3(2/3line_thickness, 180);
918 penpos b4(2/3line_thickness, 240);
919 penpos b5(2/3line_thickness, 300);
920
921 reg_poly_points(a)(6, centre, r, 90);
922
923 z.b0 = z.b1 = z.b2 = z.b3 = z.b4 = z.b5 = centre;
924
925 fill stroke z.a0e -- z.b0e;
926 fill stroke z.a1e -- z.b1e;
927 fill stroke z.a2e -- z.b2e;
928 fill stroke z.a3e -- z.b3e;
929 fill stroke z.a4e -- z.b4e;
930 fill stroke z.a5e -- z.b5e;
931 endchar;
932
933 beginsymbol(18/10order_width# + 2side_bearing#, vcentre(2equal_spread# + line_thickness#)); "infinity";
934 pair centre;
935 centre := (w/2, (h-d)/2);
936 thick := line_thickness;
937 thin := letter_line_thickness;
938 alpha := 0;
939
940 z0 = centre - (9/10order_width - 1/2thin) * dir alpha;
941 z1 = centre + (9/10order_width - 1/2thin) * dir alpha;
942 z6 = 1/5[z0,z1];
943 z7 = 4/5[z0,z1];
944 z2 = z6 + equal_spread * dir (alpha + 90);
945 z3 = z6 - equal_spread * dir (alpha + 90);
946 z4 = z7 + equal_spread * dir (alpha + 90);
947 z5 = z7 - equal_spread * dir (alpha + 90);
948 z8 = z9 = centre;
949
950 penpos0(thin, alpha);
951 penpos1(thin, alpha);
952 penpos2(thick, alpha - 90);
953 penpos3(thick, alpha + 90);
954 penpos4(thick, alpha + 90);
955 penpos5(thick, alpha - 90);
956 penpos8(thin, alpha - 135);
957 penpos9(thin, alpha + 135);
958
959 fill stroke z4.e{dir (alpha + 180)}
960 .. {dir (alpha + 225)}z9.e
961 .. {dir (alpha + 180)}z3.e
962 .. {dir (alpha + 90)}z0.e
963 .. {dir alpha}z2.e
964 .. {dir (alpha - 45)}z8.e
965 .. {dir alpha}z5.e
966 .. {dir (alpha + 90)}z1.e
967 .. cycle;
968
969 penlabels (0,1,2,3,4,5,6,7,8,9);
970 endchar;
971
972 for alpha = 0, 180:
973 beginsymbol(16/10order_width# + 2side_bearing#, vcentre(2equal_spread# + line_thickness#)); "proportional";
974 pair centre;
975 centre := (w/2, (h-d)/2);
976 thick := line_thickness;
977
978 z0 = centre - (8/10order_width - 1/2thick) * dir alpha;
979 z1 = centre + (7/10order_width - 1/2thick) * dir alpha;
980 z4 = z1 + equal_spread * dir (alpha + 90);
981 z5 = z1 - equal_spread * dir (alpha + 90);
982 z6 - z4 = z7 - z5 = (1/10order_width + 1/2thick) * dir alpha;
983 z10 = 1/4[z0,z1];
984 z2 = z10 + equal_spread * dir (alpha + 90);
985 z3 = z10 - equal_spread * dir (alpha + 90);
986 z8 = z9 = centre + 1/10order_width * dir alpha;
987
988 penpos0(thick, alpha);
989 penpos2(thick, alpha - 90);
990 penpos3(thick, alpha + 90);
991 penpos4(thick, alpha + 90);
992 penpos5(thick, alpha - 90);
993 penpos6(thick, alpha + 90);
994 penpos7(thick, alpha - 90);
995 penpos8(thick, alpha + 225);
996 penpos9(thick, alpha + 135);
997
998 fill stroke z6.e
999 -- z4.e{dir (alpha + 180)}
1000 .. {dir (alpha + 225)}z9.e
1001 .. {dir (alpha + 180)}z3.e
1002 .. {dir (alpha + 90)}z0.e
1003 .. {dir alpha}z2.e
1004 .. {dir (alpha - 45)}z8.e
1005 .. {dir alpha}z5.e
1006 -- z7.e;
1007
1008 penlabels (0,1,2,3,4,5,6,7,8,9);
1009 endchar;
1010 endfor;
1011
1012 beginsymbol(14/10order_width# + 2side_bearing#, vcentre(2equal_spread# + line_thickness#)); "crossing";
1013 pair centre;
1014 centre := (w/2, (h-d)/2);
1015 thick := line_thickness;
1016 alpha := 0;
1017
1018 z0 = centre - (6/10order_width - 1/2thick) * dir alpha;
1019 z1 = centre + (6/10order_width - 1/2thick) * dir alpha;
1020 z2 = z0 + equal_spread * dir (alpha + 90);
1021 z3 = z0 - equal_spread * dir (alpha + 90);
1022 z4 = z1 + equal_spread * dir (alpha + 90);
1023 z5 = z1 - equal_spread * dir (alpha + 90);
1024 z6 - z4 = z7 - z5 = (1/10order_width + 1/2thick) * dir alpha;
1025 z2 - z8 = z3 - z9 = (1/10order_width + 1/2thick) * dir alpha;
1026 z10 = z11 = 1/2[z0,z1];
1027
1028 penpos2(thick, alpha + 90);
1029 penpos3(thick, alpha + 90);
1030 penpos4(thick, alpha + 90);
1031 penpos5(thick, alpha + 90);
1032 penpos6(thick, alpha + 90);
1033 penpos7(thick, alpha + 90);
1034 penpos8(thick, alpha + 90);
1035 penpos9(thick, alpha + 90);
1036 penpos10(thick, alpha + 45);
1037 penpos11(thick, alpha + 135);
1038
1039 fill stroke z6.e
1040 -- z4.e{dir (alpha + 180)}
1041 .. {dir (alpha + 225)}z11.e
1042 .. {dir (alpha + 180)}z3.e
1043 -- z9.e;
1044 fill stroke z8.e
1045 -- z2.e{dir alpha}
1046 .. {dir (alpha - 45)}z10.e
1047 .. {dir alpha}z5.e
1048 -- z7.e;
1049
1050 penlabels (0,1,2,3,4,5,6,7,8,9,10,11);
1051 endchar;
1052
1053 beginsymbol(equal_spread# + line_thickness# + 2side_bearing#, vcentre(med_op_size#)); "between";
1054 pair centre;
1055 centre := (w/2, (h-d)/2);
1056 r := med_op_size/2;
1057
1058 z0 = centre;
1059 z1 = centre;
1060
1061 draw_smile(a, 1, z0 - r * up, z0 + r * up, equal_spread, line_thickness, true);
1062 draw_smile(b, -1, z1 - r * up, z1 + r * up, equal_spread, line_thickness, true);
1063 endchar;
1064
1065 beginsymbol(2equal_spread# + 2side_bearing#, x_height#, desc_depth#); "intercalate";
1066 z1 - z0 = z3 - z2 = (2equal_spread - line_thickness) * right;
1067 z2 - z0 = (h + d - line_thickness) * up;
1068
1069 1/2[1/2[z0,z1], 1/2[z2,z3]] = (w/2, (h-d)/2);
1070
1071 draw_line(z2, z3, true);
1072 draw_line(1/2[z0,z1], 1/2[z2,z3], true);
1073 endchar;
1074
1075 beginsymbol(2/3equal_spread# + line_thickness# + 2side_bearing#, vcentre(plus_size#)); "wreath";
1076 pair centre;
1077 centre := (w/2, (h-d)/2);
1078
1079 draw_sim(a, centre + 1/2plus_size * up, centre - 1/2plus_size * up, 1/3equal_spread, thick);
1080 endchar;
1081
1082 for sign = 1, -1:
1083 beginoperator(plus_size#, 1); "angle";
1084 z0 = centre + (plus_size - line_thickness)/2 * down;
1085 z1 = z0 + sign * 1/2plus_size * right;
1086 z2 = z0 + sign * 1/2plus_size * left;
1087 x3 = xpart centre + sign * 1/2plus_size;
1088 y3 = ypart centre + 2/3plus_size;
1089 z4 = 4/5[z2,z3];
1090 z5 = z4l + whatever * (z2 - z4);
1091 z5 = z1r + whatever * right;
1092 z6 = z4r + whatever * (z2 - z4);
1093 z6 = z1r + whatever * right;
1094 z7 = z1l + whatever * right;
1095 z7 = z6 + whatever * dir (90 + sign * 17);
1096
1097 penpos1(line_thickness, 90);
1098 penpos4(line_thickness, angle(z3 - z2) + sign * 90);
1099
1100 fill z1r -- z5 -- z4l -- z4r -- z6 -- z7 -- z1l -- cycle;
1101
1102 penlabels(1,2,3,4,5,6,7);
1103 endchar;
1104 endfor;
1105
1106 for sign = 1, -1:
1107 beginoperator(plus_size#, 1); "measured angle";
1108 z0 = centre + (plus_size - line_thickness)/2 * down;
1109 z1 = z0 + sign * 1/2plus_size * right;
1110 z2 = z0 + sign * 1/2plus_size * left;
1111 x3 = xpart centre + sign * 1/2plus_size;
1112 y3 = ypart centre + 2/3plus_size;
1113 z4 = 4/5[z2,z3];
1114 z5 = z4l + whatever * (z2 - z4);
1115 z5 = z1r + whatever * right;
1116 z6 = z4r + whatever * (z2 - z4);
1117 z6 = z1r + whatever * right;
1118 z7 = z1l + whatever * right;
1119 z7 = z6 + whatever * dir (90 + sign * 17);
1120 z8 = 2/3[z2,z1];
1121 z9 = z2 + sign * ((z8 - z2) rotated angle (z3 - z2));
1122
1123 penpos1(line_thickness, 90);
1124 penpos4(line_thickness, angle(z3 - z2) + sign * 90);
1125 penpos8(line_thickness, 90 - sign * 90);
1126 penpos9(line_thickness, angle(z3 - z2));
1127
1128 fill z1r -- z5 -- z4l -- z4r -- z6 -- z7 -- z1l -- cycle;
1129 fill stroke z8.e{up} .. {dir (angle (z3 - z2) + sign * 90)}z9.e;
1130
1131 penlabels(1,2,3,4,5,6,7,8,9);
1132 endchar;
1133 endfor;
1134
1135 for alpha = 0, 90, 180, 270:
1136 beginoperator(plus_size#, 1); "spherical angle (" & decimal alpha & ")";
1137 draw_less(a, centre - 1/2plus_size * dir alpha, centre + 1/2plus_size * dir alpha, 2radius, line_thickness, false, false);
1138 z3 = 2/3[z2a, z0a];
1139 z4 = 2/3[z2a, z1a];
1140
1141 penpos3(line_thickness, alpha + 35);
1142 penpos4(line_thickness, alpha - 35);
1143
1144 fill stroke z4.e{dir (alpha + 55)} .. {dir (alpha + 125)}z3.e;
1145
1146 penlabels(3,4);
1147 endchar;
1148 endfor;
1149
1150 beginoperator(plus_size#, 1); "right angle";
1151 z3 - z0 = z2 - z1 = 2radius * right;
1152 z0 - z1 = 2radius * up;
1153 1/2[1/2[z0,z1], 1/2[z2,z3]] = centre;
1154
1155 draw_line(z0, z1, true);
1156 draw_line(z1, z2, true);
1157 endchar;
1158
1159 beginoperator(plus_size#, 1); "measured right angle";
1160 thick := line_thickness;
1161
1162 z3 - z0 = z2 - z1 = 2radius * right;
1163 z0 - z1 = 2radius * up;
1164 1/2[1/2[z0,z1], 1/2[z2,z3]] = centre;
1165 z4 = 3/5[z1,z0] + (1/2thick - eps) * right;
1166 z5 = 3/5[z1,z2] + (1/2thick - eps) * up;
1167
1168 penpos4(thick, 90);
1169 penpos5(thick, 0);
1170
1171 draw_line(z0, z1, true);
1172 draw_line(z1, z2, true);
1173 fill stroke z4.e{right} .. {down}z5.e;
1174
1175 penlabels(0,1,2,3,4,5);
1176 endchar;
1177
1178 beginoperator(plus_size#, 1); "squared right angle";
1179 z3 - z0 = z2 - z1 = 2radius * right;
1180 z0 - z1 = 2radius * up;
1181 1/2[1/2[z0,z1], 1/2[z2,z3]] = centre;
1182 z4 = 1/2[z1,z0];
1183 z5 = 1/2[z1,z2];
1184
1185 penpos4(line_thickness, 90);
1186 penpos5(line_thickness, 0);
1187
1188 draw_line(z0, z1, true);
1189 draw_line(z1, z2, true);
1190 draw_line(z4, centre, true);
1191 draw_line(z5, centre, true);
1192
1193 penlabels(0,1,2,3,4,5);
1194 endchar;
1195
1196 beginoperator(plus_size#, 1); "right angle with dot";
1197 thick := line_thickness;
1198
1199 z3 - z0 = z2 - z1 = 2radius * right;
1200 z0 - z1 = 2radius * up;
1201 1/2[1/2[z0,z1], 1/2[z2,z3]] = centre;
1202 z4 = 3/5[z1,z0] + (1/2thick - eps) * right;
1203 z5 = 3/5[z1,z2] + (1/2thick - eps) * up;
1204 z6 = 1/4[z1,z3];
1205
1206 penpos4(line_thickness, 90);
1207 penpos5(line_thickness, 0);
1208
1209 draw_line(z0, z1, true);
1210 draw_line(z1, z2, true);
1211 fill stroke z4.e{right} .. {down}z5.e;
1212 fill dot(z6, 1/2dot_size);
1213
1214 penlabels(0,1,2,3,4,5);
1215 endchar;
1216
1217 beginsymbol(3u# + line_thickness#, 3/5asc_height#, 0); "prime";
1218 z0 = (w, h);
1219 z1 = z0 + (3/4u + line_thickness) * left;
1220 z2 = (1u, 1/9h);
1221 z3 = z2 + 5/4line_thickness * right;
1222
1223 fill z0 -- z1 -- z2 -- z3 -- cycle;
1224 labels(0,1,2,3);
1225 endchar;
1226
1227 beginsymbol(3u# + line_thickness#, 3/5asc_height#, 0); "backprime";
1228 z0 = (0, h);
1229 z1 = z0 + (3/4u + line_thickness) * right;
1230 z2 = (w - 1u, 1/9h);
1231 z3 = z2 + 5/4line_thickness * left;
1232
1233 fill z0 -- z1 -- z2 -- z3 -- cycle;
1234 labels(0,1,2,3);
1235 endchar;
1236
1237 for sign = 1, -1:
1238 beginoperator(plus_size#, 1); "product";
1239 draw_product(centre, plus_size, plus_size, sign, letter_line_thickness);
1240 endchar;
1241 endfor;
1242
1243 beginsymbol(2/5asc_height# + 2side_bearing# + line_thickness#, asc_height#, 0); "small integral";
1244 pair centre;
1245 centre := (w/2, (h - d)/2);
1246
1247 draw_integral(a, 1/2, centre, line_thickness);
1248 endchar;
1249
1250 beginsymbol(11u# + line_thickness# + 2side_bearing#, asc_height#, 0); "check mark";
1251 thick := line_thickness;
1252
1253 x1l = side_bearing;
1254 y1 = math_axis;
1255 x2 = side_bearing + 3u;
1256 y2 = -d;
1257 x3 = w -x2;
1258 y3 = h;
1259 x4r = w - side_bearing;
1260 y4l = h;
1261 z5r = 1/10[z4r,z1r];
1262
1263 theta := angle(z3 - z2);
1264
1265 penpos1(4/3thick, 30);
1266 penpos2(thick, 0);
1267 penpos3(thick, -90 + theta);
1268 penpos4(1/3thick, -80);
1269 penpos5(thick, -50);
1270
1271 z6 = z1r + whatever * (z2l - z1l);
1272 z6 = z3l + whatever * (z3r - z2r);
1273
1274 fill z1l -- z2l -- z2r{z3r - z2r} .. {dir 40}z5r .. z4r -- z4l{dir 180} ... z5l{dir 220} .. {z2l - z3l}z6 -- z1r -- cycle;
1275
1276 penlabels(1,2,3,4,5,6);
1277 endchar;
1278
1279 beginsymbol(6u# + line_thickness# + 2side_bearing#, 5/4asc_height#, 1/8asc_height#); "lightning";
1280 thick := line_thickness;
1281
1282 x3r = w - side_bearing;
1283 x2l = side_bearing + u;
1284 x4 = 1/3w;
1285 y1l = h;
1286 y3r = 14/24h;
1287 y4 = -d + 1/2thick;
1288 z6 - z5 = whatever * dir 15;
1289
1290 penpos1(3/2thick, -20);
1291 penpos2(3/2thick, 15);
1292 penpos3(2thick, 15);
1293 penpos4(thick, -20);
1294 penpos5(thick, -75);
1295 penpos6(thick, -75);
1296
1297 z1 - z2 = whatever * (z4 - z3);
1298 z5r = z2;
1299 z6l = z3;
1300 z7 = whatever[z1r,z2r];
1301 z7 = whatever[z5l,z6l];
1302 z8 = whatever[z4l,z3l];
1303 z8 = whatever[z6r,z5r];
1304
1305 fill z1l -- z2l -- z8 -- z4l -- z4r -- z3r -- z7 -- z1r -- cycle;
1306 draw_arrowhead(z4, angle (z4l - z3l), 4/5arrow_spread, thick);
1307
1308 penlabels(1,2,3,4,7,8);
1309 endchar;
1310
1311 for filled = false, true:
1312 beginsymbol(13u#, cap_height#, 0); "diamond suit";
1313 thick := line_thickness;
1314 bend := 5;
1315
1316 x0 = x2 = x4 = x6 = w/2;
1317 1/2[y0,y2] = 1/2[y4,y6] = h/2;
1318 y2 - y0 = h;
1319 1/2[x1,x3] = 1/2[x5,x7] = w/2;
1320 x3 - x1 = w - 2side_bearing;
1321 y1 = y3 = y5 = y7 = h/2;
1322
1323 theta := angle(z2 - z1);
1324
1325 y6 - y4 = h - 2thick / cosd theta;
1326 x7 - x5 = w - 2side_bearing - 2thick / sind theta;
1327
1328 fill z0{dir (180-theta-bend)} .. {dir (180-theta+bend)}z1{dir (theta-bend)} .. {dir (theta+bend)}z2{dir (-theta-bend)} .. {dir (-theta+bend)}z3{dir (180+theta-bend)} .. {dir (180+theta+bend)}z0 & cycle;
1329 if not filled:
1330 unfill z4{dir (180-theta-bend)} .. {dir (180-theta+bend)}z5{dir (theta-bend)} .. {dir (theta+bend)}z6{dir (-theta-bend)} .. {dir (-theta+bend)}z7{dir (180+theta-bend)} .. {dir (180+theta+bend)}z4 & cycle;
1331 fi;
1332 labels(0,1,2,3,4,5,6,7);
1333 endchar;
1334 endfor;
1335
1336 for filled = false, true:
1337 beginsymbol(14u#, cap_height#, 0); "heart suit";
1338 thick := line_thickness;
1339
1340 x0 = x1l = x1'l = w/2;
1341 y0 = 0;
1342 1/2[x2l,x3l] = w/2;
1343 x3l - x2l = w - 2side_bearing;
1344 y1r = y1'r;
1345 y2l = y3l = 3/4h;
1346 x4 = 1/2[x1,x2];
1347 x5 = 1/2[x1',x3];
1348 y4l = y5l = h;
1349 h - y2 = 2(h - y1l);
1350
1351 penpos1(thick, 180+45);
1352 penpos1'(thick, -45);
1353 penpos2(thick, 0);
1354 penpos3(thick, 180);
1355 penpos4(thick, -90);
1356 penpos5(thick, -90);
1357
1358 path p[];
1359 numeric t[];
1360
1361 z6 = z1r + whatever * dir (270+45);
1362 z6 = z1'r + whatever * dir (270-45);
1363 z7 = z0 + thick * dir 20;
1364 z8 = z0 + thick * dir (180-20);
1365 p1 = z7{dir (90+35)} .. {dir 90}z2r;
1366 p2 = z3r{dir 270} .. {dir (270-35)}z8;
1367 (t1,t2) = p1 intersectiontimes p2;
1368
1369 fill z0{dir (90+35)} .. {dir 90}z2l .. {dir 0}z4l .. {dir (270+45)}z1l{dir (90-45)} .. {dir 0}z5l .. {dir 270}z3l .. {dir (270-35)}z0 & cycle;
1370 if not filled:
1371 unfill subpath (t1,1) of p1 & z2r{dir 90} .. {dir 0}z4r .. {dir (270+45)}z1r -- z6 -- z1'r{dir (90-45)} .. {dir 0}z5r .. {dir 270}z3r & subpath (0,t2) of p2 -- cycle;
1372 fi;
1373
1374 penlabels(0,1,1',2,3,4,5,6,7,8,10);
1375 endchar;
1376 endfor;
1377
1378 beginsymbol(13u#, cap_height#, 0); "spade suit";
1379 x0 = x1 = w/2;
1380 y0 = h;
1381 1/2[x2,x3] = w/2;
1382 x3 - x2 = w - 2side_bearing;
1383 y2 = y3;
1384 x4 = 1/2[x1,x2];
1385 x5 = 1/2[x1,x3];
1386 y4 = y5 = 1/6h;
1387 y2 - y4 = x4 - x2;
1388 y1 = 3/5[y2,y4];
1389 x6 = x0;
1390 y6 = 0;
1391
1392 penpos1(2u, 0);
1393 penpos6(3u, 0);
1394
1395 fill z0{dir (270-30)} .. z2 .. z4 .. {dir (90-30)}z1l -- z6l --
1396 z6r -- z1r{dir (270+30)} .. z5 .. z3 .. {dir (90+30)}z0 -- cycle;
1397
1398 penlabels(0,1,2,3,4,5,6);
1399 endchar;
1400
1401 beginsymbol(14u#, cap_height#, 0); "club suit";
1402 r := 1/4(w - 2side_bearing);
1403
1404 x0 = w/2;
1405 y0 = h - 2.5r;
1406 x1 = w - x3 = side_bearing + r;
1407 y1 = y3 = y0;
1408 x2 = x4 = x0;
1409 y2 = h - r;
1410 y4 = 0;
1411
1412 penpos0(3/2u, 0);
1413 penpos2(3/2u, 0);
1414 penpos4(3u, 0);
1415
1416 fill circle(z1, r);
1417 fill circle(z2, r);
1418 fill circle(z3, r);
1419 fill stroke z2e -- z0e -- z4e;
1420
1421 penlabels(0,1,2,3,4);
1422 endchar;
1423
1424 beginoperator(med_op_size#, 1); "maltese";
1425 r := 1/2med_op_size;
1426 thick := line_thickness;
1427
1428 1/2[z0,z1] = centre + r * left;
1429 1/2[z2,z3] = centre + r * down;
1430 1/2[z4,z5] = centre + r * right;
1431 1/2[z6,z7] = centre + r * up;
1432 z0 - z1 = z5 - z4 = r * up;
1433 z3 - z2 = z6 - z7 = r * right;
1434 1/2[z8,z9] = centre + 1/2thick * up;
1435 1/2[z10,z11] = centre - 1/2thick * up;
1436 z9 - z8 = z11 - z10 = 2thick * right;
1437 1/2[z12,z13] = centre + thick * up;
1438 1/2[z14,z15] = centre - thick * up;
1439 z13 - z12 = z15 - z14 = thick * right;
1440
1441 fill z0 -- z1 -- z10 -- z11 -- z4 -- z5 -- z9 -- z8 -- cycle;
1442 fill z6 -- z7 -- z12 -- z14 -- z2 -- z3 -- z15 -- z13 -- cycle;
1443
1444 labels(0,1,2,3,4,5,6,7,8,9,10,11,12,13,14,15);
1445 endchar;
1446
1447 beginoperator(med_op_size#, 2/sqrt(3)); "star of david";
1448 r := med_op_size/sqrt(3);
1449
1450 reg_poly_points(a)(6, centre, r, 90);
1451
1452 s := r - 4/5line_thickness / sind (270 - angle (z.a2 - z.a0));
1453
1454 reg_poly_points(b)(6, centre, s, 90);
1455
1456 z0.r = z.a0; z0.l = z.b0;
1457 z1.r = z.a2; z1.l = z.b2;
1458 z2.r = z.a4; z2.l = z.b4;
1459 z3.r = z.a1; z3.l = z.b1;
1460 z4.r = z.a3; z4.l = z.b3;
1461 z5.r = z.a5; z5.l = z.b5;
1462
1463 fill stroke z0.e -- z1.e -- z2.e -- cycle;
1464 fill stroke z4.e -- z5.e -- z3.e -- cycle;
1465
1466 penlabels(0,1,2,3,4,5);
1467 endchar;
1468
1469 beginoperator(plus_size#, 1); "sector";
1470 path p;
1471 numeric r,s;
1472
1473 thick := line_thickness;
1474 alpha := 90;
1475
1476 z0 = centre - 1/2plus_size * dir alpha;
1477 z1 = z0 + 9/10plus_size * dir alpha;
1478
1479 put_less(a, z0, z1, 9/10plus_size, thick, false, false);
1480
1481 z9 = whatever[z3a.l, z0a.l] = whatever[z4a.l,z1a.l];
1482
1483 penpos1'(thick, 90);
1484
1485 z1'r = z9 + length(z0a.l - z9)*up;
1486 z4r = z0a.l - line_thickness*(dir(angle(z0a.l-z9)));
1487 z5r = z1a.l - line_thickness*(dir(angle(z1a.l-z9)));
1488
1489 theta := angle(z0a.l - z9);
1490
1491 p = (z4r{dir(theta -90)} .. z1'l .. {dir(-theta +90)}z5r);
1492 r = ypart ((z5a -- z0a.r) intersectiontimes p);
1493 s = ypart ((z5a -- z1a.r) intersectiontimes p);
1494 show(-theta-90);
1495 fill z0a.l{dir(theta -90)} .. z1'.r .. {dir(-theta +90)}z1a.l -- z4a.l -- z3a.l -- cycle;
1496 unfill subpath (r,s) of p -- z5a -- cycle;
1497
1498 penlabels(1',4,5,9);
1499 endchar;
1500
1501 beginsymbol(5/4order_width# + 2side_bearing#, cap_height#, 0); "forall";
1502 thick := line_thickness;
1503
1504 x0 = side_bearing + 1/2thick;
1505 x1 = w - side_bearing - 1/2thick;
1506 x2 = w/2 - 1/4thick;
1507 x3 = w/2 + 1/4thick;
1508 y0 = y1 = h;
1509 y2 = y3 = 0;
1510
1511 penpos0(thick / sind(abs(angle(z2 - z0))), 0);
1512 penpos1(thick / sind(abs(angle(z2 - z0))), 0);
1513
1514 z4 = z0l + whatever * (z2 - z0) = z2 + whatever * right;
1515 z5 = z1r + whatever * (z3 - z1) = z2 + whatever * right;
1516 z6 = z0r + whatever * (z2 - z0) = z1l + whatever * (z3 - z1);
1517 z7 = whatever [z0,z2];
1518 z8 = whatever [z1,z2];
1519 y7 = y8 = 0.6 * y0;
1520
1521 fill z0l -- z4 -- z5 -- z1r -- z1l -- z6 -- z0r -- cycle;
1522 draw_line(z7, z8, false);
1523
1524 penlabels(0,1,2,3,4,5,6,7,8);
1525 endchar;
1526
1527 for negated = 0, 1:
1528 beginsymbol(order_width# + 2side_bearing#, if negated = 0: cap_height# else: cap_height# + 2/3equal_spread# fi, if negated = 0: 0 else: 2/3equal_spread# fi); "exists";
1529 thick := line_thickness;
1530
1531 x1 = x3 = w - side_bearing - thick/2;
1532 y1 = cap_height;
1533 y3 = 0;
1534 x1' = x3' = w - side_bearing;
1535 x0 = x2 = side_bearing;
1536 y0 = y1' = cap_height - line_thickness/2;
1537 y2 = y3' = line_thickness/2;
1538 z4 = 1/8[1/2[z0,z2], 1/2[z1,z3]];
1539
1540 draw_straight(z1, z3, thick, false);
1541 draw_line(z0, z1', false);
1542 draw_line(z4, 1/2[z1,z3], false);
1543 draw_line(z2, z3', false);
1544
1545 if negated = 1:
1546 stroke_through(1/2[1/2[z0,z2], 1/2[z1,z3]], h + d - stroke_through_thickness)
1547 fi;
1548 endchar;
1549 endfor;
1550
1551 beginsymbol(order_width# + 2side_bearing#, cap_height#, 0); "exists finitely many";
1552 thick := line_thickness;
1553
1554 x1 = x3 = w - side_bearing - thick/2;
1555 y1 = cap_height;
1556 y3 = 0;
1557 x3' = w - side_bearing;
1558 x0 = x2 = side_bearing;
1559 y0 = cap_height - line_thickness/2;
1560 y2 = y3' = line_thickness/2;
1561 z4 = 1/8[1/2[z0,z2], 1/2[z1,z3]];
1562
1563 draw_straight(z1, z3, thick, false);
1564 draw_line(z4, 1/2[z1,z3], false);
1565 draw_line(z2, z3', false);
1566 endchar;
1567
1568 beginsymbol(5/4order_width# + 2side_bearing#, cap_height#, 0); "game quantifier";
1569 thick := line_thickness;
1570
1571 x0 = x1 = 1/2order_width + side_bearing;
1572 y0 = cap_height - 1/2thick;
1573 y1 = 1/2line_thickness;
1574 x2 = w - side_bearing - 1/2thick;
1575 y2 = (h - d)/2;
1576 x3r = x4r = side_bearing;
1577 y3 = 5/6cap_height;
1578 y4 = 1/6cap_height;
1579
1580 penpos0(thick, 90);
1581 penpos1(thick, -90);
1582 penpos2(thick, 0);
1583 penpos3(thick, 125);
1584 penpos4(thick, -125);
1585
1586 fill stroke z3.e .. z0.e .. z2.e{down} .. z1.e{left} .. z4.e;
1587 draw_straight(z4r + 1/2thick * right, 2/5[z4r,z3r] + 1/2thick * right, thick, false);
1588 draw_line(2/5[z4r,z3r], 2/5[z4r,z3r] + 1/2order_width * right, false);
1589
1590 penlabels(0,1,2,3,4);
1591 endchar;
1592
1593 beginsymbol(7/8order_width# + 2side_bearing#, cap_height#, 0); "complement";
1594 thick := line_thickness;
1595
1596 z0 - z1 = (cap_height - thick) * up;
1597 z3 - z2 = (w - 2side_bearing - thick) * right;
1598 1/2[z0,z1] = 1/2[z2,z3] = (w/2,(h-d)/2);
1599 x4 = x6 = x2;
1600 x5 = x7 = x3;
1601 y4 = y5 = 1/4[y0,y1];
1602 y6 = y7 = 3/4[y0,y1];
1603
1604 penpos0(thick, 90);
1605 penpos1(thick, -90);
1606 penpos4(thick, -180);
1607 penpos5(thick, 0);
1608 penpos6(thick, -180);
1609 penpos7(thick, 0);
1610
1611 fill stroke z5.e{up} .. z0.e .. {down}z4.e -- z6.e{down} .. z1.e .. {up}z7.e;
1612
1613 penlabels(0,1,2,3,4,5,6,7);
1614 endchar;
1615
1616 beginsymbol(4u# + line_thickness# + 2side_bearing#, asc_height#, 0); "flat";
1617 thick := line_thickness;
1618
1619 x0l = x1l = side_bearing;
1620 x4l = x5 = side_bearing + thick;
1621 y0 = -d;
1622 y1 = h;
1623 x2r = w - side_bearing;
1624 x3 = w/2;
1625 y3r = x_height;
1626 y2 = 1/2[y0,y1];
1627 y4r = 5/6x_height;
1628 y5 = thick / cosd 35 - d;
1629
1630 penpos0(thick, 0);
1631 penpos1(thick, 0);
1632 penpos2(thick, 0);
1633 penpos3(7/8thick, 90);
1634 penpos4(2/3thick, 130);
1635
1636 fill z1.l -- z0.l -- z0.r{dir 35} ... {up}z2.r .. {left}z3.r ..{dir 230}z4.r -- z4.l{dir 50} .. {right}z3.l .. {down}z2.l .. {dir 215}z5 -- z1.r -- cycle;
1637
1638 penlabels (0,1,2,3,4,5);
1639 endchar;
1640
1641 beginsymbol(4u# + line_thickness# + 2side_bearing#, asc_height#, desc_depth#); "natural";
1642 thick := line_thickness;
1643
1644 x0l = x1l = w - x2r = w - x3r = side_bearing;
1645 x4 = x5 = w - x6 = w - x7 = side_bearing;
1646 y1 = y3 = h;
1647 y7r = x_height;
1648 y4l = 0;
1649 y0 = y2 = -d;
1650 z6 = z4 + whatever * dir 15;
1651 z5 = z7 + whatever * dir 15;
1652
1653 penpos0(thick, 0);
1654 penpos1(thick, 0);
1655 penpos2(thick, 0);
1656 penpos3(thick, 0);
1657 penpos4(thick/cosd(15), 90);
1658 penpos5(thick/cosd(15), 90);
1659 penpos6(thick/cosd(15), 90);
1660 penpos7(thick/cosd(15), 90);
1661
1662 z8 = whatever[z0,z1] = whatever[z4,z6];
1663 z9 = whatever[z2,z3] = whatever[z5,z7];
1664
1665 penpos8(thick, 0);
1666 penpos9(thick, 0);
1667
1668 fill stroke z1e -- z8e;
1669 fill stroke z9e -- z2e;
1670 fill stroke z4e -- z6e;
1671 fill stroke z5e -- z7e;
1672
1673 penlabels(1,2,4,5,6,7);
1674 endchar;
1675
1676 beginsymbol(4u# + line_thickness# + 2side_bearing#, asc_height#, desc_depth#); "sharp";
1677 thick := line_thickness;
1678
1679 x0l - x4 = x1l - x5 = x6 - x2r = x7 - x3r;
1680 x2l - x0r = x3l - x1r = 2(x0l - x4);
1681 x4 = x5 = w - x6 = w - x7 = side_bearing;
1682 y3 = h;
1683 y7r = x_height;
1684 y4l = 0;
1685 y0 = -d;
1686 z2 = z0 + whatever * dir 20;
1687 z1 = z3 + whatever * dir 20;
1688 z6 = z4 + whatever * dir 15;
1689 z5 = z7 + whatever * dir 15;
1690
1691 penpos0(thick, 0);
1692 penpos1(thick, 0);
1693 penpos2(thick, 0);
1694 penpos3(thick, 0);
1695 penpos4(thick/cosd(15), 90);
1696 penpos5(thick/cosd(15), 90);
1697 penpos6(thick/cosd(15), 90);
1698 penpos7(thick/cosd(15), 90);
1699
1700 fill stroke z0e -- z1e;
1701 fill stroke z2e -- z3e;
1702 fill stroke z4e -- z6e;
1703 fill stroke z5e -- z7e;
1704
1705 penlabels (0,1,2,3,4,5,6,7);
1706 endchar;
1707
1708 beginsymbol(8u# + letter_line_thickness# + 2side_bearing#, cap_height#, 0); "aleph";
1709 thick := letter_line_thickness;
1710
1711 x0l = x2l = side_bearing;
1712 x1r = x3r = w - side_bearing;
1713 y0l = h;
1714 y1 = h;
1715 y2 = 0;
1716 y3r = 0;
1717
1718 penpos0(thick/sind(abs(angle(z3r-z0l))), 0);
1719 penpos1(thick, 0);
1720 penpos2(thick, 0);
1721 penpos3(thick/sind(abs(angle(z3r-z0l))), 0);
1722
1723 path p;
1724 p = z0{dir -70} .. {dir -70}z3;
1725
1726 z4 = point 3/10 of p;
1727 z5 = point 5/8 of p;
1728 z6 = point 1/2 of p;
1729
1730 penpos4(8/9thick, -40);
1731 penpos5(8/9thick, -45);
1732
1733 penpos6(thick/sind(abs(angle(z3r-z0l))),0);
1734
1735 fill stroke z0.e{dir -70} .. z6.e .. {dir -70}z3.e;
1736 fill stroke z2.e{up} .. {dir 50}z4.e;
1737 fill stroke z5.e{dir 45} .. {up}z1.e;
1738
1739 penlabels(0,1,2,3,4,5,6);
1740 endchar;
1741
1742 beginsymbol(8u# + letter_line_thickness# + 2side_bearing#, cap_height#, 0); "beth";
1743 thick := letter_line_thickness;
1744
1745 x0 = u + side_bearing;
1746 x1 = 5/8[x2,x4];
1747 x2 = side_bearing;
1748 x3 = w - side_bearing;
1749 y0r = h;
1750 y1r = h;
1751 y2l = 0;
1752 y3l = 0;
1753 z4r = 7/8[z2,z3];
1754 x5 = x4;
1755 y5 = 2/3h;
1756
1757 penpos0(thick, 90);
1758 penpos1(thick, 90);
1759 penpos2(thick, 90);
1760 penpos3(thick, 90);
1761 penpos4(thick, 0);
1762 penpos5(thick, 0);
1763
1764 fill stroke z2.e -- z3.e;
1765 fill stroke z0.e -- z1.e{right} ..tension3/4.. {down}z5.e -- z4.e;
1766
1767 penlabels(0,1,2,3,4,5);
1768 endchar;
1769
1770 beginsymbol(6u# + letter_line_thickness# + 2side_bearing#, cap_height#, 0); "gimel";
1771 thick := letter_line_thickness;
1772
1773 x0 = x2 = side_bearing;
1774 x2'r = 1/8[x0,x1];
1775 x1 = x3r = w - side_bearing;
1776 x4 = 1/4[x0,x1];
1777 x5 = 1/2[x0,x1];
1778 x6 = 2/3[x0,x1];
1779 y0 = y1 = h;
1780 y2l = y3 = 0;
1781 y2' = y2;
1782 y4r = h + 1/4thick;
1783 z5 = z4 + whatever * dir -30;
1784 y6 = 2/3h;
1785
1786 penpos2(thick, 90);
1787 penpos2'(thick * sind 80, 90);
1788 penpos3(thick, 0);
1789 penpos4(thick, 60);
1790 penpos5(thick, 60);
1791 penpos6(thick, 0);
1792
1793 path p;
1794 p = z6{dir -82} .. {dir -67}z3;
1795 z7 = point 1/4 of p;
1796 x8 = 2/5[x0,x1];
1797 z7 = z8 + whatever * dir 60;
1798
1799 penpos7(5/6thick, 150);
1800 penpos8(thick, 125);
1801
1802 fill stroke z4.e -- z5.e{dir -30} .. {dir -82}z6.e .. {dir -67}z3.e;
1803 fill stroke z2.e -- z2'.e{right} ... {dir 60}z8.e -- z7.e;
1804
1805 penlabels(0,1,2,2',3,4,5,6,7,8);
1806 endchar;
1807
1808 beginsymbol(7u# + letter_line_thickness# + 2side_bearing#, cap_height#, 0); "daleth";
1809 thick := letter_line_thickness;
1810
1811 x0 = side_bearing;
1812 x1 = w - side_bearing;
1813 y0r = y1r = h;
1814 x3r = x2r = 4/5[x0,x1];
1815 y2 = y0;
1816 y3 = 0;
1817
1818 penpos0(thick, 90);
1819 penpos1(thick, 90);
1820 penpos2(thick, 0);
1821 penpos3(thick, 0);
1822
1823 fill stroke z0.e -- z1.e;
1824 fill stroke z2.e -- z3.e;
1825
1826 penlabels(0,1,2,3);
1827 endchar;
1828
1829 begingroup;
1830 save slant;
1831 save currenttransform;
1832 slant := 0.212557;
1833 transform currenttransform;
1834 currenttransform := identity slanted slant yscaled aspect_ratio scaled granularity shifted (-u,0);
1835
1836 beginsymbol(9u# + 2letter_line_thickness#, x_height#, desc_depth#); "Weierstrass p";
1837 numeric theta;
1838 theta = 90 - angle(8u,h);
1839 slope := -h/8u; % angle at middle
1840 superness := 1/sqrt 2;
1841 superpull := 1/6;
1842
1843 penpos2(letter_line_thickness, -60);
1844 penpos1(letter_line_thickness, theta);
1845 penpos7(letter_line_thickness, -90);
1846
1847 x2 + 1/2u = x1 = x7 - 1/2u = 3u;
1848 y2l = h;
1849 y7r = -d;
1850 y1 = 2/5[-d, h];
1851 x3l = 1/2u;
1852 x6r = max(x7 + letter_line_thickness, 1/2w - 1/4u);
1853 x3r - x3l = x6r - x6l =letter_line_thickness;
1854
1855 ellipse_set(2l,3l,4l,1l);
1856 ellipse_set(2r,3r,4r,1r);
1857 ellipse_set(7l,6l,5l,1l);
1858 ellipse_set(7r,6r,5r,1r);
1859
1860 y3 = y3r;
1861 y6 = y6r;
1862
1863 fill stroke super_arc.e(2,3) & z3e{down} .. z4e .. z5e .. z6e{down} & super_arc.e(6,7); % flourish
1864
1865 penpos8(letter_line_thickness, 180);
1866 penpos9(letter_line_thickness, 90);
1867 penpos10(letter_line_thickness, 0);
1868 penpos11(letter_line_thickness, -90);
1869 penpos12(letter_line_thickness, -100);
1870
1871 x10r = w - 3/2u + 1/2letter_line_thickness;
1872 x8r = u;
1873 x9 = x11 = 1/2w + 3/2u;
1874 x12l = max(x6r, .5w + .5u);
1875 y8 = y11r = 0;
1876 y9r = 19/20h;
1877 y10 = 1/2[y9,y11];
1878 y12r = 1/4[y11r,y1l];
1879
1880 fill stroke z7e{left} ... z8e{up} ... z9e .. z10e .. z11e .. z12.e; % stem and bowl
1881
1882 penlabels(1,2,3,4,5,6,7,8,9,10,11,12);
1883 endchar;
1884 endgroup;
1885
1886 beginsymbol(8u# + letter_line_thickness# + 2side_bearing#, cap_height#, 0); "nabla";
1887 thick:=letter_line_thickness;
1888 thin := 4/5thick;
1889 thicker := thick;
1890
1891 y0r = y1r = h;
1892 y2 = 0;
1893
1894 x0r = side_bearing;
1895 x1r = w - side_bearing;
1896 x2 = w/2;
1897
1898 penpos0(thin, 90);
1899 penpos1(thin,90);
1900 penpos2(thicker,0);
1901
1902 y3 = y4 = h-thick;
1903 z3 = z2r + whatever*(z0l-z2l);
1904 z4 = z2l + whatever*(z1l-z2r);
1905
1906 z5 = whatever[z3,z2r] = whatever[z4,z2l];
1907
1908 fill z0r -- z0l -- z2l -- z2r -- z1l -- z1r -- cycle;
1909 unfill z3 -- z4 -- z5 -- cycle;
1910
1911 penlabels(0,1,2,3,4,5);
1912 endchar;
1913
1914 for sign = 1, -1:
1915 beginoperator(plus_size#, 1); "product integral";
1916 draw_productintegral(centre, plus_size, plus_size, sign, letter_line_thickness);
1917 endchar;
1918 endfor;