Debian Codegraph @

texmf-dist/fonts/source/public/phonetic/symchar.mf

raw
1 % More character codes. Created by Emma Pease, CSLI,
2 % Stanford University. Based for the most part on computer modern characters
3
4 % down hook and up hook were created in order to form hookuparrows and
5 % hookdownarrows
6
7 cmchar "Down hook";
8 compute_spread(.45x_height#,.55x_height#);
9 beginchar(oct"173",5u#,v_center(2spread#+rule_thickness#));
10 adjust_fit(0,0); pickup rule.nib; autorounded;
11 rt x2=hround(w-u)+eps; x1=x3=w-x2;
12 y1-y3=spread; y2=.5[y1,y3]; y3=math_axis;
13 draw z1{right}...z2{down}...z3{left}; % hook
14 currentpicture:=currentpicture rotatedaround ((.5w,y2),90);
15 labels(1,2,3); endchar;
16
17 cmchar "Up hook";
18 compute_spread(.45x_height#,.55x_height#);
19 beginchar(oct"174",5u#,v_center(2spread#+rule_thickness#));
20 adjust_fit(0,0); pickup rule.nib; autorounded;
21 rt x2=hround(w-u)+eps; x1=x3=w-x2;
22 y1-y3=spread; y2=.5[y1,y3]; y3=math_axis;
23 draw z1{right}...z2{down}...z3{left}; % hook
24 currentpicture:=currentpicture rotatedaround ((.5w,y2),-90);
25 labels(1,2,3); endchar;
26
27 cmchar "2bsquare";
28 beginchar(oct"176",9u#,fig_height#,comma_depth#);
29 adjust_fit(0,0); pickup rule.nib;
30 x1=x4=x8=x7; x2=x3=x5=x6; top y1=top y2=h;
31 y3=.6[y2,math_axis]; y3=y4; y5=y8; y7=y6;
32 y5=.6[y6,math_axis]; math_axis=.5[y3,y5];
33 y1-y4=x3-x4; lft x4=w-rt x3;
34 filldraw z1--z2--z3--z4--cycle;
35 filldraw z5--z6--z7--z8--cycle;
36 labels(1,2,3,4,5,6,7,8); endchar;
37
38
39 cmchar "bsquare";
40 beginchar(oct"175",9u#,v_center(7u#));
41 adjust_fit(0,0); pickup rule.nib;
42 numeric a; a=sqrt(3.14159);
43 lft x6=lft x7=lft x5=hround (w/2 - (w-2u)*a/4);
44 x2=x1=x3=w-x6; top y1=top y7=h;
45 y6=y2=math_axis; y5=y3; z2=.5[z3,z1];
46 filldraw z1--z2--z3--z5--z7--cycle;
47 labels(1,2,3,5,7); endchar;