Debian Codegraph @

cmake/tribits/examples/TribitsSimpleExampleApp/CMakeLists.txt

raw
1 cmake_minimum_required(VERSION 3.23.1)
2
3 project(TribitsSimpleExApp
4 DESCRIPTION
5 "Example raw CMake project using packages installed from TribitsExampleProject"
6 VERSION 0.0.0
7 LANGUAGES NONE # Defined below after reading in compilers
8 )
9
10 find_package(TribitsExProj REQUIRED
11 COMPONENTS SimpleCxx MixedLang WithSubpackages)
12
13 message("Setting compilers and flags read in from 'TribitsExProjConfig.cmake' file:")
14
15 set(CMAKE_CXX_COMPILER ${TribitsExProj_CXX_COMPILER} )
16 set(CMAKE_C_COMPILER ${TribitsExProj_C_COMPILER} )
17 set(CMAKE_Fortran_COMPILER ${TribitsExProj_Fortran_COMPILER} )
18
19 set(CMAKE_CXX_FLAGS "${TribitsExProj_CXX_COMPILER_FLAGS} ${CMAKE_CXX_FLAGS}")
20 set(CMAKE_C_FLAGS "${TribitsExProj_C_COMPILER_FLAGS} ${CMAKE_C_FLAGS}")
21 set(CMAKE_Fortran_FLAGS "${TribitsExProj_Fortran_COMPILER_FLAGS} ${CMAKE_Fortran_FLAGS}")
22
23 # Enable the compilers now that we have gotten them from TribitsExProjConfig.cmake
24 enable_language(C)
25 enable_language(CXX)
26 if (CMAKE_Fortran_COMPILER)
27 enable_language(Fortran)
28 endif()
29
30 # Build a utility and link to libraries from WithSubpackagesB
31 add_executable(util util.cpp)
32 target_link_libraries(util PRIVATE WithSubpackagesB::all_libs)
33
34 # Build the APP and link to libraries from TribitsExProj packages
35 add_executable(app app.cpp)
36 target_link_libraries(app PRIVATE TribitsExProj::all_selected_libs)
37
38 # Set up tests
39
40 enable_testing()
41
42 if (TARGET SimpleTpl::all_libs)
43 set(simpleCxxDeps "simpletpl headeronlytpl")
44 else()
45 set(simpleCxxDeps "headeronlytpl")
46 endif()
47
48 add_test(NAME util_test COMMAND util)
49 set_tests_properties(util_test PROPERTIES
50 PASS_REGULAR_EXPRESSION "Util Deps: B A SimpleCxx ${simpleCxxDeps} SimpleCxx ${simpleCxxDeps}"
51 )
52
53 add_test(NAME app_test COMMAND app)
54 set_tests_properties(app_test PROPERTIES
55 PASS_REGULAR_EXPRESSION "Full Deps: WithSubpackages:B A SimpleCxx ${simpleCxxDeps} SimpleCxx ${simpleCxxDeps} A SimpleCxx ${simpleCxxDeps}[;] MixedLang:Mixed Language[;] SimpleCxx:${simpleCxxDeps}"
56 )