Debian Codegraph @

texmf-dist/doc/metapost/mp3d/gutmp4.mp

raw
1 % D. Roegel, 7 January 2001
2 % [email protected]
3
4 verbatimtex
5 %&latex
6 \documentclass{article}
7 \usepackage{mathpple}
8 \begin{document}
9 etex
10
11 input 3danim
12 input 3dgeom
13 output_res:=72;
14 drawing_scale:=13cm;
15
16 numeric b,c,d,e;b=70;c=0;d=20;e=50; % parameterized angles
17
18 vardef def_T(expr inst)=
19 new_obj_points(inst,10); % 10 points
20 set_T_points(inst);
21 enddef;
22
23 vardef set_T_points(expr inst)=
24 set_point(1)(0,0,0);
25 set_point(2)(3*cosd(b),3*sind(b),0);
26 set_point(3)(6*cosd(c),6*sind(c),0);
27 new_vec(v_a);new_vec(v_b);
28 vec_def_vec_(v_a,vec_I);
29 vec_rotate_(v_a,vec_K,d);
30 vec_prod_(v_b,v_a,vec_K);
31 vec_rotate_(v_a,v_b,e);
32 vec_mult_(v_a,v_a,4.5);
33 vec_sum_(pnt(4),pnt(1),v_a);
34 free_vec(v_b);free_vec(v_a);
35 % Determination of I and J:
36 % I=A + unit(AB)
37 vec_diff(5,2,1);
38 vec_unit(5,5);
39 vec_sum(5,5,1);
40 % J=A + 4*unit(AC)
41 vec_diff(6,3,1);
42 vec_unit(6,6);
43 vec_mult(6,6,4);
44 vec_sum(6,6,1);
45 new_plane(bcd)(2,3,4);
46 new_line(ij)(5,6);
47 boolean b;
48 b:=def_inter_p_l_pl(7)(ij)(bcd); if not b: ... fi;
49 % K=middle of AD
50 mid_point(8,1,4);
51 set_line(ij)(5,8);
52 b:=def_inter_p_l_pl(9)(ij)(bcd); if not b: ... fi;
53 set_line(ij)(6,8);
54 b:=def_inter_p_l_pl(10)(ij)(bcd); if not b: ... fi;
55 free_line(ij);
56 free_plane(bcd);
57 enddef;
58
59 vardef draw_T(expr inst)=
60 drawoptions(dashed evenly);draw_line(2,4);draw_line(8,5);
61 drawoptions();
62 draw_line(1,2);draw_line(1,3);draw_line(1,4);
63 draw_line(2,3);draw_line(3,4);
64 pickup pencircle scaled 2pt;
65 draw_line(5,5);draw_line(6,6);draw_line(7,7);draw_line(8,8);
66 draw_line(9,9);draw_line(10,10);
67 pickup pencircle scaled .4pt;
68 draw_line(5,7);draw_line(3,7);
69 draw_line(8,9);draw_line(4,9);
70 draw_line(8,10);draw_line(3,10);
71 draw_line_extra(9,10)(-0.1,1.1);
72 label_obj.top(btex $A_1$ etex,1);
73 label_obj.lft(btex $B_2$ etex,2);
74 label_obj.llft(btex $C_3$ etex,3) shifted (-2.5mm,1mm);
75 label_obj.top(btex $D_4$ etex,4);
76 label_obj.lft(btex $I_5$ etex,5);
77 label_obj.lft(btex $J_6$ etex,6) shifted (-2mm,0);
78 label_obj.lrt(btex $M_7$ etex,7);
79 label_obj.urt(btex $K_8$ etex,8);
80 label_obj.lrt(btex $N_9$ etex,9);
81 label_obj.lrt(btex $L_{10}$ etex,10);
82
83 enddef;
84
85 assign_obj("tetra","T");
86
87 new_vec(v_a);new_vec(v_b);new_vec(v_c);
88 vec_diff_(v_a,pnt_obj("tetra",3),pnt_obj("tetra",4)); % vec(DC)
89 vec_mult_(v_a,v_a,5);
90 vec_diff_(v_b,pnt_obj("tetra",3),pnt_obj("tetra",2)); % vec(BC)
91 vec_mult_(v_b,v_b,5);
92 vec_diff_(v_c,pnt_obj("tetra",1),pnt_obj("tetra",3)); % vec(CA)
93 vec_mult_(v_c,v_c,3);
94 vec_sum_(Obs,pnt_obj("tetra",3),v_a); % C + 5DC
95 vec_sum_(Obs,Obs,v_b);% C + 5DC + 5BC
96 vec_sum_(Obs,Obs,v_c);% C + 5DC + 5BC + 3CA
97 free_vec(v_c);free_vec(v_b);free_vec(v_a);
98
99 %for i:=0 upto 20:
100 i=8;
101 beginfig(200+i);
102 % Observator
103 %set_point_(Obs)(20*cosd(3.6*i),20*sind(3.6*i),6);
104 Obs_phi:=0;Obs_dist:=2;point_of_view_obj("tetra",1,Obs_phi);
105 draw_obj("tetra");
106 endfig;
107 %endfor;
108
109 end.
110
111
112
113