Debian Codegraph @

cmake/tribits/core/installation/TribitsProjectConfigTemplate.cmake.in

raw
1 # @HEADER
2 # *****************************************************************************
3 # TriBITS: Tribal Build, Integrate, and Test System
4 #
5 # Copyright 2013-2016 NTESS and the TriBITS contributors.
6 # SPDX-License-Identifier: BSD-3-Clause
7 # *****************************************************************************
8 # @HEADER
9
10 ##############################################################################
11 #
12 # CMake variable for use by ${PROJECT_NAME} clients.
13 #
14 # ${DISCOURAGE_EDITING}
15 #
16 ##############################################################################
17
18 if(CMAKE_VERSION VERSION_LESS 3.3)
19 set(${PDOLLAR}{CMAKE_FIND_PACKAGE_NAME}_NOT_FOUND_MESSAGE
20 "${PROJECT_NAME} requires CMake 3.3 or later for 'if (... IN_LIST ...)'"
21 )
22 set(${PDOLLAR}{CMAKE_FIND_PACKAGE_NAME}_FOUND FALSE)
23 return()
24 endif()
25 cmake_minimum_required(VERSION 3.3...${TRIBITS_CMAKE_MINIMUM_REQUIRED})
26
27 ## ---------------------------------------------------------------------------
28 ## Compilers used by ${PROJECT_NAME} build
29 ## ---------------------------------------------------------------------------
30
31 set(${PROJECT_NAME}_CXX_COMPILER "${CMAKE_CXX_COMPILER_FOR_CONFIG_FILE}")
32
33 set(${PROJECT_NAME}_C_COMPILER "${CMAKE_C_COMPILER_FOR_CONFIG_FILE}")
34
35 set(${PROJECT_NAME}_Fortran_COMPILER "${CMAKE_Fortran_COMPILER_FOR_CONFIG_FILE}")
36
37 ## ---------------------------------------------------------------------------
38 ## Compiler flags used by ${PROJECT_NAME} build
39 ## ---------------------------------------------------------------------------
40
41 set(${PROJECT_NAME}_CMAKE_BUILD_TYPE "${CMAKE_BUILD_TYPE}")
42
43 set(${PROJECT_NAME}_CXX_COMPILER_FLAGS [[${CMAKE_CXX_FLAGS} ${CMAKE_CXX_FLAGS_${CMAKE_BUILD_TYPE}}]])
44
45 set(${PROJECT_NAME}_C_COMPILER_FLAGS [[${CMAKE_C_FLAGS} ${CMAKE_C_FLAGS_${CMAKE_BUILD_TYPE}}]])
46
47 set(${PROJECT_NAME}_Fortran_COMPILER_FLAGS [[${CMAKE_Fortran_FLAGS} ${CMAKE_Fortran_FLAGS_${CMAKE_BUILD_TYPE}}]])
48
49 ## Extra link flags (e.g., specification of fortran libraries)
50 set(${PROJECT_NAME}_EXTRA_LD_FLAGS [[${${PROJECT_NAME}_EXTRA_LINK_FLAGS}]])
51
52 ## This is the command-line entry used for setting rpaths. In a build
53 ## with static libraries it will be empty.
54 set(${PROJECT_NAME}_SHARED_LIB_RPATH_COMMAND "${SHARED_LIB_RPATH_COMMAND}")
55 set(${PROJECT_NAME}_BUILD_SHARED_LIBS "${BUILD_SHARED_LIBS}")
56
57 set(${PROJECT_NAME}_LINKER ${CMAKE_LINKER})
58 set(${PROJECT_NAME}_AR ${CMAKE_AR})
59
60
61 ## ---------------------------------------------------------------------------
62 ## Set library specifications and paths
63 ## ---------------------------------------------------------------------------
64
65 ## The project version number
66 set(${PROJECT_NAME}_VERSION "${${PROJECT_NAME}_VERSION}")
67
68 # For best practices in handling of components, see
69 # <http://www.cmake.org/cmake/help/v3.2/manual/cmake-developer.7.html#find-modules>.
70 #
71 # If components were requested, include only those. If not, include all of
72 # Trilinos.
73 if (${PROJECT_NAME}_FIND_COMPONENTS)
74 set(COMPONENTS_LIST ${PDOLLAR}{${PROJECT_NAME}_FIND_COMPONENTS})
75 else()
76 set(COMPONENTS_LIST ${FULL_PACKAGE_SET})
77 endif()
78
79 # Initialize ${PROJECT_NAME}_FOUND with true, and set it to FALSE if any of
80 # the required components wasn't found.
81 set(${PROJECT_NAME}_FOUND TRUE)
82 set(${PROJECT_NAME}_NOT_FOUND_MESSAGE "")
83 set(selectedComponentsFound "")
84 foreach (comp IN ITEMS ${PDOLLAR}{COMPONENTS_LIST})
85 set(compPkgConfigFile
86 ${PDOLLAR}{CMAKE_CURRENT_LIST_DIR}/../${PDOLLAR}{comp}/${PDOLLAR}{comp}Config.cmake
87 )
88 if (EXISTS ${PDOLLAR}{compPkgConfigFile})
89 # Set ${PROJECT_NAME}_<component>_FOUND.
90 set(${PROJECT_NAME}_${PDOLLAR}{comp}_FOUND TRUE)
91 # Include the package file.
92 include(${PDOLLAR}{compPkgConfigFile})
93 # Add variables to lists.
94 list(APPEND ${PROJECT_NAME}_LIBRARIES ${PDOLLAR}{${PDOLLAR}{comp}_LIBRARIES})
95 list(APPEND selectedComponentsFound ${PDOLLAR}{comp})
96 else()
97 set(${PROJECT_NAME}_${PDOLLAR}{comp}_FOUND FALSE)
98 if(${PROJECT_NAME}_FIND_REQUIRED_${PDOLLAR}{comp})
99 string(APPEND ${PROJECT_NAME}_NOT_FOUND_MESSAGE
100 "ERROR: Could not find component '${PDOLLAR}{comp}'!\n")
101 set(${PROJECT_NAME}_FOUND FALSE)
102 endif()
103 endif()
104 endforeach()
105
106 # Deprecated (see #299)!
107 set(${PROJECT_NAME}_INCLUDE_DIRS "${TRIBITS_PROJECT_INSTALL_INCLUDE_DIR}")
108
109 # Remove duplicates in ${PROJECT_NAME}_LIBRARIES
110 list(REMOVE_DUPLICATES ${PROJECT_NAME}_LIBRARIES)
111
112 ## ---------------------------------------------------------------------------
113 ## MPI specific variables
114 ## These variables are provided to make it easier to get the mpi libraries
115 ## and includes on systems that do not use the mpi wrappers for compiling
116 ## ---------------------------------------------------------------------------
117
118 set(${PROJECT_NAME}_INSTALL_DIR "${CMAKE_INSTALL_PREFIX}")
119 set(${PROJECT_NAME}_MPI_LIBRARIES "${TPL_MPI_LIBRARIES}")
120 set(${PROJECT_NAME}_MPI_LIBRARY_DIRS "${TPL_MPI_LIBRARY_DIRS}")
121 set(${PROJECT_NAME}_MPI_INCLUDE_DIRS "${TPL_MPI_INCLUDE_DIRS}")
122 set(${PROJECT_NAME}_MPI_EXEC "${MPI_EXEC}")
123 set(${PROJECT_NAME}_MPI_EXEC_PRE_NUMPROCS_FLAGS "${MPI_EXEC_PRE_NUMPROCS_FLAGS}")
124 set(${PROJECT_NAME}_MPI_EXEC_MAX_NUMPROCS "${MPI_EXEC_MAX_NUMPROCS}")
125 set(${PROJECT_NAME}_MPI_EXEC_POST_NUMPROCS_FLAGS "${MPI_EXEC_POST_NUMPROCS_FLAGS}")
126 set(${PROJECT_NAME}_MPI_EXEC_NUMPROCS_FLAG "${MPI_EXEC_NUMPROCS_FLAG}")
127
128 ## ---------------------------------------------------------------------------
129 ## Compiler vendor identifications
130 ## ---------------------------------------------------------------------------
131 set(${PROJECT_NAME}_SYSTEM_NAME "${CMAKE_SYSTEM_NAME}")
132 set(${PROJECT_NAME}_CXX_COMPILER_ID "${CMAKE_CXX_COMPILER_ID}")
133 set(${PROJECT_NAME}_C_COMPILER_ID "${CMAKE_C_COMPILER_ID}")
134 set(${PROJECT_NAME}_Fortran_COMPILER_ID "${CMAKE_Fortran_COMPILER_ID}")
135 set(${PROJECT_NAME}_Fortran_IMPLICIT_LINK_LIBRARIES "${CMAKE_Fortran_IMPLICIT_LINK_LIBRARIES}")
136
137 ## ---------------------------------------------------------------------------
138 ## Set useful general variables
139 ## ---------------------------------------------------------------------------
140
141 ## The packages enabled for this project
142 set(${PROJECT_NAME}_PACKAGE_LIST "${FULL_PACKAGE_SET}")
143
144 ## The selected packages for this project
145 set(${PROJECT_NAME}_SELECTED_PACKAGE_LIST "${PDOLLAR}{selectedComponentsFound}")
146
147 ## ---------------------------------------------------------------------------
148 ## Modern CMake (IMPORTED) targets
149 ## ---------------------------------------------------------------------------
150
151 # ${PROJECT_NAME}::all_libs (Does *not* depend on COMPONENTS)
152 if (NOT TARGET ${PROJECT_NAME}::all_libs)
153 set(${PROJECT_NAME}_ALL_PACKAGES_TARGETS)
154 foreach (pkg IN ITEMS ${FULL_PACKAGE_SET})
155 list(APPEND ${PROJECT_NAME}_ALL_PACKAGES_TARGETS ${PDOLLAR}{pkg}::all_libs)
156 endforeach()
157 add_library(${PROJECT_NAME}::all_libs IMPORTED INTERFACE GLOBAL)
158 target_link_libraries(${PROJECT_NAME}::all_libs
159 INTERFACE ${PDOLLAR}{${PROJECT_NAME}_ALL_PACKAGES_TARGETS} )
160 endif()
161
162 # ${PROJECT_NAME}::all_selected_libs (Depend on COMPONENTS)
163 if (NOT TARGET ${PROJECT_NAME}::all_selected_libs)
164 set(${PROJECT_NAME}_ALL_SELECTED_PACKAGES_TARGETS)
165 foreach (pkg IN ITEMS ${PDOLLAR}{selectedComponentsFound})
166 list(APPEND ${PROJECT_NAME}_ALL_SELECTED_PACKAGES_TARGETS ${PDOLLAR}{pkg}::all_libs)
167 endforeach()
168 add_library(${PROJECT_NAME}::all_selected_libs IMPORTED INTERFACE GLOBAL)
169 target_link_libraries(${PROJECT_NAME}::all_selected_libs
170 INTERFACE ${PDOLLAR}{${PROJECT_NAME}_ALL_SELECTED_PACKAGES_TARGETS} )
171 endif()