Debian Codegraph @

bin/plotoffsets_cc

raw
1 #!/bin/csh -f
2 # plotoffsets_cc for gmt3-3
3 # used by Doris software for plotting of offset vectors after coarse coregistration.
4 # plotting magnitude background may require some diskspace
5 # (subx, suby..)
6 # bg assumed to be in one file, size=(width*height); width=pN-p0+1
7 #
8 # AO: Adapted for coarse correlation step
9 #
10 # Developers:
11 # Bert Kampes
12 # Anneleen Oyen
13 ################
14 ################
15
16 ### Handle input.
17 # give doris time to write result file
18 sleep 1
19 set PRG = `basename "$0"`
20 set VER = "v1.0, FMR software"
21 set AUT = "TUDelft, (c) 1999-2010"
22 echo "$PRG $VER, $AUT"
23 echo " "
24
25 ###
26 set USAGE = "0" #synopsis
27 set HELP = "0" #exit afterwards
28 set IFILE = "interferogram.out" # arg 1 default
29 # args 2:5 (default) file dimension (plot dim.)
30 @ L0 = 1
31 @ LN = 25000
32 @ P0 = 1
33 @ PN = 4900
34 set THRESHOLD = "0.4" # arg6 default
35 set SLCFILE = "" # arg7 optional
36 set SLCFORMAT = ""
37 set DOBG = "0" # default (not possible w/o l0,lN,p0,pN
38
39 switch ( $#argv )
40 case '7':
41 set DOBG = "1"
42 set SLCFILE = "$7"
43 # ||| fall through |||
44 #
45 case '6':
46 set THRESHOLD = "$6"
47 # ||| fall through |||
48 #
49 case '5':
50 @ L0 = $2
51 @ LN = $3
52 @ P0 = $4
53 @ PN = $5
54 # ||| fall through |||
55 #
56 case '2':
57 case '1':
58 set IFILE = $1
59 breaksw
60 # --- no fall through ---
61 #
62 default:
63 set HELP = "1"
64 endsw
65 if ( $#argv == 2) set THRESHOLD = "$2"
66 # Check input
67 if ( ! -r "$IFILE" ) then
68 echo " input file: $IFILE cannot be read."
69 set HELP = "1"
70 endif
71
72 # Check if something went wrong
73 set MORE = more;
74 less >& /dev/null
75 if ( $status == 0 ) set MORE = 'less -de'
76 echo "Using as pager program: $MORE"
77 if ( $HELP ) set USAGE = "1"
78 if ( $USAGE ) then
79 #cat << __EOF_USAGE | more -d
80 cat << __EOF_USAGE | $MORE
81
82 -----------------------------------------------------------------------
83
84 $PRG -- Program to plot offset vectors from Doris
85 Position, correlation, and background image can be plotted.
86
87 SYNOPSIS:
88 $PRG ifile [linelo hi pixlo hi [threshold [slcfile]]]
89
90 ifile: Resultfile from Doris [mandatory arg]
91 linelo: First azimuth line. [default: 1]
92 linehi: Last azimuth line. [default: 25000]
93 pixlo: First range pixel. [default: 1]
94 pixhi: Last range pixel. [default: 4900]
95 threshold: Only plot estimated with correlation above threshold.
96 [default: 0.4]
97 slcfile: Complex raw file. Magnitude is used as background image.
98 (format can be complex real4 or short int.)
99
100 EXAMPLE:
101 $PRG interferogram.out 1 25000 1 4900 0.4 slcfile.raw
102
103 PROG may depend on gawk or nawk and not work with std awk...
104
105 -----------------------------------------------------------------------
106
107 __EOF_USAGE
108 endif
109 if ( $HELP ) then
110 #cat << __EOF_HELP | more -de
111 cat << __EOF_HELP | $MORE
112
113 ifile is the interferogram result file from the Doris software, see
114 this script for details. Somewhere the coarse coregistration output section should be
115 present, containing lines such as:
116
117 *******************************************************************
118 *_Start_coarse_correl:
119 *******************************************************************
120 Estimated translation slave w.r.t. master:
121 Coarse_correlation_translation_lines: -2
122 Coarse_correlation_translation_pixels: -4
123 Number of correlation windows: 21 of 21
124
125 center(l,p) coherence offsetL offsetP
126 0 1532 248 0.391786 -2 -3
127 1 1532 2805 0.381579 -2 -4
128 ...
129 20 25217 5361 0.581629 -2 -4
130
131 *******************************************************************
132 * End_coarse_correl:_NORMAL
133 *******************************************************************
134
135 See also: cpxfiddle, GMT.
136
137 __EOF_HELP
138 exit -1
139 endif
140
141
142 ### Initialize variables
143 set TMPDIR = "."
144 if ( ! -w "$TMPDIR" ) then
145 set TMPDIR = "/tmp"
146 endif
147 if ( ! -w "$TMPDIR" ) then
148 echo "Sorry, directory $TMPDIR seems not writable, exiting."
149 exit -2
150 endif
151 set PSFILE = $TMPDIR/tmpplot.ps
152 set TMPFILE = $TMPDIR/tmpdata.plot
153 rm -f $PSFILE $TMPFILE
154
155 ### ifile is transformed to tmpfile with columns:
156 # 1: window number
157 # 2: location x
158 # 3: location y
159 # 4: offset x
160 # 5: offset y
161 # 6: correlation
162
163
164 ### Create tmpfile with only data: grep fine section with awk and
165 ### remove trailing comment lines (5) and tailing comment (2)
166 ###
167 ###1: *_Start_fine_coreg
168 ###2: *******************************************************************
169 ###3: Oversampling factor: 16
170 ###4: Number_of_correlation_windows: 100
171 ###5: Number posL posP offsetL offsetP correlation
172 ###6: 0 27 27 241.06 3.19 0.42
173 ### ...
174 ###x: 99 4733 971 241.06 3.50 0.41
175 ###x+1:
176 ###x+2: *******************************************************************
177 ###x+3: * End_fine_coreg:_NORMAL
178 ###x+4: *******************************************************************
179 ###
180 #
181 ######################################################################
182 ### find out if nawk is available, since awk seems not to know atan2?
183 set AWK = awk;
184 echo 1 | /usr/xpg4/bin/awk '{print 1}' >& /dev/null
185 if ( $status == 0 ) set AWK = '/usr/xpg4/bin/awk'
186 echo 1 | gawk '{print 1}' >& /dev/null
187 if ( $status == 0 ) set AWK = 'gawk'
188 echo 1 | nawk '{print 1}' >& /dev/null
189 if ( $status == 0 ) set AWK = 'nawk'
190 echo "Using as awk program: $AWK"
191
192
193
194 ######################################################################
195 ### 1. Grep between start stop pair:
196 echo "TMPFILE BEING GENERATED: step1"
197 $AWK '/Start_coarse_correl/, /End_coarse_correl/' $IFILE >! $TMPFILE.$$
198 #echo $AWK
199 ### 2. Get number of points (starting at window 0):
200 @ NUMPOINTS = `$AWK '/Number of correlation windows/ {print $5}' $TMPFILE.$$`
201 #echo NUMPOINTS=$NUMPOINTS
202 #### 3. Reduce file only to data:
203 #tail -n +6 $TMPFILE.$$ | head -n $NUMPOINTS >! $TMPFILE
204 #### 4. Remove above threshold (here is most easy...)
205 #$AWK -v t=$THRESHOLD '$6>=t' $TMPFILE >! $TMPFILE.$$
206 #mv -f $TMPFILE.$$ $TMPFILE
207 #
208 #%// BK 25-Sep-2001: following bug report by Irek Baran.
209 echo "TMPFILE BEING GENERATED: step2"
210 #$AWK -v n=$NUMPOINTS -v t=$THRESHOLD '{if(NR>5&&NR<n+6){if ($6>t){print $0}}}' $TMPFILE.$$ > $TMPFILE
211 #rm -f $TMPFILE.$$
212
213 #test how to pass arguments. failsave seems to be: #echo 111 | $AWK '{print '$t'}'
214 #%// BK 16-Jun-2003
215 #$AWK '{if(NR>5&&NR<'$NUMPOINTS'+6){if ($6>'$THRESHOLD'){print $0}}}' $TMPFILE.$$ > $TMPFILE
216 # v3.16: more info lines in resfile, skip more.
217 $AWK '{if(NR>8&&NR<'$NUMPOINTS'+9){if ($4>'$THRESHOLD'){print $0}}}' $TMPFILE.$$ > $TMPFILE
218 #rm -f $TMPFILE.$$
219 echo "TMPFILE GENERATED"
220
221
222
223 ### Check if we have points ##########################################
224 @ NP = `$AWK '{l=NR};END{print l}' $TMPFILE`
225 echo "$NP points above coherence threshold $THRESHOLD found."
226 if ( $NP < 1 ) then
227 echo "exiting..."
228 rm -f $TMPFILE
229 exit
230 endif
231
232
233
234 ######################################################################
235 ### Plot: location of windows / wtests
236 # plotted are:
237 # - normalized observations (offsets)
238 # - optionally background of magnitude image
239 # - correlation as circles (legenda... o=1), thickness arrow?
240
241
242 ######################################################################
243 echo "Setting GMT defaults"
244 # PAPER_MEDIA a4+ \
245 gmtset MEASURE_UNIT cm \
246 PAPER_MEDIA a4 \
247 PAGE_ORIENTATION portrait \
248 ANOT_FONT Helvetica \
249 ANOT_FONT_SIZE 10p \
250 ANOT_OFFSET 0.2 \
251 BASEMAP_AXES WeSn \
252 LABEL_FONT Helvetica \
253 LABEL_FONT_SIZE 10 \
254 UNIX_TIME_POS -2/-2 \
255 D_FORMAT %lg
256
257
258
259 ######################################################################
260 ### Labeling of axis.
261 echo " +++ Plotting the observed offset vectors (normalized) +++"
262 set TITLE = "Offset_vectors_(Corr_>_$THRESHOLD)"
263 set XLABEL = "Azimuth"
264 set YLABEL = "Range"
265 # height=y=azimuth, assume 5*stretched
266 @ WIDTH = ( ( $PN - $P0 ) + 1)
267 @ HEIGHT = ( ( $LN - $L0 ) + 1)
268 set SLCFORMAT = "cr4"
269 if ( $DOBG ) then
270 # filewidth should be used, but is equal...
271 @ SIZECI2 = $WIDTH * $HEIGHT * 4
272 @ SIZECR4 = $WIDTH * $HEIGHT * 8
273 set FSIZE = `ls -l $SLCFILE | $AWK '{print $5}'`
274 if ( $FSIZE == $SIZECI2 ) then
275 echo " *** File format ${SLCFILE}: complex short."
276 set SLCFORMAT = ci2
277 else if ( $FSIZE == $SIZECR4 ) then
278 echo " *** File format ${SLCFILE}: complex float."
279 set SLCFORMAT = cr4
280 else
281 echo " *** Sorry, no background, file format could not be determined."
282 set DOBG = "0"
283 endif
284 endif
285
286
287
288 ######################################################################
289 # GMT options
290 @ TICKSL = $HEIGHT / 7
291 @ TICKSP = $WIDTH / 7
292 set RANGE = "-R$P0/$PN/$L0/$LN"
293 set GENOPT = "-P -: "
294 set FRAME = "-B"$TICKSP":"$YLABEL":/"$TICKSL":"$XLABEL"::."$TITLE":"
295 set XSIZE = "16"
296 set YSIZE = "0"
297 @ NUMPIXS = ( $WIDTH * $HEIGHT )
298 # size paper, largest size $XSIZE
299 # actually should go to landscape in that case...
300 # strict stretching ERS1/2 only...
301 set RATIO = "5"
302 @ HEIGHT = $HEIGHT / $RATIO
303 if ( $HEIGHT > $WIDTH ) then
304 set YSIZE = $XSIZE
305 #%// Bert Kampes, 31-Mar-2005: changed to awk from bc
306 #set XSIZE = `echo "scale=3; $WIDTH/$HEIGHT*$YSIZE" | bc -l`
307 set XSIZE = `echo "$WIDTH $HEIGHT $YSIZE" | $AWK '{printf "%f", $1 / $2 * $3}'`
308 else
309 #%// Bert Kampes, 31-Mar-2005: changed to awk from bc
310 #set YSIZE = `echo "scale=3; $HEIGHT/$WIDTH*$XSIZE" | bc -l`
311 set YSIZE = `echo "$HEIGHT $WIDTH $XSIZE" | $AWK '{printf "%f", $1 / $2 * $3}'`
312 endif
313 echo " *** Size plot (x,y): $XSIZE $YSIZE"
314 set SIZE = "-JX$XSIZE/$YSIZE"
315
316
317 ######################################################################
318 ### First plot background if requested.
319 # for now, otherwize error
320 set GRDFILE = $$.grd
321 set CPTFILE = $$.cpt
322 if ( $DOBG ) then
323 echo " *** Making background plot..."
324 set SUBX = "1"
325 set SUBY = "1"
326 # try to limit tmp GRDFILE to 10MB (2.500.000 binary float pixels)
327 if ( $NUMPIXS > 10000000 ) then # eg. 25.000 * 5.000
328 set SUBY = "15" # else > 10MB tmpfile
329 set SUBX = "3" # else > 10MB tmpfile
330 else if ( $NUMPIXS > 5000000 ) then # eg. 10.000 * 5000
331 set SUBY = "10" # else > 10MB tmpfile
332 set SUBX = "2" # else > 10MB tmpfile
333 else if ( $NUMPIXS > 1250000 ) then # eg. 1500 * 5000
334 set SUBY = "5"
335 endif
336 echo " *** Subsampling data with factors (x,y): $SUBX $SUBY"
337 #
338 # assume total file has to be plotted (call from Doris...)
339 #echo \\n" Mirroring in horiz, rather do it with GMT, but how?" : -Jx/-y !
340 set PROG = "cpxfiddle -w$WIDTH -f$SLCFORMAT -qmag -e0.2 -ofloat -M$SUBX/$SUBY -- $SLCFILE"
341
342 # correct for GMT, subsampling output = ceil ((P-p+1)/sub)
343 # outputlines after subsampling = ceil((P-p+1)/sub)
344 #subsampling
345 #set NUMX = `echo "$P0 $PN $SUBX" | $AWK '{printf "%i", ($2-$1)/$3+1}'`
346 #set NUMY = `echo "$L0 $LN $SUBY" | $AWK '{printf "%i", ($2-$1)/$3+1}'`
347 #multilooking
348 set NUMX = `echo "$P0 $PN $SUBX" | $AWK '{print int(($2-$1+1)/$3)}'`
349 set NUMY = `echo "$L0 $LN $SUBY" | $AWK '{print int(($2-$1+1)/$3)}'`
350 echo " *** Number of output pixels (x,y): $NUMX $NUMY"
351
352 #set EAST = `echo "$P0+($NUMX-1)*$SUBX" | bc -l`
353 #set NORTH = `echo "$L0+($NUMY-1)*$SUBY" | bc -l`
354 #%// Bert Kampes, 31-Mar-2005: changed to awk from bc
355 set EAST = `echo "$P0 $NUMX $SUBX" | $AWK '{printf "%f", $1 + ( $2 - 1 ) * $3}'`
356 set NORTH = `echo "$L0 $NUMY $SUBY" | $AWK '{printf "%f", $1 + ( $2 - 1 ) * $3}'`
357 set BKRANGE = "-R$P0/$EAST/$L0/$NORTH"
358 echo " *** GMT range: $BKRANGE"
359
360 set GRDFILE = $$.grd
361 set INC = "-I$SUBX/$SUBY"
362 set IFORMAT = "-Zf" # binary float values
363 echo " Calling: $PROG | xyz2grd -G$GRDFILE $BKRANGE $INC $IFORMAT"
364 $PROG | xyz2grd -G$GRDFILE $BKRANGE $INC $IFORMAT
365 #
366 set CPTFILE = $$.cpt
367 set CPTNAME = gray
368 echo " Calling: grd2cpt $GRDFILE -C$CPTNAME -Z >! $CPTFILE"
369 grd2cpt $GRDFILE -C$CPTNAME -Z >! $CPTFILE
370 #
371 # lower left is O of coord. system, while upperleft for grd file -> mirror horiz.
372 #OK.. grdimage $GRDFILE $SIZE -C$CPTFILE -P -K -T >! $PSFILE
373 # T slow, large: grdimage $GRDFILE $SIZE -C$CPTFILE -P -K -T >! $PSFILE
374 set BKSIZE = "-JX$XSIZE/-$YSIZE"
375 echo " Calling: grdimage $GRDFILE $BKSIZE -C$CPTFILE -P -K >! $PSFILE"
376 grdimage $GRDFILE $BKSIZE -C$CPTFILE -P -K >! $PSFILE
377 # Tidy tidy tidy
378 echo " removing grdfile, cptfile: $GRDFILE $CPTFILE"
379 rm -f $GRDFILE
380 rm -f $CPTFILE
381
382 # Set Overlay for next if this was first, else initialize new plot system
383 set GMTFLAGS = "-K -O -N $GENOPT $RANGE $FRAME $SIZE -U -Sc -W6/255/0/0"
384 else
385 set GMTFLAGS = "-K -N $GENOPT $RANGE $FRAME $SIZE -U -Sc -W6/255/0/0"
386 endif
387
388
389
390 ######################################################################
391 ### Plot the location circles, where correl=size.
392 echo " +++ Plotting location circles, size (cm) is correlation +++"
393 $AWK '{print $2, $3, $6}' $TMPFILE | psxy $GMTFLAGS >> $PSFILE
394 #
395 set GMTFLAGS = "-K -O -N $GENOPT $RANGE $SIZE -Sc -W6/255/0/0"
396 echo " +++ Plotting legenda circle +++"
397 echo "$L0 $P0 1.0" | psxy -X-1.0 -Y-1.0 $GMTFLAGS >> $PSFILE
398 echo "$L0 $P0 0.5" | psxy -Y-0.25 $GMTFLAGS >> $PSFILE
399 #pstext:(x, y, size, angle, fontno, justify, text)
400 set GMTFLAGS = "-K -O -N $GENOPT $RANGE $SIZE"
401 echo "$L0 $P0 12 0 0 CM correlation" | pstext -Y1.0 $GMTFLAGS >> $PSFILE
402 echo "$L0 $P0 12 0 0 LM 1.0" | pstext -X0.5 -Y-0.5 $GMTFLAGS >> $PSFILE
403 echo "$L0 $P0 12 0 0 LM 0.5" | pstext -Y-0.5 $GMTFLAGS >> $PSFILE
404
405
406
407 ######################################################################
408 ### Plot normalized offset vectors.
409 # -G fill
410 # -Sv arrowwidth/headlength/headwidth [0.075c/0.3c/0.25c]
411 set GMTFLAGS = "-N -O -K -X0.5 -Y1.25 $GENOPT $RANGE $SIZE -Sv0.04/0.25/0.125 -G0/0/255 -W2/0/0/255"
412 #
413 echo "START STDL computation"
414 set MINL = `$AWK 'NR==1{m=$5}$5<m{m=$5}END{print m}'<$TMPFILE`
415 set MAXL = `$AWK 'NR==1{m=$5}$5>m{m=$5}END{print m}'<$TMPFILE`
416 set MEANL = `$AWK '{s += $5}END{printf "%f", s/NR}'<$TMPFILE`
417 set STDL = `$AWK '{sq += ( $5 - '$MEANL' ) * ( $5 - '$MEANL' )};END{printf "%f", sq / ( NR - 1 )}'<$TMPFILE`
418 #set STDL = `$AWK -v m=$MEANL '{sq+=($5-m)*($5-m)};END{print sq/(NR-1)}'<$TMPFILE`
419 #
420 echo "START STDP computation"
421 set MINP = `$AWK 'NR==1{m=$6}$6<m{m=$6}END{print m}'<$TMPFILE`
422 set MAXP = `$AWK 'NR==1{m=$6}$6>m{m=$6}END{print m}'<$TMPFILE`
423 set MEANP = `$AWK '{s += $6}END{printf "%f", s / NR}'<$TMPFILE`
424 set STDP = `$AWK '{sq += ( $6 - '$MEANP' ) * ( $6 - '$MEANP' )};END{printf "%f", sq / ( NR - 1 )}'<$TMPFILE`
425 #set STDP = `$AWK -v m=$MEANP '{sq+=($6-m)*($6-m)};END{print sq/(NR-1)}'<$TMPFILE`
426 echo " *** min, max, mean, std (line): $MINL $MAXL $MEANL $STDL"
427 echo " *** min, max, mean, std (pixel): $MINP $MAXP $MEANP $STDP"
428
429
430
431 ######################################################################
432 ### Normalize vectors by subtracting mean-2:
433 ### plot arrows as they are, normalized by max length ? (always longest==3cm?)
434 #no cause then offset 1000 <> 1001 is no difference while it is the same as 10<>11
435 # thus scale length by l-max
436 echo " *** Normalizing offset line by subtracting: $MEANL - 1"
437 echo " *** Normalizing offset pixel by subtracting: $MEANP - 1"
438 #
439 #$AWK -v wl=$MEANL -v wp=$MEANP \
440 # '{ \
441 # {l=$5-wl-1.} \
442 # {p=$6-wp-1.} \
443
444 echo "start psxy vector drawing"
445 # {dir=57.3*atan2(l,p)} \
446 # possibly gawk or nawk define atan2, not standard awk...
447 $AWK '{{l = $5 - '$MEANL' - 1.0 }{p = $6 - '$MEANP' - 1.0 } \
448 {l = l + 0.0000001} {p = p + 0.0000001} \
449 {dir = 57.3 * atan2(l,p)} \
450 {scale = 1.5} \
451 {len = scale * sqrt ( l * l + p * p )} \
452 {printf "%.1f %.1f %.1f %.1f\n", $2, $3, dir, len} \
453 }' \
454 $TMPFILE | \
455 psxy $GMTFLAGS >> $PSFILE
456 echo "...finished psxy vector drawing"
457
458
459 ### Print info on points as text (# offl offp).
460 set GMTFLAGS = "-M -Wo -D0/2.5 -O -N -K $GENOPT $RANGE $SIZE"
461 echo "> $LN $P0 8 0 0 LB 0.4 15 l" >! $TMPFILE.2
462 $AWK '{printf "@;255/0/0; @:10: %4.0i @;0/0/0; @:8: (%4.2f;%4.2f) - \n", $1,$5,$6}' $TMPFILE >> $TMPFILE.2
463 # Avoid overflow with head.
464 head -n 60 $TMPFILE.2 | pstext $GMTFLAGS >> $PSFILE
465 rm -f $TMPFILE.2
466
467
468 ### Add the window numbers (last overlay, no -K (close plot system)).
469 #pstext: (x, y, size(pts), angle(ccw), fontno, justify, text)
470 set GMTFLAGS = "-O -N -G0/0/0 $GENOPT $RANGE $SIZE"
471 echo " Calling: pstext $GMTFLAGS >> $PSFILE"
472 #green, 14pts, RightTop BottomLeft
473 $AWK '{printf "%.1f %.1f 10 0 0 RT %s\n", $2, $3, $1}' $TMPFILE | pstext $GMTFLAGS >> $PSFILE
474
475
476 # calls from Doris, cannot interactive...
477 #%// BK 19-Jul-2000
478 echo " Calling: viewanddel"
479 rm -f $TMPFILE $GRDFILE $CPTFILE
480 viewanddel $PSFILE
481
482 ### EOF
483