Debian Codegraph @

gcc/testsuite/gcc.target/riscv/cset-sext-zicond-rtl.c

raw
1 /* { dg-do compile { target { ! riscv_abi_e } } } */
2 /* { dg-require-effective-target rv64 } */
3 /* { dg-skip-if "" { *-*-* } { "-O0" "-Og" "-flto" } } */
4 /* { dg-options "-march=rv64gc_zicond -mtune=rocket -mbranch-cost=3 -fdump-rtl-ce1" } */
5
6 int __RTL (startwith ("ce1"))
7 foo (long a, long b)
8 {
9 (function "foo"
10 (param "a"
11 (DECL_RTL (reg/v:DI <2> [ a ]))
12 (DECL_RTL_INCOMING (reg:DI a0 [ a ])))
13 (param "b"
14 (DECL_RTL (reg/v:DI <3> [ b ]))
15 (DECL_RTL_INCOMING (reg:DI a1 [ b ])))
16 (insn-chain
17 (block 2
18 (edge-from entry (flags "FALLTHRU"))
19 (cnote 6 [bb 2] NOTE_INSN_BASIC_BLOCK)
20 (cinsn 2 (set (reg/v:DI <2> [ a ])
21 (reg:DI a0 [ a ])) "cset-sext-zicond.c":8:1
22 (expr_list:REG_DEAD (reg:DI a0 [ a ])))
23 (cinsn 3 (set (reg/v:DI <3> [ b ])
24 (reg:DI a1 [ b ])) "cset-sext-zicond.c":8:1
25 (expr_list:REG_DEAD (reg:DI a1 [ b ])))
26 (cnote 4 NOTE_INSN_FUNCTION_BEG)
27 (cjump_insn 8 (set (pc)
28 (if_then_else (eq (reg/v:DI <3> [ b ])
29 (const_int 0))
30 (label_ref:DI 24)
31 (pc))) "cset-sext-zicond.c":9:6
32 (expr_list:REG_DEAD (reg/v:DI <3> [ b ])
33 (int_list:REG_BR_PROB 365072228)))
34 (edge-to 4)
35 (edge-to 3 (flags "FALLTHRU"))
36 ) ;; block 2
37 (block 3
38 (edge-from 2 (flags "FALLTHRU"))
39 (cnote 9 [bb 3] NOTE_INSN_BASIC_BLOCK)
40 (cinsn 10 (set (reg:SI <5>)
41 (ne:SI (reg/v:DI <2> [ a ])
42 (const_int 0))) "cset-sext-zicond.c":11:11
43 (expr_list:REG_DEAD (reg/v:DI <2> [ a ])))
44 (cinsn 11 (set (reg:DI <1> [ <retval> ])
45 (sign_extend:DI (reg:SI <5>))) "cset-sext-zicond.c":11:11
46 (expr_list:REG_DEAD (reg:SI <5>)))
47 (edge-to 5 (flags "FALLTHRU"))
48 ) ;; block 3
49 (block 4
50 (edge-from 2)
51 (clabel 24 3)
52 (cnote 23 [bb 4] NOTE_INSN_BASIC_BLOCK)
53 (cinsn 5 (set (reg:DI <1> [ <retval> ])
54 (const_int 0)) "cset-sext-zicond.c":10:12)
55 (edge-to 5 (flags "FALLTHRU"))
56 ) ;; block 4
57 (block 5
58 (edge-from 4 (flags "FALLTHRU"))
59 (edge-from 3 (flags "FALLTHRU"))
60 (clabel 12 2)
61 (cnote 13 [bb 5] NOTE_INSN_BASIC_BLOCK)
62 (cinsn 18 (set (reg/i:DI a0)
63 (reg:DI <1> [ <retval> ])) "cset-sext-zicond.c":15:1
64 (expr_list:REG_DEAD (reg:DI <1> [ <retval> ])))
65 (cinsn 19 (use (reg/i:DI a0)) "cset-sext-zicond.c":15:1)
66 (edge-to exit (flags "FALLTHRU"))
67 ) ;; block 5
68 ) ;; insn-chain
69 (crtl
70 (return_rtx
71 (reg/i:DI a0)
72 ) ;; return_rtx
73 ) ;; crtl
74 ) ;; function "foo"
75 }
76
77 /* Expect branchless assembly like:
78
79 snez a0,a0
80 czero.eqz a0,a0,a1
81 */
82
83 /* { dg-final { scan-rtl-dump-times "if-conversion succeeded through noce_try_cmove_arith" 1 "ce1" } } */
84 /* { dg-final { scan-assembler-times "\\ssnez\\s" 1 } } */
85 /* { dg-final { scan-assembler-times "\\sczero\\.eqz\\s" 1 } } */
86 /* { dg-final { scan-assembler-not "\\s(?:beq|bne)\\s" } } */