Debian Codegraph @

texmf-dist/fonts/source/public/archaic/copsn10.mf

raw
1 %%
2 %% This is file `copsn10.mf',
3 %% generated with the docstrip utility.
4 %%
5 %% The original source files were:
6 %%
7 %% oldprsn.dtx (with options: `up')
8 %% ------------------------------------------------------------------
9 %% Author: Peter Wilson (Herries Press) herries dot press at earthlink dot net
10 %% Copyright 1999--2005 Peter R. Wilson
11 %%
12 %% This work may be distributed and/or modified under the
13 %% conditions of the Latex Project Public License, either
14 %% version 1.3 of this license or (at your option) any
15 %% later version.
16 %% The latest version of the license is in
17 %% http://www.latex-project.org/lppl.txt
18 %% and version 1.3 or later is part of all distributions of
19 %% LaTeX version 2003/06/01 or later.
20 %%
21 %% This work has the LPPL maintenance status "author-maintained".
22 %%
23 %% This work consists of the files listed in the README file.
24 %% ------------------------------------------------------------------
25 %%% COPSN10.MF Computer Old Persian Cuneiform font 10 point design size.
26
27
28 font_identifier:="oldprsn"; font_size 10pt#;
29
30 u#:=.2pt#; % unit width
31 ht#:=8pt#; % height of characters (CM cap-height is approx 6.8pt)
32 s#:=1.5pt#; % width correction (right and left)
33 o#:=1/20pt#; % overshoot
34 px#:=.4pt#; % horizontal width of pen
35 font_normal_space:=7pt#; % width of a blank space
36 font_normal_shrink:=.9pt#; % width correction for blank space
37 font_x_height:=4.5pt#; % height of one ex
38 font_quad:=10pt#; % an em
39
40 font_coding_scheme:="Old Persian glyphs";
41 mode_setup;
42
43 ho#:=o#; % horizontal overshoot
44 leftloc#:=s#; % leftmost xcoord of character
45 py#:=px#; % vertical thickness of the pen
46
47 define_pixels(s,u);
48 define_blacker_pixels(px,py);
49 define_good_x_pixels(leftloc);
50 define_corrected_pixels(o); % turn on overshoot correction
51 define_horizontal_corrected_pixels(ho);
52
53 numeric midloc, rightloc, aw;
54 pickup pencircle xscaled px yscaled py;
55 stylus:=savepen;
56
57 numeric trht, trbs;
58 numeric th, tb;
59 th = 6/24; tb = 8/24;
60 numeric wiht, wibs;
61 numeric wh, wb;
62 wh = 10/24; wb = 20/24;
63 def beginglyph(expr code, unit_width) =
64 beginchar(code, unit_width*ht#+2s#, ht#, 0);
65 midloc:=1/2w; rightloc:=(w-s); aw := rightloc-leftloc;
66 trht := th*h; trbs := tb*h;
67 wiht := wh*h; wibs := wb*h;
68 pickup stylus enddef;
69
70 let cmchar=\;
71
72
73 def triangle(suffix $)(expr ht, bs, ang) =
74 path pth[];
75 pair pr[];
76 pr1 := (x$-ht,y$); % midpoint of base in default position
77 pr2 := pr1 shifted (1/2bs*up); % base points
78 pr3 := pr1 shifted (1/2bs*down);
79 z$trl = pr2 rotatedaround(z$, ang);
80 z$trr = pr3 rotatedaround(z$, ang);
81 z$trc = 1/2[z$trl,z$trr];
82 z$tic = 1/2[z$,z$trc];
83 pth$ := z$--z$trl--z$trr--cycle;
84 enddef;
85
86
87 def trir(suffix $)(expr ht, bs) =
88 path pth[];
89 z$trc = (x$-ht, y$); % midpoint of base
90 z$trl = (x$trc, y$trc+1/2bs); % base points
91 z$trr = (x$trc, y$trc-1/2bs);
92 z$tic = 1/2[z$,z$trc];
93 pth$ := z$--z$trl--z$trr--cycle;
94 enddef;
95
96
97 def triu(suffix $)(expr ht, bs) =
98 path pth[];
99 z$trc = (x$, y$-ht); % midpoint of base
100 z$trl = (x$-1/2bs, y$trc); % base points
101 z$trr = (x$+1/2bs, y$trc); % base points
102 z$tic = 1/2[z$,z$trc];
103 pth$ := z$--z$trl--z$trr--cycle;
104 enddef;
105
106
107 def tril(suffix $)(expr ht, bs) =
108 path pth[];
109 z$trc = (x$+ht, y$); % midpoint of base
110 z$trl = (x$trc, y$trc-1/2bs); % base points
111 z$trr = (x$trc, y$trc+1/2bs);
112 z$tic = 1/2[z$,z$trc];
113 pth$ := z$--z$trl--z$trr--cycle;
114 enddef;
115
116
117 def tril(suffix $)(expr ht, bs) =
118 path pth[];
119 z$trc = (x$+ht, y$); % midpoint of base
120 z$trl = (x$trc, y$trc-1/2bs); % base points
121 z$trr = (x$trc, y$trc+1/2bs);
122 z$tic = 1/2[z$,z$trc];
123 pth$ := z$--z$trl--z$trr--cycle;
124 enddef;
125
126
127 def trid(suffix $)(expr ht, bs) =
128 path pth[];
129 z$trc = (x$, y$+ht); % midpoint of base
130 z$trl = (x$+1/2bs, y$trc); % base points
131 z$trr = (x$-1/2bs, y$trc); % base points
132 z$tic = 1/2[z$,z$trc];
133 pth$ := z$--z$trl--z$trr--cycle;
134 enddef;
135
136
137 def wing(suffix $)(expr ht, bs, ang) =
138 path pth[];
139 pair pr[];
140 pr1 := (x$+ht,y$); % midpoint of base in default position
141 pr2 := pr1 shifted (1/2bs*down); % base points
142 pr3 := pr1 shifted (1/2bs*up);
143 pr4 := pr1 rotatedaround(z$, ang);
144 z$wil = pr2 rotatedaround(z$, ang);
145 z$wir = pr3 rotatedaround(z$, ang);
146 z$wic = 1/2[z$,pr4];
147 pth$ := z$--z$wil{(z$wic-z$wil)}..z$wic..{(z$wir-z$wic)}z$wir--cycle;
148 enddef;
149
150
151 def wingl(suffix $)(expr ht, bs) =
152 path pth[];
153 z$wil = (x$+ht, y$-1/2bs); % base points
154 z$wir = (x$wil, y$+1/2bs);
155 z$wic = (1/2[x$,x$wil], y$); % midpoint of base curve
156 pth$ := z$--z$wil{(z$wic-z$wil)}..z$wic..{(z$wir-z$wic)}z$wir--cycle;
157 enddef;
158
159
160 def wingd(suffix $)(expr ht, bs) =
161 path pth[];
162 z$wil = (x$+1/2bs, y$+ht); % base points
163 z$wir = (x$-1/2bs, y$wil);
164 z$wic = (x$, 1/2[y$,y$wil]); % midpoint of base curve
165 pth$ := z$--z$wil{(z$wic-z$wil)}..z$wic..{(z$wir-z$wic)}z$wir--cycle;
166 enddef;
167
168
169 def wingr(suffix $)(expr ht, bs) =
170 path pth[];
171 z$wil = (x$-ht, y$+1/2bs); % base points
172 z$wir = (x$wil, y$-1/2bs);
173 z$wic = (1/2[x$,x$wil], y$); % midpoint of base curve
174 pth$ := z$--z$wil{(z$wic-z$wil)}..z$wic..{(z$wir-z$wic)}z$wir--cycle;
175 enddef;
176
177
178 def wingu(suffix $)(expr ht, bs) =
179 path pth[];
180 z$wil = (x$-1/2bs, y$-ht); % base points
181 z$wir = (x$+1/2bs, y$wil);
182 z$wic = (x$, 1/2[y$,y$wil]); % midpoint of base curve
183 pth$ := z$--z$wil{(z$wic-z$wil)}..z$wic..{(z$wir-z$wic)}z$wir--cycle;
184 enddef;
185
186 cmchar "Old Persian letter a";
187 beginglyph("a", (3tb+2th));
188 z1trl=(leftloc,h); % top pin
189 trir(1, trht, trbs); fill pth1;
190 z1'=(rightloc,y1); draw z1tic--z1';
191 z12trc=(midloc,y1trr); % middle pin
192 trid(12, trht, trbs); fill pth12;
193 z12'=(x12,0); draw z12tic--z12';
194 z11trl=z12trr; % left pin
195 trid(11, trht, trbs); fill pth11;
196 z11'=(x11,0); draw z11tic--z11';
197 z13trr=z12trl; % right pin
198 trid(13, trht, trbs); fill pth13;
199 z13'=(x13,0); draw z13tic--z13';
200 labels(1,11,12,13);
201 endchar;
202
203 cmchar "Old Persian letter i";
204 beginglyph("i", (2tb)); %% 3tb too large
205 z1trl=(leftloc,h); % top pin
206 trir(1, trht, trbs); fill pth1;
207 z1'=(rightloc,y1); draw z1tic--z1';
208 z11trr=z1trr; % left pin
209 trid(11, trht, trbs); fill pth11;
210 z11'=(x11,0); draw z11tic--z11';
211 z12trr=z11trl; % middle pin
212 trid(12, trht, trbs); fill pth12;
213 z12'=(x12,0); draw z12tic--z12';
214 z2trc=(x11trl,y1); % second top head
215 trir(2, trht, trbs); fill pth2;
216 labels(1,2,11,12,13);
217 endchar;
218
219 cmchar "Old Persian letter u";
220 beginglyph("u", (2tb+wh)); %% 3tb+wh too large
221 z31=(leftloc,1/2h); % left wing
222 wingl(31, wiht, wibs); fill pth31;
223 z1trl=(x31wil,h); % top pin
224 trir(1, trht, trbs); fill pth1;
225 z1'=(rightloc,y1); draw z1tic--z1';
226 z11trr=z1trr; % left pin
227 trid(11, trht, trbs); fill pth11;
228 z11'=(x11,0); draw z11tic--z11';
229 z12trr=z11trl; % middle pin
230 trid(12, trht, trbs); fill pth12;
231 z12'=(x12,0); draw z12tic--z12';
232 labels(1,2,11,12,13);
233 endchar;
234
235 cmchar "Old Persian syllable ka (k)";
236 beginglyph("k", (3tb)); %% 4tb too large
237 z1trr=(leftloc,h); % left pin
238 trid(1, trht, trbs); fill pth1;
239 z1'=(x1,0); draw z1tic--z1';
240 z11trr=(x1trl,1/2h); % top pin
241 trir(11, trht, trbs); fill pth11;
242 z11'=(rightloc,y11); draw z11tic--z11';
243 z12trl=z11trr; % bottom pin
244 trir(12, trht, trbs); fill pth12;
245 z12'=(rightloc,y12); draw z12tic--z12';
246 labels(1,11,12);
247 endchar;
248
249 cmchar "Old Persian syllable ku (K)";
250 beginglyph("K", (tb+wh));
251 z1=(leftloc,1/2h); % wing
252 wingl(1, wiht, wibs); fill pth1;
253 z2trr=(x1wil,h); % pin
254 trid(2, trht, trbs); fill pth2;
255 z2'=(x2,0); draw z2tic--z2';
256 labels(1,2);
257 endchar;
258
259 cmchar "Old Persian syllable xa (x)";
260 beginglyph("x", (2tb+2wh));
261 z1=(leftloc,1/2h); % left wing
262 wingl(1, wiht, wibs); fill pth1;
263 z2=(x1wil,y1); % right wing
264 wingl(2, wiht, wibs); fill pth2;
265 z11trr=(x2wil,h); % left pin
266 trid(11, trht, trbs); fill pth11;
267 z11'=(x11,0); draw z11tic--z11';
268 z12trr=z11trl; % right pin
269 trid(12, trht, trbs); fill pth12;
270 z12'=(x12,0); draw z12tic--z12';
271 labels(1,2,11,12);
272 endchar;
273
274 cmchar "Old Persian syllable ga (g)";
275 beginglyph("g", (3tb+wh));
276 z1=(leftloc,1/2h); % wing
277 wingl(1, wiht, wibs); fill pth1;
278 z11trr=(x1wil,h); % left pin
279 trid(11, trht, trbs); fill pth11;
280 z11'=(x11,0); draw z11tic--z11';
281 z12trr=z11trl; % right pin
282 trid(12, trht, trbs); fill pth12;
283 z12'=(x12,0); draw z12tic--z12';
284 z21trc=(x12trl,y1); % small pin
285 trir(21, trht, trbs); fill pth21;
286 z21'=(rightloc,y21); draw z21tic--z21';
287 labels(1,2,11,12,21);
288 endchar;
289
290 cmchar "Old Persian syllable gu (G)";
291 beginglyph("G", (2tb+th+wh)); %% 3tb+wh too large
292 z1=(leftloc,1/2h); % wing
293 wingl(1, wiht, wibs); fill pth1;
294 z12trc=(x1wil, 1/2h); % middle pin
295 trir(12, trht, trbs); fill pth12;
296 z12'=(rightloc,y12); draw z12tic--z12';
297 z13trl=z12trr; % bottom pin
298 trir(13, trht, trbs); fill pth13;
299 z13'=(rightloc,y13); draw z13tic--z13';
300 z11trr=z12trl; % top pin
301 trir(11, trht, trbs); fill pth11;
302 z11'=(rightloc,y11); draw z11tic--z11';
303 z111trc=1/2[z11trc,z11'];
304 trir(111, trht, trbs); fill pth111;
305 labels(1,2,3,4,5,6,11,12,13,111);
306 endchar;
307
308 cmchar "Old Persian syllable ca (c)";
309 beginglyph("c", (4tb));
310 z1trl=(leftloc,h); % top pin
311 trir(1, trht, trbs); fill pth1;
312 z11trr=(x1, y1trr); % left pin
313 trid(11, trht, trbs); fill pth11;
314 z11'=(x11,0); draw z11tic--z11';
315 z12trr=z11trl; % middle pin
316 trid(12, trht, trbs); fill pth12;
317 z12'=(x12,0); draw z12tic--z12';
318 z2trl=z12trl; % bottom pin
319 trir(2, trht, trbs); fill pth2;
320 z2'=(rightloc,y2); draw z2tic--z2';
321 z1'=(x2trl,y1); draw z1tic--z1'; % body of top pin
322 labels(1,2,3,4,5,6,11,12,13);
323 endchar;
324
325 cmchar "Old Persian syllable ja (j)";
326 beginglyph("j", (th+tb+wh));
327 z1trc=(leftloc,1/2h); % hor pin
328 trir(1, trht, trbs); fill pth1;
329 z2=(rightloc-wiht,y1); % wing
330 wingl(2, wiht, wibs); fill pth2;
331 draw z1tic--z2;
332 z11trc=(1/2[x1,x2], h); % vert pin
333 trid(11, trht, trbs); fill pth11;
334 z11'=(x11,0); draw z11tic--z11';
335 labels(1,2,3,4,11,12,13);
336 endchar;
337
338 cmchar "Old Persian syllable ji (J)";
339 beginglyph("J",(7/2tb+wh)); %% 4tb+wh too large
340 z1trc=(leftloc, 1/2h); % left pin
341 trir(1, trht, trbs); fill pth1;
342 z2=(x1+trbs, y1); % wing
343 draw z1tic--z2;
344 wingl(2, wiht, wibs); fill pth2;
345 z12trc=(x2wil,y1); % middle pin
346 trir(12, trht, trbs); fill pth12;
347 z12'=(rightloc, y12); draw z12tic--z12';
348 z11trr=z12trl; % top pin
349 trir(11, trht, trbs); fill pth11;
350 z11'=(rightloc, y11); draw z11tic--z11';
351 z13trl=z12trr; % bottom pin
352 trir(13, trht, trbs); fill pth13;
353 z13'=(rightloc, y13); draw z13tic--z13';
354 labels(1,2,3,4,5,6,7,8,9,10,11,12,13);
355 endchar;
356
357 cmchar "Old Persian syllable ta (t)";
358 beginglyph("t", (4tb+th)); %% 5tb too large
359 z3trl=(rightloc,h); % right pin
360 trid(3, trht, trbs); fill pth3;
361 z3'=(x3,0); draw z3tic--z3';
362 z1trl=(x3trr-trbs,h); % left pin
363 trid(1, trht, trbs); fill pth1;
364 z1'=(x1,0); draw z1tic--z1';
365 z11trr=(leftloc,1/2h); % top pin
366 trir(11, trht, trbs); fill pth11;
367 z11'=(x1,y11); draw z11tic--z11';
368 z12trl=z11trr; % bottom pin
369 trir(12, trht, trbs); fill pth12;
370 z12'=(x1,y12); draw z12tic--z12';
371 z2trc=(1/2[x1,x3], y11trl); % middle pin
372 trid(2, trht, trbs); fill pth2;
373 z2'=(x2,0); draw z2tic--z2';
374 labels(1,2,3,4,5,6,7,8,9,10,11,12);
375 endchar;
376
377 cmchar "Old Persian syllable tu (T)";
378 beginglyph("T", (4tb+th)); %% 5tb too large
379 z1trr=(leftloc,h); % left pin
380 trid(1, trht, trbs); fill pth1;
381 z1'=(x1,0); draw z1tic--z1';
382 z2trr=z1trl; % center pin
383 trid(2, trht, trbs); fill pth2;
384 z2'=(x2,0); draw z2tic--z2';
385 z3trr=z2trl; % right pin
386 trid(3, trht, trbs); fill pth3;
387 z3'=(x3,0); draw z3tic--z3';
388 z11trl=(x3trl, 1/2h); % short hor pin
389 trir(11, trht, trbs); fill pth11;
390 z11'=(rightloc,y11); draw z11tic--z11';
391 labels(1,2,3,11);
392 endchar;
393
394 cmchar "Old Persian syllable tha (o)";
395 beginglyph("o", (2tb+wh));
396 z1trr=(leftloc,h); % left pin
397 trid(1, trht, trbs); fill pth1;
398 z1'=(x1,0); draw z1tic--z1';
399 z2=(x1,1/2h); % wing
400 wingl(2, wiht, wibs); fill pth2;
401 z3trr=(x2wil,h); % right pin
402 trid(3, trht, trbs); fill pth3;
403 z3'=(x3,0); draw z3tic--z3';
404 labels(1,2,3);
405 endchar;
406
407 cmchar "Old Persian syllable c(cedilla)a (C)";
408 beginglyph("C", (2tb));
409 z1trl=(leftloc,h); % top pin
410 trir(1, trht, trbs); fill pth1;
411 z1'=(rightloc,y1); draw z1tic--z1';
412 z2trl=z1trr; % center pin
413 trir(2, trht, trbs); fill pth2;
414 z2'=(rightloc,y2); draw z2tic--z2';
415 z11trr=z2trr; % left pin
416 trid(11, trht, trbs); fill pth11;
417 z11'=(x11,0); draw z11tic--z11';
418 z12trr=z11trl; % right pin
419 trid(12, trht, trbs); fill pth12;
420 z12'=(x12,0); draw z12tic--z12';
421 labels(1,2,11,12);
422 endchar;
423
424 cmchar "Old Persian syllable da (d)";
425 beginglyph("d", (2tb));
426 z1trl=(leftloc,h); % top pin
427 trir(1, trht, trbs); fill pth1;
428 z1'=(rightloc,y1); draw z1tic--z1';
429 z11trr=z1trr; % left pin
430 trid(11, trht, trbs); fill pth11;
431 z11'=(x11,0); draw z11tic--z11';
432 z12trr=z11trl; % right pin
433 trid(12, trht, trbs); fill pth12;
434 z12'=(x12,0); draw z12tic--z12';
435 labels(1,2,11,12);
436 endchar;
437
438 cmchar "Old Persian syllable di (P)";
439 beginglyph("P", (3tb+th)); %% 4tb too large
440 z2trl=(rightloc,h); % right pin
441 trid(2, trht, trbs); fill pth2;
442 z2'=(x2,0); draw z2tic--z2';
443 z1trl=z2trr; % left pin
444 trid(1, trht, trbs); fill pth1;
445 z1'=(x1,0); draw z1tic--z1';
446 z12trc=(leftloc,1/2h); % center pin
447 trir(12, trht, trbs); fill pth12;
448 z12'=(x1,y12); draw z12tic--z12';
449 z11trr=z12trl; % top pin
450 trir(11, trht, trbs); fill pth11;
451 z11'=(x1,y11); draw z11tic--z11';
452 z13trl=z12trr; % bottom pin
453 trir(13, trht, trbs); fill pth13;
454 z13'=(x1,y13); draw z13tic--z13';
455 labels(1,2,11,12,13);
456 endchar;
457
458 cmchar "Old Persian syllable du (D)";
459 beginglyph("D", (2tb+th+wh)); %% 3tb+wh too large
460 z1=(leftloc,h/2); % wing
461 wingl(1, wiht, wibs); fill pth1;
462 z2trl=(rightloc,h); % right pin
463 trid(2, trht, trbs); fill pth2;
464 z2'=(x2,0); draw z2tic--z2';
465 z12trc=(x1wil,h/2); % center pin
466 trir(12, trht, trbs); fill pth12;
467 z12'=(x2,y12); draw z12tic--z12';
468 z11trr=z12trl; % top pin
469 trir(11, trht, trbs); fill pth11;
470 z11'=(x2,y11); draw z11tic--z11';
471 z13trl=z12trr; % bottom pin
472 trir(13, trht, trbs); fill pth13;
473 z13'=(x2,y13); draw z13tic--z13';
474 labels(1,2,11,12,13);
475 endchar;
476
477 cmchar "Old Persian syllable na (n)";
478 beginglyph("n", (2tb+wh));
479 z1=(rightloc-wiht, h/2); % wing
480 wingl(1, wiht, wibs); fill pth1;
481 z11trr=(leftloc,h/2); % top pin
482 trir(11, trht, trbs); fill pth11;
483 z11'=(x1,y11); draw z11tic--z11';
484 z12trl=z11trr; % bottom pin
485 trir(12, trht, trbs); fill pth12;
486 z12'=(x1,y12); draw z12tic--z12';
487 labels(1,11,12);
488 endchar;
489
490 cmchar "Old Persian syllable nu (N)";
491 beginglyph("N", (2tb+2wh));
492 z1=(leftloc, h/2); % left wing
493 wingl(1, wiht, wibs); fill pth1;
494 z2=(x1wil, y1); % right wing
495 wingl(2, wiht, wibs); fill pth2;
496 z11trr=(x2wil,h/2); % top pin
497 trir(11, trht, trbs); fill pth11;
498 z11'=(rightloc,y11); draw z11tic--z11';
499 z12trl=z11trr; % bottom pin
500 trir(12, trht, trbs); fill pth12;
501 z12'=(rightloc,y12); draw z12tic--z12';
502 labels(1,2,11,12);
503 endchar;
504
505 cmchar "Old Persian syllable pa (p)";
506 beginglyph("p", (2tb));
507 z1trc=(leftloc,h); % top pin
508 trir(1, trht, trbs); fill pth1;
509 z1'=(rightloc,y1); draw z1tic--z1';
510 z2trl=(x1,y1); % middle pin
511 trir(2, trht, trbs); fill pth2;
512 z2'=(rightloc,y2); draw z2tic--z2';
513 z3trl=(x1trc,y2); % bottom pin
514 trir(3, trht, trbs); fill pth3;
515 z3'=(rightloc,y3); draw z3tic--z3';
516 z11trr=z3trr; % left pin
517 trid(11, trht, trbs); fill pth11;
518 z11'=(x11,0); draw z11tic--z11';
519 z12trr=z11trl; % right pin
520 trid(12, trht, trbs); fill pth12;
521 z12'=(x12,0); draw z12tic--z12';
522 labels(1,2,3,11,12);
523 endchar;
524
525 cmchar "Old Persian syllable fa (f)";
526 beginglyph("f", (tb+2wh));
527 z1trr=(leftloc,h); % left pin
528 trid(1, trht, trbs); fill pth1;
529 z1'=(x1,0); draw z1tic--z1';
530 z11=(x1,h/2); % left wing
531 wingl(11, wiht, wibs); fill pth11;
532 z12=(x11wil,y11); % right wing
533 wingl(12, wiht, wibs); fill pth12;
534 labels(1,11,12);
535 endchar;
536
537 cmchar "Old Persian syllable ba (b)";
538 beginglyph("b", (3tb));
539 z1trl=(rightloc,h); % right pin
540 trid(1, trht, trbs); fill pth1;
541 z1'=(x1,0); draw z1tic--z1';
542 z11trr=(leftloc,h/2); % top pin
543 trir(11, trht, trbs); fill pth11;
544 z11'=(x1,y11); draw z11tic--z11';
545 z12trl=z11trr; % bottom pin
546 trir(12, trht, trbs); fill pth12;
547 z12'=(x1,y12); draw z12tic--z12';
548 labels(1,11,12);
549 endchar;
550
551 cmchar "Old Persian syllable ma (m)";
552 beginglyph("m", (4tb+th)); %% 5tb too large
553 z3trl=(rightloc,h); % right pin
554 trid(3, trht, trbs); fill pth3;
555 z3'=(x3,0); draw z3tic--z3';
556 z2trl=(x3trr,y3); % center pin
557 trid(2, trht, trbs); fill pth2;
558 z2'=(x2,0); draw z2tic--z2';
559 z1trl=(x2trr,h); % left pin
560 trid(1, trht, trbs); fill pth1;
561 z1'=(x1,0); draw z1tic--z1';
562 z11trc=(leftloc, h/2); % hor pin
563 trir(11, trht, trbs); fill pth11;
564 z11'=(x1,y11); draw z11tic--z11';
565 labels(1,2,3,11);
566 endchar;
567
568 cmchar "Old Persian syllable mi (w)";
569 beginglyph("w", (2tb+wh));
570 z1trr=(leftloc,h); % left pin
571 trid(1, trht, trbs); fill pth1;
572 z1'=(x1,0); draw z1tic--z1';
573 z2=(x1,h/2); % wing
574 wingl(2, wiht, wibs); fill pth2;
575 z11trr=(x2wil, h/2); % top pin
576 trir(11, trht, trbs); fill pth11;
577 z11'=(rightloc,y11); draw z11tic--z11';
578 z12trl=z11trr; % bottom pin
579 trir(12, trht, trbs); fill pth12;
580 z12'=(rightloc,y12); draw z12tic--z12';
581 labels(1,2,11,12);
582 endchar;
583
584 cmchar "Old Persian syllable mu (M)";
585 beginglyph("M", (5tb+wh));
586 z5trc=(rightloc-2trbs, h/2); % right pin
587 trir(5, trht, trbs); fill pth5;
588 z5'=(rightloc,y5); draw z5tic--z5';
589 z4=(x5trc-wiht,y5); % wing
590 wingl(4, wiht, wibs); fill pth4;
591 z2trc=(leftloc+trht,y5); % middle pin
592 trir(2, trht, trbs); fill pth2;
593 z2'=z4; draw z2tic--z2';
594 z1trr=(leftloc,y2trl); % top pin
595 trir(1, trht, trbs); fill pth1;
596 z1'=(3/4[x1,x2'],y1); draw z1tic--z1';
597 z3trl=(leftloc,y2trr); % bottom pin
598 trir(3, trht, trbs); fill pth3;
599 z3'=(x1',y3); draw z3tic--z3';
600 labels(1,2,3,4);
601 endchar;
602
603 cmchar "Old Persian syllable ya (y)";
604 beginglyph("y", (2tb+wh));
605 z1trr=(leftloc,h); % left pin
606 trid(1, trht, trbs); fill pth1;
607 z1'=(x1,0); draw z1tic--z1';
608 z2=(x1,h/2); % wing
609 wingl(2, wiht, wibs); fill pth2;
610 z11trc=(x2wil, h/2); % right pin
611 trir(11, trht, trbs); fill pth11;
612 z11'=(rightloc,y11); draw z11tic--z11';
613 labels(1,2,11,12);
614 endchar;
615
616 cmchar "Old Persian syllable ra (r)";
617 beginglyph("r", (3tb+th)); %% 4tb too large
618 z11trl=(rightloc, h); % right pin
619 trid(11, trht, trbs); fill pth11;
620 z11'=(x11,0); draw z11tic--z11';
621 z2trc=(leftloc+trht,h/2); % middle pin
622 trir(2, trht, trbs); fill pth2;
623 z2'=(x11,y2); draw z2tic--z2';
624 z1trr=(leftloc,y2trl); % top pin
625 trir(1, trht, trbs); fill pth1;
626 z1'=(x2',y1); draw z1tic--z1';
627 z3trl=(leftloc,y2trr); % bottom pin
628 trir(3, trht, trbs); fill pth3;
629 z3'=(x2',y3); draw z3tic--z3';
630 labels(1,2,3,4);
631 endchar;
632
633 cmchar "Old Persian syllable ru (R)";
634 beginglyph("R", (tb+th+2wh)); %% 2tb+2wh too large
635 z3=(rightloc-wiht,h/2); % right wing
636 wingl(3, wiht, wibs); fill pth3;
637 z2=(x3-wiht,y3); % left wing
638 wingl(2, wiht, wibs); fill pth2;
639 z1trc=(leftloc,y3); % pin
640 trir(1, trht, trbs); fill pth1;
641 z1'=z2; draw z1tic--z1';
642 labels(1,2,3);
643 endchar;
644
645 cmchar "Old Persian syllable la (l)";
646 beginglyph("l", (3tb+th)); %% 4tb too large
647 z11trl=(rightloc,h); % right pin
648 trid(11, trht, trbs); fill pth11;
649 z11'=(x11,0); draw z11tic--z11';
650 z2trc=(leftloc,h/2); % middle pin
651 trir(2, trht, trbs); fill pth2;
652 z2'=(x11,y2); draw z2tic--z2';
653 z1trr=(x2,y2trl); % top pin
654 trir(1, trht, trbs); fill pth1;
655 z1'=(x2',y1); draw z1tic--z1';
656 z3trl=(x1trr,y2trr); % bottom pin
657 trir(3, trht, trbs); fill pth3;
658 z3'=(x2',y3); draw z3tic--z3';
659 labels(1,2,3,11);
660 endchar;
661
662 cmchar "Old Persian syllable va (v)";
663 beginglyph("v", (5tb));
664 z11trc=(leftloc,h/2); % left hor pin
665 trir(11, trht, trbs); fill pth11;
666 z11'=(x11+trbs,y11); draw z11tic--z11';
667 z12trc=(x11',h); % vert pin
668 trid(12, trht, trbs); fill pth12;
669 z12'=(x12,0); draw z12tic--z12';
670 z2=(x12+1/2trbs+2trht, h/2); % middle pin
671 trir(2, trht, trbs); fill pth2;
672 z2'=(rightloc,y2); draw z2tic--z2';
673 z1trr=(x2trc-trht,y2trl); % top pin
674 trir(1, trht, trbs); fill pth1;
675 z1'=(x2',y1); draw z1tic--z1';
676 z3trl=(x1trr,y2trr); % bottom pin
677 trir(3, trht, trbs); fill pth3;
678 z3'=(x2',y3); draw z3tic--z3';
679 labels(1,2,3,11);
680 endchar;
681
682 cmchar "Old Persian syllable vi (V)";
683 beginglyph("V", (2tb));
684 z1trl=(midloc,1/3h); % left pin
685 trid(1, trht, trbs); fill pth1;
686 z1'=(x1,0); draw z1tic--z1';
687 z2trr=z1trl; % right pin
688 trid(2, trht, trbs); fill pth2;
689 z2'=(x2,0); draw z2tic--z2';
690 z3trc=(x1trl,h); % top pin
691 trid(3, trht, trbs); fill pth3;
692 z3'=(x3,y1trl); draw z3tic--z3';
693 z11trc=(leftloc, 1/2[y1trl,y3trl]); % hor pin
694 trir(11, trht, trbs); fill pth11;
695 z11'=(rightloc,y11); draw z11tic--z11';
696 labels(1,2,3,4,11);
697 endchar;
698
699 cmchar "Old Persian syllable sa (s)";
700 beginglyph("s", (3tb+th)); %% 4tb too large
701 z12trr=(leftloc,h); % vert pin
702 trid(12, trht, trbs); fill pth12;
703 z12'=(x12,0); draw z12tic--z12';
704 z2=(x12+1/2trbs+2trht, h/2); % middle pin
705 trir(2, trht, trbs); fill pth2;
706 z2'=(rightloc,y2); draw z2tic--z2';
707 z1trr=(x2trc-trht,y2trl); % top pin
708 trir(1, trht, trbs); fill pth1;
709 z1'=(x2',y1); draw z1tic--z1';
710 z3trl=(x1trr,y2trr); % bottom pin
711 trir(3, trht, trbs); fill pth3;
712 z3'=(x2',y3); draw z3tic--z3';
713 labels(1,2,3,11,12);
714 endchar;
715
716 cmchar "Old Persian syllable sva (S)";
717 beginglyph("S", (2wh));
718 z1=(leftloc,1/2wibs); % left wing
719 wingl(1, wiht, wibs); fill pth1;
720 z2=(x1+wiht,y1); % right wing
721 wingl(2, wiht, wibs); fill pth2;
722 z3trl=(leftloc,h); % pin
723 trir(3, trht, trbs); fill pth3;
724 z3'=(rightloc,y3); draw z3tic--z3';
725 labels(1,2,3);
726 endchar;
727
728 cmchar "Old Persian syllable za (z)";
729 beginglyph("z", (4tb));
730 z1trr=(leftloc,h); % left pin
731 trid(1, trht, trbs); fill pth1;
732 z1'=(x1,0); draw z1tic--z1';
733 z2trl=(rightloc,h); % right pin
734 trid(2, trht, trbs); fill pth2;
735 z2'=(x2,0); draw z2tic--z2';
736 z11trc=(x1trl,h/2); % hor pins
737 trir(11, trht, trbs); fill pth11;
738 z11'=(x2trr,y11); draw z11tic--z11';
739 z12trc=1/2[z11trc,z11'];
740 trir(12, trht, trbs); fill pth12;
741 labels(1,2,11);
742 endchar;
743
744 cmchar "Old Persian syllable ha (h)";
745 beginglyph("h", (2tb+2wh));
746 z1=(leftloc,h/2); % left wing
747 wingl(1, wiht, wibs); fill pth1;
748 z2=(rightloc-wiht,y1); % right wing
749 wingl(2, wiht, wibs); fill pth2;
750 z11trr=(x1wil,y1); % top pin
751 trir(11, trht, trbs); fill pth11;
752 z11'=(x2,y11); draw z11tic--z11';
753 z12trl=z11trr; % bottom pin
754 trir(12, trht, trbs); fill pth12;
755 z12'=(x2,y12); draw z12tic--z12';
756 labels(1,2,11,12);
757 endchar;
758
759 cmchar "Old Persian word: king (X)";
760 beginglyph("X", (3tb+2wh));
761 z4=(rightloc-wiht, h/2); % right wing
762 wingl(4, wiht, wibs); fill pth4;
763 z11trc=(x4,h); % center vert pin
764 trid(11, trht, trbs); fill pth11;
765 z11'=(x11,0); draw z11tic--z11';
766 z3wir=(x11trr,y4wir); % left wing
767 wingl(3, wiht, wibs); fill pth3;
768 z1trr=(leftloc,y4); % top pin
769 trir(1, trht, trbs); fill pth1;
770 z1'=(x3,y1); draw z1tic--z1';
771 z2trl=z1trr; % bottom pin
772 trir(2, trht, trbs); fill pth2;
773 z2'=(x1',y2); draw z2tic--z2';
774 labels(1,2,3,4,11);
775 endchar;
776
777 cmchar "Old Persian word: country (version a) (q)";
778 beginglyph("q", (9/4tb+wh)); %% 5/2tb+wh too large
779 numeric n[];
780 n1 := 1/2wiht;
781 n2 := 1/2wibs;
782 z12trl=(rightloc,h); % right pin
783 trid(12, trht, trbs); fill pth12;
784 z12'=(x12,0); draw z12tic--z12';
785 z11trl=z12trr; % left pin
786 trid(11, trht, trbs); fill pth11;
787 z11'=(x11,0); draw z11tic--z11';
788 z1=(leftloc, h-1/2n2); % top left wing
789 wingl(1, n1, n2); fill pth1;
790 z2=(x1wil, y1); % top right wing
791 wingl(2, n1, n2); fill pth2;
792 z3=(x1, 1/2n2); % bottom left wing
793 wingl(3, n1, n2); fill pth3;
794 z4=(x2, y3); % bottom right wing
795 wingl(4, n1, n2); fill pth4;
796 labels(1,2,3,4,11,12);
797 endchar;
798
799 cmchar "Old Persian word: country (version b) (Q)";
800 beginglyph("Q", (5/4tb+wh)); %% 3/2tb+wh too large
801 numeric n[];
802 n1 := 1/2wiht;
803 n2 := 1/2wibs;
804 z11trl=(rightloc,h); % right pin
805 trid(11, trht, trbs); fill pth11;
806 z11'=(x11,0); draw z11tic--z11';
807 z1=(leftloc, h-1/2n2); % top left wing
808 wingl(1, n1, n2); fill pth1;
809 z2=(x1wil, y1); % top right wing
810 wingl(2, n1, n2); fill pth2;
811 z3=(x1, 1/2n2); % bottom left wing
812 wingl(3, n1, n2); fill pth3;
813 z4=(x2, y3); % bottom right wing
814 wingl(4, n1, n2); fill pth4;
815 labels(1,2,3,4,11,12);
816 endchar;
817
818 cmchar "Old Persian word: earth (L)";
819 beginglyph("L", (3wh));
820 z1=(leftloc, wiht); % left wing
821 wingl(1, wiht, wibs); fill pth1;
822 z2=(x1wil, y1); % center wing
823 wingl(2, wiht, wibs); fill pth2;
824 z3=(x2wil, y1); % right wing
825 wingl(3, wiht, wibs); fill pth3;
826 z11trr=(x1,y1wir); % top pin
827 trir(11, trht, trbs); fill pth11;
828 z11'=(rightloc,y11); draw z11tic--z11';
829 z12trc=(x2,y11);
830 trir(12, trht, trbs); fill pth12;
831 z13trc=(x3,y11);
832 trir(13, trht, trbs); fill pth13;
833 labels(1,2,3,11,12,13);
834 endchar;
835
836 cmchar "Old Persian word: god (B)";
837 beginglyph("B", (2tb+2wh));
838 z4=(rightloc-wiht, h/2); % right wing
839 wingl(4, wiht, wibs); fill pth4;
840 z3=(x4-wiht, y4); % left wing
841 wingl(3, wiht, wibs); fill pth3;
842 z1trc=(leftloc,y4); % pin
843 trir(1, trht, trbs); fill pth1;
844 z1'=z3; draw z1tic--z1';
845 z2trc=1/2[z1trc,z1'];
846 trir(2, trht, trbs); fill pth2;
847 labels(1,2,3,4);
848 endchar;
849
850 cmchar "Old Persian word: Auramazda (version a) (e)";
851 beginglyph("e", (3tb+wh));
852 z43=(rightloc-wiht, h/2); % wing
853 wingl(43, wiht, wibs); fill pth43;
854 z46trc=(x43,h); % vert pin
855 trid(46, trht, trbs); fill pth46;
856 z46'=(x46,0); draw z46tic--z46';
857 z14trr=(leftloc,h/2); % pin 3
858 trir(14, trht, trbs); fill pth14;
859 z14'=(x46,y14); draw z14tic--z14';
860 z24trc=1/2[z14trc,z14']; z34trc=2/3[z14trc,z14'];
861 trir(24, trht, trbs); fill pth24;
862
863 z12trl=z14trr; % pin 2
864 trir(12, trht, trbs); fill pth12;
865 z12'=(x46,y12); draw z12tic--z12';
866 z22=(x24,y12); z32=(x34,y12);
867 trir(22, trht, trbs); fill pth22;
868
869 labels(12,14,21,22,23,24,25,31,32,33,34,35,41,42,43,44,45,46);
870 endchar;
871
872 cmchar "Old Persian word: Auramazda (version b) (E)";
873 beginglyph("E", (4tb));
874 %% z43=(rightloc-wiht, h/2); % wing
875 %% wingl(43, wiht, wibs); fill pth43;
876 z46trc=(rightloc,h+trht); % vert pin
877 trid(46, trht, trbs); fill pth46;
878 z46'=(x46,-1/2trbs); draw z46tic--z46';
879 z14trr=(leftloc,h/2); % pin 3
880 trir(14, trht, trbs); fill pth14;
881 z14'=(x46,y14); draw z14tic--z14';
882 z24trc=1/3[z14trc,z14']; z34trc=2/3[z14trc,z14'];
883 trir(24, trht, trbs); fill pth24;
884 trir(34, trht, trbs); fill pth34;
885
886 z12trl=z14trr; % pin 2
887 trir(12, trht, trbs); fill pth12;
888 z12'=(x46,y12); draw z12tic--z12';
889 z22=(x24,y12); z32=(x34,y12);
890 trir(22, trht, trbs); fill pth22;
891 trir(32, trht, trbs); fill pth32;
892
893 z21trl=(x24trc, y12trr); % pin 1
894 trir(21, trht, trbs); fill pth21;
895 z21'=(x46,y21); draw z21tic--z21';
896 z31=(x34,y21);
897 trir(31, trht, trbs); fill pth31;
898
899 z25trr=(x24trc, y14trl); % pin 4
900 trir(25, trht, trbs); fill pth25;
901 z25'=(x46,y25); draw z25tic--z25';
902 z35=(x34,y25);
903 trir(35, trht, trbs); fill pth35;
904 labels(12,14,21,22,23,24,25,31,32,33,34,35,41,42,43,44,45,46);
905 endchar;
906
907 cmchar "Old Persian word: Auramazda (version c) (F)";
908 beginglyph("F", (4tb+wh));
909 z43=(rightloc-wiht, h/2); % wing
910 wingl(43, wiht, wibs); fill pth43;
911 z46trc=(x43,h+trht); % vert pin
912 trid(46, trht, trbs); fill pth46;
913 z46'=(x46,-1/2trbs); draw z46tic--z46';
914 z14trr=(leftloc,y43); % pin 3
915 trir(14, trht, trbs); fill pth14;
916 z14'=(x46,y14); draw z14tic--z14';
917 z24trc=1/3[z14trc,z14']; z34trc=2/3[z14trc,z14'];
918 trir(24, trht, trbs); fill pth24;
919 trir(34, trht, trbs); fill pth34;
920
921 z12trl=z14trr; % pin 2
922 trir(12, trht, trbs); fill pth12;
923 z12'=(x46,y12); draw z12tic--z12';
924 z22=(x24,y12); z32=(x34,y12);
925 trir(22, trht, trbs); fill pth22;
926 trir(32, trht, trbs); fill pth32;
927
928 z21trl=(x24trc, y12trr); % pin 1
929 trir(21, trht, trbs); fill pth21;
930 z21'=(x46,y21); draw z21tic--z21';
931 z31=(x34,y21);
932 trir(31, trht, trbs); fill pth31;
933
934 z25trr=(x24trc, y14trl); % pin 4
935 trir(25, trht, trbs); fill pth25;
936 z25'=(x46,y25); draw z25tic--z25';
937 z35=(x34,y25);
938 trir(35, trht, trbs); fill pth35;
939 labels(12,14,21,22,23,24,25,31,32,33,34,35,41,42,43,44,45,46);
940 endchar;
941
942 cmchar "Old Persian numeral 1 (1)";
943 beginglyph("1", (tb));
944 z1trc=(midloc,h);
945 trid(1, trht, trbs); fill pth1;
946 z1'=(x1,0); draw z1tic--z1';
947 labels(1,2);
948 endchar;
949
950 cmchar "Old Persian numeral 2 (2)";
951 beginglyph("2", (tb));
952 z1trc=(midloc,h);
953 trid(1, trht, trbs); fill pth1;
954 z1'=(x1,0); draw z1tic--z1';
955 z2trc=1/2[z1trc,z1'];
956 trid(2, trht, trbs); fill pth2;
957 labels(1,2);
958 endchar;
959
960 cmchar "Old Persian numeral 10 (3)";
961 beginglyph("3", (wh));
962 z1=(leftloc,h/2);
963 wingl(1, wiht, wibs); fill pth1;
964 labels(1,2);
965 endchar;
966
967 cmchar "Old Persian numeral 20 (4)";
968 beginglyph("4", (1/2wh));
969 z1=(leftloc,3/4h);
970 wingl(1, 1/2wiht, 1/2wibs); fill pth1;
971 z2=(leftloc,1/4h);
972 wingl(2, 1/2wiht, 1/2wibs); fill pth2;
973 labels(1,2);
974 endchar;
975
976 cmchar "Old Persian numeral 100 (5)";
977 beginglyph("5", (tb+2th));
978 z1trl=(leftloc,h); % top pins
979 trir(1, trht, trbs); fill pth1;
980 z2trr=(rightloc,h);
981 tril(2, trht, trbs); fill pth2;
982 draw z1tic--z2tic;
983 z11trc=(1/2[x1,x2],y1trr); % vertical pin
984 trid(11, trht, trbs); fill pth11;
985 z11'=(x11,0); draw z11tic--z11';
986 labels(1,2,11);
987 endchar;
988
989 cmchar "Old Persian word divider (:)";
990 beginglyph(":", (3tb));
991 numeric alpha;
992 alpha := trbs;
993 z1=(leftloc+alpha, h-alpha);
994 z2=(rightloc-alpha, alpha);
995 triangle(1, trht, trbs, angle((z2-z1)));
996 fill pth1; draw z1tic--z2;
997 labels(1,2);
998 endchar;
999
1000 end
1001