Debian Codegraph @

src/meson.build

raw
1 sh = find_program('sh')
2 dbus_interfaces = files(
3 'net.reactivated.Fprint.Manager.xml',
4 'net.reactivated.Fprint.Device.xml',
5 )
6
7 install_data(dbus_interfaces, install_dir: dbus_interfaces_dir)
8
9 fprintd_dbus_sources = gnome.gdbus_codegen('fprintd-dbus',
10 sources: dbus_interfaces,
11 autocleanup: 'all',
12 interface_prefix: 'net.reactivated.Fprint.',
13 namespace: 'FprintDBus',
14 object_manager: true,
15 extra_args: ['--glib-min-required', glib_min_version]
16 )
17
18 fprintd_enum_files = gnome.mkenums_simple('fprintd-enums',
19 sources: 'fprintd.h',
20 )
21
22 fprintd_deps = declare_dependency(
23 include_directories: [
24 include_directories('..'),
25 ],
26 sources: [
27 fprintd_enum_files,
28 fprintd_dbus_sources,
29 ],
30 dependencies: [
31 glib_dep,
32 gio_dep,
33 gio_unix_dep,
34 gmodule_dep,
35 libfprint_dep,
36 polkit_gobject_dep,
37 ],
38 compile_args: [
39 '-DG_LOG_DOMAIN="@0@"'.format(meson.project_name()),
40 '-DLOCALEDIR="@0@"'.format(localedir),
41 '-DPLUGINDIR="@0@"'.format(fprintd_plugindir),
42 ],
43 )
44
45 libfprintd_private = static_library('fprintd-private',
46 sources: [
47 'device.c',
48 'fprintd.h',
49 'manager.c',
50 ],
51 dependencies: fprintd_deps,
52 gnu_symbol_visibility: 'hidden',
53 )
54
55 fprintd = executable('fprintd',
56 sources: [
57 'file_storage.c',
58 'file_storage.h',
59 'fprintd.h',
60 'main.c',
61 'storage.h',
62 ],
63 dependencies: fprintd_deps,
64 link_with: libfprintd_private,
65 gnu_symbol_visibility: 'hidden',
66 install: true,
67 install_dir: fprintd_installdir,
68 )