Debian Codegraph @

time/date/traverse.ha

raw
1 // SPDX-License-Identifier: MPL-2.0
2 // (c) Hare authors <https://harelang.org>
3
4 use time::chrono;
5
6 // Calculates the [[span]] between two [[date]]s, from A to B.
7 //
8 // The returned span, provided to [[reckon]] with [[rflag]]::DEFAULT and date A,
9 // will produce B. The span's fields will all be the same sign.
10 //
11 // Be aware, using date of different [[locality]]s may return unexpected
12 // results.
13 export fn traverse(a: date, b: date) span = {
14 let s = span { ... };
15
16 if (chrono::compare(&a, &b) == 0) {
17 return s;
18 };
19
20 let reverse = chrono::compare(&a, &b) > 0;
21 if (reverse) {
22 let tmp = a;
23 a = b;
24 b = tmp;
25 };
26
27 s.years = _year(&b) - _year(&a);
28
29 s.months = _month(&b) - _month(&a);
30 if (s.months < 0) {
31 s.years -= 1;
32 s.months += 12;
33 };
34
35 s.days = _day(&b) - _day(&a);
36 let year = _year(&b);
37 let month = _month(&b);
38 let monthdays = calc_days_in_month(year, month);
39 for (_day(&a) > monthdays || s.days < 0) {
40 month -= 1;
41 if (month == 0) {
42 year -= 1;
43 month = 12;
44 };
45 monthdays = calc_days_in_month(year, month);
46
47 s.months -= 1;
48 if (s.months < 0) {
49 s.years -= 1;
50 s.months += 12;
51 };
52 s.days += monthdays;
53 };
54
55 s.hours = _hour(&b) - _hour(&a);
56 if (s.hours < 0) {
57 s.days -= 1;
58 s.hours += 24;
59 };
60
61 s.minutes = _minute(&b) - _minute(&a);
62 if (s.minutes < 0) {
63 s.hours -= 1;
64 s.minutes += 60;
65 };
66
67 s.seconds = _second(&b) - _second(&a);
68 if (s.seconds < 0) {
69 s.minutes -= 1;
70 s.seconds += 60;
71 };
72
73 s.nanoseconds = _nanosecond(&b) - _nanosecond(&a);
74 if (s.nanoseconds < 0) {
75 s.seconds -= 1;
76 s.nanoseconds += 1000000000; // 10E9
77 };
78
79 return if (reverse) neg(s) else s;
80 };
81
82 @test fn traverse() void = {
83 const cases = [
84 (
85 new(UTC, 0, 2021, 1, 15, 0, 0, 0, 0)!,
86 new(UTC, 0, 2022, 2, 16, 0, 0, 0, 0)!,
87 span {
88 years = 1,
89 months = 1,
90 days = 1,
91 ...
92 },
93 ),
94 (
95 new(UTC, 0, 2021, 1, 15, 0, 0, 0, 0)!,
96 new(UTC, 0, 2022, 3, 27, 0, 0, 0, 0)!,
97 span {
98 years = 1,
99 months = 2,
100 days = 12,
101 ...
102 },
103 ),
104 (
105 new(UTC, 0, 2021, 1, 15, 0, 0, 0, 0)!,
106 new(UTC, 0, 2022, 3, 14, 0, 0, 0, 0)!,
107 span {
108 years = 1,
109 months = 1,
110 days = 27,
111 ...
112 },
113 ),
114 (
115 new(UTC, 0, 2021, 1, 15, 0, 0, 0, 0)!,
116 new(UTC, 0, 2021, 1, 16, 0, 0, 0, 0)!,
117 span {
118 days = 1,
119 ...
120 },
121 ),
122 (
123 new(UTC, 0, 2021, 1, 15, 0, 0, 0, 0)!,
124 new(UTC, 0, 2021, 1, 16, 1, 3, 2, 4)!,
125 span {
126 days = 1,
127 hours = 1,
128 minutes = 3,
129 seconds = 2,
130 nanoseconds = 4,
131 ...
132 },
133 ),
134 (
135 new(UTC, 0, 2021, 1, 15, 2, 3, 2, 2)!,
136 new(UTC, 0, 2021, 1, 16, 1, 1, 2, 4)!,
137 span {
138 hours = 22,
139 minutes = 58,
140 nanoseconds = 2,
141 ...
142 },
143 ),
144 (
145 new(UTC, 0, 500, 1, 1, 0, 0, 0, 0)!,
146 new(UTC, 0, 3500, 1, 1, 0, 6, 0, 0)!,
147 span {
148 years = 3000,
149 minutes = 6,
150 ...
151 },
152 ),
153 (
154 new(UTC, 0, -500, 1, 1, 0, 0, 0, 0)!,
155 new(UTC, 0, 2500, 1, 1, 0, 6, 0, 0)!,
156 span {
157 years = 3000,
158 minutes = 6,
159 ...
160 },
161 ),
162 (
163 new(UTC, 0, 2000, 1, 1, 0, 0, 0, 0)!,
164 new(UTC, 0, 2000, 1, 1, 0, 6, 0, 999999999)!,
165 span {
166 minutes = 6,
167 nanoseconds = 999999999,
168 ...
169 },
170 ),
171 (
172 new(UTC, 0, 2000, 1, 1, 0, 6, 0, 999999999)!,
173 new(UTC, 0, 2000, 1, 1, 0, 6, 1, 0)!,
174 span {
175 nanoseconds = 1,
176 ...
177 },
178 ),
179 (
180 new(UTC, 0, -4000, 1, 1, 0, 6, 0, 999999999)!,
181 new(UTC, 0, 4000, 1, 1, 0, 6, 1, 0)!,
182 span {
183 years = 8000,
184 nanoseconds = 1,
185 ...
186 },
187 ),
188 ];
189 for (let (da, db, expected) .. cases) {
190 const actual = traverse(da, db);
191 assert(equalspan(actual, expected), "traverse miscalculation");
192 };
193 };