Debian Codegraph @

test/regress/cli/regress1/quantifiers/pool-decidable-arrays-1.smt2

raw
1 ; COMMAND-LINE: --user-pat=strict
2 ; EXPECT: unsat
3 ; DISABLE-TESTER: unsat-core
4 (set-logic ALL)
5 (set-info :status unsat)
6
7 (define-sort I () Int)
8 ;(declare-sort E 0)
9 (define-sort E () Int)
10 (declare-sort Arr 0)
11 (declare-fun arr.select (Arr I) E)
12 (declare-fun arr.store (Arr I E) Arr)
13
14 (declare-const w Int)
15 (declare-const x Int)
16 (declare-const y Int)
17 (declare-const z Int)
18 (declare-const k Int)
19 (declare-const l Int)
20 (declare-const n Int)
21 (declare-const a Arr)
22
23 (declare-pool Index I (0 (- n 1)))
24
25 (assert
26 (forall ((a Arr) (i I) (e E)) (!
27 (and (= (arr.select (arr.store a i e) i) e)
28 (forall ((j I)) (!
29 (=> (not (= i j)) (= (arr.select a j) (arr.select (arr.store a i e) j)))
30 :pool (Index)
31 )
32 ))
33 :pattern ((arr.store a i e))
34 :inst-add-to-pool ((- i 1) Index)
35 :inst-add-to-pool ((+ i 1) Index)
36 :inst-add-to-pool (i Index)
37 ))
38 )
39
40 (define-fun sorted ((l I) (u I) (a Arr)) Bool
41 (forall ((i I) (j I)) (!
42 (=>
43 (<= l i j u)
44 (<= (arr.select a i) (arr.select a j)))
45 :pool (Index Index))
46 ))
47
48
49 (assert (< w x y z))
50 (assert (< 0 k l n))
51 (assert (> (- l k) 1))
52 (assert (sorted 0 (- n 1) (arr.store (arr.store a k x) l w)))
53 (assert (sorted 0 (- n 1) (arr.store (arr.store a k y) l z)))
54
55 (check-sat)