Debian Codegraph @

time/date/error.ha

raw
1 // SPDX-License-Identifier: MPL-2.0
2 // (c) Hare authors <https://harelang.org>
3
4 use fmt;
5 use fs;
6 use io;
7 use time::chrono;
8
9 // All possible errors returned from this module.
10 export type error = !(
11 invalid
12 | insufficient
13 | zfunresolved
14 | parsefail
15 | invalidtzif
16 | tzdberror
17 | chrono::tscmismatch
18 );
19
20 // Converts an [[error]] into a human-friendly string. The result may be
21 // statically allocated.
22 export fn strerror(err: error) const str = {
23 static let buf: [92]u8 = [0...];
24 match (err) {
25 case insufficient =>
26 return "Insufficient date information";
27 case invalid =>
28 return "Invalid date information";
29 case let e: zfunresolved =>
30 switch (e) {
31 case zferror::GAP =>
32 return "Failed to resolve zone-offset in a timezone transition overlap";
33 case zferror::LAP =>
34 return "Failed to resolve zone-offset in a timezone transition gap";
35 };
36 case let pf: parsefail =>
37 const (bi, rn) = pf;
38 def FMTMSG = "Date parsing failure for layout rune '{}' at byteindex {}";
39 static let buf: [len(FMTMSG) + 3]u8 = [0...];
40 return fmt::bsprintf(buf, FMTMSG, rn, bi)!;
41 case invalidtzif =>
42 return "Invalid TZif data";
43 case let err: tzdberror =>
44 static let buf: [1024]u8 = [0...];
45 match (err) {
46 case let err: fs::error =>
47 return fmt::bsprintf(buf,
48 "Timezone database error: {}",
49 fs::strerror(err),
50 )!;
51 case let err: io::error =>
52 return fmt::bsprintf(buf,
53 "Timezone database error: {}",
54 io::strerror(err),
55 )!;
56 case invalidtzif =>
57 return "Timezone database error: Invalid TZif data";
58 };
59 case let err: chrono::tscmismatch =>
60 return chrono::strerror(err);
61 };
62 };