Debian Codegraph @

src/nspawn/meson.build

raw
1 # SPDX-License-Identifier: LGPL-2.1-or-later
2
3 if conf.get('ENABLE_NSPAWN') != 1
4 subdir_done()
5 endif
6
7 nspawn_sources = files(
8 'nspawn.c',
9 'nspawn-bind-user.c',
10 'nspawn-cgroup.c',
11 'nspawn-register.c',
12 'nspawn-seccomp.c',
13 'nspawn-setuid.c',
14 'nspawn-stub-pid1.c',
15 )
16 nspawn_extract_sources = files(
17 'nspawn-expose-ports.c',
18 'nspawn-mount.c',
19 'nspawn-network.c',
20 'nspawn-oci.c',
21 'nspawn-settings.c',
22 )
23
24 nspawn_gperf_c = custom_target(
25 input : 'nspawn-gperf.gperf',
26 output : 'nspawn-gperf.c',
27 command : [gperf, '@INPUT@', '--output-file', '@OUTPUT@'])
28
29 generated_sources += nspawn_gperf_c
30 nspawn_extract_sources += nspawn_gperf_c
31
32 nspawn_common_template = {
33 'dependencies' : libseccomp_cflags,
34 'objects' : ['systemd-nspawn'],
35 }
36 nspawn_test_template = test_template + nspawn_common_template
37 nspawn_fuzz_template = fuzz_template + nspawn_common_template
38
39 executables += [
40 executable_template + {
41 'name' : 'systemd-nspawn',
42 'public' : true,
43 'sources' : nspawn_sources,
44 'extract' : nspawn_extract_sources,
45 'include_directories' : [
46 include_directories('.'),
47 executable_template['include_directories'],
48 ],
49 'dependencies' : [
50 libmount_cflags,
51 libseccomp_cflags,
52 libselinux_cflags,
53 ],
54 },
55 nspawn_test_template + {
56 'sources' : files('test-nspawn-tables.c'),
57 },
58 nspawn_fuzz_template + {
59 'sources' : files('fuzz-nspawn-settings.c'),
60 },
61 nspawn_fuzz_template + {
62 'sources' : files('fuzz-nspawn-oci.c'),
63 },
64 ]