Debian Codegraph @

packages/seacas/applications/gen3d/g3_splxyz.f

raw
1 C Copyright(C) 1999-2020 National Technology & Engineering Solutions
2 C of Sandia, LLC (NTESS). Under the terms of Contract DE-NA0003525 with
3 C NTESS, the U.S. Government retains certain rights in this software.
4 C
5 C See packages/seacas/LICENSE for details
6
7 C=======================================================================
8 SUBROUTINE SPLXYZ (XN, YN, XN3, YN3, ZN3, IXNP, NRNP, ZCORD,
9 & NSPL1, NSPL2, RSA, ZSA, ZS2A, DISTA, SCRA,
10 & RSB, ZSB, ZS2B, DISTB, SCRB, SLLFT, SLRGT, RDTHET,
11 & SWEEP, NOSCAL)
12 C=======================================================================
13
14 C --*** SPLXYZ *** (GEN3D) Calculate 3D coordinates for Double-surface
15 C Spline projection
16 C -- Written by Greg Sjaardema - 01/08/90
17 C --
18 C --SPLXYZ calculates the coordinate array for the 3D spline translations.
19 C --
20 C --Parameters:
21 C -- XN, YN - IN - the 2D coordinates, destroyed
22 C -- XN3, YN3, ZN3 - OUT - the 3D coordinates
23 C -- IXNP - IN - the new index for each node
24 C -- NRNP - IN - the number of new nodes generated for each node
25 C -- ZCORD - SCRATCH - size = NNREPL, holds z coordinate for transformations
26 C --
27 C --Common Variables:
28 C -- Uses NDIM, NUMNP of /DBNUMS/
29 C -- Uses NDIM3, NUMNP3 of /DBNUM3/
30 C -- Uses DOTRAN, NNREPL, DIM3, NRTRAN, D3TRAN, ZGRAD,
31 C -- CENTER, NUMCOL, NUMROW of /PARAMS/
32
33 INCLUDE 'g3_dbnums.blk'
34 INCLUDE 'g3_dbnum3.blk'
35 INCLUDE 'g3_params.blk'
36
37 PARAMETER (BINGO = 1.0E38)
38 PARAMETER (TOLER = 1.0E-8)
39
40 INTEGER XSWEEP, YSWEEP, SPHERI, SWEEP
41 PARAMETER (XSWEEP = 10)
42 PARAMETER (YSWEEP = 1)
43 PARAMETER (SPHERI = 11)
44
45 REAL XN(NUMNP), YN(NUMNP),
46 & XN3(NUMNP3), YN3(NUMNP3), ZN3(NUMNP3)
47 INTEGER IXNP(*), NRNP(*)
48 REAL ZCORD(NNREPL)
49 REAL RSA(NSPL1), ZSA(NSPL1), ZS2A(NSPL1), DISTA(NSPL1),
50 & SCRA(NSPL1)
51 REAL RSB(NSPL2), ZSB(NSPL2), ZS2B(NSPL2), DISTB(NSPL2),
52 & SCRB(NSPL2)
53 REAL SLLFT(2), SLRGT(2)
54
55 LOGICAL RDTHET, NOSCAL
56
57 PI = ATAN2(0.0, -1.0)
58 xb = 0.0
59 xt = 0.0
60 yb = 0.0
61 yt = 0.0
62
63 C ... Check for valid options...
64 IF (RDTHET .AND. NOSCAL) THEN
65 CALL PRTERR('ERROR', 'Cannot use NOSCALE with ANGULAR spline')
66 RETURN
67 END IF
68
69 C ... CALCULATE THE THICKNESS INCREMENT FOR EACH TRANSLATION
70 IBLK = 0
71 ZTOT = 0.0
72 1 CONTINUE
73 IBLK = IBLK + 1
74 IF (NRTRAN(IBLK) .GT. 0) THEN
75 ZTOT = ZTOT + D3TRAN(IBLK)
76 IF (IBLK .LT. MAXINT) GO TO 1
77 END IF
78
79 NXTNR = 1
80 IBLK = 0
81 ZEND = 0.0
82
83 2 CONTINUE
84 IBLK = IBLK + 1
85 IF (NRTRAN(IBLK) .GT. 0) THEN
86 ZBEG = ZEND
87 ZEND = ZBEG + D3TRAN(IBLK)
88 CALL INIGRD (ZBEG/ZTOT, ZEND/ZTOT, ZGRAD(IBLK),
89 * NRTRAN(IBLK), NRTRAN(IBLK)+1, ZCORD(NXTNR) )
90 NXTNR = NXTNR + NRTRAN(IBLK)
91 IF (IBLK .LT. MAXINT) GO TO 2
92 END IF
93
94 C ... Convert angles from degrees to radians
95
96 IF (RDTHET) THEN
97 DO 10 IPT = 1, NSPL1
98 RSA(IPT) = RSA(IPT) * PI / 180.0
99 10 CONTINUE
100 DO 20 IPT = 1, NSPL2
101 RSB(IPT) = RSB(IPT) * PI / 180.0
102 20 CONTINUE
103
104 END IF
105
106 CALL SPLINE (RSA, ZSA, NSPL1, SLLFT(1), SLRGT(1), ZS2A, SCRA)
107 CALL SPLINE (RSB, ZSB, NSPL2, SLLFT(2), SLRGT(2), ZS2B, SCRB)
108
109 C ... Calculate approximate distance along curve. Distance is computed
110 C as the straight line distance of the segments. Accurate for
111 C smooth curves; bad for non-smooth curves.
112 C ... If 'NOSCALE' is set, then the spline must be linear and
113 C we use the input RSA values for the distance.
114
115 IF (NOSCAL) THEN
116 DO 22 IPT = 1, NSPL1
117 DISTA(IPT) = RSA(IPT)
118 22 CONTINUE
119 DO 24 IPT = 1, NSPL2
120 DISTB(IPT) = RSB(IPT)
121 24 CONTINUE
122 ELSE
123 IF (RDTHET) THEN
124 DISTA(1) = ZSA(1) * SIN(RSA(1))
125 DISTB(1) = ZSB(1) * SIN(RSB(1))
126 DO 30 IPT = 2, NSPL1
127 DISTA(IPT) = DISTA(IPT-1) + SQRT(
128 & (ZSA(IPT) * SIN(RSA(IPT)) -
129 & ZSA(IPT-1) * SIN(RSA(IPT-1)))**2 +
130 & (ZSA(IPT) * COS(RSA(IPT)) -
131 & ZSA(IPT-1) * COS(RSA(IPT-1)))**2)
132 30 CONTINUE
133 DO 40 IPT = 2, NSPL2
134 DISTB(IPT) = DISTB(IPT-1) + SQRT(
135 & (ZSB(IPT) * SIN(RSB(IPT)) -
136 & ZSB(IPT-1) * SIN(RSB(IPT-1)))**2 +
137 & (ZSB(IPT) * COS(RSB(IPT)) -
138 & ZSB(IPT-1) * COS(RSB(IPT-1)))**2)
139 40 CONTINUE
140 ELSE
141 DISTA(1) = RSA(1)
142 DO 50 IPT = 2, NSPL1
143 DISTA(IPT) = SQRT( (RSA(IPT-1) - RSA(IPT))**2 +
144 & (ZSA(IPT-1) - ZSA(IPT))**2 ) + DISTA(IPT-1)
145 50 CONTINUE
146 DISTB(1) = RSB(1)
147 DO 60 IPT = 2, NSPL2
148 DISTB(IPT) = SQRT( (RSB(IPT-1) - RSB(IPT))**2 +
149 & (ZSB(IPT-1) - ZSB(IPT))**2 ) + DISTB(IPT-1)
150 60 CONTINUE
151 END IF
152 END IF
153
154 C... Determine maximum radius of mesh
155
156 RMAX = 0.0
157 RMIN = BINGO
158 IF (SWEEP .EQ. SPHERI) THEN
159 DO 80 INP = 1, NUMNP
160 DX = XN(INP)
161 DY = YN(INP)
162 RMIN = MIN (RMIN, (DX**2 + DY**2))
163 RMAX = MAX (RMAX, (DX**2 + DY**2))
164 80 CONTINUE
165 RMAX = SQRT(RMAX)
166 RMIN = SQRT(RMIN)
167 ELSE IF (SWEEP .EQ. XSWEEP) THEN
168 DO 82 INP = 1, NUMNP
169 DY = YN(INP)
170 RMIN = MIN (RMIN, DY)
171 RMAX = MAX (RMAX, DY)
172 82 CONTINUE
173 ELSE IF (SWEEP .EQ. YSWEEP) THEN
174 DO 84 INP = 1, NUMNP
175 DX = XN(INP)
176 RMIN = MIN (RMIN, DX)
177 RMAX = MAX (RMAX, DX)
178 84 CONTINUE
179 END IF
180
181 C... If there is not a node at 0,0 - RMIN will not equal zero, therefore,
182 C we assume that if the spline starts at zero, the mesh also starts
183 C at zero.
184 IF (DISTA(1) .EQ. 0.0 .OR. DISTB(1) .EQ. 0.0) THEN
185 RMIN = 0.0
186 END IF
187
188 IF (NOSCAL) THEN
189 PROPA = 1.0
190 PROPB = 1.0
191 ELSE
192 PROPA = (DISTA(NSPL1) - DISTA(1)) / (RMAX - RMIN)
193 PROPB = (DISTB(NSPL2) - DISTB(1)) / (RMAX - RMIN)
194 END IF
195
196 C ... Echo spline data
197 WRITE (*,*) ' '
198 WRITE (*,70) 'top spline', DISTA(NSPL1), PROPA
199 WRITE (*,70) 'bottom spline',DISTB(NSPL2), PROPB
200 70 FORMAT (' Total length of ',A,T32,' = ',1PE12.5,
201 & ', Proportion = ',1PE12.5)
202
203 KLOA = 1
204 KLOB = 1
205 DO 100 INP = 1, NUMNP
206 JNP0 = IXNP(INP) - 1
207 DX = XN(INP)
208 DY = YN(INP)
209 RAD = 0.0
210 IF (SWEEP .EQ. SPHERI) THEN
211 RAD = SQRT (DX**2 + DY**2)
212 ELSE IF (SWEEP .EQ. XSWEEP) THEN
213 RAD = DY
214 ELSE IF (SWEEP .EQ. YSWEEP) THEN
215 RAD = DX
216 END IF
217
218 RADA = DISTA(1) + PROPA * (RAD - RMIN)
219 RADB = DISTB(1) + PROPB * (RAD - RMIN)
220
221 C ... Determine segment containing point and proportion within segment
222 C Assume last segment was close to this segment and start search
223 C there.
224
225 CALL HUNT (DISTA, NSPL1, RADA, KLOA)
226 KLOA = MIN(NSPL1-1, MAX(1, KLOA))
227
228 CALL HUNT (DISTB, NSPL2, RADB, KLOB)
229 KLOB = MIN(NSPL2-1, MAX(1, KLOB))
230
231 C ... We want to map the X-Y plane onto the spline surface without
232 C stretching. Therefore, calculate a new radius RNEW which is
233 C the distance from the Z axis to the point on the spline such
234 C that the arc length from R=0 to R=RAD is the distance RNEW.
235 C The new X and Y coordinates corresponding to RNEW are calculated
236 C as the proportion of RNEW / RAD. FIXR is added to RAD in case
237 C RAD is 0; FIXR = 1 iff RAD = 0, else FIXR = 0
238
239 IF (RAD .EQ. 0.0) THEN
240 FIXR = 1.0
241 ELSE
242 FIXR = 0.0
243 END IF
244 C FIXR = SIGN(0.5, RAD) + SIGN(0.5, -RAD)
245
246 PROP = (RADA - DISTA(KLOA)) / (DISTA(KLOA+1) - DISTA(KLOA))
247 RNEWA = RSA(KLOA) + PROP * (RSA(KLOA+1) - RSA(KLOA))
248 PROP = (RADB - DISTB(KLOB)) / (DISTB(KLOB+1) - DISTB(KLOB))
249 RNEWB = RSB(KLOB) + PROP * (RSB(KLOB+1) - RSB(KLOB))
250
251 H = RSA(KLOA+1) - RSA(KLOA)
252 A = (RSA(KLOA+1)-RNEWA) / H
253 B = (RNEWA-RSA(KLOA)) / H
254
255 ZT = A * ZSA(KLOA) + B * ZSA(KLOA+1) +
256 * ((A**3-A) * ZS2A(KLOA)+(B**3-B) * ZS2A(KLOA+1)) * (H**2)/6.
257
258 H = RSB(KLOB+1) - RSB(KLOB)
259 A = (RSB(KLOB+1)-RNEWB) / H
260 B = (RNEWB-RSB(KLOB)) / H
261
262 ZB = A * ZSB(KLOB) + B * ZSB(KLOB+1) +
263 * ((A**3-A) * ZS2B(KLOB)+(B**3-B) * ZS2B(KLOB+1)) * (H**2)/6.
264
265 IF (RDTHET) THEN
266 RSAV = RNEWA
267 ZSAV = ZT
268 ZT = ZSAV * COS(RSAV)
269 RNEWA = ZSAV * SIN(RSAV)
270
271 RSAV = RNEWB
272 ZSAV = ZB
273 ZB = ZSAV * COS(RSAV)
274 RNEWB = ZSAV * SIN(RSAV)
275 END IF
276
277 IF (SWEEP .EQ. SPHERI) THEN
278 C ... Spherical Sweep of Spline Surface
279 XT = RNEWA * DX / (RAD + FIXR)
280 YT = RNEWA * DY / (RAD + FIXR)
281 XB = RNEWB * DX / (RAD + FIXR)
282 YB = RNEWB * DY / (RAD + FIXR)
283
284 ELSE IF (SWEEP .EQ. XSWEEP) THEN
285 C ... Sweep spline along the X axis
286 XT = DX
287 YT = RNEWA * DY / (RAD + FIXR)
288 XB = DX
289 YB = RNEWB * DY / (RAD + FIXR)
290
291 ELSE IF (SWEEP .EQ. YSWEEP) THEN
292 C ... Sweep spline along the X axis
293 XT = RNEWA * DX / (RAD + FIXR)
294 YT = DY
295 XB = RNEWB * DX / (RAD + FIXR)
296 YB = DY
297
298 END IF
299 DELZ = ZT - ZB
300 DELX = XT - XB
301 DELY = YT - YB
302
303 DO 90 NR = 1, NRNP(INP)
304 ZN3(JNP0+NR) = ZT - DELZ * ZCORD(NR)
305 YN3(JNP0+NR) = YT - DELY * ZCORD(NR)
306 XN3(JNP0+NR) = XT - DELX * ZCORD(NR)
307 90 CONTINUE
308 100 CONTINUE
309
310 RETURN
311 END