Debian Codegraph @

LspCpp/third_party/rapidjson/CMakeLists.txt

raw
1 CMAKE_MINIMUM_REQUIRED(VERSION 2.8.12)
2 if(POLICY CMP0025)
3 # detect Apple's Clang
4 cmake_policy(SET CMP0025 NEW)
5 endif()
6 if(POLICY CMP0054)
7 cmake_policy(SET CMP0054 NEW)
8 endif()
9
10 SET(CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/CMakeModules)
11
12 set(LIB_MAJOR_VERSION "1")
13 set(LIB_MINOR_VERSION "1")
14 set(LIB_PATCH_VERSION "0")
15 set(LIB_VERSION_STRING "${LIB_MAJOR_VERSION}.${LIB_MINOR_VERSION}.${LIB_PATCH_VERSION}")
16
17 if (CMAKE_VERSION VERSION_LESS 3.0)
18 PROJECT(RapidJSON CXX)
19 else()
20 cmake_policy(SET CMP0048 NEW)
21 PROJECT(RapidJSON VERSION "${LIB_VERSION_STRING}" LANGUAGES CXX)
22 endif()
23
24 # compile in release with debug info mode by default
25 if(NOT CMAKE_BUILD_TYPE)
26 set(CMAKE_BUILD_TYPE "RelWithDebInfo" CACHE STRING "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel." FORCE)
27 endif()
28
29 # Build all binaries in a separate directory
30 SET(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/bin)
31
32 option(RAPIDJSON_BUILD_DOC "Build rapidjson documentation." ON)
33 option(RAPIDJSON_BUILD_EXAMPLES "Build rapidjson examples." ON)
34 option(RAPIDJSON_BUILD_TESTS "Build rapidjson perftests and unittests." ON)
35 option(RAPIDJSON_BUILD_THIRDPARTY_GTEST
36 "Use gtest installation in `thirdparty/gtest` by default if available" OFF)
37
38 option(RAPIDJSON_BUILD_CXX11 "Build rapidjson with C++11" ON)
39 option(RAPIDJSON_BUILD_CXX17 "Build rapidjson with C++17" OFF)
40 if(RAPIDJSON_BUILD_CXX11)
41 set(CMAKE_CXX_STANDARD 11)
42 set(CMAKE_CXX_STANDARD_REQUIRED TRUE)
43 endif()
44
45 option(RAPIDJSON_BUILD_ASAN "Build rapidjson with address sanitizer (gcc/clang)" OFF)
46 option(RAPIDJSON_BUILD_UBSAN "Build rapidjson with undefined behavior sanitizer (gcc/clang)" OFF)
47
48 option(RAPIDJSON_ENABLE_INSTRUMENTATION_OPT "Build rapidjson with -march or -mcpu options" ON)
49
50 option(RAPIDJSON_HAS_STDSTRING "" OFF)
51 if(RAPIDJSON_HAS_STDSTRING)
52 add_definitions(-DRAPIDJSON_HAS_STDSTRING)
53 endif()
54
55 option(RAPIDJSON_USE_MEMBERSMAP "" OFF)
56 if(RAPIDJSON_USE_MEMBERSMAP)
57 add_definitions(-DRAPIDJSON_USE_MEMBERSMAP=1)
58 endif()
59
60 find_program(CCACHE_FOUND ccache)
61 if(CCACHE_FOUND)
62 set_property(GLOBAL PROPERTY RULE_LAUNCH_COMPILE ccache)
63 set_property(GLOBAL PROPERTY RULE_LAUNCH_LINK ccache)
64 if (CMAKE_CXX_COMPILER_ID MATCHES "Clang")
65 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Qunused-arguments -fcolor-diagnostics")
66 endif()
67 endif(CCACHE_FOUND)
68
69 if (CMAKE_CXX_COMPILER_ID STREQUAL "GNU")
70 if(RAPIDJSON_ENABLE_INSTRUMENTATION_OPT AND NOT CMAKE_CROSSCOMPILING)
71 if(CMAKE_SYSTEM_PROCESSOR STREQUAL "powerpc" OR CMAKE_SYSTEM_PROCESSOR STREQUAL "ppc" OR CMAKE_SYSTEM_PROCESSOR STREQUAL "ppc64" OR CMAKE_SYSTEM_PROCESSOR STREQUAL "ppc64le")
72 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -mcpu=native")
73 else()
74 #FIXME: x86 is -march=native, but doesn't mean every arch is this option. To keep original project's compatibility, I leave this except POWER.
75 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -march=native")
76 endif()
77 endif()
78 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Wall -Wextra -Werror")
79 set(EXTRA_CXX_FLAGS -Weffc++ -Wswitch-default -Wfloat-equal -Wconversion -Wsign-conversion)
80 if (RAPIDJSON_BUILD_CXX11 AND CMAKE_VERSION VERSION_LESS 3.1)
81 if (CMAKE_CXX_COMPILER_VERSION VERSION_LESS "4.7.0")
82 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -std=c++0x")
83 else()
84 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -std=c++11")
85 endif()
86 elseif (RAPIDJSON_BUILD_CXX17 AND NOT CMAKE_CXX_COMPILER_VERSION VERSION_LESS "5.0")
87 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -std=c++17")
88 endif()
89 if (RAPIDJSON_BUILD_ASAN)
90 if (CMAKE_CXX_COMPILER_VERSION VERSION_LESS "4.8.0")
91 message(FATAL_ERROR "GCC < 4.8 doesn't support the address sanitizer")
92 else()
93 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fsanitize=address")
94 endif()
95 endif()
96 if (RAPIDJSON_BUILD_UBSAN)
97 if (CMAKE_CXX_COMPILER_VERSION VERSION_LESS "4.9.0")
98 message(FATAL_ERROR "GCC < 4.9 doesn't support the undefined behavior sanitizer")
99 else()
100 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fsanitize=undefined")
101 endif()
102 endif()
103 elseif (CMAKE_CXX_COMPILER_ID MATCHES "Clang")
104 if(NOT CMAKE_CROSSCOMPILING)
105 if(CMAKE_SYSTEM_PROCESSOR STREQUAL "powerpc" OR CMAKE_SYSTEM_PROCESSOR STREQUAL "ppc" OR CMAKE_SYSTEM_PROCESSOR STREQUAL "ppc64" OR CMAKE_SYSTEM_PROCESSOR STREQUAL "ppc64le")
106 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -mcpu=native")
107 else()
108 #FIXME: x86 is -march=native, but doesn't mean every arch is this option. To keep original project's compatibility, I leave this except POWER.
109 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -march=native")
110 endif()
111 endif()
112 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Wall -Wextra -Werror -Wno-missing-field-initializers")
113 set(EXTRA_CXX_FLAGS -Weffc++ -Wswitch-default -Wfloat-equal -Wconversion -Wimplicit-fallthrough)
114 if (RAPIDJSON_BUILD_CXX11 AND CMAKE_VERSION VERSION_LESS 3.1)
115 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -std=c++11")
116 elseif (RAPIDJSON_BUILD_CXX17 AND NOT CMAKE_CXX_COMPILER_VERSION VERSION_LESS "4.0")
117 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -std=c++17")
118 endif()
119 if (RAPIDJSON_BUILD_ASAN)
120 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fsanitize=address")
121 endif()
122 if (RAPIDJSON_BUILD_UBSAN)
123 if (CMAKE_CXX_COMPILER_ID STREQUAL "AppleClang")
124 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fsanitize=undefined-trap -fsanitize-undefined-trap-on-error")
125 else()
126 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fsanitize=undefined")
127 endif()
128 endif()
129 elseif (CMAKE_CXX_COMPILER_ID STREQUAL "MSVC")
130 add_definitions(-D_CRT_SECURE_NO_WARNINGS=1)
131 add_definitions(-DNOMINMAX)
132 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /EHsc")
133 # CMake >= 3.10 should handle the above CMAKE_CXX_STANDARD fine, otherwise use /std:c++XX with MSVC >= 19.10
134 if (RAPIDJSON_BUILD_CXX11 AND NOT CMAKE_CXX_COMPILER_VERSION VERSION_LESS "19.10")
135 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /std:c++11")
136 elseif (RAPIDJSON_BUILD_CXX17 AND NOT CMAKE_CXX_COMPILER_VERSION VERSION_LESS "19.14")
137 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /std:c++17")
138 endif()
139 # Always compile with /WX
140 if(CMAKE_CXX_FLAGS MATCHES "/WX-")
141 string(REGEX REPLACE "/WX-" "/WX" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
142 else()
143 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /WX")
144 endif()
145 elseif (CMAKE_CXX_COMPILER_ID MATCHES "XL")
146 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -qarch=auto")
147 endif()
148
149 #add extra search paths for libraries and includes
150 SET(INCLUDE_INSTALL_DIR "${CMAKE_INSTALL_PREFIX}/include" CACHE PATH "The directory the headers are installed in")
151 SET(LIB_INSTALL_DIR "${CMAKE_INSTALL_PREFIX}/lib" CACHE STRING "Directory where lib will install")
152 SET(DOC_INSTALL_DIR "${CMAKE_INSTALL_PREFIX}/share/doc/${PROJECT_NAME}" CACHE PATH "Path to the documentation")
153
154 IF(UNIX OR CYGWIN)
155 SET(_CMAKE_INSTALL_DIR "${LIB_INSTALL_DIR}/cmake/${PROJECT_NAME}")
156 ELSEIF(WIN32)
157 SET(_CMAKE_INSTALL_DIR "${CMAKE_INSTALL_PREFIX}/cmake")
158 ENDIF()
159 SET(CMAKE_INSTALL_DIR "${_CMAKE_INSTALL_DIR}" CACHE PATH "The directory cmake files are installed in")
160
161 include_directories(${CMAKE_CURRENT_SOURCE_DIR}/include)
162
163 if(RAPIDJSON_BUILD_DOC)
164 add_subdirectory(doc)
165 endif()
166
167 add_custom_target(travis_doc)
168 add_custom_command(TARGET travis_doc
169 COMMAND ${CMAKE_CURRENT_SOURCE_DIR}/travis-doxygen.sh)
170
171 if(RAPIDJSON_BUILD_EXAMPLES)
172 add_subdirectory(example)
173 endif()
174
175 if(RAPIDJSON_BUILD_TESTS)
176 if(MSVC11)
177 # required for VS2012 due to missing support for variadic templates
178 add_definitions(-D_VARIADIC_MAX=10)
179 endif(MSVC11)
180 add_subdirectory(test)
181 include(CTest)
182 endif()
183
184 # pkg-config
185 IF (UNIX OR CYGWIN)
186 CONFIGURE_FILE (${CMAKE_CURRENT_SOURCE_DIR}/${PROJECT_NAME}.pc.in
187 ${CMAKE_CURRENT_BINARY_DIR}/${PROJECT_NAME}.pc
188 @ONLY)
189 INSTALL (FILES ${CMAKE_CURRENT_BINARY_DIR}/${PROJECT_NAME}.pc
190 DESTINATION "${LIB_INSTALL_DIR}/pkgconfig"
191 COMPONENT pkgconfig)
192 ENDIF()
193
194 install(FILES readme.md
195 DESTINATION "${DOC_INSTALL_DIR}"
196 COMPONENT doc)
197
198 install(DIRECTORY include/rapidjson
199 DESTINATION "${INCLUDE_INSTALL_DIR}"
200 COMPONENT dev)
201
202 install(DIRECTORY example/
203 DESTINATION "${DOC_INSTALL_DIR}/examples"
204 COMPONENT examples
205 # Following patterns are for excluding the intermediate/object files
206 # from an install of in-source CMake build.
207 PATTERN "CMakeFiles" EXCLUDE
208 PATTERN "Makefile" EXCLUDE
209 PATTERN "cmake_install.cmake" EXCLUDE)
210
211 # Provide config and version files to be used by other applications
212 # ===============================
213
214 ################################################################################
215 # Export package for use from the build tree
216 EXPORT( PACKAGE ${PROJECT_NAME} )
217
218 # Create the RapidJSONConfig.cmake file for other cmake projects.
219 # ... for the build tree
220 SET( CONFIG_SOURCE_DIR ${CMAKE_CURRENT_SOURCE_DIR})
221 SET( CONFIG_DIR ${CMAKE_CURRENT_BINARY_DIR})
222 SET( ${PROJECT_NAME}_INCLUDE_DIR "\${${PROJECT_NAME}_SOURCE_DIR}/include" )
223
224 CONFIGURE_FILE( ${CMAKE_CURRENT_SOURCE_DIR}/${PROJECT_NAME}Config.cmake.in
225 ${CMAKE_CURRENT_BINARY_DIR}/${PROJECT_NAME}Config.cmake @ONLY )
226 CONFIGURE_FILE(${CMAKE_CURRENT_SOURCE_DIR}/${PROJECT_NAME}ConfigVersion.cmake.in
227 ${CMAKE_CURRENT_BINARY_DIR}/${PROJECT_NAME}ConfigVersion.cmake @ONLY)
228
229 # ... for the install tree
230 SET( CMAKECONFIG_INSTALL_DIR ${LIB_INSTALL_DIR}/cmake/${PROJECT_NAME} )
231 FILE( RELATIVE_PATH REL_INCLUDE_DIR
232 "${CMAKECONFIG_INSTALL_DIR}"
233 "${CMAKE_INSTALL_PREFIX}/include" )
234
235 SET( ${PROJECT_NAME}_INCLUDE_DIR "\${${PROJECT_NAME}_CMAKE_DIR}/${REL_INCLUDE_DIR}" )
236 SET( CONFIG_SOURCE_DIR )
237 SET( CONFIG_DIR )
238 CONFIGURE_FILE( ${CMAKE_CURRENT_SOURCE_DIR}/${PROJECT_NAME}Config.cmake.in
239 ${CMAKE_CURRENT_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/${PROJECT_NAME}Config.cmake @ONLY )
240
241 INSTALL(FILES "${CMAKE_CURRENT_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/${PROJECT_NAME}Config.cmake"
242 DESTINATION ${CMAKECONFIG_INSTALL_DIR} )
243
244 # Install files
245 IF(CMAKE_INSTALL_DIR)
246 INSTALL(FILES
247 ${CMAKE_CURRENT_BINARY_DIR}/${PROJECT_NAME}Config.cmake
248 ${CMAKE_CURRENT_BINARY_DIR}/${PROJECT_NAME}ConfigVersion.cmake
249 DESTINATION "${CMAKE_INSTALL_DIR}"
250 COMPONENT dev)
251 ENDIF()