Debian Codegraph @

src/network/hp/procurve/snmp/mode/components/temperature.pm

raw
1 #
2 # Copyright 2024 Centreon (http://www.centreon.com/)
3 #
4 # Centreon is a full-fledged industry-strength solution that meets
5 # the needs in IT infrastructure and application monitoring for
6 # service performance.
7 #
8 # Licensed under the Apache License, Version 2.0 (the "License");
9 # you may not use this file except in compliance with the License.
10 # You may obtain a copy of the License at
11 #
12 # http://www.apache.org/licenses/LICENSE-2.0
13 #
14 # Unless required by applicable law or agreed to in writing, software
15 # distributed under the License is distributed on an "AS IS" BASIS,
16 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
17 # See the License for the specific language governing permissions and
18 # limitations under the License.
19 #
20
21 package network::hp::procurve::snmp::mode::components::temperature;
22
23 use strict;
24 use warnings;
25
26 my $mapping = {
27 name => { oid => '.1.3.6.1.4.1.11.2.14.11.1.2.8.1.1.2' }, # hpSystemAirName
28 value => { oid => '.1.3.6.1.4.1.11.2.14.11.1.2.8.1.1.3' }, # hpSystemAirCurrentTemp
29 threshold => { oid => '.1.3.6.1.4.1.11.2.14.11.1.2.8.1.1.7' } # hpSystemAirThresholdTemp
30 };
31 my $oid_airTempTable = '.1.3.6.1.4.1.11.2.14.11.1.2.8.1'; # hpSystemAirTempTable
32
33 sub load {
34 my ($self) = @_;
35
36 push @{$self->{request}}, {
37 oid => $oid_airTempTable,
38 start => $mapping->{name}->{oid},
39 end => $mapping->{threshold}->{oid}
40 };
41 }
42
43 sub check {
44 my ($self) = @_;
45
46 $self->{output}->output_add(long_msg => 'checking temperatures');
47 $self->{components}->{temperature} = { name => 'temperatures', total => 0, skip => 0 };
48 return if ($self->check_filter(section => 'temperature'));
49
50 foreach my $oid ($self->{snmp}->oid_lex_sort(keys %{$self->{results}->{ $oid_airTempTable }})) {
51 next if ($oid !~ /^$mapping->{name}->{oid}\.(.*)$/);
52 my $instance = $1;
53
54 my $result = $self->{snmp}->map_instance(mapping => $mapping, results => $self->{results}->{ $oid_airTempTable }, instance => $instance);
55
56 next if ($self->check_filter(section => 'temperature', instance => $instance));
57
58 next if ($result->{value} !~ /^(\d+)C/i);
59 my $value = $1;
60
61 $self->{components}->{temperature}->{total}++;
62 $self->{output}->output_add(
63 long_msg => sprintf(
64 "temperature '%s' is '%s' celsius [instance: %s]",
65 $result->{name}, $value, $instance
66 )
67 );
68
69 my ($exit, $warn, $crit, $checked) = $self->get_severity_numeric(section => 'temperature', instance => $instance, value => $value);
70 if ($checked == 0 && $result->{threshold} =~ /^(\d+)C/i) {
71 my $crit_th = $1;
72 $self->{perfdata}->threshold_validate(label => 'critical-temperature-instance-' . $instance, value => $crit_th);
73
74 $crit = $self->{perfdata}->get_perfdata_for_output(label => 'critical-temperature-instance-' . $instance);
75 }
76
77 if (!$self->{output}->is_status(value => $exit, compare => 'ok', litteral => 1)) {
78 $self->{output}->output_add(
79 severity => $exit,
80 short_msg => sprintf(
81 "temperature '%s' is '%s' celsius", $result->{name}, $value
82 )
83 );
84 }
85
86 $self->{output}->perfdata_add(
87 nlabel => 'hardware.temperature.celsius',
88 unit => 'C',
89 instances => $result->{name},
90 value => $value,
91 warning => $warn,
92 critical => $crit
93 );
94 }
95 }
96
97 1;