Debian Codegraph @

texmf-dist/fonts/source/public/archaic/gvibc10.mf

raw
1 %%
2 %% This is file `gvibc10.mf',
3 %% generated with the docstrip utility.
4 %%
5 %% The original source files were:
6 %%
7 %% greek6cbc.dtx (with options: `up')
8 %% ------------------------------------------------------------------
9 %% Author: Peter Wilson (Herries Press) herries dot press at earthlink dot net
10 %% Copyright 1999--2005 Peter R. Wilson
11 %%
12 %% This work may be distributed and/or modified under the
13 %% conditions of the Latex Project Public License, either
14 %% version 1.3 of this license or (at your option) any
15 %% later version.
16 %% The latest version of the license is in
17 %% http://www.latex-project.org/lppl.txt
18 %% and version 1.3 or later is part of all distributions of
19 %% LaTeX version 2003/06/01 or later.
20 %%
21 %% This work has the LPPL maintenance status "author-maintained".
22 %%
23 %% This work consists of the files listed in the README file.
24 %% ------------------------------------------------------------------
25 %%% GVIBC10.MF Computer Greek font (6th century BC) 10 point design size.
26
27
28 font_identifier:="Greek"; font_size 10pt#;
29
30 u#:=.2pt#; % unit width
31 ht#:=7pt#; % height of characters (CM cap-height is approx 6.8pt)
32 s#:=1.5pt#; % width correction (right and left)
33 o#:=1/20pt#; % overshoot
34 px#:=.7pt#; % horizontal width of pen
35 font_normal_space:=7pt#; % width of a blank space
36 font_normal_shrink:=.9pt#; % width correction for blank space
37 font_x_height:=4.5pt#; % height of one ex
38 font_quad:=10pt#; % an em
39
40
41 %%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
42 %%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
43
44 font_coding_scheme:="Greek glyphs";
45 mode_setup;
46
47 ho#:=o#; % horizontal overshoot
48 leftloc#:=s#; % leftmost xcoord of character
49 py#:=.9px#; % vertical thickness of the pen
50
51 define_pixels(s,u);
52 define_blacker_pixels(px,py);
53 define_good_x_pixels(leftloc);
54 define_corrected_pixels(o); % turn on overshoot correction
55 define_horizontal_corrected_pixels(ho);
56
57 numeric midloc, rightloc;
58 pickup pencircle xscaled px yscaled py;
59 stylus:=savepen;
60
61 def beginglyph(expr code, unit_width) =
62 beginchar(code, unit_width*ht#+2s#, ht#, 0);
63 midloc:=1/2w; rightloc:=(w-s);
64 pickup stylus enddef;
65
66 let cmchar=\;
67
68
69 %%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
70 %%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
71
72
73 cmchar "Greek letter alpha (a)";
74 beginglyph("a",0.6);
75 x1=leftloc; x3=rightloc; % base points
76 bot y1 = bot y3 = -o;
77 x2 = midloc; top y2 = h; % apex
78 draw z1--z2--z3; % draw the legs
79 z4 = 0.4[z1, z2];
80 draw z3--z4; % draw the bar
81 labels(1,2,3,4);
82 endchar;
83
84
85 cmchar "Greek letter beta (b)";
86 beginglyph("b",0.6);
87 x1=x3=x5=leftloc;
88 x2=x4=rightloc;
89 bot y1=-o; top y5=h;
90 y2=1/4h; y3=1/2h; y4=3/4h;
91 draw z1--z5; % the upright
92 draw z1{right}..z2..z3{left}; % lower bowl
93 draw z3{right}..z4..z5{left}; % upper bowl
94 labels(1,2,3,4,5); endchar;
95
96
97 cmchar "Greek letter gamma (g)";
98 beginglyph("g", 0.4);
99 x1=x2=leftloc; x3=rightloc;
100 bot y1=-o; top y2 = top y3= h;
101 draw z1--z2--z3;
102 labels(1,2,3); endchar;
103
104
105 cmchar "Greek letter delta (d)";
106 beginglyph("d",0.6);
107 x1=leftloc; x2=midloc; x3=rightloc;
108 bot y1 = bot y3= 0;
109 top y2=h;
110 draw z1--z2--z3--cycle;
111 labels(1,2,3); endchar;
112
113
114 cmchar "Greek letter epsilon (e)";
115 beginglyph("e",0.6);
116 x1=x3=leftloc; x4=x6=rightloc;
117 bot y1= bot y4= -o; top y3= top y6= h;
118 z2=0.5[z1,z3]; z5=0.5[z4,z6];
119 draw z4--z1--z3--z6;
120 draw z2--z5;
121 labels(1,2,3,4,5,6); endchar;
122
123
124 cmchar "Greek letter digamma (F)";
125 beginglyph("F",0.6);
126 x1=x3=leftloc; x4=x6=rightloc;
127 bot y1= bot y4= -o; top y3= top y6= h;
128 z2=0.65[z1,z3]; z5=0.65[z4,z6];
129 draw z1--z3--z6;
130 draw z2--z5;
131 labels(1,2,3,4,5,6); endchar;
132
133
134 cmchar "Greek letter zeta (z)";
135 beginglyph("z",0.2);
136 x1=x2=midloc;
137 bot y1=-o; top y2=h;
138 draw z1--z2; % the upright
139 x3=x5=leftloc; x4=x6=rightloc;
140 y3=y4=y1; y5=y6=y2;
141 draw z3--z4; % lower bar
142 draw z5--z6; % upper bar
143 labels(1,2); endchar;
144
145
146 cmchar "Greek letter eta (h)";
147 beginglyph("h", 0.6);
148 numeric alpha;
149 x1=x3=leftloc; x4=x6=rightloc;
150 bot y1 = bot y4= -o; top y3= top y6= h;
151 z2=0.5[z1,z3]; z5=0.5[z4,z6];
152 draw z1--z3--z6--z4--cycle; % rectangle
153 draw z2--z5; % bar
154 labels(1,2,3,4,5,6); endchar;
155
156
157 cmchar "Greek letter theta (T)";
158 beginglyph("T",1.0);
159 path p;
160 x1=leftloc; x3=rightloc;
161 y2=h; y4=0;
162 x2=x4=midloc;
163 y1=y3=h/2;
164 z100=(x2,y3); % circle center
165 p = z1..z2..z3..z4..cycle; % the circle
166 draw p;
167 draw z1--z3; draw z2--z4; % the cross
168 labels(1,2,3,4); endchar;
169
170
171 cmchar "Greek letter iota (i)";
172 beginglyph("i",0.2);
173 x1=x2=midloc;
174 bot y1=-o; top y2=h;
175 draw z1--z2;
176 labels(1,2); endchar;
177
178
179 cmchar "Greek letter kappa (k)";
180 beginglyph("k",0.6);
181 numeric alpha;
182 alpha:=0.1;
183 x1=rightloc;
184 x2=x1+alpha*(w-s);
185 x3=x4=x5=leftloc;
186 bot y1= bot y3=-o;
187 y2=y5=h; y4=1/2h;
188 draw z3--z5; % the upright
189 draw z1--z4; draw z4--z2; % the arms
190 labels(1,2,3,4,5); endchar;
191
192
193 cmchar "Greek letter lambda (l)";
194 beginglyph("l",0.4);
195 x1=x2=leftloc; x3=rightloc;
196 bot y1=-o; y2=h;
197 y3=.7h;
198 draw z1--z2--z3;
199 labels(1,2,3); endchar;
200
201
202 cmchar"Greek letter mu (m)";
203 beginglyph("m",1.0);
204 x1=rightloc;
205 x5=x6=leftloc;
206 x2=3/4[x5,x1]; x3=1/2[x5,x1]; x4=1/4[x5,x1];
207 bot y6= -o;
208 top y5= top y3 = h;
209 top y1=.8h;
210 y2=.6h;
211 y4=.7h;
212 draw z6--z5;
213 draw z1--z2--z3--z4--z5;
214 labels(1,2,3,4,5,6); endchar;
215
216
217 cmchar "Greek letter nu (n)";
218 beginglyph("n",0.6);
219 x1=x2=leftloc; x3=x4=rightloc;
220 y1=0; y2=0.8h; y3=0.3h; y4=h;
221 draw z1--z2--z3--z4;
222 labels(1,2,3,4); endchar;
223
224
225 cmchar "Greek letter xi (x)";
226 beginglyph("x", 0.6);
227 x1=x3=leftloc; x4=x6=rightloc;
228 bot y1= bot y4= -o; top y3= top y6= h;
229 z2=0.5[z1,z3]; z5=0.5[z4,z6];
230 z7=0.5[z1,z4]; z8=0.5[z3,z6];
231 draw z1--z4; draw z2--z5; draw z3--z6; % horizontals
232 draw z7--z8; % vertical
233 labels(1,2,3,4,5,6,7,8); endchar;
234
235
236 cmchar "Greek letter omicron (o)";
237 beginglyph("o",1.0);
238 x1=leftloc; x3=rightloc;
239 y2=h; y4=0;
240 x2=x4=midloc;
241 y1=y3=h/2;
242 draw z1..z2..z3..z4..cycle;
243 labels(1,2,3,4); endchar;
244
245
246 cmchar "Greek letter pi (p)";
247 beginglyph("p", 0.4);
248 x1=x2=leftloc; x3=x4=rightloc;
249 bot y1=-o; top y2= top y3= h; y4=0.6h;
250 draw z1--z2--z3--z4;
251 labels(1,2,3,4); endchar;
252
253
254 cmchar "Greek letter (koppa) q";
255 beginglyph("q",0.6);
256 numeric alpha;
257 x1=leftloc;
258 x3=rightloc;
259 alpha=0.5(x3-x1); % circle radius
260 y2=h;
261 y4=y2-2alpha;
262 bot y5=-o;
263 x2=x4=x5=midloc;
264 y1=y3=h-alpha;
265 draw z1..z2..z3..z4..cycle; % the circle
266 draw z5--z4; % the upright
267 labels(1,2,3,4,5); endchar;
268
269
270 cmchar "Greek letter rho (r)";
271 beginglyph("r", 0.4);
272 x1=x2=x3=leftloc; x4=rightloc;
273 bot y1=-o; top y2=h;
274 y3=y4=0.5h;
275 draw z1--z2--z4--z3; % the P shape
276 x5=midloc; y5=0.2h;
277 draw z3--z5; % a little leg
278 labels(1,2,3,4); endchar;
279
280
281 cmchar "Greek letter sigma (s)";
282 beginglyph("s", 0.8);
283 x2=x4=leftloc; x1=x5=rightloc;
284 y1=0; y5=h;
285 y2=0.1h; y4=0.9h;
286 z3=(midloc,0.5h);
287 draw z1--z2--z3--z4--z5;
288 labels(1,2,3,4,5); endchar;
289
290
291 cmchar "Greek letter tau (t)";
292 beginglyph("t", 0.6);
293 x1=midloc; x2=leftloc; x4=rightloc;
294 bot y1=-o; top y2= top y4= h;
295 z3=0.5[z2,z4];
296 draw z1--z3; % upright
297 draw z2--z4; % bar
298 labels(1,2,3,4); endchar;
299
300
301 cmchar "Greek letter upsilon (y)";
302 beginglyph("y", 0.6);
303 x1=x3=midloc; x2=leftloc; x4=rightloc;
304 bot y1=-o; top y2= top y4= h;
305 y3=0.6h;
306 draw z1--z3; % upright
307 draw z2--z3--z4; % V
308 labels(1,2,3,4); endchar;
309
310
311 cmchar "Greek letter chi (X)";
312 beginglyph("X", 0.6);
313 x1=x2=leftloc; x3=x4=rightloc;
314 bot y1= bot y3=-o; top y2= top y4=h;
315 draw z1--z4; draw z2--z3;
316 labels(1,2,3,4); endchar;
317
318
319 cmchar "Greek letter phi (f)";
320 beginglyph("f",0.6);
321 x1=leftloc; x3=rightloc;
322 x2=x4=midloc;
323 y1=y3=0.5h;
324 y2=h; y4=0;
325 draw z1..z2..z3..z4..cycle; % the oval
326 draw z4--z2; % the upright
327 labels(1,2,3,4,5); endchar;
328
329
330 cmchar "Greek letter psi (P)";
331 beginglyph("P", 0.6);
332 x1=x3=midloc; x2=leftloc; x4=rightloc;
333 bot y1=-o; top y2= top y4= h;
334 y3=0.5h;
335 z5=0.5[z2,z4];
336 draw z1--z5; % upright
337 draw z2--z3--z4; % V
338 labels(1,2,3,4,5); endchar;
339
340
341 cmchar "Greek letter omega (O)";
342 beginglyph("O", 1.0);
343 x1=leftloc; x4=rightloc;
344 y1=y4=0;
345 z2=0.35[z1,z4]; z3=0.35[z4,z1];
346 x7=midloc; y7=h;
347 x5=0.1[x1,x4]; x6=0.1[x4,x1];
348 y5=y6=0.5h;
349 draw z1--z2..z5..z7..z6..z3--z4;
350 labels(1,2,3,4,5,6,7); endchar;
351
352
353 end
354