Debian Codegraph @

cmake/tribits/examples/tpls/Tpl2/CMakeLists.txt

raw
1 cmake_minimum_required(VERSION 3.23.0)
2
3 project(Tpl2
4 DESCRIPTION
5 "Simple TPL with two header file, two libraries, and depends on Tpl1"
6 LANGUAGES C CXX
7 )
8
9 find_package(Tpl1 REQUIRED)
10
11
12 add_library(tpl2a Tpl2a.hpp Tpl2a.cpp)
13 target_include_directories(tpl2a
14 PUBLIC $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}>)
15 target_link_libraries(tpl2a PRIVATE tpl1::tpl1)
16
17 add_library(tpl2b Tpl2b.hpp Tpl2b.cpp)
18 target_include_directories(tpl2b
19 PUBLIC $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}>)
20
21 # NOTE: The above libs tpl2a and tpl2b do not depend on each other. They just
22 # depend on tpl1::tpl1.
23
24 include(GNUInstallDirs)
25
26 install(
27 TARGETS tpl2a tpl2b
28 EXPORT ${PROJECT_NAME}
29 INCLUDES DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}
30 )
31
32 install(
33 FILES Tpl2a.hpp Tpl2b.hpp
34 DESTINATION "${CMAKE_INSTALL_INCLUDEDIR}"
35 )
36
37 install(EXPORT ${PROJECT_NAME}
38 DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/${PROJECT_NAME}
39 NAMESPACE tpl2::
40 FILE ${PROJECT_NAME}ConfigTargets.cmake
41 )
42
43 configure_file(
44 "${CMAKE_CURRENT_SOURCE_DIR}/Tpl2Config.cmake.in"
45 "${CMAKE_CURRENT_BINARY_DIR}/CMakeFiles/Tpl2Config.install.cmake"
46 @ONLY
47 )
48
49 install(
50 FILES "${CMAKE_CURRENT_BINARY_DIR}/CMakeFiles/Tpl2Config.install.cmake"
51 RENAME "Tpl2Config.cmake"
52 DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/${PROJECT_NAME}
53 )