Debian Codegraph @

cmake/targets/libminizinc_atlantis.cmake

raw
1 ### MiniZinc Atlantis Solver Target
2
3 if(atlantis_FOUND)
4
5 ### Compile target for the Atlantis interface
6 add_library(minizinc_atlantis OBJECT
7 solvers/atlantis/atlantis_solverfactory.cpp
8 solvers/atlantis/atlantis_solverinstance.cpp
9
10 include/minizinc/solvers/atlantis_solverfactory.hh
11 include/minizinc/solvers/atlantis_solverinstance.hh
12 )
13 target_link_libraries(minizinc_atlantis PRIVATE atlantis::atlantis)
14 target_compile_definitions(minizinc_atlantis PRIVATE ATLANTIS_VERSION="${atlantis_FOUND}")
15 add_dependencies(minizinc_atlantis minizinc_parser)
16
17 ### Setup correct compilation into the MiniZinc library
18 target_compile_definitions(mzn PRIVATE HAS_ATLANTIS)
19 target_sources(mzn PRIVATE $<TARGET_OBJECTS:minizinc_atlantis>)
20
21 target_link_libraries(mzn atlantis::atlantis)
22
23 ### Copy minizinc library from Atlantis (so we don't have to keep a copy in this repo)
24 get_property(ATLANTIS_LIBRARY TARGET atlantis::atlantis PROPERTY LOCATION)
25 get_filename_component(ATLANTIS_LIB_DIR ${ATLANTIS_LIBRARY} DIRECTORY)
26 set(ATLANTIS_SHARE_DIR ${ATLANTIS_LIB_DIR}/../../${CMAKE_INSTALL_DATAROOTDIR})
27 file(COPY "${ATLANTIS_SHARE_DIR}/minizinc/atlantis/" DESTINATION "${CMAKE_BINARY_DIR}/share/minizinc/atlantis_internal")
28 install(
29 DIRECTORY "${ATLANTIS_SHARE_DIR}/minizinc/atlantis/"
30 DESTINATION "${CMAKE_INSTALL_DATAROOTDIR}/minizinc/atlantis_internal"
31 )
32
33 ### Add Atlantis' msc file but remove the executable field so it loads the builtin solver
34 file(READ "${ATLANTIS_SHARE_DIR}/minizinc/solvers/atlantis.msc" atlantis_solver_config)
35 string(REGEX REPLACE "\"se.uu.it.atlantis\"" "\"org.minizinc.atlantis\"" atlantis_solver_config ${atlantis_solver_config})
36 string(REGEX REPLACE "\"executable\":" "\"_executable\":" atlantis_solver_config ${atlantis_solver_config})
37 string(REGEX REPLACE "\"\.\./atlantis\"" "\"../atlantis_internal\"" atlantis_solver_config ${atlantis_solver_config})
38 file(WRITE "${CMAKE_BINARY_DIR}/share/minizinc/solvers/atlantis_internal.msc" ${atlantis_solver_config})
39 install(
40 FILES "${CMAKE_BINARY_DIR}/share/minizinc/solvers/atlantis_internal.msc"
41 DESTINATION "${CMAKE_INSTALL_DATAROOTDIR}/minizinc/solvers"
42 )
43
44 else()
45
46 ### Remove Atlantis' library if present, so that it doesn't get accidentally picked up
47 file(REMOVE_RECURSE "${CMAKE_BINARY_DIR}/share/minizinc/atlantis_internal")
48 file(REMOVE "${CMAKE_BINARY_DIR}/share/minizinc/solvers/atlantis_internal.msc")
49
50 endif()