Debian Codegraph @

gcc/testsuite/gcc.target/riscv/cset-sext-sfb-rtl32.c

raw
1 /* { dg-do compile { target { ! riscv_abi_e } } } */
2 /* { dg-require-effective-target rv32 } */
3 /* { dg-skip-if "" { *-*-* } { "-O0" "-Og" "-flto" } } */
4 /* { dg-options "-march=rv32gc -mtune=sifive-7-series -mbranch-cost=1 -fdump-rtl-ce1" } */
5
6 int __RTL (startwith ("ce1"))
7 foo (long a, long b)
8 {
9 (function "foo"
10 (param "a"
11 (DECL_RTL (reg/v:SI <2> [ a ]))
12 (DECL_RTL_INCOMING (reg:SI a0 [ a ])))
13 (param "b"
14 (DECL_RTL (reg/v:SI <3> [ b ]))
15 (DECL_RTL_INCOMING (reg:SI a1 [ b ])))
16 (insn-chain
17 (block 2
18 (edge-from entry (flags "FALLTHRU"))
19 (cnote 6 [bb 2] NOTE_INSN_BASIC_BLOCK)
20 (cinsn 2 (set (reg/v:SI <2> [ a ])
21 (reg:SI a0 [ a ])) "cset-sext-sfb.c":8:1
22 (expr_list:REG_DEAD (reg:SI a0 [ a ])))
23 (cinsn 3 (set (reg/v:SI <3> [ b ])
24 (reg:SI a1 [ b ])) "cset-sext-sfb.c":8:1
25 (expr_list:REG_DEAD (reg:SI a1 [ b ])))
26 (cnote 4 NOTE_INSN_FUNCTION_BEG)
27 (cjump_insn 8 (set (pc)
28 (if_then_else (eq (reg/v:SI <3> [ b ])
29 (const_int 0))
30 (label_ref:SI 23)
31 (pc))) "cset-sext-sfb.c":9:6
32 (int_list:REG_BR_PROB 365072228))
33 (edge-to 4)
34 (edge-to 3 (flags "FALLTHRU"))
35 ) ;; block 2
36 (block 3
37 (edge-from 2 (flags "FALLTHRU"))
38 (cnote 9 [bb 3] NOTE_INSN_BASIC_BLOCK)
39 (cinsn 10 (set (reg:SI <1> [ <retval> ])
40 (ne:SI (reg/v:SI <2> [ a ])
41 (const_int 0))) "cset-sext-sfb.c":11:11
42 (expr_list:REG_DEAD (reg/v:SI <2> [ a ])))
43 (edge-to 5 (flags "FALLTHRU"))
44 ) ;; block 3
45 (block 4
46 (edge-from 2)
47 (clabel 23 3)
48 (cnote 22 [bb 4] NOTE_INSN_BASIC_BLOCK)
49 (cinsn 5 (set (reg:SI <1> [ <retval> ])
50 (const_int 0)) "cset-sext-sfb.c":10:12
51 (expr_list:REG_DEAD (reg/v:SI <3> [ b ])))
52 (edge-to 5 (flags "FALLTHRU"))
53 ) ;; block 4
54 (block 5
55 (edge-from 4 (flags "FALLTHRU"))
56 (edge-from 3 (flags "FALLTHRU"))
57 (clabel 16 1)
58 (cnote 19 [bb 5] NOTE_INSN_BASIC_BLOCK)
59 (cinsn 17 (set (reg/i:SI a0)
60 (reg:SI <1> [ <retval> ])) "cset-sext-sfb.c":15:1
61 (expr_list:REG_DEAD (reg:SI <1> [ <retval> ])))
62 (cinsn 18 (use (reg/i:SI a0)) "cset-sext-sfb.c":15:1)
63 (edge-to exit (flags "FALLTHRU"))
64 ) ;; block 5
65 ) ;; insn-chain
66 (crtl
67 (return_rtx
68 (reg/i:SI a0)
69 ) ;; return_rtx
70 ) ;; crtl
71 ) ;; function "foo"
72 }
73
74 /* Expect short forward branch assembly like:
75
76 snez a0,a0
77 bne a1,zero,1f # movcc
78 mv a0,zero
79 1:
80 */
81
82 /* { dg-final { scan-rtl-dump-times "if-conversion succeeded through noce_try_cmove_arith" 1 "ce1" } } */
83 /* { dg-final { scan-assembler-times "\\ssnez\\s" 1 } } */
84 /* { dg-final { scan-assembler-times "\\sbne\\s\[^\\s\]+\\s# movcc\\s" 1 } } */
85 /* { dg-final { scan-assembler-not "\\sbeq\\s" } } */