Debian Codegraph @

cmake/tribits/examples/tpls/Tpl3/CMakeLists.txt

raw
1 cmake_minimum_required(VERSION 3.23.0)
2
3 project(Tpl3
4 DESCRIPTION
5 "Simple TPL with one header file, one library, and depends on Tpl2"
6 LANGUAGES C CXX
7 )
8
9 find_package(Tpl2 REQUIRED)
10
11 add_library(tpl3 Tpl3.hpp Tpl3.cpp)
12 target_include_directories(tpl3
13 PUBLIC $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}>)
14 target_link_libraries(tpl3 PRIVATE tpl2::tpl2a tpl2::tpl2b)
15 # Does CMake maintain the above order?
16
17 include(GNUInstallDirs)
18
19 install(
20 TARGETS tpl3
21 EXPORT ${PROJECT_NAME}
22 INCLUDES DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}
23 )
24
25 install(
26 FILES Tpl3.hpp
27 DESTINATION "${CMAKE_INSTALL_INCLUDEDIR}"
28 )
29
30 install(EXPORT ${PROJECT_NAME}
31 DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/${PROJECT_NAME}
32 NAMESPACE tpl3::
33 FILE ${PROJECT_NAME}ConfigTargets.cmake
34 )
35
36 configure_file(
37 "${CMAKE_CURRENT_SOURCE_DIR}/Tpl3Config.cmake.in"
38 "${CMAKE_CURRENT_BINARY_DIR}/CMakeFiles/Tpl3Config.install.cmake"
39 @ONLY
40 )
41
42 install(
43 FILES "${CMAKE_CURRENT_BINARY_DIR}/CMakeFiles/Tpl3Config.install.cmake"
44 RENAME "Tpl3Config.cmake"
45 DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/${PROJECT_NAME}
46 )