Debian Codegraph @

test/regress/cli/regress1/quantifiers/set3.smt2

raw
1 ; COMMAND-LINE: --full-saturate-quant
2
3 (set-logic AUFLIA)
4 (set-info :source | Assertion verification of simple set manipulation programs. |)
5 (set-info :smt-lib-version 2.6)
6 (set-info :category "crafted")
7 (set-info :status unsat)
8 (declare-sort Set 0)
9 (declare-fun set.member (Int Set) Bool)
10 (declare-fun set.insert (Set Int) Set)
11 (declare-fun delete (Set Int) Set)
12 (declare-fun sup (Set) Int)
13 (assert (forall ((?x Int) (?s Set)) (set.member ?x (set.insert ?s ?x))))
14 (assert (forall ((?x Int) (?y Int) (?s Set)) (=> (not (= ?x ?y)) (= (set.member ?x (set.insert ?s ?y)) (set.member ?x ?s)))))
15 (assert (forall ((?x Int) (?s Set)) (=> (not (set.member ?x ?s)) (= (delete ?s ?x) ?s))))
16 (assert (forall ((?x Int) (?s Set)) (= (delete (set.insert ?s ?x) ?x) (delete ?s ?x))))
17 (assert (forall ((?x Int) (?y Int) (?s Set)) (=> (not (= ?x ?y)) (= (delete (set.insert ?s ?y) ?x) (set.insert (delete ?s ?x) ?y)))))
18 (assert (forall ((?s Set)) (set.member (sup ?s) ?s)))
19 (assert (forall ((?s Set) (?x Int)) (=> (set.member ?x ?s) (<= ?x (sup ?s)))))
20 (assert (forall ((?s Set) (?x Int)) (=> (< (sup ?s) ?x) (= (sup (set.insert ?s ?x)) ?x))))
21 (declare-fun arr () (Array Int Int))
22 (declare-fun s0 () Set)
23 (assert (forall ((?i Int)) (=> (> ?i 0) (< (select arr ?i) (sup s0)))))
24 (declare-fun i1 () Int)
25 (declare-fun s1 () Set)
26 (declare-fun g (Int) Int)
27 (assert (forall ((?i Int)) (> (g ?i) 0)))
28 (assert (= s1 (set.insert s0 (select arr (g i1)))))
29 (assert (not (= (sup s1) (sup s0))))
30 (check-sat)
31 (exit)