Debian Codegraph @

texmf-dist/fonts/source/public/mdsymbol/mddelims.mf

raw
1 %
2 % Copyright (c) 2011, 2012, Sebastian Schubert <[email protected]>
3 %
4 % This Font Software is licensed under the SIL Open Font License,
5 % Version 1.1. This license is in the accompanying file OFL.txt, and
6 % is also available with a FAQ at: http://scripts.sil.org/OFL
7 %
8
9 % thickness factor for delimiters
10 def dthick(expr scale) =
11 %option 1: make symbols thicker with scale
12 % sqrt sqrt scale
13 %option 2: keep same thickness
14 1
15 enddef;
16
17 % parenthesis
18
19 lparen_char = current_char + 1;
20 rparen_char = current_char + 7;
21 for sign = 1, -1:
22 for scale = 1, 1.2, 1.5, 1.8, 2.4, 3:
23 beginsymbol((2scale + 2.5)/2 * u# + line_thickness# + 2side_bearing#, vcentre(2scale * delim_height#)); "parenthesis";
24 draw_paren(sign, dthick(scale) * line_thickness);
25 endchar;
26 endfor;
27 endfor;
28
29 for sign = 1, -1:
30 beginsymbol((6 + 4.5)/2 * u# + line_thickness# + 2side_bearing#, vcentre(3delim_height#)); "parenthesis -- top";
31 thick := dthick(3) * line_thickness;
32
33 penpos1(thick, -90 + sign * 90);
34 penpos2(1.1thick, 90 - sign * 90);
35 penpos2'(1.1thick, 90 - sign * 90);
36
37 if sign = 1:
38 x2l = side_bearing;
39 x1r = w - side_bearing;
40 else:
41 x1r = side_bearing;
42 x2l = w - side_bearing;
43 fi
44 x2 = x2';
45 y1 = h;
46 y2 = -d + 1/2line_thickness;
47 y2' = -d - 1/2line_thickness;
48
49 fill stroke z2'.e -- z2e{up} ... z1e;
50
51 penlabels(1,2,2');
52 endchar;
53 endfor;
54
55 for sign = 1, -1:
56 beginsymbol((6 + 4.5)/2 * u# + line_thickness# + 2side_bearing#, vcentre(3delim_height#)); "parenthesis -- bot";
57 thick := dthick(3) * line_thickness;
58
59 penpos0(thick, 90 - sign * 90);
60 penpos2(1.1thick, 90 - sign * 90);
61 penpos2'(1.1thick, 90 - sign * 90);
62
63 if sign = 1:
64 x2l = side_bearing;
65 x0r = w - side_bearing;
66 else:
67 x0r = side_bearing;
68 x2l = w - side_bearing;
69 fi
70 x2 = x2';
71 y2 = h - 1/2line_thickness;
72 y2' = h + 1/2line_thickness;
73 y0 = -d;
74
75 fill stroke z0e ... {up}z2e -- z2'.e;
76
77 penlabels(1,2,2');
78 endchar;
79 endfor;
80
81 for sign = 1, -1:
82 beginsymbol((6 + 4.5)/2 * u# + line_thickness# + 2side_bearing#, vcentre(0.6delim_height#)); "parenthesis -- module";
83 thick := dthick(3) * line_thickness;
84
85 penpos2(1.1thick, 90 - sign * 90);
86 penpos3(1.1thick, 90 - sign * 90);
87
88 if sign = 1:
89 x2l = x3l = side_bearing;
90 else:
91 x2l = x3l = w - side_bearing;
92 fi
93 y2 = h + 1/2line_thickness;
94 y3 = -d - 1/2line_thickness;
95
96 fill stroke z2e -- z3e;
97 endchar;
98 endfor;
99
100 extensible current_char - 1: current_char - 5, 0, current_char - 3, current_char - 1; %left parenthesis
101 extensible current_char: current_char - 4, 0, current_char - 2, current_char; %right parenthesis
102
103 charlist lparen_char: lparen_char + 1: lparen_char + 2: lparen_char + 3: lparen_char + 4: lparen_char + 5: current_char - 1;
104 charlist rparen_char: rparen_char + 1: rparen_char + 2: rparen_char + 3: rparen_char + 4: rparen_char + 5: current_char;
105
106 % brackets
107
108 lsquare_char = current_char + 1;
109 rsquare_char = current_char + 7;
110 for sign = 1, -1:
111 for scale = 1, 1.2, 1.5, 1.8, 2.4, 3:
112 beginsymbol((2scale + 4)/2 * u# + line_thickness# + 2side_bearing#, vcentre(2scale * delim_height#)); "square bracket";
113 draw_bracket(sign, dthick(scale) * line_thickness, true, true, true, false);
114 endchar;
115 endfor;
116 endfor;
117
118 lfloor_char = current_char + 1;
119 rfloor_char = current_char + 7;
120 for sign = 1, -1:
121 for scale = 1, 1.2, 1.5, 1.8, 2.4, 3:
122 beginsymbol((2scale + 4)/2 * u# + line_thickness# + 2side_bearing#, vcentre(2scale * delim_height#)); "floor";
123 draw_bracket(sign, dthick(scale) * line_thickness, false, true, true, false);
124 endchar;
125 endfor;
126 endfor;
127
128 lceil_char = current_char + 1;
129 rceil_char = current_char + 7;
130 for sign = 1, -1:
131 for scale = 1, 1.2, 1.5, 1.8, 2.4, 3:
132 beginsymbol((2scale + 4)/2 * u# + line_thickness# + 2side_bearing#, vcentre(2scale * delim_height#)); "ceiling";
133 draw_bracket(sign, dthick(scale) * line_thickness, true, true, false, false);
134 endchar;
135 endfor;
136 endfor;
137
138 ulcorner_char = current_char + 1;
139 urcorner_char = current_char + 7;
140 for sign = 1, -1:
141 for scale = 1, 1.2, 1.5, 1.8, 2.4, 3:
142 beginsymbol((2scale + 4)/2 * u# + line_thickness# + 2side_bearing#, vcentre(2scale * delim_height#)); "upper corner";
143 draw_bracket(sign, dthick(scale) * line_thickness, true, false, false, false);
144 endchar;
145 endfor;
146 endfor;
147
148 charlist ulcorner_char: ulcorner_char + 1: ulcorner_char + 2: ulcorner_char + 3: ulcorner_char + 4: ulcorner_char + 5;
149 charlist urcorner_char: urcorner_char + 1: urcorner_char + 2: urcorner_char + 3: urcorner_char + 4: urcorner_char + 5;
150
151 llcorner_char = current_char + 1;
152 lrcorner_char = current_char + 7;
153 for sign = 1, -1:
154 for scale = 1, 1.2, 1.5, 1.8, 2.4, 3:
155 beginsymbol((2scale + 4)/2 * u# + line_thickness# + 2side_bearing#, vcentre(2scale * delim_height#)); "lower corner";
156 draw_bracket(sign, dthick(scale) * line_thickness, false, false, true, false);
157 endchar;
158 endfor;
159 endfor;
160
161 charlist llcorner_char: llcorner_char + 1: llcorner_char + 2: llcorner_char + 3: llcorner_char + 4: llcorner_char + 5;
162 charlist lrcorner_char: lrcorner_char + 1: lrcorner_char + 2: lrcorner_char + 3: lrcorner_char + 4: lrcorner_char + 5;
163
164 ullcorner_char = current_char + 1;
165 ulrcorner_char = current_char + 7;
166 for sign = 1, -1:
167 for scale = 1, 1.2, 1.5, 1.8, 2.4, 3:
168 beginsymbol((2scale + 4)/2 * u# + line_thickness# + 2side_bearing#, vcentre(2scale * delim_height#)); "upper/lower corner";
169 draw_bracket(sign, dthick(scale) * line_thickness, true, false, true, false);
170 endchar;
171 endfor;
172 endfor;
173
174 charlist ullcorner_char: ullcorner_char + 1: ullcorner_char + 2: ullcorner_char + 3: ullcorner_char + 4: ullcorner_char + 5;
175 charlist ulrcorner_char: ulrcorner_char + 1: ulrcorner_char + 2: ulrcorner_char + 3: ulrcorner_char + 4: ulrcorner_char + 5;
176
177 for sign = 1, -1:
178 beginsymbol(5u# + line_thickness# + 2side_bearing#, vcentre(1.2delim_height#)); "square bracket -- top";
179 draw_bracket(sign, dthick(3) * line_thickness, true, true, false, false);
180 endchar;
181 endfor;
182
183 for sign = 1, -1:
184 beginsymbol(5u# + line_thickness# + 2side_bearing#, vcentre(1.2delim_height#)); "square bracket -- bot";
185 draw_bracket(sign, dthick(3) * line_thickness, false, true, true, false);
186 endchar;
187 endfor;
188
189 for sign = 1, -1:
190 beginsymbol(5u# + line_thickness# + 2side_bearing#, vcentre(0.6delim_height#)); "square bracket -- module";
191 draw_bracket(sign, dthick(3) * line_thickness, false, true, false, false);
192 endchar;
193 endfor;
194
195 extensible current_char - 1: current_char - 5, 0, current_char - 3, current_char - 1; %left square bracket
196 extensible current_char: current_char - 4, 0, current_char - 2, current_char; %right square bracket
197 extensible current_char - 3: 0, 0, current_char - 3, current_char - 1; %left floor
198 extensible current_char - 2: 0, 0, current_char - 2, current_char; %right floor
199 extensible current_char - 5: current_char - 5, 0, 0, current_char - 1; %left ceiling
200 extensible current_char - 4: current_char - 4, 0, 0, current_char; %right ceiling
201
202 charlist lsquare_char: lsquare_char + 1: lsquare_char + 2: lsquare_char + 3: lsquare_char + 4: lsquare_char + 5: current_char - 1;
203 charlist rsquare_char: rsquare_char + 1: rsquare_char + 2: rsquare_char + 3: rsquare_char + 4: rsquare_char + 5: current_char;
204 charlist lfloor_char: lfloor_char + 1: lfloor_char + 2: lfloor_char + 3: lfloor_char + 4: lfloor_char + 5: current_char - 3;
205 charlist rfloor_char: rfloor_char + 1: rfloor_char + 2: rfloor_char + 3: rfloor_char + 4: rfloor_char + 5: current_char - 2;
206 charlist lceil_char: lceil_char + 1: lceil_char + 2: lceil_char + 3: lceil_char + 4: lceil_char + 5: current_char - 5;
207 charlist rceil_char: rceil_char + 1: rceil_char + 2: rceil_char + 3: rceil_char + 4: rceil_char + 5: current_char - 4;
208
209 % semantic brackets
210
211 lsem_char = current_char + 1;
212 rsem_char = current_char + 7;
213 for sign = 1, -1:
214 for scale = 1, 1.2, 1.5, 1.8, 2.4, 3:
215 beginsymbol((2scale + 4)/2 * u# + 2line_thickness# + 2side_bearing#, vcentre(2scale * delim_height#)); "semantic bracket";
216 draw_bracket(sign, dthick(scale) * line_thickness, true, true, true, true);
217 endchar;
218 endfor;
219 endfor;
220
221 for sign = 1, -1:
222 beginsymbol(5u# + 2line_thickness# + 2side_bearing#, vcentre(1.2delim_height#)); "semantic bracket -- top";
223 draw_bracket(sign, dthick(3) * line_thickness, true, true, false, true);
224 endchar;
225 endfor;
226
227 for sign = 1, -1:
228 beginsymbol(5u# + 2line_thickness# + 2side_bearing#, vcentre(1.2delim_height#)); "semantic bracket -- bot";
229 draw_bracket(sign, dthick(3) * line_thickness, false, true, true, true);
230 endchar;
231 endfor;
232
233 for sign = 1, -1:
234 beginsymbol(5u# + line_thickness# + 2side_bearing#, vcentre(0.6delim_height#)); "semantic bracket -- module";
235 draw_bracket(sign, dthick(3) * line_thickness, false, true, false, true);
236 endchar;
237 endfor;
238
239 extensible current_char - 1: current_char - 5, 0, current_char - 3, current_char - 1; %left semantic bracket
240 extensible current_char: current_char - 4, 0, current_char - 2, current_char; %right semantic bracket
241
242 charlist lsem_char: lsem_char + 1: lsem_char + 2: lsem_char + 3: lsem_char + 4: lsem_char + 5: current_char - 1;
243 charlist rsem_char: rsem_char + 1: rsem_char + 2: rsem_char + 3: rsem_char + 4: rsem_char + 5: current_char;
244
245 % curly braces
246
247 lcurly_char = current_char + 1;
248 rcurly_char = current_char + 7;
249 for sign = 1, -1:
250 for scale = 1, 1.2, 1.5, 1.8, 2.4, 3:
251 beginsymbol((2scale + 5.5)/2 * u# + line_thickness# + 2side_bearing#, vcentre(2scale * delim_height#)); "curly brace";
252 thick := dthick(scale) * line_thickness;
253
254 draw_brace((w/2, (h-d)/2), h + d, w - 2side_bearing, 90 + sign * 90, thick, 0, 0, 0)
255 endchar;
256 endfor;
257 endfor;
258
259 beginsymbol((6 + 5.5)/2 * u# + line_thickness# + 2side_bearing#, vcentre(1.2delim_height#)); "curly brace -- top";
260 thick := dthick(3) * line_thickness;
261
262 draw_brace((w/2, h - 3delim_height), 6delim_height, w - 2side_bearing, 180, thick, 0, 0, h + d);
263 endchar;
264
265 beginsymbol((6 + 5.5)/2 * u# + line_thickness# + 2side_bearing#, vcentre(1.2delim_height#)); "curly brace -- top";
266 thick := dthick(3) * line_thickness;
267
268 draw_brace((w/2, h - 3delim_height), 6delim_height, w - 2side_bearing, 0, thick, h + d, 0, 0);
269 endchar;
270
271 beginsymbol((6 + 5.5)/2 * u# + line_thickness# + 2side_bearing#, vcentre(1.2delim_height#)); "curly brace -- bot";
272 thick := dthick(3) * line_thickness;
273
274 draw_brace((w/2, 3delim_height - d), 6delim_height, w - 2side_bearing, 180, thick, h + d, 0, 0)
275 endchar;
276
277 beginsymbol((6 + 5.5)/2 * u# + line_thickness# + 2side_bearing#, vcentre(1.2delim_height#)); "curly brace -- bot";
278 thick := dthick(3) * line_thickness;
279
280 draw_brace((w/2, 3delim_height - d), 6delim_height, w - 2side_bearing, 0, thick, 0, 0, h + d)
281 endchar;
282
283 for sign = 1, -1:
284 beginsymbol((6 + 5.5)/2 * u# + line_thickness# + 2side_bearing#, vcentre(1.2delim_height#)); "curly brace -- middle";
285 thick := dthick(3) * line_thickness;
286
287 draw_brace((w/2, (h-d)/2), 6delim_height, w - 2side_bearing, 90 + sign * 90, thick, 0, h + d, 0);
288 endchar;
289 endfor;
290
291 beginsymbol((6 + 5.5)/2 * u# + line_thickness# + 2side_bearing#, vcentre(0.6delim_height#)); "curly brace -- module";
292 thick := dthick(3) * line_thickness;
293
294 x2 = x3 = w/2;
295 y2 = h + 1/2line_thickness;
296 y3 = -d - 1/2line_thickness;
297
298 draw_straight(z2, z3, thick, false);
299 endchar;
300
301 extensible current_char - 6: current_char - 6, 0, current_char - 4, current_char; %sharp left parenthesis
302 extensible current_char - 5: current_char - 5, 0, current_char - 3, current_char; %sharp right parenthesis
303 extensible current_char - 3: current_char - 6, 0, current_char - 3, current_char; %left moustache
304 extensible current_char - 4: current_char - 5, 0, current_char - 4, current_char; %right moustache
305 extensible current_char - 2: current_char - 6, current_char - 2, current_char - 4, current_char; %left curly brace
306 extensible current_char - 1: current_char - 5, current_char - 1, current_char - 3, current_char; %right curly brace
307 extensible current_char: 0, 0, 0, current_char; %vertical line
308
309 charlist lcurly_char: lcurly_char + 1: lcurly_char + 2: lcurly_char + 3: lcurly_char + 4: lcurly_char + 5: current_char - 2;
310 charlist rcurly_char: rcurly_char + 1: rcurly_char + 2: rcurly_char + 3: rcurly_char + 4: rcurly_char + 5: current_char - 1;
311
312 % angle brackets
313
314 for sign = 1, -1:
315 for scale = 1, 1.2, 1.5, 1.8, 2.4, 3:
316 beginsymbol((2scale + 4)/2 * u# + line_thickness# + 2side_bearing#, vcentre(2scale * delim_height#)); "angle bracket";
317 draw_angle(a, 0, sign, dthick(scale) * line_thickness);
318 endchar;
319 endfor;
320 charlist current_char - 5: current_char - 4: current_char - 3: current_char - 2: current_char - 1: current_char;
321 endfor;
322
323 for sign = 1, -1:
324 for scale = 1, 1.2, 1.5, 1.8, 2.4, 3:
325 beginsymbol((2scale + 8)/2 * u# + 2line_thickness# + 2side_bearing#, vcentre(2scale * delim_height#)); "double angle bracket";
326 thick := dthick(scale) * line_thickness;
327
328 draw_angle(a, -5/4thick, sign, thick);
329 draw_angle(b, 5/4thick, sign, thick);
330 endchar;
331 endfor;
332 charlist current_char - 5: current_char - 4: current_char - 3: current_char - 2: current_char - 1: current_char;
333 endfor;
334
335 for sign = 1, -1:
336 for scale = 1, 1.2, 1.5, 1.8, 2.4, 3:
337 beginsymbol((2scale + 4)/2 * u# + line_thickness# + 2side_bearing#, vcentre(2scale * delim_height#)); "angle bracket with dot";
338 thick := dthick(scale) * line_thickness;
339
340 draw_angle(a, 0, sign, thick);
341
342 if sign > 0:
343 x3 = w - side_bearing - 3/4dot_size;
344 else:
345 x3 = side_bearing + 3/4dot_size;
346 fi
347 y3 = 1/2(h - d);
348
349 fill dot(z3, 3/4dot_size);
350 endchar;
351 endfor;
352 charlist current_char - 5: current_char - 4: current_char - 3: current_char - 2: current_char - 1: current_char;
353 endfor;
354
355 % slash
356
357 for sign = 1, -1:
358 for scale = 1, 1.2, 1.5, 1.8, 2.4, 3:
359 beginsymbol(6scale * u# + line_thickness# + side_bearing#, vcentre(2scale * delim_height#)); "slash";
360 x1 - x0 = sign * (w - 2side_bearing - line_thickness);
361 y1 = h;
362 y0 = -d;
363 1/2[x0,x1] = w/2;
364
365 draw_line_cut(0, 1);
366 endchar;
367 endfor;
368 charlist current_char - 5: current_char - 4: current_char - 3: current_char - 2: current_char - 1: current_char;
369 endfor;
370
371 % vertical bars
372
373 for negated = false, true:
374 for scale = 0.5, 1, 1.2:
375 beginsymbol(2u# + if negated: 2u# + floor scale * u# else: 0u# fi + line_thickness# + 2side_bearing#, vcentre(2scale * delim_height#)); "vertical bar";
376 x0 = x1 = w/2;
377 y0 = h;
378 y1 = -d;
379
380 draw_line(z0, z1, false);
381
382 if negated:
383 if scale < 1: theta := 30; else: theta := 45; fi
384 len := 1/2(4u + floor scale * u) / cosd theta;
385
386 draw_straight(1/2[z0,z1] + len * dir theta, 1/2[z0,z1] - len * dir theta, stroke_through_thickness, true);
387 fi
388 endchar;
389 endfor;
390 endfor;
391
392 beginsymbol(2u# + line_thickness# + 2side_bearing#, vcentre(0.6delim_height#)); "vertical bar -- module";
393 x0 = x1 = w/2;
394 y0 = h + 1/2line_thickness;
395 y1 = -d - 1/2line_thickness;
396
397 draw_line(z0, z1, false);
398 endchar;
399
400 extensible current_char: 0, 0, 0, current_char; % vertical bar
401 charlist current_char - 5: current_char - 4: current_char;
402
403 for negated = false, true:
404 for scale = 0.5, 1, 1.2:
405 beginsymbol(5u# + if negated: 2u# + floor scale * u# else: 0u# fi + 2line_thickness# + 2side_bearing#, vcentre(2scale * delim_height#)); "double vertical bar";
406 x0 = x1;
407 x2 = x3;
408 1/2[x0,x2] = w/2;
409 x2 - x0 = 3u + line_thickness;
410 y0 = y2 = h;
411 y1 = y3 = -d;
412
413 draw_line(z0, z1, false);
414 draw_line(z2, z3, false);
415
416 if negated:
417 if scale < 1: theta := 30; else: theta := 45; fi
418 len := 1/2(7u + floor scale * u + line_thickness) / cosd theta;
419 pair centre;
420 centre := 1/2[1/2[z0,z1],1/2[z2,z3]];
421
422 draw_straight(centre + len * dir theta, centre - len * dir theta, stroke_through_thickness, true);
423 fi
424 endchar;
425 endfor;
426 endfor;
427
428 beginsymbol(5u# + 2line_thickness# + 2side_bearing#, vcentre(0.6delim_height#)); "double vertical bar -- module";
429 x0 = x1;
430 x2 = x3;
431 1/2[x0,x2] = w/2;
432 x2 - x0 = 3u + line_thickness;
433 y0 = y2 = h + 1/2line_thickness;
434 y1 = y3 = -d - 1/2line_thickness;
435
436 draw_line(z0, z1, false);
437 draw_line(z2, z3, false);
438 endchar;
439
440 extensible current_char: 0, 0, 0, current_char; % double vertical line
441 charlist current_char - 5: current_char -4: current_char;
442
443 for scale = 1, 1.2:
444 beginsymbol(8u# + 3line_thickness# + 2side_bearing#, vcentre(2scale * delim_height#)); "triple vertical bar";
445 x0 = x1;
446 x2 = x3;
447 x4 = x5;
448 1/2[x0,x4] = w/2;
449 x2 - x0 = x4 - x2 = 3u + line_thickness;
450 y0 = y2 = y4 = h;
451 y1 = y3 = y5 = -d;
452
453 draw_line(z0, z1, false);
454 draw_line(z2, z3, false);
455 draw_line(z4, z5, false);
456 endchar;
457 endfor;
458
459 beginsymbol(8u# + 3line_thickness# + 2side_bearing#, vcentre(0.6delim_height#)); "triple vertical bar -- module";
460 x0 = x1;
461 x2 = x3;
462 x4 = x5;
463 1/2[x0,x4] = w/2;
464 x2 - x0 = x4 - x2 = 3u + line_thickness;
465 y0 = y2 = y4 = h + 1/2line_thickness;
466 y1 = y3 = y5 = -d - 1/2line_thickness;
467
468 draw_line(z0, z1, false);
469 draw_line(z2, z3, false);
470 draw_line(z4, z5, false);
471 endchar;
472
473 extensible current_char: 0, 0, 0, current_char; % triple vertical line
474 charlist current_char - 2: current_char -1: current_char;
475
476 % Arrows
477
478 for arrow_dir = 90, 270:
479 beginsymbol(5u# + line_thickness# + 2side_bearing#, vcentre(1.2delim_height#)); "arrow up/down";
480 pair foot, head;
481
482 if arrow_dir = 90:
483 head = (w/2, h - 1/2line_thickness);
484 foot = (w/2, -d);
485 else:
486 head = (w/2, -d + 1/2line_thickness);
487 foot = (w/2, h + 1/2line_thickness);
488 fi;
489
490 draw_line(foot, head, false);
491 draw_arrowhead(head, arrow_dir, arrow_spread, line_thickness);
492 endchar;
493 endfor;
494
495 beginsymbol(5u# + line_thickness# + 2side_bearing#, vcentre(0.6delim_height#)); "arrow module";
496 z0 = (w/2, h);
497 z1 = (w/2, -d);
498
499 draw_line(z0, z1, true);
500 endchar;
501
502 extensible current_char-2: current_char-2, 0, current_char, current_char;
503 extensible current_char-1: current_char, 0, current_char-1, current_char;
504 extensible current_char: current_char-2, 0, current_char-1, current_char;
505
506 for arrow_dir = 90, 270:
507 beginsymbol(7u# + line_thickness# + 2side_bearing#, vcentre(1.2delim_height#)); "double arrow up/down";
508 pair foot, head;
509
510 if arrow_dir = 90:
511 head = (w/2, h - 1/2line_thickness);
512 foot = (w/2, -d - 1/2line_thickness);
513 else:
514 head = (w/2, -d + 1/2line_thickness);
515 foot = (w/2, h + 1/2line_thickness);
516 fi;
517
518 z1 - z0 = z3 - z2 = equal_spread * dir (arrow_dir + 90);
519 1/2[z0,z1] = foot;
520 1/2[z2,z3] = head;
521
522 draw_line(z0, arrowhead_intersection(head, arrow_dir, 13/10arrow_spread, z0 -- z2), false);
523 draw_line(z1, arrowhead_intersection(head, arrow_dir, 13/10arrow_spread, z1 -- z3), false);
524 draw_arrowhead(head, arrow_dir, 13/10arrow_spread, line_thickness);
525 endchar;
526 endfor;
527
528 beginsymbol(7u# + line_thickness# + 2side_bearing#, vcentre(0.6delim_height#)); "double arrow module";
529 z1 - z0 = z3 - z2 = equal_spread * right;
530 1/2[z0,z1] = (w/2, h);
531 1/2[z2,z3] = (w/2, -d);
532
533 draw_line(z0, z2, true);
534 draw_line(z1, z3, true);
535 endchar;
536
537 extensible current_char-2: current_char-2, 0, current_char, current_char;
538 extensible current_char-1: current_char, 0, current_char-1, current_char;
539 extensible current_char: current_char-2, 0, current_char-1, current_char;
540
541 % horizontal curly braces
542
543 beginsymbol(1/2delim_height#, vcentre((6 + 5.5)/2 * u# + line_thickness#)); "horizontal curly brace -- left";
544 draw_brace((3delim_height, (h-d)/2), 6delim_height, h + d, 90, line_thickness, w, 0, 0);
545 endchar;
546
547 beginsymbol(1/2delim_height#, vcentre((6 + 5.5)/2 * u# + line_thickness#)); "horizontal curly brace -- left";
548 draw_brace((3delim_height, (h-d)/2), 6delim_height, h + d, -90, line_thickness, 0, 0, w);
549 endchar;
550
551 beginsymbol(1/2delim_height#, vcentre((6 + 5.5)/2 * u# + line_thickness#)); "horizontal curly brace -- right";
552 draw_brace((w - 3delim_height, (h-d)/2), 6delim_height, h + d, 90, line_thickness, 0, 0, w);
553 endchar;
554
555 beginsymbol(1/2delim_height#, vcentre((6 + 5.5)/2 * u# + line_thickness#)); "horizontal curly brace -- right";
556 draw_brace((w - 3delim_height, (h-d)/2), 6delim_height, h + d, -90, line_thickness, w, 0, 0);
557 endchar;
558
559 for sign = 1, -1:
560 beginsymbol(delim_height#, vcentre((6 + 5.5)/2 * u# + line_thickness#)); "horizontal curly brace -- middle";
561 draw_brace((w/2, (h-d)/2), 6delim_height, h + d, sign * 90, line_thickness, 0, w, 0);
562 endchar;
563 endfor;
564
565 beginsymbol(u#, vcentre((6 + 5.5)/2 * u# + line_thickness#)); "horizontal curly brace -- module";
566 y2 = y3 = (h - d)/2;
567 x2 = -1/2line_thickness;
568 x3 = w + 1/2line_thickness;
569
570 draw_line(z2, z3, false);
571 endchar;
572
573 % roots
574
575 root_char = current_char + 1;
576
577 for scale = 1, 1.2, 1.5, 1.8, 2.4, 3:
578 beginsymbol((4scale + 2) * u# + 3/2line_thickness# + 2side_bearing#, rule_thickness#, 2scale * delim_height# - rule_thickness#); "root";
579 draw_root(line_thickness);
580 endchar;
581 endfor;
582
583 beginsymbol(14u# + 3/2line_thickness# + 2side_bearing#, rule_thickness#, 1.2delim_height# - rule_thickness#); "root -- top";
584 draw_root_top(line_thickness);
585 endchar;
586
587 beginsymbol(14u# + 3/2line_thickness# + 2side_bearing#, 0, 2.4delim_height#); "root -- bottom";
588 draw_root_bot(line_thickness);
589 endchar;
590
591 beginsymbol(14u# + 3/2line_thickness# + 2side_bearing#, vcentre(0.6delim_height#)); "root -- module";
592 x0 = x1 = 4/9w + 1/2line_thickness;
593 y0 = h;
594 y1 = -d;
595
596 draw_line(z0, z1, true);
597 endchar;
598
599 extensible current_char - 2: current_char - 2, 0, current_char - 1, current_char;
600 charlist root_char: root_char + 1: root_char + 2: root_char + 3: root_char + 4: root_char + 5: current_char - 2;
601
602 % more roots
603
604 for scale = 1, 1.2, 1.5, 1.8, 2.4, 3:
605 beginsymbol((4scale + 2) * u# + 5/2line_thickness# + 2side_bearing#, vcentre(2scale * delim_height#)); "root";
606 draw_root(line_thickness);
607 endchar;
608 endfor;
609
610 beginsymbol(14u# + 5/2line_thickness# + 2side_bearing#, 1.2delim_height#, 0); "root -- top";
611 draw_root_top(line_thickness);
612 endchar;
613
614 beginsymbol(14u# + 5/2line_thickness# + 2side_bearing#, 2.4delim_height#, 0); "root -- bottom";
615 draw_root_bot(line_thickness);
616 endchar;