Debian Codegraph @

cmake/modules/FindPETSc.cmake

raw
1 # - Try to find PETSc
2 # Once done this will define
3 #
4 # PETSC_FOUND - system has PETSc
5 # PETSC_INCLUDE_DIRS - include directories for PETSc
6 # PETSC_LIBRARY_DIRS - library directories for PETSc
7 # PETSC_LIBRARIES - libraries for PETSc
8 # PETSC_STATIC_LIBRARIES - libraries for PETSc (static linking, undefined if not required)
9 # PETSC_VERSION - version for PETSc
10 # PETSC_VERSION_MAJOR - First number in PETSC_VERSION
11 # PETSC_VERSION_MINOR - Second number in PETSC_VERSION
12 # PETSC_VERSION_SUBMINOR - Third number in PETSC_VERSION
13 # PETSC_INT_SIZE - sizeof(PetscInt)
14 #
15 #=============================================================================
16 # Copyright (C) 2010-2016 Garth N. Wells, Anders Logg and Johannes Ring
17 # All rights reserved.
18 #
19 # Redistribution and use in source and binary forms, with or without
20 # modification, are permitted provided that the following conditions
21 # are met:
22 #
23 # 1. Redistributions of source code must retain the above copyright
24 # notice, this list of conditions and the following disclaimer.
25 # 2. Redistributions in binary form must reproduce the above copyright
26 # notice, this list of conditions and the following disclaimer in
27 # the documentation and/or other materials provided with the
28 # distribution.
29 #
30 # THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
31 # "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
32 # LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS
33 # FOR A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE
34 # COPYRIGHT HOLDER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT,
35 # INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING,
36 # BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES;
37 # LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER
38 # CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
39 # LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN
40 # ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
41 # POSSIBILITY OF SUCH DAMAGE.
42 #=============================================================================
43
44 # Outline:
45 # 1. Get flags from PETSc-generated pkg-config file
46 # 2. Test compile and run program using shared library linking
47 # 3. If shared library linking fails, test with static library linking
48
49 # Load pkg-config module (provided by CMake)
50 find_package(PkgConfig REQUIRED)
51
52 # Find PETSc pkg-config file. Note: craypetsc_real is on Cray systems
53 set(ENV{PKG_CONFIG_PATH} "$ENV{CRAY_PETSC_PREFIX_DIR}/lib/pkgconfig:$ENV{PETSC_DIR}/$ENV{PETSC_ARCH}/lib/pkgconfig:$ENV{PETSC_DIR}/lib/pkgconfig:$ENV{PKG_CONFIG_PATH}")
54 pkg_search_module(PETSC craypetsc_real petsc PETSc)
55
56 # Extract major, minor, etc from version string
57 if (PETSC_VERSION)
58 string(REPLACE "." ";" VERSION_LIST ${PETSC_VERSION})
59 list(GET VERSION_LIST 0 PETSC_VERSION_MAJOR)
60 list(GET VERSION_LIST 1 PETSC_VERSION_MINOR)
61 list(GET VERSION_LIST 2 PETSC_VERSION_SUBMINOR)
62 endif()
63
64 # Configure PETSc IMPORT (this involves creating an 'imported' target
65 # and attaching 'properties')
66 if (PETSC_FOUND AND NOT TARGET PETSC::petsc)
67 add_library(PETSC::petsc INTERFACE IMPORTED)
68
69 # Add include paths
70 set_property(TARGET PETSC::petsc PROPERTY
71 INTERFACE_INCLUDE_DIRECTORIES ${PETSC_INCLUDE_DIRS})
72
73 # Add libraries
74 unset(_libs)
75 foreach (lib ${PETSC_LIBRARIES})
76 find_library(LIB_${lib} NAMES ${lib} PATHS ${PETSC_LIBRARY_DIRS} NO_DEFAULT_PATH)
77 list(APPEND _libs ${LIB_${lib}})
78 endforeach()
79 set_property(TARGET PETSC::petsc PROPERTY INTERFACE_LINK_LIBRARIES "${_libs}")
80 endif()
81
82 # Configure PETSc 'static' IMPORT (this involves creating an
83 # 'imported' target and attaching 'properties')
84 if (PETSC_FOUND AND NOT TARGET PETSC::petsc_static)
85 add_library(PETSC::petsc_static INTERFACE IMPORTED)
86
87 # Add libraries (static)
88 unset(_libs)
89 foreach (lib ${PETSC_STATIC_LIBRARIES})
90 find_library(LIB_${lib} ${lib} HINTS ${PETSC_STATIC_LIBRARY_DIRS})
91 list(APPEND _libs ${LIB_${lib}})
92 endforeach()
93 set_property(TARGET PETSC::petsc_static PROPERTY INTERFACE_LINK_LIBRARIES "${_libs}")
94 endif()
95
96 # Attempt to build and run PETSc test program
97 if (DOLFIN_SKIP_BUILD_TESTS)
98
99 # Assume PETSc works
100 set(PETSC_TEST_RUNS TRUE)
101
102 elseif (PETSC_FOUND)
103
104 # Create PETSc test program
105 set(PETSC_TEST_LIB_CPP
106 "${CMAKE_CURRENT_BINARY_DIR}/CMakeFiles/petsc_test_lib.cpp")
107 file(WRITE ${PETSC_TEST_LIB_CPP} "
108 #include \"petscts.h\"
109 #include \"petsc.h\"
110 int main()
111 {
112 PetscErrorCode ierr;
113 TS ts;
114 int argc = 0;
115 char** argv = NULL;
116 ierr = PetscInitialize(&argc, &argv, PETSC_NULL, PETSC_NULL);CHKERRQ(ierr);
117 ierr = TSCreate(PETSC_COMM_WORLD,&ts);CHKERRQ(ierr);
118 ierr = TSSetFromOptions(ts);CHKERRQ(ierr);
119 ierr = TSDestroy(&ts);CHKERRQ(ierr);
120 ierr = PetscFinalize();CHKERRQ(ierr);
121 return 0;
122 }
123 ")
124
125 # Add MPI variables if MPI has been found
126 if (MPI_C_FOUND)
127 set(CMAKE_REQUIRED_INCLUDES ${CMAKE_REQUIRED_INCLUDES} ${MPI_C_INCLUDE_PATH})
128 set(CMAKE_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES} ${MPI_C_LIBRARIES})
129 set(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} ${MPI_C_COMPILE_FLAGS}")
130 endif()
131
132 # Try to run test program (shared linking)
133 try_run(
134 PETSC_TEST_LIB_EXITCODE
135 PETSC_TEST_LIB_COMPILED
136 ${CMAKE_CURRENT_BINARY_DIR}
137 ${PETSC_TEST_LIB_CPP}
138 CMAKE_FLAGS
139 "-DINCLUDE_DIRECTORIES:STRING=${CMAKE_REQUIRED_INCLUDES}"
140 LINK_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES} PETSC::petsc
141 COMPILE_OUTPUT_VARIABLE PETSC_TEST_LIB_COMPILE_OUTPUT
142 RUN_OUTPUT_VARIABLE PETSC_TEST_LIB_OUTPUT)
143
144 # Check program output
145 if (PETSC_TEST_LIB_COMPILED AND PETSC_TEST_LIB_EXITCODE EQUAL 0)
146
147 message(STATUS "Test PETSC_TEST_RUNS with shared library linking - Success")
148 set(PETSC_TEST_RUNS TRUE)
149
150 # Static libraries not required, so unset
151 set_property(TARGET PETSC::petsc_static PROPERTY INTERFACE_LINK_LIBRARIES)
152
153 else()
154
155 message(STATUS "Test PETSC_TEST_RUNS with shared library linking - Failed")
156
157 file(APPEND ${CMAKE_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/CMakeError.log
158 "Failed to run PETSc test with shared library linking:\n"
159 "CMAKE_REQUIRED_INCLUDES: ${CMAKE_REQUIRED_INCLUDES}\n"
160 "CMAKE_REQUIRED_LIBRARIES: ${CMAKE_REQUIRED_LIBRARIES}\n"
161 "CMAKE_REQUIRED_FLAGS: ${CMAKE_REQUIRED_FLAGS}\n"
162 "PETSC_TEST_LIB_EXITCODE: ${PETSC_TEST_LIB_EXITCODE}\n"
163 "PETSC_TEST_LIB_COMPILED: ${PETSC_TEST_LIB_COMPILED}\n"
164 "PETSC_TEST_LIB_COMPILE_OUTPUT: ${PETSC_TEST_LIB_COMPILE_OUTPUT}\n"
165 "PETSC_TEST_LIB_OUTPUT: ${PETSC_TEST_LIB_OUTPUT}\n\n")
166
167 # Add MPI variables if MPI has been found
168 if (MPI_C_FOUND)
169 set(CMAKE_REQUIRED_INCLUDES ${CMAKE_REQUIRED_INCLUDES} ${MPI_C_INCLUDE_PATH})
170 set(CMAKE_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES} ${MPI_C_LIBRARIES})
171 set(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} ${MPI_C_COMPILE_FLAGS}")
172 endif()
173
174 # Try to run test program (static linking)
175 try_run(
176 PETSC_TEST_LIB_EXITCODE
177 PETSC_TEST_LIB_COMPILED
178 ${CMAKE_CURRENT_BINARY_DIR}
179 ${PETSC_TEST_LIB_CPP}
180 CMAKE_FLAGS
181 "-DINCLUDE_DIRECTORIES:STRING=${CMAKE_REQUIRED_INCLUDES}"
182 LINK_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES} PETSC::petsc PETSC::petsc_static
183 COMPILE_OUTPUT_VARIABLE PETSC_TEST_LIB_COMPILE_OUTPUT
184 RUN_OUTPUT_VARIABLE PETSC_TEST_LIB_OUTPUT)
185
186 if (PETSC_TEST_LIB_COMPILED AND PETSC_TEST_LIB_EXITCODE EQUAL 0)
187 message(STATUS "Test PETSC_TEST_RUNS static linking - Success")
188 set(PETSC_TEST_RUNS TRUE)
189 else()
190 message(STATUS "Test PETSC_TEST_RUNS static linking - Failed")
191
192 file(APPEND ${CMAKE_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/CMakeError.log
193 "Failed to run PETSc test with static library linking:\n"
194 "CMAKE_REQUIRED_INCLUDES: ${CMAKE_REQUIRED_INCLUDES}\n"
195 "CMAKE_REQUIRED_LIBRARIES: ${CMAKE_REQUIRED_LIBRARIES}\n"
196 "CMAKE_REQUIRED_FLAGS: ${CMAKE_REQUIRED_FLAGS}\n"
197 "PETSC_TEST_LIB_EXITCODE: ${PETSC_TEST_LIB_EXITCODE}\n"
198 "PETSC_TEST_LIB_COMPILED: ${PETSC_TEST_LIB_COMPILED}\n"
199 "PETSC_TEST_LIB_COMPILE_OUTPUT: ${PETSC_TEST_LIB_COMPILE_OUTPUT}\n"
200 "PETSC_TEST_LIB_OUTPUT: ${PETSC_TEST_LIB_OUTPUT}\n\n")
201
202 set(PETSC_TEST_RUNS FALSE)
203 endif()
204
205 endif()
206 endif()
207
208 # Check sizeof(PetscInt)
209 if (PETSC_INCLUDE_DIRS)
210 include(CheckTypeSize)
211 set(CMAKE_REQUIRED_INCLUDES ${CMAKE_REQUIRED_INCLUDES} ${PETSC_INCLUDE_DIRS})
212 set(CMAKE_EXTRA_INCLUDE_FILES petscsys.h)
213 check_type_size("PetscInt" PETSC_INT_SIZE)
214
215 unset(CMAKE_EXTRA_INCLUDE_FILES)
216 unset(CMAKE_REQUIRED_INCLUDES)
217 endif()
218
219 # Standard package handling
220 include(FindPackageHandleStandardArgs)
221 if (PETSC_FOUND)
222 find_package_handle_standard_args(PETSc
223 REQUIRED_VARS PETSC_FOUND PETSC_TEST_RUNS VERSION_VAR PETSC_VERSION
224 FAIL_MESSAGE "PETSc could not be configured.")
225 else()
226 find_package_handle_standard_args(PETSc
227 REQUIRED_VARS PETSC_FOUND
228 FAIL_MESSAGE "PETSc could not be found. Be sure to set PETSC_DIR.")
229 endif()