Debian Codegraph @

texmf-dist/fonts/source/public/lfb/capitals.mf

raw
1
2 %% capitals.mf
3 %% Copyright 2005 Laurie Field
4 %
5 % This work is LFB, version 1.0.
6 %
7 % This work may be distributed and/or modified under the
8 % conditions of the LaTeX Project Public License, either version 1.3
9 % of this license or (at your option) any later version.
10 % The latest version of this license is in
11 % http://www.latex-project.org/lppl.txt
12 % and version 1.3 or later is part of all distributions of LaTeX
13 % version 2003/12/01 or later.
14 %
15 % This work has the LPPL maintenance status "maintained".
16 %
17 % This Current Maintainer of this work is Laurie Field.
18 %
19 % This work consists of the files:
20 %
21 % example.tex
22 % lfbacc.tex
23 %
24 % accents.mf
25 % alpha.mf
26 % beta.mf
27 % capitals.mf
28 % charmap.mf
29 % delta.mf
30 % epsilon.mf
31 % eta.mf
32 % gamma.mf
33 % iota.mf
34 % kappa.mf
35 % khi.mf
36 % lambda.mf
37 % lfb.mf
38 % lfb5.mf
39 % lfb6.mf
40 % lfb7.mf
41 % lfb8.mf
42 % lfb9.mf
43 % lfb10.mf
44 % lfb11.mf
45 % lfb12.mf
46 % lfbb5.mf
47 % lfbb6.mf
48 % lfbb7.mf
49 % lfbb8.mf
50 % lfbb9.mf
51 % lfbb10.mf
52 % lfbb11.mf
53 % lfbb12.mf
54 % ligature.mf
55 % mu.mf
56 % nu.mf
57 % omega.mf
58 % omikron.mf
59 % others.mf
60 % phi.mf
61 % pi.mf
62 % psi.mf
63 % rho.mf
64 % serifs.mf
65 % sigma.mf
66 % sigmafin.mf
67 % tau.mf
68 % theta.mf
69 % upsilon.mf
70 % xi.mf
71 % zeta.mf
72 %
73 % and the derived files:
74 %
75 % lfb5.tfm
76 % lfb6.tfm
77 % lfb7.tfm
78 % lfb8.tfm
79 % lfb9.tfm
80 % lfb10.tfm
81 % lfb11.tfm
82 % lfb12.tfm
83 % lfbb5.tfm
84 % lfbb6.tfm
85 % lfbb7.tfm
86 % lfbb8.tfm
87 % lfbb9.tfm
88 % lfbb10.tfm
89 % lfbb11.tfm
90 % lfbb12.tfm
91 %
92 % lfb5.600pk
93 % lfb6.600pk
94 % lfb7.600pk
95 % lfb8.600pk
96 % lfb9.600pk
97 % lfb10.600pk
98 % lfb11.600pk
99 % lfb12.600pk
100 % lfbb5.600pk
101 % lfbb6.600pk
102 % lfbb7.600pk
103 % lfbb8.600pk
104 % lfbb9.600pk
105 % lfbb10.600pk
106 % lfbb11.600pk
107 % lfbb12.600pk
108 %
109
110 width#:=10u#;
111 extra#:=2letterspace#;
112 define_pixels(width, extra);
113
114 def gen_letter =
115 z1=(1/2[x2,x12], ascender);
116 z2=(width-xthick-.5thick, 0);
117 z12=(xthick+.5thin, 0);
118 singlestem(4,5,6,7,8)(z1, z2, 90-angle(z1-z2), thick, slab, xthick);
119 z11=z4l+.5thin*dir(angle(z1-z12)-90); % cheap hack, but close enough
120 singlestem(14,15,16,17,18)(z11, z12, 90-angle(z11-z12), thin, slab, xthick);
121
122 penpos21(thin, angle(z11-z12));
123 penpos22(thin, angle(z1-z2));
124 y21=y22;
125 z21=whatever[z11,z12];
126 z22=4/7[z1,z2];
127 penstroke z21e..z22e;
128 enddef;
129
130 beginchar(Alpha, width#+extra#, ascender#, 0);
131 gen_letter; penlabels(1,2,11,12,21,22);
132 endchar;
133
134
135 width#:=9u#;
136 extra#:=2letterspace#;
137 define_pixels(width, extra);
138
139 def gen_letter =
140 stem(1,2,3,4,5,6,7,8)((xthick+.5thick,ascender),
141 (xthick+.5thick,0), 0, 0, thick, slab, xthick);
142 penpos11(slab, 90);
143 penpos12(slab, 90);
144 penpos13(thick, 0);
145 penpos14(slab, -90);
146 penpos15(slab, -90);
147 penpos16(thick, 180);
148 penpos17(slab, 90);
149 penpos18(slab, 90);
150 x11=x15=x18=x1;
151 x12=x14=x17=5u;
152 y11r=y12r=ascender;
153 y14=y15=.55ascender;
154 y17l=y18l=0;
155 x13r=width-.5u;
156 x16l=width;
157 y13=1/2[y11,y15];
158 y16=1/2[y15,y18];
159 penstroke z11e..z12e{right}..z13e..{left}z14e..z15e;
160 penstroke z15e..z14e{right}..z16e..{left}z17e..z18e;
161 enddef;
162
163 beginchar(Beta, width#+extra#, ascender#, 0);
164 gen_letter; penlabels(1,2,3,4,5,6,7,8,11,12,13,14,15,16,17,18);
165 endchar;
166
167
168 width#:=9u#;
169 extra#:=2letterspace#;
170 define_pixels(width, extra);
171
172 def gen_letter =
173 stem(1,2,3,4,5,6,7,8)((xthick+.5thick,ascender),
174 (xthick+.5thick,0), 0, 0, thick, slab, xthick);
175
176 barrightserif(11,12,13,14)
177 ((x1,ascender),(width,ascender),slab,thin,2u,small);
178 enddef;
179
180 beginchar(Gamma, width#+extra#, ascender#, 0);
181 gen_letter; penlabels(1,2,3,4,5,6,7,8,11,12,13,14);
182 endchar;
183
184
185 width#:=10u#;
186 extra#:=2letterspace#;
187 define_pixels(width, extra);
188
189 def gen_letter =
190 z1=(1/2[x2,x12], ascender);
191 z2=(width-.5thick, 0);
192 z12=(.5thin, 0);
193 z11=z1l+.5thin*dir(angle(z1-z12)-90); % cheap hack, but close enough
194 % penpos's come last because angle needs a known pair at all times
195 penpos1(thick, angle(z1-z2)-90);
196 penpos2(thick, 0);
197 penpos11(thin, angle(z11-z12)-90);
198 penpos12(thin, 0);
199 penstroke z1e..z2e;
200 penstroke z11e..z12e;
201
202 penpos21(slab, angle(z11l-z12l));
203 penpos22(slab, angle(z1l-z2l));
204 z21l=(0,0); z22l=(width,0);
205 penstroke z21e..z22e;
206 enddef;
207
208 beginchar(Delta, width#+extra#, ascender#, 0);
209 gen_letter; penlabels(1,2,11,12,21,22);
210 endchar;
211
212
213 width#:=10u#;
214 extra#:=2letterspace#;
215 define_pixels(width, extra);
216
217 def gen_letter =
218 stem(1,2,3,4,5,6,7,8)((xthick+.5thick,ascender),
219 (xthick+.5thick,0), 0, 0, thick, slab, xthick);
220
221 barrightserif(11,12,13,14)
222 ((x1,ascender),(width-.5u,ascender),slab,thin,2u,small);
223 fill z11r--z13r--(z13r+(0,-slab))--(z11r+(0,-slab))--cycle;
224 barleftserif(15,16,17,18)
225 ((x1,0),(width,0),slab,thin,2.5u,small);
226 fill z15r--z17r--(z17r+(0,slab))--(z15r+(0,slab))--cycle;
227
228 numeric centreheight;
229 centreheight=.52ascender;
230 singlestem(19,20,21,22,23)
231 ((x1,centreheight),(width-2.5u,centreheight), 0, thin, slab, xthick);
232 enddef;
233
234 beginchar(Epsilon, width#+extra#, ascender#, 0);
235 gen_letter; penlabels(1,2,3,4,5,6,7,8,11,12,13,14,15,16,17,18,19,20,21,22,23);
236 endchar;
237
238
239 width#:=9u#;
240 extra#:=2letterspace#;
241 define_pixels(width, extra);
242
243 def gen_letter =
244 numeric topinset;
245 topinset=tiny;
246 barleftserif(1,2,3,4)
247 ((width-topinset,ascender),(topinset,ascender),slab,thin,2u,small);
248 barleftserif(5,6,7,8)
249 ((0,0),(width,0),slab,thin,2.5u,small);
250
251 z9r=z1l+(0,1);
252 z10l=z5l+(0,-1);
253 penpos9(thick/sind(angle(z9r-z10l)), 0); % close enough, again
254 penpos10(thick/sind(angle(z9r-z10l)), 0);
255 penstroke z9e..z10e;
256 enddef;
257
258 beginchar(Zeta, width#+extra#, ascender#, 0);
259 gen_letter; penlabels(1,2,3,4,5,6,7,8,9,10);
260 endchar;
261
262
263 width#:=4xthick#+4thick#;
264 extra#:=2letterspace#;
265 define_pixels(width, extra);
266
267 def gen_letter =
268 stem(1,2,3,4,5,6,7,8)((xthick+.5thick,ascender),
269 (xthick+.5thick,0), 0, 0, thick, slab, xthick);
270 stem(11,12,13,14,15,16,17,18)((width-xthick-.5thick,ascender),
271 (width-xthick-.5thick,0), 0, 0, thick, slab, xthick);
272 penpos20(thin, 90);
273 penpos21(thin, 90);
274 z20=whatever[z1,z2];
275 z21=whatever[z11,z12];
276 y20=y21=1/2ascender;
277 penstroke z20e..z21e;
278 enddef;
279
280 beginchar(Eta, width#+extra#, ascender#, 0);
281 gen_letter; penlabels(1,2,3,4,5,6,7,8,9,10,11,12,13,14,15,16,17,18,19,20,21,22);
282 endchar;
283
284
285 width#:=10u#;
286 extra#:=2letterspace#;
287 define_pixels(width, extra);
288
289 def gen_letter =
290 penpos1(thick, 0);
291 penpos2(thin, 90);
292 penpos3(thick, 180);
293 penpos4(thin, -90);
294 y1=y3=ascender/2;
295 x2=x4=width/2;
296 x1l=0; x3l=width;
297 y2l=0; y4l=ascender;
298 penstroke z1e..z2e..z3e..z4e..cycle;
299
300 stem(5,6,7,8,9,10,11,12)((3u,1/2ascender),(width-3u,1/2ascender),
301 0, 0, thick, slab, xthick);
302 enddef;
303
304 beginchar(Theta, width#+extra#, ascender#, 0);
305 gen_letter; penlabels(1,2,3,4,5,6,7,8,9,10,11,12);
306 endchar;
307
308
309 width#:=2xthick#+1thick#;
310 extra#:=2letterspace#;
311 define_pixels(width, extra);
312
313 def gen_letter =
314 stem(1,2,3,4,5,6,7,8)((1/2width,ascender),(1/2width,0),
315 0, 0, thick, slab, xthick);
316 enddef;
317
318 beginchar(Iota, width#+extra#, ascender#, 0);
319 gen_letter; penlabels(1,2,3,4,5,6,7,8,9,10);
320 endchar;
321
322
323 width#:=12u#;
324 extra#:=2letterspace#;
325 define_pixels(width, extra);
326
327 def gen_letter =
328 stem(1,2,3,4,5,6,7,8)((xthick+.5thick,ascender),
329 (xthick+.5thick,0), 0, 0, thick, slab, xthick);
330
331 z9=3/7[z8,z5];
332 z10=(width-thin-xthick-.5thin, ascender);
333 singlestem(11,12,13,14,15)(z9, z10, 90-angle(z10-z9), thin, slab, xthick);
334
335 z19=whatever[z9,z10];
336 z19=z20+whatever*(dir(angle(z10-z9)+90));
337 z20=(width-xthick-.5thick, 0);
338 singlestem(21,22,23,24,25)(z19, z20, 90-angle(z19-z20), thick, slab, xthick);
339 enddef;
340
341 beginchar(Kappa, width#+extra#, ascender#, 0);
342 gen_letter; penlabels(1,2,3,4,5,6,7,8,11,12,13,14,15,21,22,23,24,25);
343 endchar;
344
345
346 width#:=10u#;
347 extra#:=2letterspace#;
348 define_pixels(width, extra);
349
350 def gen_letter =
351 z1=(1/2[x2,x12], ascender);
352 z2=(width-xthick-.5thick, 0);
353 z12=(xthick+.5thin, 0);
354 singlestem(4,5,6,7,8)(z1, z2, 90-angle(z1-z2), thick, slab, xthick);
355 z11=z4l+.5thin*dir(angle(z1-z12)-90); % cheap hack, but close enough
356 singlestem(14,15,16,17,18)(z11, z12, 90-angle(z11-z12), thin, slab, xthick);
357 enddef;
358
359 beginchar(Lambda, width#+extra#, ascender#, 0);
360 gen_letter; penlabels(1,2,11,12);
361 endchar;
362
363
364 width#:=4xthick#+5thick#;
365 extra#:=2letterspace#;
366 define_pixels(width, extra);
367
368 def gen_letter =
369 oneandlefthalfstem(1,2,3,4,5,6,7,8)((xthick+.5thin,ascender),
370 (xthick+.5thin,0), 0, 0, thin, slab, xthick);
371 oneandrighthalfstem(11,12,13,14,15,16,17,18)((width-xthick-.5thick,ascender),
372 (width-xthick-.5thick,0), 0, 0, thick, slab, xthick);
373
374 z20l=z4r-(thin,0);
375 z21l=1/2[z7l,z16l]+(0,thin);
376 numeric topwidth;
377 topwidth*cosd(angle(z20l-z21l)-90)=thick; % close enough
378
379 z22l=z13r;
380 z23l=z21l;
381 numeric topwidthright;
382 topwidthright*cosd(angle(z22l-z23l)-90)=thin; % again, close enough
383 penpos22(topwidthright, 0);
384 penpos23(topwidthright, 0);
385 penstroke z22e..z23e;
386
387 penpos20(topwidth, 0);
388 penpos21(whatever, angle(z22r-z23l));
389 z20r-z21r=whatever*(z20l-z21l);
390 penstroke z20e..z21e;
391 enddef;
392
393 beginchar(Mu, width#+extra#, ascender#, 0);
394 gen_letter; penlabels(1,2,3,4,5,6,7,8,9,10,11,12,13,14,15,16,17,18,20,21,22,23);
395 endchar;
396
397
398 width#:=4xthick#+4thick#;
399 extra#:=2letterspace#;
400 define_pixels(width, extra);
401
402 def gen_letter =
403 oneandlefthalfstem(1,2,3,4,5,6,7,8)((xthick+.5thin,ascender),
404 (xthick+.5thin,0), 0, 0, thin, slab, xthick);
405 singlestem(11,12,13,14,15)((width-xthick-.5thin,0),
406 (width-xthick-.5thin,ascender), 0, thin, slab, xthick);
407 z20=z4r;
408 z21l=z11r;
409 numeric topwidth;
410 topwidth*cosd(angle(z20-z21l)-90)=thick; % again, close enough
411 penpos20(topwidth, 0);
412 penpos21(whatever, 90);
413 z20r-z21r=whatever*(z20l-z21l);
414 penstroke z20e..z21e;
415 enddef;
416
417 beginchar(Nu, width#+extra#, ascender#, 0);
418 gen_letter; penlabels(1,2,3,4,5,6,7,8,9,10,11,12,13,14,15,20,21);
419 endchar;
420
421
422 width#:=10u#;
423 extra#:=2letterspace#;
424 define_pixels(width, extra);
425
426 def gen_letter =
427 numeric topinset;
428 topinset=.5u;
429 barleftserif(1,2,3,4)
430 ((.5width,ascender),(topinset,ascender),medthick,thin,1.5u,small);
431 barrightserif(5,6,7,8)
432 ((.5width,ascender),(width-topinset,ascender),medthick,thin,1.5u,small);
433 fill z3r--z7r--(z7r+(0,-medthick-1))--(z3r+(0,-medthick-1))--cycle;
434
435 barleftserif(11,12,13,14)
436 ((.5width,0),(width,0),medthick,thin,2u,small);
437 barrightserif(15,16,17,18)
438 ((.5width,0),(0,0),medthick,thin,2u,small);
439 fill z13r--z17r--(z17r+(0,medthick+1))--(z13r+(0,medthick+1))--cycle;
440
441 stem(21,22,23,24,25,26,27,28)((2u,.52ascender),(width-2u,.52ascender),
442 0, 0, thick, slab, xthick);
443 enddef;
444
445 beginchar(Xi, width#+extra#, ascender#, 0);
446 gen_letter; penlabels(1,2,3,4,5,6,7,8,11,12,13,14,15,16,17,18,21,22,23,24,25,26,27,28);
447 endchar;
448
449
450 width#:=10u#;
451 extra#:=2letterspace#;
452 define_pixels(width, extra);
453
454 def gen_letter =
455 penpos1(thick, 0);
456 penpos2(thin, 90);
457 penpos3(thick, 180);
458 penpos4(thin, -90);
459 y1=y3=ascender/2;
460 x2=x4=width/2;
461 x1l=0; x3l=width;
462 y2l=0; y4l=ascender;
463 penstroke z1e..z2e..z3e..z4e..cycle;
464 enddef;
465
466 beginchar(Omikron, width#+extra#, ascender#, 0);
467 gen_letter; penlabels(1,2,3,4);
468 endchar;
469
470
471 width#:=4xthick#+4thick#;
472 extra#:=2letterspace#;
473 define_pixels(width, extra);
474
475 def gen_letter =
476 stem(1,2,3,4,5,6,7,8)((xthick+.5thick,ascender),
477 (xthick+.5thick,0), 0, 0, thick, slab, xthick);
478 stem(11,12,13,14,15,16,17,18)((width-xthick-.5thick,ascender),
479 (width-xthick-.5thick,0), 0, 0, thick, slab, xthick);
480 penpos20(slab, 90);
481 penpos21(slab, 90);
482 z20r=z3r; z21r=z14r;
483 penstroke z20e..z21e;
484 enddef;
485
486 beginchar(Pi, width#+extra#, ascender#, 0);
487 gen_letter; penlabels(1,2,3,4,5,6,7,8,9,10,11,12,13,14,15,16,17,18,19,20,21,22);
488 endchar;
489
490
491 width#:=9u#;
492 extra#:=2letterspace#;
493 define_pixels(width, extra);
494
495 def gen_letter =
496 stem(1,2,3,4,5,6,7,8)((xthick+.5thick,ascender),
497 (xthick+.5thick,0), 0, 0, thick, slab, xthick);
498 penpos11(slab, 90);
499 penpos12(slab, 90);
500 penpos13(thick, 0);
501 penpos14(slab, -90);
502 penpos15(slab, -90);
503 x11=x15=x1;
504 x12=x14=5u;
505 y11r=y12r=ascender;
506 y14=y15=1/2ascender;
507 x13r=width;
508 y13=1/2[y11,y15];
509 penstroke z11e..z12e{right}..z13e..{left}z14e..z15e;
510 enddef;
511
512 beginchar(Rho, width#+extra#, ascender#, 0);
513 gen_letter; penlabels(1,2,3,4,5,6,7,8,11,12,13,14,15);
514 endchar;
515
516
517 width#:=10u#;
518 extra#:=2letterspace#;
519 define_pixels(width, extra);
520
521 def gen_letter =
522 barrightserif(1,2,3,4)
523 ((0,ascender),(width-.5u,ascender),slab,thin,2u,small);
524
525 z9l=z1l;
526 z10=(.5width,.55ascender);
527 penpos9(thick/sind(angle(z9l-z10)-90), 0);
528 penpos10(thick/sind(angle(z9l-z10)-angle(z10)), angle(z10));
529 penstroke z9e..z10e;
530
531 z11l=z10r;
532 z12l=(0,0);
533 penpos11(thin/sind(angle(z9l-z10)-angle(z10)), angle(z9l-z10)-180);
534 penpos12(thin/sind(angle(z10)), 0);
535 penstroke z11e..z12e;
536
537 barleftserif(5,6,7,8)
538 ((x12r+thick*sind(90-angle(z10))/sind(angle(z10)),0),
539 (width,0),thick,thin,2u,small);
540 fill z12l--z5l--z5r--cycle;
541 enddef;
542
543 beginchar(Sigma, width#+extra#, ascender#, 0);
544 gen_letter; penlabels(1,2,3,4,5,6,7,8,9,10,11,12);
545 endchar;
546
547
548 width#:=10u#;
549 extra#:=2letterspace#;
550 define_pixels(width, extra);
551
552 def gen_letter =
553 stem(1,2,3,4,5,6,7,8)((.5width,ascender),
554 (.5width,0), 0, 0, thick, slab, xthick);
555
556 barrightserif(11,12,13,14)
557 ((x1,ascender),(width,ascender),slab,thin,2u,small);
558 barleftserif(15,16,17,18)
559 ((x1,ascender),(0,ascender),slab,thin,2u,small);
560 enddef;
561
562 beginchar(Tau, width#+extra#, ascender#, 0);
563 gen_letter; penlabels(1,2,3,4,5,6,7,8,9,10,11,12);
564 endchar;
565
566
567 width#:=8u#;
568 extra#:=2letterspace#;
569 define_pixels(width, extra);
570
571 def gen_letter =
572 singlestem(1,2,3,4,5)((.5width,.5ascender),
573 (.5width,0), 0, thick, slab, xthick);
574
575 penpos6(medthin, 0);
576 z6l=(0,ascender);
577 penstroke z6e..{down}z1e;
578
579 numeric diameter;
580 diameter=1.5u;
581 penpos7(thin, -90);
582 y9=y7r=ascender-1/2diameter;
583 x7=width-diameter;
584 y8=ascender;
585 x8=x10=width-.5diameter;
586 x9=width;
587 y10=ascender-diameter;
588
589 fill z1{up}..tension 1.3..z7l..z8..z9..z10..z7r & z7r..{down}z1r--cycle;
590 enddef;
591
592 beginchar(Upsilon, width#+extra#, ascender#, 0);
593 gen_letter; penlabels(1,2,3,4,5,6,7,8,9,10);
594 endchar;
595
596
597 width#:=10u#;
598 extra#:=2letterspace#;
599 define_pixels(width, extra);
600
601 def gen_letter =
602 penpos1(thick, 0);
603 penpos2(thin, 90);
604 penpos3(thick, 180);
605 penpos4(thin, -90);
606 y1=y3=ascender/2;
607 x2=x4=width/2;
608 x1l=0; x3l=width;
609 y2l=ascender-y4l=2u;
610 penstroke z1e..z2e..z3e..z4e..cycle;
611
612 stem(11,12,13,14,15,16,17,18)((1/2width,ascender),(1/2width,0),
613 0, 0, thick, slab, xthick);
614 enddef;
615
616 beginchar(Phi, width#+extra#, ascender#, 0);
617 gen_letter; penlabels(1,2,3,4,11,12,13,14,15,16,17,18);
618 endchar;
619
620
621 width#:=4xthick#+4thick#;
622 extra#:=2letterspace#;
623 define_pixels(width, extra);
624
625 def gen_letter =
626 z20=(thin+xthick+.5thick,ascender);
627 z21=(width-xthick-.5thick,0);
628 z22=(width-thin-.5thin-xthick,ascender);
629 z23=(.5thin+xthick,0);
630 stem(1,2,3,4,5,6,7,8)(z20, z21,
631 90-angle(z20-z21), 90-angle(z20-z21), thick, slab, xthick);
632 stem(11,12,13,14,15,16,17,18)(z22, z23,
633 90-angle(z22-z23), 90-angle(z22-z23), thin, slab, xthick);
634 penpos20(thin, 90);
635 penpos21(thin, 90);
636 enddef;
637
638 beginchar(Khi, width#+extra#, ascender#, 0);
639 gen_letter; penlabels(1,2,3,4,5,6,7,8,9,10,11,12,13,14,15,16,17,18,19);
640 endchar;
641
642
643 width#:=10u#;
644 extra#:=3letterspace#;
645 define_pixels(width, extra);
646
647 def gen_letter =
648 penpos1(medium, 225);
649 penpos2(medthin, 90);
650 penpos3(thick, 0);
651 penpos4(thick, 0);
652 penpos5(thin, 90);
653 penpos6(thin, 135);
654 penpos7(thick, 180);
655 penpos8(tiny, 180);
656
657 offset=1/2(ascender-x_height);
658 y2r=x_height-tiny+offset;
659 y1l=y2l-thick;
660 y3=y2l-thin;
661 y4=y3-2u;
662 y5l=0+offset;
663 y7=1/2(y8-offset)+offset;
664 y8=x_height+offset;
665 x1r=0;
666 x2=x1+medium;
667 x4l=x3l=x2+thin;
668 x5=(x3r+width)/2;
669 x7r=width;
670 x8r=x7r-thin;
671
672 fill z1l..tension 1.8..z2l..z3l---z4l..z5l..z7l..z8l
673 --z8r..z7r..z5r..z4r---z3r..z2r..tension 1.5..z1r--cycle;
674
675 stem(11,12,13,14,15,16,17,18)((x5-.1u,ascender),(x5-.1u,0),
676 0, 0, thick, slab, xthick);
677 enddef;
678
679 beginchar(Psi, width#+extra#, ascender#, 0);
680 gen_letter; penlabels(1,2,3,4,5,6,7,8,11,12,13,14,15,16,17,18);
681 endchar;
682
683
684 width#:=10u#;
685 extra#:=2letterspace#;
686 define_pixels(width, extra);
687
688 def gen_letter =
689 barleftserif(1,2,3,4)
690 ((.6width,0),(width,0),thick,thin,2u,small);
691 barrightserif(5,6,7,8)
692 ((.4width,0),(0,0),thick,thin,2u,small);
693
694 penpos9(thin, 0);
695 penpos10(thin, 0);
696 penpos11(thin, 0);
697 penpos12(thin, 0);
698 z9=z5r; z11=z1r;
699 z10-z9=z12-z11=(0, 2thick);
700 penstroke z9e..z10e;
701 penstroke z11e..z12e;
702
703 penpos13(thin, 90);
704 penpos14(thick, 0);
705 penpos15(thin, -90);
706 penpos16(thick, 180);
707 penpos17(thin, 90);
708 z13r=z10r; z17r=z12l;
709 z15l=(.5width, ascender);
710 y14=y16=.5[y13l,y15l];
711 x14l=0; x16l=width;
712 penstroke z13e..{up}z14e..z15e..z16e{down}..z17e;
713 enddef;
714
715 beginchar(Omega, width#+extra#, ascender#, 0);
716 gen_letter; penlabels(1,2,3,4,5,6,7,8,9,10,11,12,13,14,15,16,17);
717 endchar;