| 1 |
# @HEADER |
| 2 |
# ***************************************************************************** |
| 3 |
# TriBITS: Tribal Build, Integrate, and Test System |
| 4 |
# |
| 5 |
# Copyright 2013-2016 NTESS and the TriBITS contributors. |
| 6 |
# SPDX-License-Identifier: BSD-3-Clause |
| 7 |
# ***************************************************************************** |
| 8 |
# @HEADER |
| 9 |
|
| 10 |
|
| 11 |
include(PrintVar) |
| 12 |
include(TribitsParseArgumentsHelpers) |
| 13 |
include(TribitsReadTagFile) |
| 14 |
|
| 15 |
|
| 16 |
################################################################################ |
| 17 |
# |
| 18 |
# This module contains functions for constructing CDash URLs to build and test |
| 19 |
# results from inside of a CTest -S script. |
| 20 |
# |
| 21 |
################################################################################ |
| 22 |
|
| 23 |
|
| 24 |
# @FUNCTION: tribits_get_cdash_results_string_and_write_to_file() |
| 25 |
# |
| 26 |
# Calls `tribits_get_cdash_results_urls_string()`_ and then writes the CDash |
| 27 |
# URLs to a file. |
| 28 |
# |
| 29 |
# Usage:: |
| 30 |
# |
| 31 |
# tribits_get_cdash_results_string_and_write_to_file( |
| 32 |
# [CDASH_RESULTS_STRING_OUT <cdashResultsStringOut>] |
| 33 |
# [CDASH_RESULTS_FILE_OUT <cdashResultsFileOut>] |
| 34 |
# ) |
| 35 |
# |
| 36 |
function(tribits_get_cdash_results_string_and_write_to_file) |
| 37 |
# Parse args |
| 38 |
cmake_parse_arguments( PARSE_ARGV 0 |
| 39 |
PARSE "" "" # prefix, options, one_value_keywords |
| 40 |
"CDASH_RESULTS_STRING_OUT;CDASH_RESULTS_FILE_OUT" # multi_value_keywords |
| 41 |
) |
| 42 |
tribits_check_for_unparsed_arguments(PARSE) |
| 43 |
tribits_assert_parse_arg_zero_or_one_value(PARSE CDASH_RESULTS_STRING_OUT |
| 44 |
CDASH_RESULTS_FILE_OUT ) |
| 45 |
# Get and set CDash results URL |
| 46 |
tribits_get_cdash_results_urls_string(cdashResultsString) |
| 47 |
if (PARSE_CDASH_RESULTS_STRING_OUT) |
| 48 |
set(${PARSE_CDASH_RESULTS_STRING_OUT} "${cdashResultsString}" PARENT_SCOPE) |
| 49 |
endif() |
| 50 |
if (PARSE_CDASH_RESULTS_FILE_OUT) |
| 51 |
file(WRITE "${PARSE_CDASH_RESULTS_FILE_OUT}" "${cdashResultsString}") |
| 52 |
endif() |
| 53 |
endfunction() |
| 54 |
|
| 55 |
|
| 56 |
# @FUNCTION: tribits_get_cdash_results_urls_string() |
| 57 |
# |
| 58 |
# Call `tribits_get_cdash_results_urls()`_ and then construct a CDash URLs |
| 59 |
# string fit for printing. |
| 60 |
# |
| 61 |
# Usage:: |
| 62 |
# |
| 63 |
# tribits_get_cdash_results_urls_string( |
| 64 |
# <cdashResultsUrlsStringOut> |
| 65 |
# ) |
| 66 |
# |
| 67 |
# Construct the build and test URLs on CDash given the site name, buildname, |
| 68 |
# and buildstamp (taken from the TAG file) from inside of a running ctest -S |
| 69 |
# program and optionally write it to a file as well. |
| 70 |
# |
| 71 |
function(tribits_get_cdash_results_urls_string cdashResultsUrlsStringOut) |
| 72 |
tribits_get_cdash_results_urls( |
| 73 |
CDASH_BUILD_URL_OUT cdashBuildUrl |
| 74 |
CDASH_REVISION_BUILDS_URL_OUT cdashRevisionBuildsUrl |
| 75 |
CDASH_REVISION_NONPASSING_TESTS_URL_OUT cdashRevisionNonpassingTestsUrl |
| 76 |
) |
| 77 |
tribits_generate_cdash_results_string_from_urls( |
| 78 |
CDASH_BUILD_URL "${cdashBuildUrl}" |
| 79 |
CDASH_REVISION_BUILDS_URL "${cdashRevisionBuildsUrl}" |
| 80 |
CDASH_REVISION_NONPASSING_TESTS_URL "${cdashRevisionNonpassingTestsUrl}" |
| 81 |
CDASH_RESULTS_STRING_OUT cdashResultsUrlsString |
| 82 |
) |
| 83 |
set(${cdashResultsUrlsStringOut} "${cdashResultsUrlsString}" PARENT_SCOPE) |
| 84 |
endfunction() |
| 85 |
|
| 86 |
|
| 87 |
# @FUNCTION: tribits_generate_cdash_results_string_from_urls() |
| 88 |
# |
| 89 |
# Generate the CDash results URL string given the individual URLs. |
| 90 |
# |
| 91 |
# Usage:: |
| 92 |
# |
| 93 |
# tribits_generate_cdash_results_string_from_urls( |
| 94 |
# CDASH_BUILD_URL "<cdashBuildUrl>" |
| 95 |
# [CDASH_REVISION_BUILDS_URL "<cdashRevisionBuildsUrl>"] |
| 96 |
# [CDASH_REVISION_NONPASSING_TESTS_URL "<cdashRevisionNonpassingTestsUrl>"] |
| 97 |
# CDASH_RESULTS_STRING_OUT <cdashResultsUrlsStringOut> |
| 98 |
# ) |
| 99 |
# |
| 100 |
# Takes the URLs returned from `tribits_get_cdash_results_urls()`_ and |
| 101 |
# generates a string out of them which is set in the return var |
| 102 |
# ``<cdashResultsUrlsStringOut>``. |
| 103 |
# |
| 104 |
function(tribits_generate_cdash_results_string_from_urls) |
| 105 |
# Parse args |
| 106 |
cmake_parse_arguments(PARSE_ARGV 0 |
| 107 |
PARSE "" "" # prefix, options, one_value_keywords |
| 108 |
# multi_value_keywords |
| 109 |
"CDASH_BUILD_URL;CDASH_REVISION_BUILDS_URL;CDASH_REVISION_NONPASSING_TESTS_URL;CDASH_RESULTS_STRING_OUT" |
| 110 |
) |
| 111 |
tribits_check_for_unparsed_arguments() |
| 112 |
tribits_assert_parse_arg_one_value(PARSE CDASH_BUILD_URL |
| 113 |
CDASH_RESULTS_STRING_OUT) |
| 114 |
tribits_assert_parse_arg_zero_or_one_value(PARSE CDASH_REVISION_BUILDS_URL |
| 115 |
CDASH_REVISION_NONPASSING_TESTS_URL) |
| 116 |
# Construct CDash results URLs string |
| 117 |
set(cdashResultsString "") |
| 118 |
string(APPEND cdashResultsString |
| 119 |
"Link to this build's results on CDash:\n" |
| 120 |
"\n" |
| 121 |
" ${PARSE_CDASH_BUILD_URL}\n") |
| 122 |
if (PARSE_CDASH_REVISION_BUILDS_URL) |
| 123 |
string(APPEND cdashResultsString |
| 124 |
"\nLink to all builds for this repo version on CDash:\n" |
| 125 |
"\n" |
| 126 |
" ${PARSE_CDASH_REVISION_BUILDS_URL}\n") |
| 127 |
endif() |
| 128 |
if (PARSE_CDASH_REVISION_NONPASSING_TESTS_URL) |
| 129 |
string(APPEND cdashResultsString |
| 130 |
"\nLink to all nonpassing tests for all builds for this repo version on CDash:\n" |
| 131 |
"\n" |
| 132 |
" ${PARSE_CDASH_REVISION_NONPASSING_TESTS_URL}\n") |
| 133 |
endif() |
| 134 |
# Set output |
| 135 |
set(${PARSE_CDASH_RESULTS_STRING_OUT} ${cdashResultsString} PARENT_SCOPE) |
| 136 |
endfunction() |
| 137 |
|
| 138 |
|
| 139 |
# @FUNCTION: tribits_get_cdash_results_urls() |
| 140 |
# |
| 141 |
# Construct the build and test URLs on CDash given the site name, buildname, |
| 142 |
# and buildstamp (taken from the TAG file) from inside of a running ctest -S |
| 143 |
# program and optionally write it to a file as well. |
| 144 |
# |
| 145 |
# Usage:: |
| 146 |
# |
| 147 |
# tribits_get_cdash_results_urls( |
| 148 |
# CDASH_BUILD_URL_OUT <cdashBuildUrlOut> |
| 149 |
# [CDASH_REVISION_BUILDS_URL_OUT <cdashRevisionBuildsUrlOut>] |
| 150 |
# [CDASH_REVISION_NONPASSING_TESTS_URL_OUT <cdashRevisionNonpassingTestsUrlOut>] |
| 151 |
# ) |
| 152 |
# |
| 153 |
# Here, the CDash URLs are constructed the following CMake variables already |
| 154 |
# set in a ``ctest -S`` process: |
| 155 |
# |
| 156 |
# * ``CTEST_DROP_SITE`` |
| 157 |
# * ``CTEST_DROP_LOCATION`` (``submit.php`` is replaced with ``index.php``) |
| 158 |
# * ``CTEST_PROJECT_NAME`` |
| 159 |
# * ``CTEST_SITE`` |
| 160 |
# * ``CTEST_BUILD_NAME`` |
| 161 |
# * ``CTEST_BINARY_DIRECTORY`` |
| 162 |
# * ``CTEST_SOURCE_DIRECTORY`` |
| 163 |
# |
| 164 |
# and other information derived from that. |
| 165 |
# |
| 166 |
# The buildstamp is read in from the file |
| 167 |
# ``${CTEST_BINARY_DIRECTORY}/Testing/TAG``. |
| 168 |
# |
| 169 |
# If available, the revision SHA1 is obtained from the git repo at |
| 170 |
# ``CTEST_SOURCE_DIRECTORY`` if the directory |
| 171 |
# ``${CTEST_SOURCE_DIRECTORY}/.git`` exists. If the base project source |
| 172 |
# directory is not a git reposistory, then ``<cdashRevisionBuildsUrlOut>`` and |
| 173 |
# ``<cdashRevisionNonpassingTestsUrlOut>``, if requested, will be set to |
| 174 |
# empty. |
| 175 |
# |
| 176 |
# Note that the CDash URLs will have ``https://`` added to the beginning so |
| 177 |
# that GitHub Actions and other systems will put in a hyperlink to them. |
| 178 |
# |
| 179 |
function(tribits_get_cdash_results_urls) |
| 180 |
# Parse args |
| 181 |
cmake_parse_arguments(PARSE_ARGV 0 |
| 182 |
PARSE "" "" # prefix, options, one_value_keywords |
| 183 |
# multi_value_keywords |
| 184 |
"CDASH_BUILD_URL_OUT;CDASH_REVISION_BUILDS_URL_OUT;CDASH_REVISION_NONPASSING_TESTS_URL_OUT" |
| 185 |
) |
| 186 |
tribits_check_for_unparsed_arguments(PARSE) |
| 187 |
tribits_assert_parse_arg_one_value(PARSE CDASH_BUILD_URL_OUT) |
| 188 |
tribits_assert_parse_arg_zero_or_one_value(PARSE CDASH_REVISION_BUILDS_URL_OUT |
| 189 |
CDASH_REVISION_NONPASSING_TESTS_URL_OUT) |
| 190 |
# Get the info |
| 191 |
tribits_get_cdash_build_url(cdashBuildUrl) |
| 192 |
tribits_git_repo_sha1("${CTEST_SOURCE_DIRECTORY}" gitRepoSha1 |
| 193 |
FAILURE_MESSAGE_OUT gitRepoSha1FailureMsg) |
| 194 |
if (gitRepoSha1) |
| 195 |
tribits_get_cdash_site_from_drop_site_and_location( |
| 196 |
CTEST_DROP_SITE "${CTEST_DROP_SITE}" |
| 197 |
CTEST_DROP_LOCATION "${CTEST_DROP_LOCATION}" |
| 198 |
CDASH_SITE_URL_OUT cdashSiteUrl |
| 199 |
) |
| 200 |
tribits_get_cdash_revision_builds_url( |
| 201 |
CDASH_SITE_URL "${cdashSiteUrl}" |
| 202 |
PROJECT_NAME "${CTEST_PROJECT_NAME}" |
| 203 |
GIT_REPO_SHA1 "${gitRepoSha1}" |
| 204 |
CDASH_REVISION_BUILDS_URL_OUT cdashRevisionBuildsUrl |
| 205 |
) |
| 206 |
tribits_get_cdash_revision_nonpassing_tests_url( |
| 207 |
CDASH_SITE_URL "${cdashSiteUrl}" |
| 208 |
PROJECT_NAME "${CTEST_PROJECT_NAME}" |
| 209 |
GIT_REPO_SHA1 "${gitRepoSha1}" |
| 210 |
CDASH_REVISION_NONPASSING_TESTS_URL_OUT cdashRevisionNonpassingTestsUrl |
| 211 |
) |
| 212 |
else() |
| 213 |
set(cdashRevisionBuildsUrl "") |
| 214 |
set(cdashRevisionNonpassingTestsUrl "") |
| 215 |
endif() |
| 216 |
# Set the outputs |
| 217 |
set(${PARSE_CDASH_BUILD_URL_OUT} "${cdashBuildUrl}" PARENT_SCOPE) |
| 218 |
set(${PARSE_CDASH_REVISION_BUILDS_URL_OUT} "${cdashRevisionBuildsUrl}" |
| 219 |
PARENT_SCOPE) |
| 220 |
set(${PARSE_CDASH_REVISION_NONPASSING_TESTS_URL_OUT} "${cdashRevisionNonpassingTestsUrl}" |
| 221 |
PARENT_SCOPE) |
| 222 |
endfunction() |
| 223 |
|
| 224 |
|
| 225 |
# @FUNCTION: tribits_get_cdash_revision_builds_url() |
| 226 |
# |
| 227 |
# Get the CDash URL for all builds with the same repo version SHA1 |
| 228 |
# |
| 229 |
# Usage:: |
| 230 |
# |
| 231 |
# tribits_get_cdash_revision_builds_url( |
| 232 |
# CDASH_SITE_URL <cdashSiteUrl> |
| 233 |
# PROJECT_NAME <projectName> |
| 234 |
# GIT_REPO_SHA1 <gitRepoSha1> |
| 235 |
# CDASH_REVISION_BUILDS_URL_OUT <cdashRevisionBuildsUrlOut> |
| 236 |
# ) |
| 237 |
# |
| 238 |
function(tribits_get_cdash_revision_builds_url) |
| 239 |
cmake_parse_arguments(PARSE_ARGV 0 |
| 240 |
PARSE "" "" # prefix, options, one_value_keywords |
| 241 |
# multi_value_keywords |
| 242 |
"CDASH_SITE_URL;PROJECT_NAME;GIT_REPO_SHA1;CDASH_REVISION_BUILDS_URL_OUT" |
| 243 |
) |
| 244 |
tribits_check_for_unparsed_arguments() |
| 245 |
tribits_assert_parse_arg_one_value(PARSE CDASH_SITE_URL PROJECT_NAME |
| 246 |
GIT_REPO_SHA1 CDASH_REVISION_BUILDS_URL_OUT) |
| 247 |
set(${PARSE_CDASH_REVISION_BUILDS_URL_OUT} |
| 248 |
"${PARSE_CDASH_SITE_URL}/index.php?project=${PARSE_PROJECT_NAME}&filtercount=1&showfilters=1&field1=revision&compare1=61&value1=${PARSE_GIT_REPO_SHA1}" |
| 249 |
PARENT_SCOPE) |
| 250 |
endfunction() |
| 251 |
|
| 252 |
|
| 253 |
# @FUNCTION: tribits_get_cdash_revision_nonpassing_tests_url() |
| 254 |
# |
| 255 |
# Get the CDash URL for all non-passing tests with the same repo version SHA1 |
| 256 |
# |
| 257 |
# Usage:: |
| 258 |
# |
| 259 |
# tribits_get_cdash_revision_nonpassing_tests_url( |
| 260 |
# CDASH_SITE_URL <cdashSiteUrl> |
| 261 |
# PROJECT_NAME <projectName> |
| 262 |
# GIT_REPO_SHA1 <gitRepoSha1> |
| 263 |
# CDASH_REVISION_NONPASSING_TESTS_URL_OUT <cdashRevisionNonpassingTestsUrlOut> |
| 264 |
# ) |
| 265 |
# |
| 266 |
function(tribits_get_cdash_revision_nonpassing_tests_url) |
| 267 |
cmake_parse_arguments( PARSE_ARGV 0 |
| 268 |
PARSE "" "" # prefix, options, one_value_keywords |
| 269 |
# multi_value_keywords |
| 270 |
"CDASH_SITE_URL;PROJECT_NAME;GIT_REPO_SHA1;CDASH_REVISION_NONPASSING_TESTS_URL_OUT" |
| 271 |
) |
| 272 |
tribits_check_for_unparsed_arguments() |
| 273 |
tribits_assert_parse_arg_one_value(PARSE CDASH_SITE_URL PROJECT_NAME |
| 274 |
GIT_REPO_SHA1 CDASH_REVISION_NONPASSING_TESTS_URL_OUT) |
| 275 |
set(${PARSE_CDASH_REVISION_NONPASSING_TESTS_URL_OUT} |
| 276 |
"${PARSE_CDASH_SITE_URL}/queryTests.php?project=${PARSE_PROJECT_NAME}&filtercount=2&showfilters=1&filtercombine=and&field1=revision&compare1=61&value1=${PARSE_GIT_REPO_SHA1}&field2=status&compare2=62&value2=passed" |
| 277 |
PARENT_SCOPE) |
| 278 |
endfunction() |
| 279 |
|
| 280 |
|
| 281 |
# @FUNCTION: tribits_get_cdash_build_url() |
| 282 |
# |
| 283 |
# Construct the build URL on CDash given the site name, buildname, and |
| 284 |
# buildstamp (taken from the TAG file) from inside of a running ctest -S |
| 285 |
# program. |
| 286 |
# |
| 287 |
# Usage:: |
| 288 |
# |
| 289 |
# tribits_get_cdash_build_url(<cdashBuildUrlOut>) |
| 290 |
# |
| 291 |
# Here, ``<cdashBuildUrlOut>`` returns the CDash Build URL constructed from |
| 292 |
# the following CMake variables already set in a ``ctest -S`` process: |
| 293 |
# |
| 294 |
# * ``CTEST_DROP_SITE`` |
| 295 |
# * ``CTEST_DROP_LOCATION`` (``submit.php`` is replaced with ``index.php``) |
| 296 |
# * ``CTEST_PROJECT_NAME`` |
| 297 |
# * ``CTEST_SITE`` |
| 298 |
# * ``CTEST_BUILD_NAME`` |
| 299 |
# |
| 300 |
# and the buildstamp read in from the file |
| 301 |
# ``${CTEST_BINARY_DIRECTORY}/Testing/TAG``. |
| 302 |
# |
| 303 |
# Note that ``<cdashBuildUrlOut>`` will have ``https://`` added to the |
| 304 |
# beginning of it so that GitHub Actions and other systems will put in a link |
| 305 |
# to them. |
| 306 |
# |
| 307 |
function(tribits_get_cdash_build_url cdashBuildUrlOut) |
| 308 |
tribits_get_cdash_index_php_from_drop_site_and_location( |
| 309 |
CTEST_DROP_SITE "${CTEST_DROP_SITE}" |
| 310 |
CTEST_DROP_LOCATION "${CTEST_DROP_LOCATION}" |
| 311 |
INDEX_PHP_URL_OUT indexPhpUrl |
| 312 |
) |
| 313 |
tribits_get_cdash_build_url_from_tag_file( |
| 314 |
INDEX_PHP_URL "${indexPhpUrl}" |
| 315 |
PROJECT_NAME "${CTEST_PROJECT_NAME}" |
| 316 |
SITE_NAME "${CTEST_SITE}" |
| 317 |
BUILD_NAME "${CTEST_BUILD_NAME}" |
| 318 |
TAG_FILE "${CTEST_BINARY_DIRECTORY}/Testing/TAG" |
| 319 |
CDASH_BUILD_URL_OUT cdashBuildUrl |
| 320 |
) |
| 321 |
set(${cdashBuildUrlOut} "${cdashBuildUrl}" PARENT_SCOPE) |
| 322 |
endfunction() |
| 323 |
|
| 324 |
|
| 325 |
# @FUNCTION: tribits_print_cdash_url() |
| 326 |
# |
| 327 |
# Print the URL on CDash where build results can be found. |
| 328 |
# |
| 329 |
# Usage:: |
| 330 |
# |
| 331 |
# tribits_print_cdash_url( <msg> <cdashUrl> ) |
| 332 |
# |
| 333 |
function(tribits_print_cdash_url msg cdashUrl) |
| 334 |
message("\n${msg}\n") |
| 335 |
message(" ${cdashUrl}\n") |
| 336 |
endfunction() |
| 337 |
|
| 338 |
|
| 339 |
# @FUNCTION: tribits_get_cdash_build_url_from_tag_file() |
| 340 |
# |
| 341 |
# Create CDash index.php URL from the build parts. |
| 342 |
# |
| 343 |
# Usage:: |
| 344 |
# |
| 345 |
# tribits_get_cdash_build_url_from_tag_file( |
| 346 |
# INDEX_PHP_URL <indexPhpUrl> |
| 347 |
# PROJECT_NAME <projectName> |
| 348 |
# SITE_NAME <siteName> |
| 349 |
# BUILD_NAME <buildName> |
| 350 |
# TAG_FILE <tagFile> |
| 351 |
# CDASH_BUILD_URL_OUT <cdashBuildUrlOut> |
| 352 |
# ) |
| 353 |
# |
| 354 |
# Note that spaces are allowed ``<siteName>`` or ``<buildName>`` and those |
| 355 |
# will be handled correctly to produce a valid URL. |
| 356 |
# |
| 357 |
function(tribits_get_cdash_build_url_from_tag_file) |
| 358 |
# Get arguments |
| 359 |
cmake_parse_arguments( |
| 360 |
PREFIX #prefix |
| 361 |
"" #options |
| 362 |
"INDEX_PHP_URL;PROJECT_NAME;SITE_NAME;BUILD_NAME;TAG_FILE;CDASH_BUILD_URL_OUT" #one_value_keywords |
| 363 |
"" #multi_value_keywords |
| 364 |
${ARGN} |
| 365 |
) |
| 366 |
# Read in the tag file and get the build stamp from that |
| 367 |
tribits_read_ctest_tag_file(${PREFIX_TAG_FILE} buildStartTime cdashGroup |
| 368 |
cdashModel # The model is not used here but we still need to include this arg |
| 369 |
) |
| 370 |
set(buildstamp "${buildStartTime}-${cdashGroup}") |
| 371 |
# Build the URL and return it |
| 372 |
tribits_get_cdash_build_url_from_parts( |
| 373 |
INDEX_PHP_URL "${PREFIX_INDEX_PHP_URL}" |
| 374 |
PROJECT_NAME "${PREFIX_PROJECT_NAME}" |
| 375 |
SITE_NAME "${PREFIX_SITE_NAME}" |
| 376 |
BUILD_NAME "${PREFIX_BUILD_NAME}" |
| 377 |
BUILD_STAMP "${buildstamp}" |
| 378 |
CDASH_BUILD_URL_OUT cdashBuildUrl |
| 379 |
) |
| 380 |
set(${PREFIX_CDASH_BUILD_URL_OUT} "${cdashBuildUrl}" PARENT_SCOPE) |
| 381 |
endfunction() |
| 382 |
|
| 383 |
|
| 384 |
# @FUNCTION: tribits_get_cdash_index_php_from_drop_site_and_location() |
| 385 |
# |
| 386 |
# Get the CDash index.php URL from the input CTEST_DROP_SITE and |
| 387 |
# CTEST_DROP_LOCATION vars used in a ctest -S script. |
| 388 |
# |
| 389 |
function(tribits_get_cdash_index_php_from_drop_site_and_location) |
| 390 |
cmake_parse_arguments( |
| 391 |
PREFIX #prefix |
| 392 |
"" #options |
| 393 |
"CTEST_DROP_SITE;CTEST_DROP_LOCATION;INDEX_PHP_URL_OUT" #one_value_keywords |
| 394 |
"" #multi_value_keywords |
| 395 |
${ARGN} |
| 396 |
) |
| 397 |
tribits_get_cdash_site_from_drop_site_and_location( |
| 398 |
CTEST_DROP_SITE ${PREFIX_CTEST_DROP_SITE} |
| 399 |
CTEST_DROP_LOCATION ${PREFIX_CTEST_DROP_LOCATION} |
| 400 |
CDASH_SITE_URL_OUT cdashSiteUrl ) |
| 401 |
set(${PREFIX_INDEX_PHP_URL_OUT} "${cdashSiteUrl}/index.php" PARENT_SCOPE) |
| 402 |
endfunction() |
| 403 |
|
| 404 |
|
| 405 |
# @FUNCTION: tribits_get_cdash_site_from_drop_site_and_location() |
| 406 |
# |
| 407 |
# Get the full CDash site base URL from the input CTEST_DROP_SITE and |
| 408 |
# CTEST_DROP_LOCATION vars used in a ctest -S script. |
| 409 |
# |
| 410 |
# Usage:: |
| 411 |
# |
| 412 |
# tribits_get_cdash_site_from_drop_site_and_location( |
| 413 |
# CTEST_DROP_SITE <ctestDropSite> |
| 414 |
# CTEST_DROP_LOCATION <ctestDropLocation> |
| 415 |
# CDASH_SITE_URL_OUT <cdashSiteUrlOut> |
| 416 |
# ) |
| 417 |
# |
| 418 |
function(tribits_get_cdash_site_from_drop_site_and_location) |
| 419 |
# Parse args |
| 420 |
cmake_parse_arguments(PARSE_ARGV 0 |
| 421 |
PREFIX #prefix |
| 422 |
"" #options |
| 423 |
"CTEST_DROP_SITE;CTEST_DROP_LOCATION;CDASH_SITE_URL_OUT" #one_value_keywords |
| 424 |
"" #multi_value_keywords |
| 425 |
) |
| 426 |
tribits_check_for_unparsed_arguments(PREFIX) |
| 427 |
tribits_assert_parse_arg_one_value(PREFIX CTEST_DROP_SITE) |
| 428 |
tribits_assert_parse_arg_one_value(PREFIX CTEST_DROP_LOCATION) |
| 429 |
tribits_assert_parse_arg_one_value(PREFIX CDASH_SITE_URL_OUT) |
| 430 |
# Get the full CDash site from parts |
| 431 |
string(FIND "${PREFIX_CTEST_DROP_LOCATION}" "?" beginningOfQueryString) |
| 432 |
string(SUBSTRING "${PREFIX_CTEST_DROP_LOCATION}" 0 ${beginningOfQueryString} submitPhpPart) |
| 433 |
string(REPLACE "/submit.php" "" endCDashUrl "${submitPhpPart}") |
| 434 |
set(cdashSiteUrl "${PREFIX_CTEST_DROP_SITE}${endCDashUrl}") |
| 435 |
set(${PREFIX_CDASH_SITE_URL_OUT} "https://${cdashSiteUrl}" PARENT_SCOPE) |
| 436 |
endfunction() |
| 437 |
|
| 438 |
|
| 439 |
# @FUNCTION: tribits_get_cdash_build_url_from_parts() |
| 440 |
# |
| 441 |
# Create CDash index.php URL from the build parts. |
| 442 |
# |
| 443 |
# Usage:: |
| 444 |
# |
| 445 |
# tribits_get_cdash_build_url_from_parts( |
| 446 |
# INDEX_PHP_URL <indexPhpUrl> |
| 447 |
# PROJECT_NAME <projectName> |
| 448 |
# SITE_NAME <siteName> |
| 449 |
# BUILD_NAME <buildName> |
| 450 |
# BUILD_STAMP <buildStamp> |
| 451 |
# CDASH_BUILD_URL_OUT <cdashBuildUrlOut> |
| 452 |
# ) |
| 453 |
# |
| 454 |
# Note that spaces are allowed ``<siteName>``, ``<buildName>`` or |
| 455 |
# ``<buildStamp>`` and those will be handled correctly to produce a valid URL. |
| 456 |
# |
| 457 |
function(tribits_get_cdash_build_url_from_parts) |
| 458 |
# Get arguments |
| 459 |
cmake_parse_arguments( |
| 460 |
PREFIX #prefix |
| 461 |
"" #options |
| 462 |
"INDEX_PHP_URL;PROJECT_NAME;SITE_NAME;BUILD_NAME;BUILD_STAMP;CDASH_BUILD_URL_OUT" #one_value_keywords |
| 463 |
"" #multi_value_keywords |
| 464 |
${ARGN} |
| 465 |
) |
| 466 |
# Do replacements for spaces and special chars in data |
| 467 |
tribits_replace_chars_for_url("${PREFIX_PROJECT_NAME}" project) |
| 468 |
tribits_replace_chars_for_url("${PREFIX_SITE_NAME}" site) |
| 469 |
tribits_replace_chars_for_url("${PREFIX_BUILD_NAME}" buildname) |
| 470 |
tribits_replace_chars_for_url("${PREFIX_BUILD_STAMP}" buildstamp) |
| 471 |
# Build the URL |
| 472 |
set(cdashIndexProj "${PREFIX_INDEX_PHP_URL}?project=${project}") |
| 473 |
set(filtersPreTxt "filtercount=3&showfilters=1&filtercombine=and") |
| 474 |
set(siteFlt "field1=site&compare1=61&value1=${site}") |
| 475 |
set(buildnameFlt "field2=buildname&compare2=61&value2=${buildname}") |
| 476 |
set(buildStampFlt "field3=buildstamp&compare3=61&value3=${buildstamp}") |
| 477 |
set(cdashBuildUrl |
| 478 |
"${cdashIndexProj}&${filtersPreTxt}&${siteFlt}&${buildnameFlt}&${buildStampFlt}") |
| 479 |
set(${PREFIX_CDASH_BUILD_URL_OUT} "${cdashBuildUrl}" PARENT_SCOPE) |
| 480 |
endfunction() |
| 481 |
|
| 482 |
|
| 483 |
# Replace chars in a regular string for usage in a URL with CDash |
| 484 |
# |
| 485 |
function(tribits_replace_chars_for_url inputStr outputStrForUrlOutVar) |
| 486 |
set(outputStrForUrl "${inputStr}") |
| 487 |
string(REPLACE " " "%20" outputStrForUrl "${outputStrForUrl}") |
| 488 |
string(REPLACE "+" "%2B" outputStrForUrl "${outputStrForUrl}") |
| 489 |
set(${outputStrForUrlOutVar} "${outputStrForUrl}" PARENT_SCOPE) |
| 490 |
endfunction() |
| 491 |
|
| 492 |
# LocalWords: GitHub tribits url buildname buildstamp |
| 493 |
# LocalWords: tribits TRIBITS |
| 494 |
# LocalWords: cmake CMake CMAKE |
| 495 |
# LocalWords: ctest CTEST cdash CDash CDASH |
| 496 |
# LocalWords: SUBSTRING |
| 497 |
# LocalWords: endif endfunction |