Debian Codegraph @

texmf-dist/fonts/source/public/fge/fgeit.mf

raw
1 % fgeit.mf : fge italic characters
2 % J.J. Green 2006
3
4 mode_setup;
5 font_setup;
6
7 proofing := 2;
8
9 slantfont slantfge;
10
11 % This is an inverted f, but an italic f with a straight
12 % descending stem rather than the more usual tail.
13 % As with the inverted d (below) a hook is attached to
14 % the left.
15
16 cmchar "inverted f with hook";
17 beginchar("f", 7.5u#, asc_height#, desc_depth#);
18 italcorr h#*slant + 0.5stem# - 2.5u#;
19 adjust_fit(serif_fit# + 2stem_shift#, serif_fit# - 2stem_shift#);
20
21 pickup tiny.nib;
22
23 % stem
24
25 pos1(stem', 0); pos2(stem', 0);
26
27 rt.x1r = hround(w/2 + 5u/4 + stem'/2);
28 x1 = x2;
29 top y1 = h;
30 bot y2 = -1/3d;
31
32 filldraw stroke z1e--z2e;
33
34 % bar
35
36 pos3(bar, 90);
37 pos4(bar, 90);
38 bot y3l = bot y4l = 0;
39
40 rt x4 = hround(w - 1/3u);
41 x2 - x3 = x4 - x2;
42
43 filldraw stroke z3e--z4e;
44
45 % arc and bulb
46
47 pos5(vair', -90);
48 pos6(hair, -180);
49 pos7(flare, -180);
50
51 x5 = 1/2[x2, x6r];
52 bot y5r = -d-oo;
53 y6 = 1/2flair = -0.88d;
54 z6r = z7r;
55 rt x7l = floor 11/4u;
56
57 (x, y5r) = whatever[z5l, z2l];
58 x5r := max(x, 1/2[x6r, x5]);
59
60 filldraw stroke z2e{down}...z5e{left};
61 bulb(5, 6, 7);
62
63 % hook
64
65 pos8(0.5[hair, curve], 0);
66 rt x8r = lft x1l;
67 y8 = 0.5x_height;
68
69 pos9(curve, 90);
70 top y9r = x_height + oo;
71 x9 = 0.4[0, x8l];
72
73 pos10(hair, 180);
74 pos11(hair, -90);
75
76 z9 - z10 = 2.0u*dir(45);
77 z8 - z11 = 2.0u*dir(55);
78
79 filldraw stroke z11e{right}...z8e{up}...{left}z9e...{down}z10e;
80
81 penlabels(1, 2, 3, 4, 5, 6, 7, 8, 9, 10, 11);
82
83 endchar;
84
85 % I'm convinced this is a rotated d, which would explain the
86 % right serif on the stem. I take the code from itall.mf's p
87 % but replace the flat serif with the slanted serif of the d.
88 % This looks a little different to the original, but then the
89 % d's of the original *do* have a flat serif -- so this is
90 % needed for consistency with computer modern's d.
91
92 cmchar "inverted d with hook";
93 beginchar("p", 13u#, asc_height#, desc_depth#);
94 italcorr 0.7x_height#*slant - u# + 0.5curve#;
95 adjust_fit(0, 0);
96
97 numeric hook_jut;
98 hook_jut = w - 9u;
99
100 pickup fine.nib;
101 x0 = hook_jut;
102 x2 - 0.5stem - hook_jut = hround(2.5u-.5stem);
103 hook_in(0, 1, 2); % opening hook
104
105 pos4(hair, -180);
106 pos5(vair, -90);
107 pos6(curve, 0);
108 pos7(vair, 90);
109 x4=x2;
110 rt x6r=hround(w-1.5u+.5curve);
111 x5=x7=.5[x4, x6];
112 bot y5r=-oo;
113 top y7r=x_height+oo;
114 y4=y6=.5[y5, y7];
115
116 filldraw stroke super_arc.e(4, 5) & pulled_arc.e(5, 6)
117 & pulled_arc.e(6, 7) & super_arc.e(7, 4); % bowl
118
119 pickup tiny.nib;
120 pos2'(stem, 0);
121 pos3(stem, 0);
122 z2=z2';
123 x3=x2;
124 bot y3=-d;
125
126 filldraw stroke z2'e--z3e; % stem
127 sloped_serif.r(3, 2', a, 1/3, jut, serif_drop); % serif
128
129 math_fit(-min(2/3x_height#*slant-.5hair#-.5u#,
130 2u#-.5stem#-desc_depth#*slant), ic#);
131
132 % bit ad-hoc this
133
134 pos8(hair, 0);
135 z8r=z0l;
136
137 pos9(curve, 90);
138 pos10(hair, 180);
139
140 x9 = 1/2[x8, x10];
141 y9r = 1/2[x_height, h];
142 y10r = 1/4[y9l, y8];
143 x8l - lft x10r = hook_jut;
144
145 % filldraw stroke z8e{up}...{left}z9e...{down}z10e;
146 filldraw stroke super_arc.e(8, 9) & super_arc.e(9, 10);
147
148 penlabels(0, 1, 2, 3, 4, 5, 6, 7, 8, 9, 10);
149
150 endchar;
151
152 cmchar "Overturned lb ligature";
153 beginchar(oct "021", 12u#, x_height#, desc_depth#);
154 italcorr 0.7x_height#*slant - 0.5u#;
155 adjust_fit(0, 0);
156
157 pickup crisp.nib;
158
159 slope := 20;
160 obstem := stem/cosd(slope);
161 tsep := 3.75*stem;
162 thair := 0.3[hair, obstem];
163
164 % 1-2-11-4-5-6 is the left trunk and flourish, 3 is a utility point
165
166 pos1(stem, 0);
167 pos2(obstem, 0);
168 pos4(hair, 180-slope);
169 pos5(hair, -slope);
170 pos11(thair, 90);
171
172 %x1l = 0.5u;
173 x2 = x1;
174 bot y1 = y3 = -d;
175 y2 = 0.70*x_height;
176
177 z2-z3 = whatever*dir(180-slope);
178
179 z4 = 1.13[z3, z2];
180 z5 = whatever[z3, z2];
181
182 x5r = w-0.5u;
183 x4r = 0.5u;
184
185 % z11 lifts the left stroke
186
187 z11 = 0.5[z2, z4] + whatever*dir(90);
188 top y11r = x_height + o;
189
190 % z6 might be better half-way between the trunks
191
192 z6 = 0.89[z3, z2];
193 pos6(hair, angle(z6-z1)+90);
194
195 filldraw stroke z1e--z2e{z2-z1}..z11e..{z1-z2}z4e..tension(1.0)..z5e{z2-z1}..z6e{z1-z6};
196
197 penlabels(1, 2, 3, 11, 4, 5, 6);
198
199 % the right trunk with foot
200
201 pos7(stem, 0);
202 pos8(hair, 90);
203 pos9(obstem, 0);
204 pos10(hair, 180-slope);
205
206 x7-x1 = x9-x2 = tsep;
207 y7 = y1;
208 y9 = y2;
209
210 % the vertical lift point
211
212 x8 = 0.3[x9, x2];
213 top y8r = x_height + o;
214
215 z10l = 0.8[z1r, z2r];
216
217 filldraw stroke z7e--z9e{z9-z7}...z8e{left}..tension(2.0)..{z7-z9}z10e;
218
219 % serif(7, 9, a, 1/3, cap_jut);
220 sloped_serif.r(7, 9, a, 1/3, jut, serif_drop); % serif
221
222 penlabels(7, 8, 9, 10);
223
224 endchar;
225
226 cmchar "inverted F";
227 beginchar("F", 11.5u#-width_adj#, x_height#, desc_depth#);
228 italcorr x_height#*slant-cap_jut#+0.5u#;
229 adjust_fit(0, cap_serif_fit#);
230
231 h := vround(h-stem_corr);
232
233 pickup tiny.nib;
234
235 pos1(cap_stem, 0);
236 pos2(cap_stem, 0);
237
238 rt x1r = rt x2r = hround w - max(2u, 3u-0.5cap_stem);
239 top y1 = x_height;
240 bot y2 = -desc_depth;
241
242 filldraw stroke z1e--z2e; % stem
243
244 pickup crisp.nib;
245
246 pos3(slab, -90);
247 pos4(hair, 180);
248
249 bot y3r = -desc_depth;
250 x3 = x1;
251 rt x4r = hround(0.75u);
252 y4 = good.y(y3r+beak)-eps;
253
254 arm(3, 4, e, beak_darkness, beak_jut); % upper arm and beak
255
256 pos5(cap_bar, -90);
257 pos6(hair, 180);
258
259 top y5l = vround(.5[y2, y1]+.5cap_bar);
260 x5 = x1;
261 pos0(cap_bar, 90);
262
263 pos7(hair, 180);
264 z0 = z5;
265 x6 = x7;
266 y6-y5l = y0l-y7;
267
268 rt x6r = hround(4u-.5hair);
269 y6 = good.y(y5l+.6beak) + eps;
270 rt x9r = hround(w-.5u);
271
272 arm(5, 6, f, beak_darkness, 0);
273 arm(0, 7, g, beak_darkness, 0); % middle arm and serif
274
275 nodish_serif(1, 2, a, 1/3, cap_jut, b, 1/3, .5cap_jut); % upper serif
276 dish_serif(2, 1, c, 1/3, cap_jut, d, 1/3, 1.25cap_jut); % lower serif
277
278 math_fit(0, ic#-2.5u#);
279 penlabels(0, 1, 2, 3, 4, 5, 6, 7);
280
281 endchar;
282
283 end