Debian Codegraph @

texmf-dist/fonts/source/public/mnsymbol/Sym-Arrows.mf

raw
1
2 def ifneg(expr a,b) =
3 if negated: a else: b fi
4 enddef;
5
6 for alpha = 0, 90, 180, 270, 45, 135, 225, 315:
7 beginarrow(alpha, 1, ifneg(3/2, 1) * arrow_spread#); "single arrow (" & decimal alpha & ")";
8 pickup rule_pen;
9 draw foot -- head;
10 draw arrowhead(head, arrow_dir, arrow_spread);
11
12 if negated:
13 stroke_through_arrow(1/2[foot, head - 1/2arrow_spread * dir arrow_dir], alpha, 3/2arrow_spread)
14 (70, 70, 110, 110, 70, 70, 110, 110);
15 fi
16 endchar;
17 endfor;
18
19 for alpha = 0, 90, 180, 270, 45, 135, 225, 315:
20 beginarrow(alpha, 6/5, ifneg(19/10, 13/10) * arrow_spread#); "double arrow (" & decimal alpha & ")";
21 pickup rule_pen;
22
23 z1 - z0 = z3 - z2 = equal_spread * dir (arrow_dir + 90);
24
25 1/2[z0,z1] = foot;
26 1/2[z2,z3] = head;
27
28 draw z0 -- arrowhead_intersection(head, arrow_dir, 13/10arrow_spread, z0 -- z2);
29 draw z1 -- arrowhead_intersection(head, arrow_dir, 13/10arrow_spread, z1 -- z3);
30
31 draw arrowhead(head, arrow_dir, 13/10arrow_spread);
32
33 if negated:
34 stroke_through_arrow(1/2[foot, head - arrow_spread * dir arrow_dir], alpha, 19/10arrow_spread)
35 (70, 70, 110, 110, 70, 70, 110, 110);
36 fi
37 endchar;
38 endfor;
39
40 for alpha = 0, 90, 45, 135:
41 beginarrow(alpha, 6/5, ifneg(3/2, 1) * arrow_spread#); "bidirectinal arrow (" & decimal alpha & ")";
42 pickup rule_pen;
43 draw foot -- head;
44 draw arrowhead(head, arrow_dir, arrow_spread);
45 draw arrowhead(foot, arrow_dir+180, arrow_spread);
46
47 if negated:
48 stroke_through_arrow(1/2[foot, head], alpha, 3/2arrow_spread)
49 (70, 70, 110, 110, 70, 70, 110, 110);
50 fi
51 endchar;
52 endfor;
53
54 for alpha = 0, 90, 45, 135:
55 beginarrow(alpha, 7/5, ifneg(19/10, 13/10) * arrow_spread#); "double bidirectional arrow (" & decimal alpha & ")";
56 pickup rule_pen;
57
58 z1 - z0 = z3 - z2 = equal_spread * dir (arrow_dir + 90);
59
60 1/2[z0,z1] = foot;
61 1/2[z2,z3] = head;
62
63 draw arrowhead_intersection(foot, arrow_dir+180, 13/10arrow_spread, z0 -- z2)
64 -- arrowhead_intersection(head, arrow_dir, 13/10arrow_spread, z0 -- z2);
65 draw arrowhead_intersection(foot, arrow_dir+180, 13/10arrow_spread, z1 -- z3)
66 -- arrowhead_intersection(head, arrow_dir, 13/10arrow_spread, z1 -- z3);
67 draw arrowhead(head, arrow_dir, 13/10arrow_spread);
68 draw arrowhead(foot, arrow_dir+180, 13/10arrow_spread);
69
70 if negated:
71 stroke_through_arrow(1/2[foot, head], alpha, 19/10arrow_spread)
72 (70, 70, 110, 110, 70, 70, 110, 110);
73 fi
74 endchar;
75 endfor;
76
77 for alpha = 0, 90, 180, 270, 45, 135, 225, 315:
78 beginarrow(alpha, 5/4, ifneg(3/2, 1) * arrow_spread#); "double-head arrow (" & decimal alpha & ")";
79 pickup rule_pen;
80 draw foot -- head;
81 draw arrowhead(head, arrow_dir, arrow_spread);
82 draw arrowhead(head - 1/4arrow_len * dir arrow_dir, arrow_dir, arrow_spread);
83
84 if negated:
85 stroke_through_arrow(1/2[foot, head - (1/2arrow_spread + 1/4arrow_len) * dir arrow_dir], alpha, 3/2arrow_spread)
86 (70, 70, 110, 110, 70, 70, 110, 110);
87 fi
88 endchar;
89 endfor;
90
91 for alpha = 0, 90, 180, 270, 45, 135, 225, 315:
92 beginarrow(alpha, 1, ifneg(3/2, 1) * arrow_spread#); "tailed arrow (" & decimal alpha & ")";
93 pickup rule_pen;
94
95 z0 = foot + 3/4arrow_spread * dir arrow_dir;
96
97 draw z0 -- head;
98 draw arrowhead(head, arrow_dir, arrow_spread);
99 draw arrowhead(z0, arrow_dir, arrow_spread);
100
101 if negated:
102 stroke_through_arrow(1/2[foot, head], alpha, 3/2arrow_spread)
103 (70, 70, 110, 110, 70, 70, 110, 110);
104 fi
105 endchar;
106 endfor;
107
108 for alpha = 0, 90, 180, 270, 45, 135, 225, 315:
109 beginarrow(alpha, 1, ifneg(3/2, 1) * arrow_spread#); "arrow with foot (" & decimal alpha & ")";
110 pickup rule_pen;
111
112 draw foot + 1/4rule_thickness * dir arrow_dir -- head;
113 draw (foot - 1/2arrow_spread * dir (arrow_dir + 90)) --
114 (foot + 1/2arrow_spread * dir (arrow_dir + 90));
115 draw arrowhead(head, arrow_dir, arrow_spread);
116
117 if negated:
118 stroke_through_arrow(1/2[foot, head - 1/2arrow_spread * dir arrow_dir], alpha, 3/2arrow_spread)
119 (70, 70, 110, 110, 70, 70, 110, 110);
120 fi
121 endchar;
122 endfor;
123
124 for alpha = 0, 90, 180, 270, 45, 135, 225, 315:
125 beginarrow(alpha, 1, ifneg(3/2, 1) * arrow_spread#); "left embedding (" & decimal alpha & ")";
126 pickup rule_pen;
127
128 draw arrowhead(head, arrow_dir, arrow_spread);
129 draw half_circle(foot + 1/4arrow_spread * (dir (arrow_dir + 90) + dir arrow_dir),
130 1/4arrow_spread, arrow_dir + 90)
131 -- head;
132
133 if negated:
134 stroke_through_arrow(1/2[foot, head - 1/2arrow_spread * dir arrow_dir], alpha, 3/2arrow_spread)
135 (70, 70, 110, 110, 70, 70, 110, 110);
136 fi
137 endchar;
138 endfor;
139
140 for alpha = 0, 90, 180, 270, 45, 135, 225, 315:
141 beginarrow(alpha, 1, ifneg(3/2, 1) * arrow_spread#); "right embedding (" & decimal alpha & ")";
142 pickup rule_pen;
143
144 draw arrowhead(head, arrow_dir, arrow_spread);
145 draw head -- half_circle(foot + 1/4arrow_spread * (dir (arrow_dir - 90) + dir arrow_dir),
146 1/4arrow_spread, arrow_dir + 90);
147
148 if negated:
149 stroke_through_arrow(1/2[foot, head - 1/2arrow_spread * dir arrow_dir], alpha, 3/2arrow_spread)
150 (70, 70, 110, 110, 70, 70, 110, 110);
151 fi
152 endchar;
153 endfor;
154
155 for alpha = 0, 90, 180, 270, 45, 135, 225, 315:
156 beginarrow(alpha, 1, ifneg(3/2, 1) * arrow_spread#); "left harpoon (" & decimal alpha & ")";
157 pickup rule_pen;
158 draw foot -- head;
159 draw arrowhead_left(head, arrow_dir, arrow_spread);
160
161 if negated:
162 stroke_through_arrow(1/2[foot, head - 1/2arrow_spread * dir arrow_dir], alpha, 3/2arrow_spread)
163 (70, 70, 110, 110, 70, 70, 110, 110);
164 fi
165 endchar;
166 endfor;
167
168 for alpha = 0, 90, 180, 270, 45, 135, 225, 315:
169 beginarrow(alpha, 1, ifneg(3/2, 1) * arrow_spread#); "right harpoon (" & decimal alpha & ")";
170 pickup rule_pen;
171 draw foot -- head;
172 draw arrowhead_right(head, arrow_dir, arrow_spread);
173
174 if negated:
175 stroke_through_arrow(1/2[foot, head - 1/2arrow_spread * dir arrow_dir], alpha, 3/2arrow_spread)
176 (70, 70, 110, 110, 70, 70, 110, 110);
177 fi
178 endchar;
179 endfor;
180
181 for alpha = 0, 90, 45, 135:
182 beginarrow(alpha, 1, ifneg(3/2, 1) * arrow_spread#); "left left harpoon (" & decimal alpha & ")";
183 pickup rule_pen;
184 draw foot -- head;
185 draw arrowhead_left(head, arrow_dir, arrow_spread);
186 draw arrowhead_left(foot, arrow_dir+180, arrow_spread);
187
188 if negated:
189 stroke_through_arrow(1/2[foot, head], alpha, 3/2arrow_spread)
190 (80, 80, 110, 110);
191 fi
192 endchar;
193 endfor;
194
195 for alpha = 0, 90, 45, 135:
196 beginarrow(alpha, 1, ifneg(3/2, 1) * arrow_spread#); "right right harpoon (" & decimal alpha & ")";
197 pickup rule_pen;
198 draw foot -- head;
199 draw arrowhead_right(head, arrow_dir, arrow_spread);
200 draw arrowhead_right(foot, arrow_dir+180, arrow_spread);
201
202 if negated:
203 stroke_through_arrow(1/2[foot, head], alpha, 3/2arrow_spread)
204 (70, 70, 100, 100);
205 fi
206 endchar;
207 endfor;
208
209 for alpha = 0, 90, 45, 135:
210 beginarrow(alpha, 1, ifneg(3/2, 1) * arrow_spread# + equal_spread#); "double left left harpoon (" & decimal alpha & ")";
211 pickup rule_pen;
212
213 z1 - z0 = z3 - z2 = equal_spread * dir (arrow_dir + 90);
214
215 0.5[z0,z1] = foot;
216 0.5[z2,z3] = head;
217
218 draw z0 -- z2;
219 draw z1 -- z3;
220 draw arrowhead_left(z3, arrow_dir, arrow_spread);
221 draw arrowhead_left(z0, arrow_dir+180, arrow_spread);
222
223 if negated:
224 stroke_through_arrow(1/2[foot, head], alpha, 3/2arrow_spread + equal_spread)
225 (80, 80, 110, 110);
226 fi
227 endchar;
228 endfor;
229
230 for alpha = 0, 90, 45, 135:
231 beginarrow(alpha, 1, ifneg(3/2, 1) * arrow_spread# + equal_spread#); "double right right harpoon (" & decimal alpha & ")";
232 pickup rule_pen;
233
234 z1 - z0 = z3 - z2 = equal_spread * dir (arrow_dir + 90);
235
236 0.5[z0,z1] = foot;
237 0.5[z2,z3] = head;
238
239 draw z0 -- z2;
240 draw z1 -- z3;
241 draw arrowhead_right(z2, arrow_dir, arrow_spread);
242 draw arrowhead_right(z1, arrow_dir+180, arrow_spread);
243
244 if negated:
245 stroke_through_arrow(1/2[foot, head], alpha, 3/2arrow_spread + equal_spread)
246 (70, 70, 100, 100);
247 fi
248 endchar;
249 endfor;
250
251 for alpha = 0, 90, 180, 270, 45, 135, 225, 315:
252 beginarrow(alpha, 1, ifneg(3/2, 1) * arrow_spread#); "broken arrow (" & decimal alpha & ")";
253 pickup rule_pen;
254
255 z0 = ifneg( 2/10, 3/10)[foot,head];
256 z1 = ifneg(13/20,11/20)[foot,head];
257
258 draw foot -- z0;
259 draw z1 -- head;
260 draw arrowhead(head, arrow_dir, arrow_spread);
261
262 if negated:
263 stroke_through_arrow(1/2[z0, z1], alpha, 3/2arrow_spread)
264 (70, 70, 110, 110, 70, 70, 110, 110);
265 fi
266 endchar;
267 endfor;
268
269 for alpha = 0, 90, 180, 270, 45, 135, 225, 315:
270 beginarrow(alpha, 6/5, ifneg(3/2, 1) * arrow_spread#); "multi map (" & decimal alpha & ")";
271 pickup rule_pen;
272
273 draw foot -- head - (4/5arrow_spread + 1/4rule_thickness) * dir arrow_dir;
274 draw circle(head - 2/5arrow_spread * dir arrow_dir, 2/5arrow_spread);
275
276 if negated:
277 stroke_through_arrow(1/2[foot, head - 4/5arrow_spread * dir arrow_dir], alpha, 3/2arrow_spread)
278 (70, 70, 110, 110, 70, 70, 110, 110);
279 fi
280 endchar;
281 endfor;
282
283 for alpha = 0, 90, 180, 270, 45, 135, 225, 315:
284 beginarrow(alpha, 6/5, ifneg(3/2, 1) * arrow_spread#); "filled multi map (" & decimal alpha & ")";
285 pickup rule_pen;
286
287 draw foot -- head - 2/5arrow_spread * dir arrow_dir;
288 fill circle(head - 2/5arrow_spread * dir arrow_dir, 2/5arrow_spread);
289
290 if negated:
291 stroke_through_arrow(1/2[foot, head - 4/5arrow_spread * dir arrow_dir], alpha, 3/2arrow_spread)
292 (70, 70, 110, 110, 70, 70, 110, 110);
293 fi
294 endchar;
295 endfor;
296
297 for alpha = 0, 90, 180, 270, 45, 135, 225, 315:
298 beginarrow(alpha, 1, ifneg(3/2, 1) * arrow_spread#); "line with foot (" & decimal alpha & ")";
299 pickup rule_pen;
300
301 draw foot -- head - 1/4rule_thickness * dir arrow_dir;
302 draw (head - 1/2arrow_spread * dir (arrow_dir + 90)) --
303 (head + 1/2arrow_spread * dir (arrow_dir + 90));
304
305 if negated:
306 stroke_through_arrow(1/2[foot, head], alpha, 3/2arrow_spread)
307 (70, 70, 110, 110, 70, 70, 110, 110);
308 fi
309 endchar;
310 endfor;
311
312 for alpha = 0, 90, 180, 270, 45, 135, 225, 315:
313 beginarrow(alpha, 1, 2/3med_op_size#); "arrow with round head (" & decimal alpha & ")";
314 pickup rule_pen;
315
316 z0 = head - 1/3equal_spread * dir arrow_dir;
317
318 draw foot -- head - 1/4rule_thickness * dir arrow_dir;
319 draw smile(1, z0 - 1/3med_op_size * dir (arrow_dir + 90),
320 z0 + 1/3med_op_size * dir (arrow_dir + 90),
321 2/3equal_spread, true);
322
323 if negated:
324 stroke_through_arrow(1/2[foot, head - 2/3equal_spread * dir arrow_dir], alpha, 2/3med_op_size)
325 (70, 70, 110, 110, 70, 70, 110, 110);
326 fi
327 endchar;
328 endfor;
329
330 for alpha = 0, 90, 180, 270, 45, 135, 225, 315:
331 beginarrow(alpha, 1, 3/4plus_size# + ifneg(1,0) * arrow_spread#); "pitchfork (" & decimal alpha & ")";
332 pickup rule_pen;
333
334 draw foot -- head;
335 draw subset(foot + 3/4plus_size * dir arrow_dir, foot, 3/4plus_size);
336
337 if negated:
338 stroke_through_arrow(1/2[foot, head - 3/8plus_size * dir arrow_dir],
339 alpha, 3/4plus_size + arrow_spread)
340 (80, 80, 100, 100, 80, 80, 100, 100);
341 fi
342 endchar;
343 endfor;
344
345 for alpha = 0, 90, 180, 270, 45, 135, 225, 315:
346 beginarrow(alpha, 1, 2arrow_spread#); "parallel arrows (" & decimal alpha & ")";
347 pickup rule_pen;
348
349 z1 - z0 = z3 - z2 = arrow_spread * dir (arrow_dir + 90);
350
351 0.5[z0,z1] = foot;
352 0.5[z2,z3] = head;
353
354 draw z0 -- z2;
355 draw z1 -- z3;
356 draw arrowhead(z2, arrow_dir, arrow_spread);
357 draw arrowhead(z3, arrow_dir, arrow_spread);
358
359 if negated:
360 stroke_through_arrow(1/2[foot, head - 1/2arrow_spread * dir arrow_dir], alpha, 2arrow_spread)
361 (70, 70, 110, 110, 70, 70, 110, 110);
362 fi
363 endchar;
364 endfor;
365
366 for alpha = 0, 90, 45, 135:
367 beginarrow(alpha, 1, 2arrow_spread#); "anti-parallel arrows right left (" & decimal alpha & ")";
368 pickup rule_pen;
369
370 z1 - z0 = z3 - z2 = arrow_spread * dir (arrow_dir + 90);
371
372 0.5[z0,z1] = foot;
373 0.5[z2,z3] = head;
374
375 draw z0 -- z2;
376 draw z1 -- z3;
377 draw arrowhead(z3, arrow_dir, arrow_spread);
378 draw arrowhead(z0, arrow_dir+180, arrow_spread);
379
380 if negated:
381 stroke_through_arrow(1/2[foot, head], alpha, 2arrow_spread)
382 (80, 80, 110, 110);
383 fi
384 endchar;
385 endfor;
386
387 for alpha = 0, 90, 45, 135:
388 beginarrow(alpha, 1, 2arrow_spread#); "anti-parallel arrows left right (" & decimal alpha & ")";
389 pickup rule_pen;
390
391 z1 - z0 = z3 - z2 = arrow_spread * dir (arrow_dir + 90);
392
393 0.5[z0,z1] = foot;
394 0.5[z2,z3] = head;
395
396 draw z0 -- z2;
397 draw z1 -- z3;
398 draw arrowhead(z2, arrow_dir, arrow_spread);
399 draw arrowhead(z1, arrow_dir+180, arrow_spread);
400
401 if negated:
402 stroke_through_arrow(1/2[foot, head], alpha, 2arrow_spread)
403 (70, 70, 100, 100);
404 fi
405 endchar;
406 endfor;
407
408 for alpha = 0, 90, 180, 270, 45, 135, 225, 315:
409 beginarrow(alpha, 1, ifneg(3/2, 1) * arrow_spread#); "left right wave arrow (" & decimal alpha & ")";
410 pickup rule_pen;
411
412 z0 = foot - 1/10arrow_spread * dir (arrow_dir + 90);
413 z1 = 15/80[foot,head] + 1/4arrow_spread * dir (arrow_dir + 90);
414 z2 = 30/80[foot,head];
415 z3 = 45/80[foot,head] - 1/4arrow_spread * dir (arrow_dir + 90);
416 z4 = 60/80[foot,head];
417 z5 = head + 1/10arrow_spread * dir (arrow_dir + 90);
418
419 draw z0{dir (arrow_dir + 45)} .. z1 .. z2{dir (arrow_dir - 45)} .. z3 .. z4 ... {dir (arrow_dir+15)}z5;
420 draw arrowhead(z5, arrow_dir+15, arrow_spread);
421
422 if negated:
423 stroke_through_arrow(1/2[foot, head - 1/2arrow_spread * dir arrow_dir], alpha, 3/2arrow_spread)
424 (70, 70, 70, 70, 70, 70, 70, 70);
425 fi
426 endchar;
427 endfor;
428
429 for alpha = 0, 90, 180, 270, 45, 135, 225, 315:
430 beginarrow(alpha, 1, ifneg(3/2, 1) * arrow_spread#); "right left wave arrow (" & decimal alpha & ")";
431 pickup rule_pen;
432
433 z0 = foot + 1/10arrow_spread * dir (arrow_dir + 90);
434 z1 = 15/80[foot,head] - 1/4arrow_spread * dir (arrow_dir + 90);
435 z2 = 30/80[foot,head];
436 z3 = 45/80[foot,head] + 1/4arrow_spread * dir (arrow_dir + 90);
437 z4 = 60/80[foot,head];
438 z5 = head - 1/10arrow_spread * dir (arrow_dir + 90);
439
440 draw z0{dir (arrow_dir - 45)} .. z1 .. z2{dir (arrow_dir + 45)} .. z3 .. z4 ... {dir (arrow_dir-15)}z5;
441 draw arrowhead(z5, arrow_dir-15, arrow_spread);
442
443 if negated:
444 stroke_through_arrow(1/2[foot, head - 1/2arrow_spread * dir arrow_dir], alpha, 3/2arrow_spread)
445 (110, 110, 110, 110, 110, 110, 110, 110);
446 fi
447 endchar;
448 endfor;
449
450 for alpha = 0, 90, 45, 135:
451 beginarrow(alpha, 19/16, ifneg(3/2, 1) * arrow_spread#); "left right bidirectional wave arrow (" & decimal alpha & ")";
452 pickup rule_pen;
453
454 z0 = foot - 1/10arrow_spread * dir (arrow_dir + 90);
455 z1 = 4/20[foot,head];
456 z2 = 7/20[foot,head] + 1/4arrow_spread * dir (arrow_dir + 90);
457 z3 = 10/20[foot,head];
458 z4 = 13/20[foot,head] - 1/4arrow_spread * dir (arrow_dir + 90);
459 z5 = 16/20[foot,head];
460 z6 = head + 1/10arrow_spread * dir (arrow_dir + 90);
461
462 draw z0{dir (arrow_dir + 15)} .. z1 .. z2 .. z3{dir (arrow_dir - 45)} .. z4 .. z5 ... {dir (arrow_dir+15)}z6;
463 draw arrowhead(z0, arrow_dir + 195, arrow_spread);
464 draw arrowhead(z6, arrow_dir + 15, arrow_spread);
465
466 if negated:
467 stroke_through_arrow(1/2[foot, head], alpha, 3/2arrow_spread)
468 (70, 70, 70, 70);
469 fi
470 endchar;
471 endfor;
472
473 for alpha = 0, 90, 45, 135:
474 beginarrow(alpha, 19/16, ifneg(3/2, 1) * arrow_spread#); "right left bidirectional wave arrow (" & decimal alpha & ")";
475 pickup rule_pen;
476
477 z0 = foot + 1/10arrow_spread * dir (arrow_dir + 90);
478 z1 = 4/20[foot,head];
479 z2 = 7/20[foot,head] - 1/4arrow_spread * dir (arrow_dir + 90);
480 z3 = 10/20[foot,head];
481 z4 = 13/20[foot,head] + 1/4arrow_spread * dir (arrow_dir + 90);
482 z5 = 16/20[foot,head];
483 z6 = head - 1/10arrow_spread * dir (arrow_dir + 90);
484
485 draw z0{dir (arrow_dir - 15)} .. z1 .. z2 .. z3{dir (arrow_dir + 45)} .. z4 .. z5 ... {dir (arrow_dir-15)}z6;
486 draw arrowhead(z0, arrow_dir - 195, arrow_spread);
487 draw arrowhead(z6, arrow_dir - 15, arrow_spread);
488
489 if negated:
490 stroke_through_arrow(1/2[foot, head], alpha, 3/2arrow_spread)
491 (110, 110, 110, 110);
492 fi
493 endchar;
494 endfor;
495
496 for alpha = 0, 90, 180, 270, 45, 135, 225, 315:
497 beginarrow(alpha, 1, ifneg(3/2,10/9) * arrow_spread#); "right bend arrow (" & decimal alpha & ")";
498 pickup rule_pen;
499
500 z0 = foot - 1/3arrow_spread * dir (arrow_dir + 90);
501 z1 = 2/5[foot,head] + 1/3arrow_spread * dir (arrow_dir + 90);
502 z2 = head - 5/9arrow_spread * dir (arrow_dir + 90);
503
504 draw z0 .. z1 .. z2;
505 draw arrowhead(z2, arrow_dir - 55, arrow_spread);
506
507 if negated:
508 stroke_through_arrow(1/10[z1,z2], alpha, 3/2arrow_spread)
509 (80, 80, 80, 80, 80, 80, 80, 80);
510 fi
511 endchar;
512 endfor;
513
514 for alpha = 0, 90, 180, 270, 45, 135, 225, 315:
515 beginarrow(alpha, 1, ifneg(3/2,10/9)*arrow_spread#); "left bend arrow (" & decimal alpha & ")";
516 pickup rule_pen;
517
518 z0 = foot + 1/3arrow_spread * dir (arrow_dir + 90);
519 z1 = 2/5[foot,head] - 1/3arrow_spread * dir (arrow_dir + 90);
520 z2 = head + 5/9arrow_spread * dir (arrow_dir + 90);
521
522 draw z0 .. z1 .. z2;
523 draw arrowhead(z2, arrow_dir + 55, arrow_spread);
524
525 if negated:
526 stroke_through_arrow(1/10[z1,z2], alpha, 3/2arrow_spread)
527 (110, 110, 110, 110, 110, 110, 110, 110);
528 fi
529 endchar;
530 endfor;
531
532 for alpha = 0, 90, 180, 270, 45, 135, 225, 315:
533 beginarrow(alpha, 1, ifneg(3/2,10/9)*arrow_spread#); "bend arrow (" & decimal alpha & ")";
534 pickup rule_pen;
535
536 z0 = foot - 5/9arrow_spread * dir (arrow_dir + 90);
537 z1 = 1/2[foot,head] + 1/3arrow_spread * dir (arrow_dir + 90);
538 z2 = head - 5/9arrow_spread * dir (arrow_dir + 90);
539
540 draw z0 .. z1 .. z2;
541 draw arrowhead(z0, arrow_dir + 240, arrow_spread);
542 draw arrowhead(z2, arrow_dir - 60, arrow_spread);
543
544 if negated:
545 stroke_through_arrow(z1, alpha, 3/2arrow_spread)
546 (80, 80, 100, 100, 80, 80, 100, 100);
547 fi
548 endchar;
549 endfor;
550
551 for alpha = 0, 90, 45, 135:
552 beginarrow(alpha, 1, ifneg(3/2,1) * arrow_spread#); "headless arrow (" & decimal alpha & ")";
553 pickup rule_pen;
554 draw foot -- head;
555
556 if negated:
557 stroke_through_arrow(1/2[foot, head], alpha, 3/2arrow_spread)
558 (70, 70, 110, 110, 70, 70, 110, 110);
559 fi
560 endchar;
561 endfor;
562
563 for alpha = 0, 90, 45, 135:
564 beginarrow(alpha, 6/5, ifneg(19/10, 13/10) * arrow_spread#); "double headless arrow (" & decimal alpha & ")";
565 pickup rule_pen;
566
567 z1 - z0 = z3 - z2 = equal_spread * dir (arrow_dir + 90);
568
569 0.5[z0,z1] = foot;
570 0.5[z2,z3] = head;
571
572 draw z0 -- z2;
573 draw z1 -- z3;
574
575 if negated:
576 stroke_through_arrow(1/2[foot, head], alpha, 19/10arrow_spread)
577 (70, 70, 110, 110, 70, 70, 110, 110);
578 fi
579 endchar;
580 endfor;
581
582 for alpha = 0, 90, 180, 270, 45, 135, 225, 315:
583 beginarrow(alpha, 2/3, ifneg(2, 3/2) * arrow_spread#); "derives (" & decimal alpha & ")";
584 pickup rule_pen;
585 draw foot + 1/4rule_thickness * dir arrow_dir -- head;
586 draw (foot - 3/4arrow_spread * dir (arrow_dir + 90)) --
587 (foot + 3/4arrow_spread * dir (arrow_dir + 90));
588
589 if negated:
590 stroke_through_arrow(1/2[foot, head], alpha, 2arrow_spread)
591 (70, 70, 110, 110, 70, 70, 110, 110);
592 fi
593 endchar;
594 endfor;
595
596 for alpha = 0, 90, 180, 270, 45, 135, 225, 315:
597 beginarrow(alpha, 2/3, ifneg(9/4, 7/4) * arrow_spread#); "models (" & decimal alpha & ")";
598 pickup rule_pen;
599
600 z1 - z0 = z3 - z2 = equal_spread * dir (arrow_dir + 90);
601
602 0.5[z0,z1] = foot;
603 0.5[z2,z3] = head;
604
605 draw z0 + 1/4rule_thickness * dir arrow_dir -- z2;
606 draw z1 + 1/4rule_thickness * dir arrow_dir -- z3;
607 draw (foot - 7/8arrow_spread * dir (arrow_dir + 90)) --
608 (foot + 7/8arrow_spread * dir (arrow_dir + 90));
609
610 if negated:
611 stroke_through_arrow(1/2[foot, head], alpha, 9/4arrow_spread)
612 (70, 70, 110, 110, 70, 70, 110, 110);
613 fi
614 endchar;
615 endfor;
616
617 for alpha = 0, 90, 180, 270, 45, 135, 225, 315:
618 beginarrow(alpha, 5/6, ifneg(9/4, 7/4) * arrow_spread#); "forces (" & decimal alpha & ")";
619 pickup rule_pen;
620
621 z0 = foot + equal_spread * dir arrow_dir;
622
623 draw z0 + 1/4rule_thickness * dir arrow_dir -- head;
624 draw (foot - 7/8arrow_spread * dir (arrow_dir + 90)) --
625 (foot + 7/8arrow_spread * dir (arrow_dir + 90));
626 draw (z0 - 7/8arrow_spread * dir (arrow_dir + 90)) --
627 (z0 + 7/8arrow_spread * dir (arrow_dir + 90));
628
629 if negated:
630 stroke_through_arrow(1/2[z0, head], alpha, 9/4arrow_spread)
631 (70, 70, 110, 110, 70, 70, 110, 110);
632 fi
633 endchar;
634 endfor;
635
636 for alpha = 0, 90, 180, 270, 45, 135, 225, 315:
637 beginarrow(alpha, 1, ifneg(5/2, 2) * arrow_spread#); "double models (" & decimal alpha & ")";
638 pickup rule_pen;
639
640 z1 - z0 = z3 - z2 = equal_spread * dir (arrow_dir + 90);
641
642 z4 = foot + equal_spread * dir arrow_dir;
643
644 0.5[z0,z1] = z4;
645 0.5[z2,z3] = head;
646
647 draw z0 + 1/4rule_thickness * dir arrow_dir -- z2;
648 draw z1 + 1/4rule_thickness * dir arrow_dir -- z3;
649 draw (foot - arrow_spread * dir (arrow_dir + 90)) --
650 (foot + arrow_spread * dir (arrow_dir + 90));
651 draw (z4 - arrow_spread * dir (arrow_dir + 90)) --
652 (z4 + arrow_spread * dir (arrow_dir + 90));
653
654 if negated:
655 stroke_through_arrow(1/2[z4, head], alpha, 5/2arrow_spread)
656 (70, 70, 110, 110, 70, 70, 110, 110);
657 fi
658 endchar;
659 endfor;
660
661 for sign = 1, -1:
662 for alpha = 0, 90, 180, 270:
663 beginoperator(large_op_size#, 1);
664 if sign > 0: "right" else: "left" fi & " circle arrow (" & decimal alpha & ")";
665
666 pickup rule_pen;
667
668 r := 0.8(w/2-u) - 1.1rule_thickness;
669
670 reg_poly_points(a)(8, centre, r, alpha);
671
672 z0 = centre + r * dir (alpha + 10);
673 z1 = centre + r * dir (alpha - 10);
674
675 draw z0{dir (alpha + 100)} .. z.a1 .. z.a2 .. z.a3 .. z.a4 .. z.a5 .. z.a6 .. z.a7 ..
676 {dir (alpha + 80)}z1;
677
678 if sign > 0:
679 draw arrowhead(z1, (alpha + 65), arrow_spread);
680 else:
681 draw arrowhead(z0, (alpha - 65), arrow_spread);
682 fi;
683
684 if negated:
685 1/2[z2,z3] = centre;
686 y2 - y3 = large_op_size;
687 z2 - z3 = whatever * dir 80;
688
689 pickup stroke_pen;
690 draw z2 -- z3;
691 fi
692 endchar;
693 endfor;
694 endfor;
695
696 %for alpha = 0, 90, 180, 270:
697 % beginoperator(large_op_size#, 1); "left circle arrow (" & decimal alpha & ")";
698 % pickup rule_pen;
699 %
700 % r := 0.8(w/2-u) - 1.1rule_thickness;
701 %
702 % reg_poly_points(a)(8, centre, r, alpha);
703 %
704 % z0 = centre + r * dir (alpha + 10);
705 % z1 = centre + r * dir (alpha - 10);
706 %
707 % draw z0{dir (alpha + 100)} .. z.a1 .. z.a2 .. z.a3 .. z.a4 .. z.a5 .. z.a6 .. z.a7 ..
708 % {dir (alpha + 80)}z1;
709 % draw arrowhead(z0, (alpha - 65), arrow_spread);
710 %
711 % if negated:
712 % 1/2[z2,z3] = centre;
713 % y2 - y3 = large_op_size;
714 % z2 - z3 = whatever * dir 80;
715 %
716 % pickup stroke_pen;
717 % draw z2 -- z3;
718 % fi
719 % endchar;
720 %endfor;
721