Debian Codegraph @

texmf-dist/doc/metapost/mp3d/gutmp2.mp

raw
1 % D. Roegel, 7 January 2001
2 % [email protected]
3
4 verbatimtex
5 %&latex
6 \documentclass{article}
7 \usepackage{mathpple}
8 \begin{document}
9 etex
10
11 input 3danim
12 input 3dgeom
13 output_res:=72;
14 drawing_scale:=13cm;
15
16 numeric b,c,d,e;b=70;c=0;d=20;e=50; % parameterized angles
17
18 vardef def_T(expr inst)=
19 new_obj_points(inst,6); % 6 points
20 set_T_points(inst);
21 enddef;
22
23 vardef set_T_points(expr inst)=
24 set_point(1)(0,0,0);
25 set_point(2)(3*cosd(b),3*sind(b),0);
26 set_point(3)(6*cosd(c),6*sind(c),0);
27 new_vec(v_a);new_vec(v_b);
28 vec_def_vec_(v_a,vec_I);
29 vec_rotate_(v_a,vec_K,d);
30 vec_prod_(v_b,v_a,vec_K);
31 vec_rotate_(v_a,v_b,e);
32 vec_mult_(v_a,v_a,4.5);
33 vec_sum_(pnt(4),pnt(1),v_a);
34 free_vec(v_b);free_vec(v_a);
35 % Determination of I and J:
36 % I=A + unit(AB)
37 vec_diff(5,2,1);
38 vec_unit(5,5);
39 vec_sum(5,5,1);
40 % J=A + 4*unit(AC)
41 vec_diff(6,3,1);
42 vec_unit(6,6);
43 vec_mult(6,6,4);
44 vec_sum(6,6,1);
45
46 enddef;
47
48 vardef draw_T(expr inst)=
49 drawoptions(dashed evenly);draw_line(2,4);drawoptions();
50 draw_line(1,2);draw_line(1,3);draw_line(1,4);
51 draw_line(2,3);draw_line(3,4);
52 pickup pencircle scaled 2pt;
53 draw_line(5,5);draw_line(6,6);
54 label_obj.top(btex $A_1$ etex,1);
55 label_obj.lft(btex $B_2$ etex,2);
56 label_obj.bot(btex $C_3$ etex,3);
57 label_obj.rt(btex $D_4$ etex,4);
58 label_obj.lft(btex $I_5$ etex,5);
59 label_obj.urt(btex $J_6$ etex,6);
60
61 enddef;
62
63 assign_obj("tetra","T");
64
65 new_vec(v_a);new_vec(v_b);new_vec(v_c);
66 vec_diff_(v_a,pnt_obj("tetra",3),pnt_obj("tetra",4)); % vec(DC)
67 vec_mult_(v_a,v_a,5);
68 vec_diff_(v_b,pnt_obj("tetra",3),pnt_obj("tetra",2)); % vec(BC)
69 vec_mult_(v_b,v_b,5);
70 vec_diff_(v_c,pnt_obj("tetra",1),pnt_obj("tetra",3)); % vec(CA)
71 vec_mult_(v_c,v_c,3);
72 vec_sum_(Obs,pnt_obj("tetra",3),v_a); % C + 5DC
73 vec_sum_(Obs,Obs,v_b);% C + 5DC + 5BC
74 vec_sum_(Obs,Obs,v_c);% C + 5DC + 5BC + 3CA
75 free_vec(v_c);free_vec(v_b);free_vec(v_a);
76
77 %for i:=0 upto 20:
78 i=8;
79 beginfig(200+i);
80 % Observator
81 %set_point_(Obs)(20*cosd(3.6*i),20*sind(3.6*i),6);
82 Obs_phi:=0;Obs_dist:=2;point_of_view_obj("tetra",1,Obs_phi);
83 draw_obj("tetra");
84 endfig;
85 %endfor;
86
87 end.
88
89
90
91