Debian Codegraph @

ports/cmake/src/CMakeLists.txt

raw
1 cmake_minimum_required(VERSION 3.12)
2
3 include(CheckCSourceCompiles)
4 include(CheckFunctionExists)
5 include(CheckIncludeFile)
6 include(CheckIncludeFiles)
7 include(CheckSymbolExists)
8 include(CheckTypeSize)
9 include(CMakeDependentOption)
10 include(TestBigEndian)
11
12 option(PORTABLE_API "Only build portable library API (no off_t, no internal I/O." OFF)
13
14 check_include_file("arpa/inet.h" HAVE_ARPA_INET_H)
15 check_include_file("dirent.h" HAVE_DIRENT_H)
16 check_include_file("dlfcn.h" HAVE_DLFCN_H)
17 check_include_file("langinfo.h" HAVE_LANGINFO_H)
18 check_include_file("locale.h" HAVE_LOCALE_H)
19 check_include_file("netdb.h" HAVE_NETDB_H)
20 check_include_file("netinet/in.h" HAVE_NETINET_IN_H)
21 check_include_file("sched.h" HAVE_SCHED_H)
22 check_include_file("signal.h" HAVE_SIGNAL_H)
23 check_include_file("strings.h" HAVE_STRINGS_H)
24 check_include_file("sys/ioctl.h" HAVE_SYS_IOCTL_H)
25 check_include_file("sys/ipc.h" HAVE_SYS_IPC_H)
26 check_include_file("sys/param.h" HAVE_SYS_PARAM_H)
27 check_include_file("sys/resource.h" HAVE_SYS_RESOURCE_H)
28 check_include_file("sys/select.h" HAVE_SYS_SELECT_H)
29 check_include_file("sys/shm.h" HAVE_SYS_SHM_H)
30 check_include_file("sys/signal.h" HAVE_SYS_SIGNAL_H)
31 check_include_file("sys/socket.h" HAVE_SYS_SOCKET_H)
32 check_include_file("sys/stat.h" HAVE_SYS_STAT_H)
33 check_include_file("sys/time.h" HAVE_SYS_TIME_H)
34 check_include_file("sys/types.h" HAVE_SYS_TYPES_H)
35 check_include_file("sys/wait.h" HAVE_SYS_WAIT_H)
36 check_include_file("termios.h" HAVE_TERMIOS)
37 check_include_file("unistd.h" HAVE_UNISTD_H)
38 check_include_file("windows.h" HAVE_WINDOWS_H)
39 function(check_m)
40 set(CMAKE_REQUIRED_LIBRARIES m)
41 check_function_exists(sin HAVE_M)
42 endfunction(check_m)
43 check_m()
44 # Cargo coding the check if there is a library rt, possibly providing
45 # a canary symbol. I am not sure if this logic really mirrors what
46 # autotools does.
47 function(check_rt)
48 set(CMAKE_REQUIRED_LIBRARIES rt)
49 check_function_exists(clock_gettime HAVE_RT)
50 endfunction(check_rt)
51 check_rt()
52
53 check_function_exists(atoll HAVE_ATOLL)
54 check_function_exists(getaddrinfo HAVE_IPV6)
55 check_function_exists(mkfifo HAVE_MKFIFO)
56 check_function_exists(mmap HAVE_MMAP)
57 check_function_exists(nl_langinfo HAVE_NL_LANGINFO)
58 check_function_exists(random HAVE_RANDOM)
59 check_function_exists(setenv HAVE_SETENV)
60 check_function_exists(unsetenv HAVE_UNSETENV)
61 check_function_exists(setlocale HAVE_SETLOCALE)
62 check_function_exists(uselocale HAVE_USELOCALE)
63 check_function_exists(setpriority HAVE_SETPRIORITY)
64 check_function_exists(shmget HAVE_SHMGET)
65 check_function_exists(shmat HAVE_SHMAT)
66 check_function_exists(shmdt HAVE_SHMDT)
67 check_function_exists(shmctl HAVE_SHMCTL)
68 check_function_exists(strerror HAVE_STRERROR)
69 check_function_exists(strerror_l HAVE_STRERROR_L)
70 check_function_exists(strtok_r HAVE_STRTOK_R)
71 check_function_exists(strtok_s HAVE_STRTOK_S)
72 check_function_exists(fork HAVE_FORK)
73 check_function_exists(execvp HAVE_EXECVP)
74 check_function_exists(ctermid HAVE_CTERMID)
75 check_function_exists(clock_gettime HAVE_CLOCK_GETTIME)
76
77 check_type_size(off_t MPG123_SIZEOF_OFF_T)
78
79 if(MPG123_SIZEOF_OFF_T LESS 8)
80 check_function_exists(lseek64 LFS_LARGEFILE_64)
81
82 if(LFS_LARGEFILE_64)
83 check_c_source_compiles(
84 " #define _LARGEFILE64_SOURCE
85 #include <sys/types.h>
86 #include <sys/stat.h>
87 #include <unistd.h>
88 #include <fcntl.h>
89
90 int main(){ return open(\"/foo\", O_RDONLY|O_LARGEFILE); }
91 " HAVE_O_LARGEFILE)
92 endif()
93 endif()
94
95 search_libs(gethostbyname GETHOSTBYNAME_LIB nsl socket network)
96 search_libs(socket SOCKET_LIB socket)
97
98 test_big_endian(WORDS_BIGENDIAN)
99
100 check_c_source_compiles(
101 "int main() { __asm__(\".balign 4\"); return 0; }"
102 ASMALIGN_BALIGN)
103 check_c_source_compiles(
104 "int main() { __asm__(\".align 3\"); return 0; }"
105 ASMALIGN_EXP)
106 if(NOT ASMALIGN_EXP)
107 set(ASMALIGN_BYTE ON)
108 endif()
109
110 check_c_source_compiles(
111 "int main() { __attribute__((aligned(16))) float var; return 0; }"
112 CCALIGN)
113
114 if(NOT LFS_INSENSITIVE)
115 check_c_source_compiles("
116 #include <sys/types.h>
117 /* Check that off_t can represent 2**63 - 1 correctly.
118 We can't simply define LARGE_OFF_T to be 9223372036854775807,
119 since some C++ compilers masquerading as C compilers
120 incorrectly reject 9223372036854775807. */
121 #define LARGE_OFF_T (((off_t) 1 << 62) - 1 + ((off_t) 1 << 62))
122 int off_t_is_large[
123 (LARGE_OFF_T % 2147483629 == 721 && LARGE_OFF_T % 2147483647 == 1) ? 1 : -1];
124 int main() { return 0; }"
125 LFS_INSENSITIVE)
126 endif()
127 if(NOT LFS_INSENSITIVE)
128 check_c_source_compiles("
129 #define _FILE_OFFSET_BITS 64
130 #include <sys/types.h>
131 /* Check that off_t can represent 2**63 - 1 correctly.
132 We can't simply define LARGE_OFF_T to be 9223372036854775807,
133 since some C++ compilers masquerading as C compilers
134 incorrectly reject 9223372036854775807. */
135 #define LARGE_OFF_T (((off_t) 1 << 62) - 1 + ((off_t) 1 << 62))
136 int off_t_is_large[
137 (LARGE_OFF_T % 2147483629 == 721 && LARGE_OFF_T % 2147483647 == 1) ? 1 : -1];
138 int main() { return 0; }"
139 LFS_SENSITIVE)
140 endif()
141
142 if(WIN32 AND HAVE_WINDOWS_H)
143 check_function_exists(GetThreadErrorMode HAVE_GETTHREADERRORMODE)
144 if(HAVE_GETTHREADERRORMODE)
145 check_c_source_compiles("
146 #include <windows.h>
147
148 int main() {
149 LoadLibraryW(0);
150 GetProcAddress(0, 0);
151 FreeLibrary(0);
152 }"
153 HAVE_WIN_DL)
154 else()
155 set(HAVE_WIN_DL OFF)
156 endif()
157 else()
158 function(check_dl)
159 set(CMAKE_REQUIRED_LIBRARIES dl)
160 check_symbol_exists(dlopen "dlfcn.h" HAVE_UNIX_DL)
161 endfunction(check_dl)
162 check_dl()
163 endif()
164
165 set(DYNAMIC_BUILD ${BUILD_SHARED_LIBS})
166 if(MSVC)
167 set(STDERR_FILENO "(_fileno(stderr))")
168 set(STDIN_FILENO "(_fileno(stdin))")
169 set(STDOUT_FILENO "(_fileno(stdout))")
170 endif()
171 set(HAVE_WIN32_FIFO ${WIN32})
172 set(WANT_WIN32_UNICODE ${WIN32})
173 set(WITH_SEEKTABLE 1000)
174
175 if(NOT WITH_SEEKTABLE EQUAL 0)
176 set(FRAME_INDEX 1)
177 endif()
178
179 if(WIN32)
180 set(HAVE_MKFIFO ON)
181 endif()
182
183 if(HAVE_NETDB_H AND HAVE_SYS_PARAM_H AND HAVE_SYS_SOCKET_H AND HAVE_NETINET_IN_H AND HAVE_ARPA_INET_H)
184 set(HAVE_NETWORK ON)
185 endif()
186
187 if(NO_MESSAGES)
188 set(NO_WARNING ON)
189 set(NO_ERRORMSG ON)
190 set(NO_ERETURN ON)
191 endif()
192
193 include(../cmake/CheckCPUArch.cmake)
194 check_cpu_arch_x86(ARCH_IS_X86)
195 check_cpu_arch_x64(ARCH_IS_X64)
196 check_cpu_arch_arm32(ARCH_IS_ARM32)
197 check_cpu_arch_arm64(ARCH_IS_ARM64)
198
199 if(WIN32 OR (ARCH_IS_ARM64 AND APPLE))
200 set(HAVE_FPU 1)
201 else()
202 cmake_host_system_information(RESULT HAVE_FPU QUERY HAS_FPU)
203 endif()
204
205 if(NOT HAVE_FPU)
206 set(NO_SYNTH32 ON)
207 endif()
208
209 # Modules
210
211 if(BUILD_LIBOUT123)
212 if(CHECK_MODULES)
213 list(FIND CHECK_MODULES alsa ALSA_REQUIRED)
214 list(FIND CHECK_MODULES coreaudio COREAUDIO_REQUIRED)
215 list(FIND CHECK_MODULES pulse PULSE_REQUIRED)
216 list(FIND CHECK_MODULES jack JACK_REQUIRED)
217 list(FIND CHECK_MODULES tinyalsa TINYALSA_REQUIRED)
218 list(FIND CHECK_MODULES win32 WIN32_REQUIRED)
219 list(FIND CHECK_MODULES win32_wasapi WIN32_WASAPI_REQUIRED)
220 set(MODULE_NOT_FOUND_MESSAGE "module required but couldn't be found")
221 endif()
222
223 if(NOT CHECK_MODULES OR NOT ALSA_REQUIRED EQUAL -1)
224 find_package(ALSA)
225 if(TARGET ALSA::ALSA)
226 list(APPEND OUTPUT_MODULES alsa)
227 elseif(CHECK_MODULES AND NOT ALSA_REQUIRED EQUAL -1)
228 message(FATAL_ERROR "alsa ${MODULE_NOT_FOUND_MESSAGE}")
229 endif()
230 endif()
231
232 if(NOT CHECK_MODULES OR NOT COREAUDIO_REQUIRED EQUAL -1)
233 if(APPLE)
234 find_library(AUDIO_TOOLBOX AudioToolbox)
235 list(APPEND OUTPUT_MODULES coreaudio)
236 elseif(CHECK_MODULES AND NOT COREAUDIO_REQUIRED EQUAL -1)
237 message(FATAL_ERROR "coreaudio ${MODULE_NOT_FOUND_MESSAGE}")
238 endif()
239 endif()
240
241 find_package(PkgConfig)
242 if(PKG_CONFIG_FOUND)
243 if(NOT CHECK_MODULES OR NOT PULSE_REQUIRED EQUAL -1)
244 pkg_search_module(PULSE libpulse-simple)
245 if(PULSE_FOUND)
246 list(APPEND OUTPUT_MODULES pulse)
247 elseif(CHECK_MODULES AND NOT PULSE_REQUIRED EQUAL -1)
248 message(FATAL_ERROR "pulse ${MODULE_NOT_FOUND_MESSAGE}")
249 endif()
250 endif()
251
252 if(NOT CHECK_MODULES OR NOT JACK_REQUIRED EQUAL -1)
253 pkg_search_module(JACK jack)
254 if(JACK_FOUND)
255 list(APPEND OUTPUT_MODULES jack)
256 elseif(CHECK_MODULES AND NOT JACK_REQUIRED EQUAL -1)
257 message(FATAL_ERROR "jack ${MODULE_NOT_FOUND_MESSAGE}")
258 endif()
259 endif()
260
261 if(NOT CHECK_MODULES OR NOT TINYALSA_REQUIRED EQUAL -1)
262 pkg_search_module(TINYALSA tinyalsa)
263 if(TINYALSA_FOUND)
264 list(APPEND OUTPUT_MODULES tinyalsa)
265 elseif(CHECK_MODULES AND NOT TINYALSA_REQUIRED EQUAL -1)
266 message(FATAL_ERROR "tinyalsa ${MODULE_NOT_FOUND_MESSAGE}")
267 endif()
268 endif()
269 endif()
270
271 if(NOT CHECK_MODULES OR NOT WIN32_REQUIRED EQUAL -1)
272 if(HAVE_WINDOWS_H)
273 set(WIN32_LIBRARIES winmm)
274 list(APPEND OUTPUT_MODULES win32)
275 elseif(CHECK_MODULES AND NOT WIN32_REQUIRED EQUAL -1)
276 message(FATAL_ERROR "win32 ${MODULE_NOT_FOUND_MESSAGE}")
277 endif()
278 endif()
279
280 if(NOT CHECK_MODULES OR NOT WIN32_WASAPI_REQUIRED EQUAL -1)
281 set(WASAPI_INCLUDES "initguid.h" "audioclient.h" "mmdeviceapi.h" "avrt.h")
282 check_include_files("${WASAPI_INCLUDES}" HAVE_WASAPI)
283 if(HAVE_WASAPI)
284 set(WIN32_WASAPI_LIBRARIES ole32 avrt)
285 list(APPEND OUTPUT_MODULES win32_wasapi)
286 elseif(CHECK_MODULES AND NOT WIN32_WASAPI_REQUIRED EQUAL -1)
287 message(FATAL_ERROR "win32_wasapi ${MODULE_NOT_FOUND_MESSAGE}")
288 endif()
289 endif()
290
291 if(CHECK_MODULES)
292 list(REMOVE_AT CHECK_MODULES
293 ${ALSA_REQUIRED}
294 ${COREAUDIO_REQUIRED}
295 ${PULSE_REQUIRED}
296 ${JACK_REQUIRED}
297 ${TINYALSA_REQUIRED}
298 ${WIN32_REQUIRED}
299 ${WIN32_WASAPI_REQUIRED})
300 list(LENGTH CHECK_MODULES CHECK_MODULES_LENGTH)
301 if(NOT CHECK_MODULES_LENGTH EQUAL 0)
302 message(FATAL_ERROR "Dunno how to find modules: ${CHECK_MODULES}")
303 endif()
304 endif()
305
306 if(NOT OUTPUT_MODULES)
307 set(DEFAULT_OUTPUT_MODULE dummy)
308 set(DEFAULT_OUTPUT_MODULES ${DEFAULT_OUTPUT_MODULE})
309 else()
310 list(GET OUTPUT_MODULES 0 _DEFAULT_OUTPUT_MODULE)
311 set(DEFAULT_OUTPUT_MODULE ${_DEFAULT_OUTPUT_MODULE} CACHE STRING "Default output module")
312 if(BUILD_SHARED_LIBS)
313 string(REPLACE ";" "," DEFAULT_OUTPUT_MODULES "${OUTPUT_MODULES}")
314 else()
315 set(DEFAULT_OUTPUT_MODULES ${DEFAULT_OUTPUT_MODULE})
316 endif()
317 set_property(CACHE DEFAULT_OUTPUT_MODULE PROPERTY STRINGS ${OUTPUT_MODULES})
318 endif()
319 endif()
320
321 option(ACCURATE_ROUNDING "use rounding instead of fast truncation for integer output, where possible" ON)
322 cmake_dependent_option(FIFO "FIFO support for control interface" ON "HAVE_MKFIFO" OFF)
323 option(GAPLESS "enable gapless" ON)
324 option(IEEE_FLOAT "use special hackery relying on IEEE 754 floating point storage format (to accurately round to 16 bit integer at bit more efficiently in generic decoder, enabled by default, disable in case you have a very special computer)" ON)
325 cmake_dependent_option(IPV6 "IPv6 support (actually any protocol your libc does with getaddrinfo)" ON "HAVE_IPV6" OFF)
326 if(CMAKE_C_COMPILER_ID MATCHES "GNU|Clang")
327 option(NAGGING "turn on GCC's pedantic nagging with error on warnings" OFF)
328 if(NAGGING)
329 set(CMAKE_C_STANDARD 99)
330 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Wall -Werror -pedantic")
331 endif()
332 endif()
333 cmake_dependent_option(NETWORK "network support (http streams / webradio)" ON "HAVE_NETWORK" OFF)
334 option(NEWOLD_WRITE_SAMPLE "enable new/old WRITE_SAMPLE macro for non-accurate 16 bit output, faster on certain CPUs (default on on x86-32)" OFF)
335 cmake_dependent_option(NO_BUFFER "enable audio buffer code (default uses system whitelist... proper checks later)" OFF "HAVE_MMAP OR HAVE_SYS_IPC_H AND HAVE_SYS_SHM_H AND HAVE_SHMGET AND HAVE_SHMAT AND HAVE_SHMDT AND HAVE_SHMCTL" ON)
336 option(NO_DOWNSAMPLE "no downsampled decoding" OFF)
337 option(NO_EQUALIZER "no equalizer support" OFF)
338 option(NO_FEEDER "no feeder decoding, no buffered readers" OFF)
339 option(NO_ICY "ICY metainfo parsing/conversion" OFF)
340 option(NO_LAYER1 "no layer I decoding" OFF)
341 option(NO_LAYER2 "no layer II decoding" OFF)
342 option(NO_LAYER3 "no layer III decoding" OFF)
343 option(NO_MESSAGES "no error/warning messages on the console" OFF)
344 option(NO_MOREINFO "no extra information for frame analyzers" OFF)
345 option(NO_NTOM "no flexible resampling" OFF)
346 option(NO_16BIT "no 16 bit integer output" OFF)
347 option(NO_32BIT "no 32 bit integer output (also 24 bit)" OFF)
348 cmake_dependent_option(NO_8BIT "no 8 bit integer output" OFF "NOT NO_16BIT" ON)
349 option(NO_REAL "no real (floating point) output" OFF)
350 option(NO_STRING "no string API (this will disable ID3v2; main mpg123 won't build anymore)" OFF)
351 cmake_dependent_option(NO_ID3V2 "no ID3v2 parsing" OFF "NOT NO_STRING" ON)
352 option(SYN123_NO_CASES "include special cases for likely parameter values (channel count, encoding sizes in libsyn123 routines) in the hope of better optimization at the expense of some code bloat (default enabled)" OFF)
353 cmake_dependent_option(USE_MODULES "dynamically loadable output modules" ON "BUILD_SHARED_LIBS;HAVE_WIN_DL OR HAVE_UNIX_DL" OFF)
354 option(USE_NEW_HUFFTABLE "use new huffman decoding scheme by Taihei (faster on modern CPUs at least, so on by default)" ON)
355
356
357 include_directories(
358 "${CMAKE_CURRENT_SOURCE_DIR}/../../../src/"
359 "${CMAKE_CURRENT_BINARY_DIR}"
360 "${CMAKE_CURRENT_SOURCE_DIR}/../../../src/include")
361
362 add_compile_definitions(
363 $<$<BOOL:${WIN32}>:_CRT_SECURE_NO_WARNINGS>
364 $<$<BOOL:${NO_BUFFER}>:NOXFERMEM>
365 $<$<BOOL:${NEWOLD_WRITE_SAMPLE}>:NEWOLD_WRITE_SAMPLE>)
366
367 add_compile_options(
368 $<$<BOOL:${MSVC}>:/wd4996>)
369
370 add_subdirectory("compat")
371 add_subdirectory("libmpg123")
372 if(BUILD_LIBOUT123)
373 add_subdirectory("libout123")
374 endif()
375 add_subdirectory("libsyn123")
376
377 if(UNIX AND NOT PORTABLE_API)
378 option(BUILD_PROGRAMS "Build programs (mpg123 executable and others)" ON)
379
380 if(BUILD_PROGRAMS)
381
382 if(HAVE_FORK AND HAVE_EXECVP AND NETWORK)
383 set(NET123 ON)
384 set(NET123_EXEC ON)
385 endif()
386
387 if(HAVE_TERMIOS)
388 set(TERM_POSIX ON)
389 else()
390 set(TERM_NONE ON)
391 endif()
392
393 add_subdirectory("tests")
394
395 if(BUILD_LIBOUT123)
396 add_executable(${PROJECT_NAME}
397 "${CMAKE_CURRENT_SOURCE_DIR}/../../../src/audio.c"
398 "${CMAKE_CURRENT_SOURCE_DIR}/../../../src/common.c"
399 "${CMAKE_CURRENT_SOURCE_DIR}/../../../src/sysutil.c"
400 "${CMAKE_CURRENT_SOURCE_DIR}/../../../src/control_generic.c"
401 "${CMAKE_CURRENT_SOURCE_DIR}/../../../src/equalizer.c"
402 "${CMAKE_CURRENT_SOURCE_DIR}/../../../src/getlopt.c"
403 "${CMAKE_CURRENT_SOURCE_DIR}/../../../src/httpget.c"
404 "${CMAKE_CURRENT_SOURCE_DIR}/../../../src/resolver.c"
405 $<$<BOOL:${NET123_EXEC}>:${CMAKE_CURRENT_SOURCE_DIR}/../../../src/net123_exec.c>
406 "${CMAKE_CURRENT_SOURCE_DIR}/../../../src/genre.c"
407 "${CMAKE_CURRENT_SOURCE_DIR}/../../../src/mpg123.c"
408 "${CMAKE_CURRENT_SOURCE_DIR}/../../../src/metaprint.c"
409 "${CMAKE_CURRENT_SOURCE_DIR}/../../../src/local.c"
410 "${CMAKE_CURRENT_SOURCE_DIR}/../../../src/playlist.c"
411 "${CMAKE_CURRENT_SOURCE_DIR}/../../../src/streamdump.c"
412 $<$<BOOL:${TERM_POSIX}>:${CMAKE_CURRENT_SOURCE_DIR}/../../../src/term_posix.c>
413 $<$<BOOL:${TERM_NONE}>:${CMAKE_CURRENT_SOURCE_DIR}/../../../src/term_none.c>
414 "${CMAKE_CURRENT_SOURCE_DIR}/../../../src/term.c")
415 target_link_libraries(${PROJECT_NAME} PRIVATE
416 compat
417 lib${PROJECT_NAME}
418 libout123
419 libsyn123
420 ${GETHOSTBYNAME_LIB}
421 ${SOCKET_LIB}
422 $<$<BOOL:${HAVE_M}>:m>)
423
424 add_executable(out123
425 "${CMAKE_CURRENT_SOURCE_DIR}/../../../src/sysutil.c"
426 "${CMAKE_CURRENT_SOURCE_DIR}/../../../src/getlopt.c"
427 "${CMAKE_CURRENT_SOURCE_DIR}/../../../src/filters.c"
428 "${CMAKE_CURRENT_SOURCE_DIR}/../../../src/local.c"
429 "${CMAKE_CURRENT_SOURCE_DIR}/../../../src/out123.c")
430 target_link_libraries(out123 PRIVATE
431 lib${PROJECT_NAME}
432 libout123
433 libsyn123)
434 install(TARGETS ${PROJECT_NAME} out123
435 EXPORT targets
436 ARCHIVE DESTINATION "${CMAKE_INSTALL_LIBDIR}/"
437 LIBRARY DESTINATION "${CMAKE_INSTALL_LIBDIR}/"
438 RUNTIME DESTINATION "${CMAKE_INSTALL_BINDIR}/")
439 endif()
440
441 add_executable(${PROJECT_NAME}-id3dump
442 "${CMAKE_CURRENT_SOURCE_DIR}/../../../src/mpg123-id3dump.c"
443 "${CMAKE_CURRENT_SOURCE_DIR}/../../../src/getlopt.c")
444 target_link_libraries(${PROJECT_NAME}-id3dump PRIVATE
445 lib${PROJECT_NAME})
446
447 add_executable(${PROJECT_NAME}-strip
448 "${CMAKE_CURRENT_SOURCE_DIR}/../../../src/mpg123-strip.c"
449 "${CMAKE_CURRENT_SOURCE_DIR}/../../../src/getlopt.c")
450 target_link_libraries(${PROJECT_NAME}-strip PRIVATE
451 lib${PROJECT_NAME}
452 libsyn123)
453
454 install(TARGETS ${PROJECT_NAME}-id3dump ${PROJECT_NAME}-strip
455 EXPORT targets
456 ARCHIVE DESTINATION "${CMAKE_INSTALL_LIBDIR}/"
457 LIBRARY DESTINATION "${CMAKE_INSTALL_LIBDIR}/"
458 RUNTIME DESTINATION "${CMAKE_INSTALL_BINDIR}/")
459
460 install(
461 FILES
462 "${CMAKE_CURRENT_SOURCE_DIR}/../../../man1/mpg123.1"
463 "${CMAKE_CURRENT_SOURCE_DIR}/../../../man1/out123.1"
464 DESTINATION "${CMAKE_INSTALL_MANDIR}")
465
466 endif()
467 endif()
468
469 configure_file(config.cmake.h.in config.h)
470
471 set(LIBMPG123_LIBS "${LIBMPG123_LIBS}" PARENT_SCOPE)
472 set(LIBOUT123_LIBS "${LIBOUT123_LIBS}" PARENT_SCOPE)
473 set(LIBSYN123_LIBS "${LIBSYN123_LIBS}" PARENT_SCOPE)