Debian Codegraph @

packages/zoltan/test/hg_simple/CMakeLists.txt

raw
1 #### Main Zoltan CTEST File
2 #### This file can be copied and modified for new Zoltan test directories.
3 #### It runs script zoltan/test/ctest_zoltan.pl.
4 #### See ctest_zoltan.pl for the list of arguments to provide to it.
5 ####
6 #### To use this file in new test directories, copy it to the new test
7 #### directory. In the copy, modify the number of processors to use in MPI
8 #### runs, ZOLTANNUMPROCS, in the SET command below.
9 #### Also modify the test name (e.g., substitute the new directory name
10 #### for "hg_simple" in all lines below.)
11
12 # Number of processors to use in MPI runs and test directory.
13 SET(ZOLTANNUMPROCS 4)
14
15 # Test directory info.
16 SET(ZZNAME simple)
17 SET(ZZDIRNAME hg_${ZZNAME})
18
19 #### For most test directories, nothing further needs to be changed to change
20 #### the test. (Any directory where the input graph/coords/etc. do not begin
21 #### with ${ZZNAME} is an exception; the copy macro at the end of this file
22 #### must be modified.)
23
24
25 # All data files needed for tested (*.graph, *.mtx, *.mtxp, *.coords, *.hg)
26 FILE(GLOB DATA_INP RELATIVE ${CMAKE_CURRENT_SOURCE_DIR} ${ZZNAME}.*)
27
28 # All zdrive.inp* and hier*inp files needed for testing.
29 FILE(GLOB ZDRIVE_INP RELATIVE ${CMAKE_CURRENT_SOURCE_DIR} zdrive.inp.*)
30 FILE(GLOB HIER_INP RELATIVE ${CMAKE_CURRENT_SOURCE_DIR} hier*.inp)
31
32 # All accepted answer files needed for testing.
33 IF (${PACKAGE_NAME}_ENABLE_ULONG_IDS OR ${PACKAGE_NAME}_ENABLE_ULLONG_IDS)
34 FILE(GLOB ANSWERS RELATIVE ${CMAKE_CURRENT_SOURCE_DIR} answersZOLTANID64/${ZZNAME}.*)
35 ELSE ()
36 FILE(GLOB ANSWERS RELATIVE ${CMAKE_CURRENT_SOURCE_DIR} answers/${ZZNAME}.*)
37 ENDIF()
38
39 # Build test arguments
40 SET(ZOLTAN_TEST_ARGS --np ${ZOLTANNUMPROCS} --debug --mpiexec ${MPI_EXEC} --mpiexecarg ${MPI_EXEC_NUMPROCS_FLAG} --pkg )
41
42 # Parallel Tests
43 TRIBITS_ADD_ADVANCED_TEST(
44 ${ZZDIRNAME}_zoltan_parallel
45 # Test Native Zoltan algorithms in parallel
46 TEST_0 ${ZOLTAN_TEST_DRIVER} ${ZOLTAN_TEST_ARGS} Zoltan
47 CATEGORIES BASIC NIGHTLY PERFORMANCE
48 COMM mpi
49 OVERALL_NUM_MPI_PROCS ${ZOLTANNUMPROCS}
50 FINAL_FAIL_REGULAR_EXPRESSION "FAILED"
51 )
52
53 SET(ZOLTAN_SERIAL_TEST_ARGS --np 1 --debug --pkg )
54
55 # Serial Tests
56 TRIBITS_ADD_ADVANCED_TEST(
57 ${ZZDIRNAME}_zoltan_serial
58 # Test Native Zoltan algorithms in serial
59 TEST_0 ${ZOLTAN_TEST_DRIVER} ${ZOLTAN_SERIAL_TEST_ARGS} Zoltan
60 CATEGORIES BASIC NIGHTLY PERFORMANCE
61 COMM serial
62 FINAL_FAIL_REGULAR_EXPRESSION "FAILED"
63 )
64
65 # Command that copies files to the executable directory.
66 TRIBITS_COPY_FILES_TO_BINARY_DIR(Zoltan_${ZZDIRNAME}_copy_files
67 SOURCE_FILES
68 ${DATA_INP}
69 ${ZDRIVE_INP}
70 ${HIER_INP}
71 ${ANSWERS}
72 EXEDEPS zdrive
73 NOEXEPREFIX
74 )