Debian Codegraph @

cmake/modules/FindUMFPACK.cmake

raw
1 # - Try to find UMFPACK
2 # Once done this will define
3 #
4 # UMFPACK_FOUND - system has UMFPACK
5 # UMFPACK_INCLUDE_DIRS - include directories for UMFPACK
6 # UMFPACK_LIBRARIES - libraries for UMFPACK
7
8 message(STATUS "Checking for package 'UMFPACK'")
9
10 # Find packages that UMFPACK depends on
11 #set(CMAKE_LIBRARY_PATH ${BLAS_DIR}/lib $ENV{BLAS_DIR}/lib ${CMAKE_LIBRARY_PATH})
12 find_package(AMD QUIET)
13 find_package(BLAS QUIET)
14 find_package(CHOLMOD QUIET)
15
16 # Check for header file
17 find_path(UMFPACK_INCLUDE_DIRS umfpack.h
18 HINTS ${UMFPACK_DIR}/include $ENV{UMFPACK_DIR}/include ${PETSC_INCLUDE_DIRS} $ENV{PETSC_DIR}/include
19 PATH_SUFFIXES suitesparse ufsparse
20 DOC "Directory where the UMFPACK header is located")
21 mark_as_advanced(UMFPACK_INCLUDE_DIRS)
22
23 # Check for UMFPACK library
24 find_library(UMFPACK_LIBRARY umfpack
25 HINTS ${UMFPACK_DIR}/lib $ENV{UMFPACK_DIR}/lib ${PETSC_LIBRARY_DIRS} $ENV{PETSC_DIR}/lib
26 DOC "The UMFPACK library")
27 mark_as_advanced(UMFPACK_LIBRARY)
28
29 # Check for SUITESPARSE library on Apple
30 if (APPLE)
31 find_library(SUITESPARSE_LIBRARY SuiteSparse
32 HINTS ${UMFPACK_DIR}/lib $ENV{UMFPACK_DIR}/lib ${PETSC_LIBRARY_DIRS} $ENV{PETSC_DIR}/lib
33 DOC "The SUITESPARSE library")
34 mark_as_advanced(SUITESPARSE_LIBRARY)
35 endif()
36
37 # Check for SUITESPARSECONFIG library
38 find_library(SUITESPARSECONFIG_LIBRARY suitesparseconfig
39 HINTS ${UMFPACK_DIR}/lib $ENV{UMFPACK_DIR}/lib ${PETSC_LIBRARY_DIRS} $ENV{PETSC_DIR}/lib
40 DOC "The SUITESPARSE library")
41 mark_as_advanced(SUITESPARSECONFIG_LIBRARY)
42
43 # Collect libraries
44 if (AMD_FOUND)
45 set(UMFPACK_LIBRARIES ${UMFPACK_LIBRARY} ${AMD_LIBRARIES})
46 endif()
47 if (BLAS_FOUND)
48 set(UMFPACK_LIBRARIES ${UMFPACK_LIBRARIES} ${BLAS_LIBRARIES})
49 endif()
50 if (CHOLMOD_FOUND)
51 set(UMFPACK_LIBRARIES ${UMFPACK_LIBRARIES} ${CHOLMOD_LIBRARIES})
52 endif()
53
54 if (SUITESPARSE_LIBRARY)
55 set(UMFPACK_LIBRARIES ${UMFPACK_LIBRARIES} ${SUITESPARSE_LIBRARY})
56 endif()
57 if (SUITESPARSECONFIG_LIBRARY)
58 set(UMFPACK_LIBRARIES ${UMFPACK_LIBRARIES} ${SUITESPARSECONFIG_LIBRARY})
59 endif()
60
61 find_program(GFORTRAN_EXECUTABLE gfortran)
62 if (GFORTRAN_EXECUTABLE)
63 execute_process(COMMAND ${GFORTRAN_EXECUTABLE} -print-file-name=libgfortran.so
64 OUTPUT_VARIABLE GFORTRAN_LIBRARY
65 OUTPUT_STRIP_TRAILING_WHITESPACE)
66 if (EXISTS "${GFORTRAN_LIBRARY}")
67 set(UMFPACK_LIBRARIES ${UMFPACK_LIBRARIES} ${GFORTRAN_LIBRARY})
68 endif()
69 endif()
70
71 # Try compiling and running test program
72 if (DOLFIN_SKIP_BUILD_TESTS)
73 set(UMFPACK_TEST_RUNS TRUE)
74 elseif (UMFPACK_INCLUDE_DIRS AND UMFPACK_LIBRARIES AND AMD_LIBRARIES)
75
76 # Set flags for building test program
77 set(CMAKE_REQUIRED_INCLUDES ${UMFPACK_INCLUDE_DIRS})
78 set(CMAKE_REQUIRED_LIBRARIES ${UMFPACK_LIBRARIES})
79
80 set(UMFPACK_TEST_LIB_CPP
81 "${CMAKE_CURRENT_BINARY_DIR}/CMakeFiles/umfpack_test_lib.cpp")
82 file(WRITE ${UMFPACK_TEST_LIB_CPP} "
83 /* Test program umfpack-ex1.c */
84
85 #include <umfpack.h>
86
87 int main()
88 {
89 int n = 5;
90 double x[5];
91 void *Symbolic, *Numeric;
92 int i;
93
94 int Ap[] = { 0, 2, 5, 9, 10, 12 };
95 int Ai[] = { 0, 1, 0, 2, 4, 1, 2, 3, 4, 2, 1, 4 };
96 double Ax[] = { 2, 3, 3, -1, 4, 4, -3, 1, 2, 2, 6, 1 };
97 double b[] = { 8, 45, -3, 3, 19 };
98
99 umfpack_di_symbolic(n, n, Ap, Ai, Ax, &Symbolic, NULL, NULL);
100 umfpack_di_numeric(Ap, Ai, Ax, Symbolic, &Numeric, NULL, NULL);
101 umfpack_di_free_symbolic(&Symbolic);
102
103 umfpack_di_solve(UMFPACK_A, Ap, Ai, Ax, x, b, Numeric, NULL, NULL);
104 umfpack_di_free_numeric(&Numeric);
105
106 return 0;
107 }
108 ")
109
110 try_run(UMFPACK_TEST_LIB_EXITCODE
111 UMFPACK_TEST_LIB_COMPILED
112 ${CMAKE_CURRENT_BINARY_DIR}
113 ${UMFPACK_TEST_LIB_CPP}
114 CMAKE_FLAGS
115 "-DINCLUDE_DIRECTORIES:STRING=${CMAKE_REQUIRED_INCLUDES}"
116 "-DLINK_LIBRARIES:STRING=${CMAKE_REQUIRED_LIBRARIES}"
117 COMPILE_OUTPUT_VARIABLE UMFPACK_TEST_LIB_COMPILE_OUTPUT
118 RUN_OUTPUT_VARIABLE UMFPACK_TEST_LIB_OUTPUT
119 )
120
121 if (UMFPACK_TEST_LIB_COMPILED AND UMFPACK_TEST_LIB_EXITCODE EQUAL 0)
122 message(STATUS "Performing test UMFPACK_TEST_RUNS - Success")
123 set(UMFPACK_TEST_RUNS TRUE)
124 else()
125 message(STATUS "Performing test UMFPACK_TEST_RUNS - Failed")
126
127 file(APPEND ${CMAKE_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/CMakeError.log
128 "Failed to run UMFPACK test:\n"
129 "CMAKE_REQUIRED_INCLUDES: ${CMAKE_REQUIRED_INCLUDES}\n"
130 "CMAKE_REQUIRED_LIBRARIES: ${CMAKE_REQUIRED_LIBRARIES}\n"
131 "CMAKE_REQUIRED_FLAGS: ${CMAKE_REQUIRED_FLAGS}\n"
132 "UMFPACK_TEST_LIB_EXITCODE: ${UMFPACK_TEST_LIB_EXITCODE}\n"
133 "UMFPACK_TEST_LIB_COMPILED: ${UMFPACK_TEST_LIB_COMPILED}\n"
134 "UMFPACK_TEST_LIB_COMPILE_OUTPUT: ${UMFPACK_TEST_LIB_COMPILE_OUTPUT}\n"
135 "UMFPACK_TEST_LIB_OUTPUT: ${UMFPACK_TEST_LIB_OUTPUT}\n\n")
136 endif()
137
138 # Build and run test program
139 include(CheckCXXSourceRuns)
140 check_cxx_source_runs("
141 /* Test program umfpack-ex1.c */
142
143 #include <umfpack.h>
144
145 int main()
146 {
147 int n = 5;
148 double x[5];
149 void *Symbolic, *Numeric;
150 int i;
151
152 int Ap[] = { 0, 2, 5, 9, 10, 12 };
153 int Ai[] = { 0, 1, 0, 2, 4, 1, 2, 3, 4, 2, 1, 4 };
154 double Ax[] = { 2, 3, 3, -1, 4, 4, -3, 1, 2, 2, 6, 1 };
155 double b[] = { 8, 45, -3, 3, 19 };
156
157 umfpack_di_symbolic(n, n, Ap, Ai, Ax, &Symbolic, NULL, NULL);
158 umfpack_di_numeric(Ap, Ai, Ax, Symbolic, &Numeric, NULL, NULL);
159 umfpack_di_free_symbolic(&Symbolic);
160
161 umfpack_di_solve(UMFPACK_A, Ap, Ai, Ax, x, b, Numeric, NULL, NULL);
162 umfpack_di_free_numeric(&Numeric);
163
164 return 0;
165 }
166 " UMFPACK_TEST_RUNS)
167 endif()
168
169 # Standard package handling
170 include(FindPackageHandleStandardArgs)
171 find_package_handle_standard_args(UMFPACK
172 "UMFPACK could not be found. Be sure to set UMFPACK_DIR."
173 UMFPACK_LIBRARIES UMFPACK_INCLUDE_DIRS AMD_LIBRARIES BLAS_LIBRARIES
174 UMFPACK_TEST_RUNS)