Debian Codegraph @

cmake/targets/libminizinc_chuffed.cmake

raw
1 ### MiniZinc Chuffed Solver Target
2
3 if(CHUFFED_FOUND)
4
5 ### Compile target for the Chuffed interface
6 add_library(minizinc_chuffed OBJECT
7 solvers/chuffed/chuffed_solverfactory.cpp
8 solvers/chuffed/chuffed_solverinstance.cpp
9
10 include/minizinc/solvers/chuffed_solverfactory.hh
11 include/minizinc/solvers/chuffed_solverinstance.hh
12 )
13 target_include_directories(minizinc_chuffed PRIVATE "${CHUFFED_INCLUDE_DIRS}")
14 target_compile_definitions(minizinc_chuffed PRIVATE CHUFFED_VERSION="${chuffed_VERSION}")
15 add_dependencies(minizinc_chuffed minizinc_parser)
16
17 ### Setup correct compilation into the MiniZinc library
18 target_compile_definitions(mzn PRIVATE HAS_CHUFFED)
19 target_sources(mzn PRIVATE $<TARGET_OBJECTS:minizinc_chuffed>)
20
21 target_link_libraries(mzn ${CHUFFED_LIBRARIES})
22
23 ### Copy minizinc library from Chuffed (so we don't have to keep a copy in this repo)
24 file(COPY "${CHUFFED_SHARE_DIR}/minizinc/chuffed/" DESTINATION "${CMAKE_BINARY_DIR}/share/minizinc/chuffed_internal")
25 install(
26 DIRECTORY "${CHUFFED_SHARE_DIR}/minizinc/chuffed/"
27 DESTINATION "${CMAKE_INSTALL_DATAROOTDIR}/minizinc/chuffed_internal"
28 )
29
30 ### Add Chuffed's msc file but remove the executable field so it loads the builtin solver
31 file(READ "${CHUFFED_SHARE_DIR}/minizinc/solvers/chuffed.msc" chuffed_solver_config)
32 string(REGEX REPLACE "\"org.chuffed.chuffed\"" "\"org.minizinc.chuffed\"" chuffed_solver_config ${chuffed_solver_config})
33 string(REGEX REPLACE "\"executable\":" "\"_executable\":" chuffed_solver_config ${chuffed_solver_config})
34 string(REGEX REPLACE "\"\.\./chuffed\"" "\"../chuffed_internal\"" chuffed_solver_config ${chuffed_solver_config})
35 file(WRITE "${CMAKE_BINARY_DIR}/share/minizinc/solvers/chuffed_internal.msc" ${chuffed_solver_config})
36 install(
37 FILES "${CMAKE_BINARY_DIR}/share/minizinc/solvers/chuffed_internal.msc"
38 DESTINATION "${CMAKE_INSTALL_DATAROOTDIR}/minizinc/solvers"
39 )
40
41 else()
42
43 ### Remove Chuffed's library if present, so that it doesn't get accidentally picked up
44 file(REMOVE_RECURSE "${CMAKE_BINARY_DIR}/share/minizinc/chuffed_internal")
45 file(REMOVE "${CMAKE_BINARY_DIR}/share/minizinc/solvers/chuffed_internal.msc")
46
47 endif()