Debian Codegraph @

ports/cmake/CMakeLists.txt

raw
1 cmake_minimum_required(VERSION 3.12)
2
3 include(cmake/read_api_version.cmake)
4 read_api_version(MPG123_VERSION)
5
6 project(mpg123 VERSION ${MPG123_VERSION} LANGUAGES C ASM)
7 set(CMAKE_C_STANDARD 99)
8
9 option(BUILD_LIBOUT123 "build libout123 (prerequisite for included programs)" ON)
10 if(CMAKE_SYSTEM_NAME STREQUAL "WindowsStore")
11 message(WARNING "Output module is not implemented for '${CMAKE_SYSTEM_NAME}' platform.")
12 message(WARNING "To prevent build errors 'BUILD_LIBOUT123' option is set to OFF.")
13 set(BUILD_LIBOUT123 OFF)
14 endif()
15
16 include(cmake/search_libs.cmake)
17 include(CMakePackageConfigHelpers)
18 include(GNUInstallDirs)
19
20 set(PACKAGE_VERSION ${PROJECT_VERSION})
21 add_subdirectory("src")
22
23 install(
24 EXPORT targets
25 DESTINATION "${CMAKE_INSTALL_LIBDIR}/cmake/${PROJECT_NAME}"
26 NAMESPACE MPG123::)
27
28 configure_package_config_file(
29 mpg123-config.cmake.in mpg123-config.cmake
30 INSTALL_DESTINATION "${CMAKE_INSTALL_LIBDIR}/cmake/${PROJECT_NAME}")
31 write_basic_package_version_file(
32 mpg123-config-version.cmake COMPATIBILITY AnyNewerVersion)
33
34 install(
35 FILES
36 "${CMAKE_CURRENT_BINARY_DIR}/mpg123-config.cmake"
37 "${CMAKE_CURRENT_BINARY_DIR}/mpg123-config-version.cmake"
38 DESTINATION "${CMAKE_INSTALL_LIBDIR}/cmake/${PROJECT_NAME}")
39
40 set(prefix "${CMAKE_INSTALL_PREFIX}")
41 set(exec_prefix "${CMAKE_INSTALL_PREFIX}")
42 set(libdir "${CMAKE_INSTALL_FULL_LIBDIR}")
43 set(includedir "${CMAKE_INSTALL_FULL_INCLUDEDIR}")
44 configure_file("${CMAKE_CURRENT_SOURCE_DIR}/../../libmpg123.pc.in" libmpg123.pc @ONLY)
45 if(BUILD_LIBOUT123)
46 configure_file("${CMAKE_CURRENT_SOURCE_DIR}/../../libout123.pc.in" libout123.pc @ONLY)
47 endif()
48 configure_file("${CMAKE_CURRENT_SOURCE_DIR}/../../libsyn123.pc.in" libsyn123.pc @ONLY)
49
50 install(
51 FILES
52 "${CMAKE_CURRENT_BINARY_DIR}/libmpg123.pc"
53 "${CMAKE_CURRENT_BINARY_DIR}/libsyn123.pc"
54 DESTINATION "${CMAKE_INSTALL_LIBDIR}/pkgconfig")
55 if(BUILD_LIBOUT123)
56 install(
57 FILES
58 "${CMAKE_CURRENT_BINARY_DIR}/libout123.pc"
59 DESTINATION "${CMAKE_INSTALL_LIBDIR}/pkgconfig")
60 endif()