Debian Codegraph @

packages/seacas/libraries/supes/fre_fld/ffistr.f

raw
1 C Copyright(C) 1999-2020 National Technology & Engineering Solutions
2 C of Sandia, LLC (NTESS). Under the terms of Contract DE-NA0003525 with
3 C NTESS, the U.S. Government retains certain rights in this software.
4 C
5 C See packages/seacas/LICENSE for details
6 SUBROUTINE FFISTR( LINE,MFIELD,IDCONT,NFIELD,KVALUE,CVALUE,IVALUE,
7 * RVALUE )
8 CHARACTER*(*) LINE,CVALUE(MFIELD)
9 CHARACTER*32 CFIELD
10 INTEGER KVALUE(MFIELD),IVALUE(MFIELD)
11 REAL RVALUE(MFIELD)
12
13 INTEGER TABC
14 TABC = 9
15
16 ************************************************************************
17
18 C FREFLD INPUT SYSTEM - ANSI FORTRAN - USER INTERFACE ROUTINE
19
20 C DESCRIPTION:
21 C This routine is the main parsing routine of the SUPES Free Field
22 C Input system. It parses a CHARACTER string into data fields, and
23 C returns the CHARACTER, REAL, and INTEGER value for each field. A
24 C value which indicates whether the character and numeric values
25 C were explicitly defined by a valid string or simply set to a
26 C default blank or zero is also returned.
27
28 C FORMAL PARAMETERS:
29 C LINE CHARACTER Input string.
30 C MFIELD INTEGER Maximum number of data fields to be returned.
31 C IDCONT INTEGER Continuation flag ( 0 = NO continuation )
32 C NFIELD INTEGER Number of data fields found.
33 C KVALUE INTEGER Translation states of the data fields:
34 C -1 = This is a null field.
35 C 0 = This is a non-numeric field.
36 C 1 = This is a REAL numeric field.
37 C 2 = This is an INTEGER numeric field.
38 C CVALUE CHARACTER Character values of the data fields.
39 C RVALUE REAL Floating-point values of the data fields.
40 C IVALUE INTEGER Integer values of the data fields.
41
42 C ROUTINES CALLED:
43 C STRIPB Strip leading/trailing blanks from a string.
44 C EXUPCS Convert a string to ANSI FORTRAN character set.
45 C QUOTED Process a quoted string.
46
47 ************************************************************************
48
49 C Initialize output arrays to their default values and zero field
50 C counter, unless IDCONT indicates that this is a continuation record.
51
52 IF ( IDCONT .EQ. 0 ) THEN
53 DO 300 I = 1 , MFIELD
54 KVALUE(I) = -1
55 CVALUE(I) = ' '
56 RVALUE(I) = 0.
57 IVALUE(I) = 0
58 300 CONTINUE
59 NFIELD = 0
60 END IF
61 IDCONT = 0
62
63 ************************************************************************
64
65 C Isolate the effective portion of the input line. At the end
66 C of this phase LINE(ILEFT:ISTOP) will represent this portion.
67 C The continuation flag IDCONT will indicate whether or not a
68 C continuation line is to follow this record. Exit at any
69 C point where the effective portion of the line becomes null.
70
71 ILEFT = 1
72 ISTOP = LEN ( LINE )
73
74 C Now start processing fields.
75 C Upper range of loop is a dummy maximum.
76
77 c Had to fix more VAX FORTRAN specific stuff. We'll try this only
78 c for a short while. JRR.
79
80 DO 1 IFLD = 1, ISTOP
81
82 CALL STRIPB( LINE(ILEFT:ISTOP), IL, ISTOP )
83 ISTOP = ISTOP + ILEFT - 1
84 ILEFT = IL + ILEFT - 1
85 IF ( ILEFT .GT. ISTOP ) THEN
86
87 C Remainder of line is null.
88
89 RETURN
90 ELSE IF ( LINE(ILEFT:ILEFT) .EQ. '$' ) THEN
91
92 C Rest is comment.
93
94 RETURN
95 ELSE IF ( LINE(ILEFT:ILEFT) .EQ. '*' ) THEN
96
97 C Continuation.
98
99 IDCONT = 1
100 RETURN
101 ELSE IF ( LINE(ILEFT:ILEFT) .EQ. '''' ) THEN
102
103 C This is the beginning of a quoted string. Call a special handler.
104
105 CALL QUOTED ( LINE(ILEFT:ISTOP), IL, IRIGHT )
106 IF ( IRIGHT .NE. 0 ) IRIGHT = IRIGHT + ILEFT - 1
107 ILEFT = IL+ ILEFT - 1
108 ELSE IF ( INDEX ( ',=', LINE(ILEFT:ILEFT) ) .NE. 0 ) THEN
109
110 C This is a null field.
111
112 IRIGHT = 0
113 ELSE
114
115 C Find the end of this token.
116 C Valid delimiters, are ' ', '*', ',', '=', '$'.
117
118 IBLNK = INDEX ( LINE(ILEFT:ISTOP), ' ' ) + ILEFT - 2
119 IAST = INDEX ( LINE(ILEFT:ISTOP), '*' ) + ILEFT - 2
120 ICOMA = INDEX ( LINE(ILEFT:ISTOP), ',' ) + ILEFT - 2
121 IEQLS = INDEX ( LINE(ILEFT:ISTOP), '=' ) + ILEFT - 2
122 IDOLR = INDEX ( LINE(ILEFT:ISTOP), '$' ) + ILEFT - 2
123
124 ITAB = INDEX ( LINE(ILEFT:ISTOP), CHAR(TABC)) + ILEFT - 2
125 IF ( IBLNK .LT. ILEFT ) IBLNK = ISTOP + 1
126 IF ( IAST .LT. ILEFT ) IAST = ISTOP + 1
127 IF ( ICOMA .LT. ILEFT ) ICOMA = ISTOP + 1
128 IF ( IEQLS .LT. ILEFT ) IEQLS = ISTOP + 1
129 IF ( IDOLR .LT. ILEFT ) IDOLR = ISTOP + 1
130 IF ( ITAB .LT. ILEFT ) ITAB = ISTOP + 1
131 IRIGHT = MIN ( IBLNK, IAST, ICOMA, IEQLS, IDOLR,
132 $ ITAB, ISTOP )
133
134 C Convert data to standard character set -
135
136 CALL EXUPCS( LINE(ILEFT:IRIGHT) )
137 END IF
138
139 C Process this field.
140 C Don't process this field unless there is room in the data arrays -
141
142 NFIELD = NFIELD + 1
143 IF ( NFIELD .LE. MFIELD ) THEN
144
145 C Calculate the effective length of this field -
146
147 LFIELD = IRIGHT - ILEFT + 1
148 IF ( LFIELD .LE. 0 ) THEN
149
150 C This is a null field; skip it -
151
152 ELSE IF ( LFIELD .GT. 32 ) THEN
153
154 C This field exceeds the maximum allowable numeric
155 C field size; define only the character value -
156
157 CVALUE(NFIELD) = LINE(ILEFT:IRIGHT)
158 KVALUE(NFIELD) = 0
159 ELSE
160
161 C Define the character value for this field,
162 C then right-justify and attempt numeric translations -
163
164 CVALUE(NFIELD) = LINE(ILEFT:IRIGHT)
165 KVALUE(NFIELD) = 0
166 CFIELD = ' '
167 IJUST = 32 - LFIELD + 1
168 CFIELD(IJUST:32) = LINE(ILEFT:IRIGHT)
169
170 C See if a digit is present in this field.
171 C If there is no digit present, then do not accept
172 C this token as a valid real or integer value.
173 C This is needed, since some systems accept a token like
174 C "E", "Q", "INF", ... as a valid real number even though
175 C no digit appears in the token.
176 IF ( INDEX(CFIELD(IJUST:32),'0').NE.0 .OR.
177 1 INDEX(CFIELD(IJUST:32),'1').NE.0 .OR.
178 2 INDEX(CFIELD(IJUST:32),'2').NE.0 .OR.
179 3 INDEX(CFIELD(IJUST:32),'3').NE.0 .OR.
180 4 INDEX(CFIELD(IJUST:32),'4').NE.0 .OR.
181 5 INDEX(CFIELD(IJUST:32),'5').NE.0 .OR.
182 6 INDEX(CFIELD(IJUST:32),'6').NE.0 .OR.
183 7 INDEX(CFIELD(IJUST:32),'7').NE.0 .OR.
184 8 INDEX(CFIELD(IJUST:32),'8').NE.0 .OR.
185 9 INDEX(CFIELD(IJUST:32),'9').NE.0 ) THEN
186 C ... One more check. If the field contains a digit, but starts with
187 C 'D' or 'E', several systems will interpret this as a valid
188 C Integer and/or real number. This is not the desired behavior
189 IF (CFIELD(IJUST:IJUST) .NE. 'D' .AND.
190 & CFIELD(IJUST:IJUST) .NE. 'E') THEN
191 IDIG = 1
192 ELSE
193 IDIG = 0
194 END IF
195 ELSE
196 IDIG = 0
197 END IF
198
199 C ... It should not be necessary to initialize ITRANS, but the gcc-4.0.0 gfortran
200 C Does not correctly set ITRANS after the first execution if it is non-zero.
201 C It seems to work correctly if initialized to zero.
202 ITRANS = 0
203 READ( CFIELD,3000,IOSTAT=ITRANS ) RFIELD
204 IF ( IDIG .EQ. 1 .AND. ITRANS .EQ. 0 ) THEN
205
206 C This field has a valid floating-point value -
207
208 RVALUE(NFIELD) = RFIELD
209 KVALUE(NFIELD) = 1
210 END IF
211 READ( CFIELD,4000,IOSTAT=ITRANS ) IFIELD
212 IF ( IDIG .EQ. 1 .AND. ITRANS .EQ. 0 ) THEN
213
214 C This field has a valid integer value -
215
216 IVALUE(NFIELD) = IFIELD
217 KVALUE(NFIELD) = 2
218 ELSE IF ( KVALUE(NFIELD) .EQ. 1 .AND.
219 * ABS ( RVALUE(NFIELD) ) .LE. 1.E9 ) THEN
220
221 C This field has a valid real that did not automatically
222 C Translate to an integer. Try to convert the real to an
223 C integer.
224
225 IFIELD = RVALUE(NFIELD)
226 RFIELD = IFIELD
227 IF ( RFIELD .EQ. RVALUE(NFIELD) ) THEN
228
229 C Successful conversion of real to integer.
230
231 IVALUE(NFIELD) = IFIELD
232 KVALUE(NFIELD) = 2
233 END IF
234 END IF
235 END IF
236 END IF
237
238 C Remove any trailing delimiters before looping.
239
240 IF ( IRIGHT .GT. 0 ) ILEFT = MAX ( ILEFT, IRIGHT ) + 1
241 IF ( ILEFT .GT. ISTOP ) RETURN
242 CALL STRIPB( LINE(ILEFT:ISTOP), IL, ISTOP )
243 ISTOP = ISTOP + ILEFT - 1
244 ILEFT = IL + ILEFT - 1
245 IF ( ILEFT .GT. ISTOP ) RETURN
246 IF ( INDEX ( ',=', LINE(ILEFT:ILEFT) ) .NE. 0 )
247 * ILEFT = ILEFT + 1
248 IF ( ILEFT .GT. ISTOP ) RETURN
249 1 continue
250
251 c The end of the VAX FORTRAN DO Loop that I commented out. jrr.
252
253 c END DO
254 3000 FORMAT( F32.0 )
255 4000 FORMAT( I32 )
256
257 END