Debian Codegraph @

texmf-dist/fonts/source/public/elvish/cirth.mf

raw
1 designsize:=10pt# ;
2 autorounding := 1 ;
3 mode_setup;
4 em#:=10pt#; ; desc#:=10/3pt#; ex#:=8pt#; o#:=1/8pt#;
5 % parameters
6
7 font_normal_space(0.4em#) ; font_x_height(ex#) ;
8 font_quad(em#) ; font_normal_stretch(0.2em#) ;
9 font_normal_shrink(0.1em#) ;
10
11 penangle := 30 ;
12 penwidth# := 1/12em# ; penthickness# := 1/50em# ;
13 define_pixels(em,desc,ex);
14 define_blacker_pixels(penwidth,penthickness) ;
15 tehta_penwidth# = 0.8penwidth# ;
16 define_blacker_pixels(tehta_penwidth) ;
17 define_corrected_pixels(o);
18 straight_sidebar# = 1/12em#; curve_sidebar# = 1/18em#;
19 define_whole_pixels(straight_sidebar,curve_sidebar) ;
20
21 fudge := 0.05 ex ; % fudge for lowering calma luva
22 u# := em#/18 ;
23 define_pixels(u) ;
24 tailjut# := 12u# - 10u# ;
25 define_whole_pixels(tailjut) ;
26 luva_width# = 0.5em# ; define_pixels(luva_width) ;
27 pickup pencircle xscaled penwidth yscaled penthickness rotated penangle;
28 main_nib := savepen ;
29 pickup pencircle xscaled tehta_penwidth yscaled penthickness rotated penangle;
30 tehta_nib := savepen ;
31
32
33
34 def draw_stem(suffix i,j)(expr serifs) = % serifs = t,b,tb for Top & Bottom
35 z.i.$ = z.i + 0.05em * dir(penangle+180) ;
36 z.i.$$ = z.i + 0.1em * down ;
37 z.j.$ = z.j + 0.05em * dir(penangle) ;
38 z.j.$$ = z.j + 0.1em * up ;
39 draw z.i .. z.j ;
40 if (serifs = "t") or (serifs = "tb"):
41 filldraw z.i -- z.i.${dir(penangle-90)}
42 .. {down}z.i.$$ & z.i.$$ .. z.i & cycle ; fi
43 if (serifs = "b") or (serifs = "tb"):
44 filldraw z.j -- z.j.${dir(penangle+90)}
45 .. {up}z.j.$$ & z.j.$$ .. z.j & cycle ; fi
46 labels(i,j)
47 enddef ;
48
49 def diag(suffix i,j) = % diag from i to j with serif at j
50 draw z.i -- z.j ;
51 theta :=
52 if x.j > x.i:
53 if y.j > y.i: penangle - 90 else: penangle fi
54 else:
55 if y.j > y.i: -penangle else: penangle + 90 fi fi ;
56 draw z.j -- (z.j + 0.05em*dir theta) ;
57 enddef ;
58
59 beginchar("p",10u#,ex#,0) ; "The rune p" ;
60 pickup main_nib ;
61 top y1 = h ; bot y2 = 0 ; lft x1 = lft x2 = straight_sidebar ;
62 draw_stem(1,2,"tb") ;
63 bot z4 = 0.4[z2,z1] ;
64 rt x3 = w - curve_sidebar ; y3 = 1/2[y4,y1] ;
65 draw z1 -- z3 -- z4 ;
66 endchar ;
67
68 beginchar("b",12u#,ex#,0) ; "The rune b" ;
69 pickup main_nib ;
70 top y1 = h ; bot y2 = 0 ; lft x1 = lft x2 = straight_sidebar ;
71 draw_stem(1,2,"tb") ;
72 bot z4 = 0.4[z2,z1] ;
73 rt x3 = w - curve_sidebar - tailjut ; y3 = 1/2[y4,y1] ;
74 draw z1 -- z3 -- z4 ;
75 y5 = y2 ; rt x5 = w - curve_sidebar ;
76 bot y4' = round y4 ; x4 = x4' ;
77 diag(4',5) ;
78 endchar ;
79
80 beginchar("f",10u#,ex#,0) ; "The rune f" ;
81 pickup main_nib ;
82 top y1 = h ; bot y2 = 0 ; rt x1 = rt x2 = w - straight_sidebar ;
83 draw_stem(1,2,"b") ;
84 bot z4 = 0.4[z2,z1] ;
85 lft x3 = curve_sidebar ; y3 = 1/2[y4,y1] ;
86 draw z1 -- z3 -- z4 ;
87 endchar ;
88
89 beginchar("v",12u#,ex#,0) ; "The rune v" ;
90 pickup main_nib ;
91 top y1 = h ; bot y2 = 0 ; rt x1 = rt x2 = w - straight_sidebar ;
92 draw_stem(1,2,"b") ;
93 bot z4 = 0.45[z2,z1] ;
94 lft x3 = curve_sidebar+tailjut ; y3 = 1/2[y4,y1] ;
95 draw z1 -- z3 -- z4 ;
96 y5 = y2 ; lft x5 = curve_sidebar ;
97 diag(4,5) ;
98 endchar ;
99
100 beginchar("W",19u#,ex#,0) ; "The rune hw" ;
101 pickup main_nib ;
102 top y1 = h ; bot y2 = 0 ; x1 = x2 = good.x 0.5w ;
103 draw_stem(1,2,"b") ;
104 bot z4 = 0.4[z2,z1] ;
105 rt x3 = w - curve_sidebar ; y3 = 1/2[y4,y1] ;
106 draw z1 -- z3 -- z4 ;
107 lft x5 = curve_sidebar ; y5 = y3 ;
108 draw z1 -- z5 -- z4 ;
109 endchar ;
110
111 beginchar("m",10u#,ex#,0) ; "The rune m" ;
112 pickup main_nib ;
113 top y1 = h ; bot y2 = 0 ; lft x1 = lft x2 = straight_sidebar ;
114 draw_stem(1,2,"b") ;
115 top z4 = 0.55[z2,z1] ;
116 rt x3 = w - curve_sidebar ; y3 = 1/2[y4,y1] ;
117 draw z1 -- z3 -- z4 ;
118 y5 = 1/2[y4,y2] ;
119 rt x5 = w - 1/2curve_sidebar ;
120 draw z4 -- z5 -- z2 ;
121 endchar ;
122
123 beginchar("M",10u#,ex#,0); "The rune mb" ;
124 pickup main_nib ;
125 top y1 = h ; bot y2 = 0 ; rt x1 = rt x2 = w- straight_sidebar ;
126 draw_stem(1,2,"b") ;
127 top z4 = 0.55[z2,z1] ;
128 lft x3 = curve_sidebar ; y3 = 1/2[y4,y1] ;
129 draw z1 -- z3 -- z4 ;
130 y5 = 1/2[y4,y2] ;
131 lft x5 = 1/2curve_sidebar ;
132 draw z4 -- z5 -- z2 ;
133 endchar ;
134
135 beginchar("t",10u#,ex#,0) ; "The rune t" ;
136 pickup main_nib ;
137 top y1 = h ; bot y2 = 0 ; lft x1 = lft x2 = straight_sidebar ;
138 draw_stem(1,2,"tb") ;
139 rt x3 = w - curve_sidebar ; y3 = .7[y2,y1] ;
140 diag(1,3) ;
141 endchar ;
142
143 beginchar("d",10u#,ex#,0) ; "The rune d" ;
144 pickup main_nib ;
145 top y1 = h ; bot y2 = 0 ; lft x1 = lft x2 = straight_sidebar ;
146 draw_stem(1,2,"tb") ;
147 rt x3 = w - curve_sidebar ; y3 = .7[y2,y1] ;
148 diag(1,3) ;
149 x4 = x1 ; x5 = x3 ; bot y4 = round (.5[y1,y2]) ; y4 - y1 = y5 - y3 ;
150 diag(4,5) ;
151 endchar ;
152
153 beginchar("T",10u#,ex#,0) ; "The rune th" ;
154 pickup main_nib ;
155 top y1 = h ; bot y2 = 0 ; rt x1 = rt x2 = w - straight_sidebar ;
156 draw_stem(1,2,"b") ;
157 lft x3 = curve_sidebar ; y3 = .7[y2,y1] ;
158 diag(1,3) ;
159 endchar ;
160
161 beginchar("D",10u#,ex#,0) ; "The rune dh" ;
162 pickup main_nib ;
163 top y1 = h ; bot y2 = 0 ; rt x1 = rt x2 = w - straight_sidebar ;
164 draw_stem(1,2,"b") ;
165 lft x3 = curve_sidebar ; y3 = .7[y2,y1] ;
166 diag(1,3) ;
167 x4 = x1 ; x5 = x3 ; bot y4 = round(.5[y1,y2]) ; y4 - y1 = y5 - y3 ;
168 diag(4,5) ;
169 endchar ;
170
171 beginchar("n",17u#,ex#,0) ; "The rune n" ;
172 pickup main_nib ;
173 top y1 = h ; bot y2 = 0 ; x1 = x2 = good.x .5w ;
174 draw_stem(1,2,"b") ;
175 lft x3 = curve_sidebar = w - rt x4 ; y3 = y4 = .7[y2,y1] ;
176 diag(1,3) ; diag(1,4) ;
177 endchar ;
178
179 beginchar("c",12u#,ex#,0) ; "The rune ch" ;
180 pickup main_nib ;
181 top y1 = h ; bot y2 = 0 ; lft x1 = lft x2 = straight_sidebar ;
182 bot y3 = .45[y1,y2] ; x3 = x1 ;
183 rt x4 = w - curve_sidebar ; y4 = y2 ;
184 draw_stem(1,2,"tb") ;
185 diag(3,4) ;
186 endchar ;
187
188 beginchar("j",13u#,ex#,0) ; "The rune j" ;
189 pickup main_nib ;
190 top y1 = h ; bot y2 = 0 ; lft x1 = lft x2 = straight_sidebar ;
191 bot y3 = .4[y1,y2] ; x3 = x1 ;
192 rt x4 = w - curve_sidebar ; y4 = y2 ;
193 draw_stem(1,2,"tb") ;
194 diag(3,4) ;
195 y5 = .5[y2,y3] ; x5 = x1 ; y6 = y4 ; z6 - z5 = whatever*(z4 - z3) ;
196 diag(5,6) ;
197 endchar ;
198
199 beginchar("C",11u#,ex#,0) ; "The rune sh" ;
200 pickup main_nib ;
201 top y1 = h ; bot y2 = 0 ; rt x1 = rt x2 = w - straight_sidebar ;
202 bot y3 = .45[y1,y2] ; x3 = x1 ;
203 lft x4 = curve_sidebar ; y4 = y2 ;
204 draw_stem(1,2,"tb") ;
205 diag(3,4) ;
206 endchar ;
207
208 beginchar("J",12u#,ex#,0) ; "The rune zh" ;
209 pickup main_nib ;
210 top y1 = h ; bot y2 = 0 ; rt x1 = rt x2 = w - straight_sidebar ;
211 bot y3 = .4[y1,y2] ; x3 = x1 ;
212 lft x4 = curve_sidebar ; y4 = y2 ;
213 draw_stem(1,2,"tb") ;
214 diag(3,4) ;
215 y5 = .5[y2,y3] ; x5 = x1 ; y6 = y4 ; z6 - z5 = whatever*(z4 - z3) ;
216 diag(5,6) ;
217 endchar ;
218
219 beginchar("Y",18u#,ex#,0) ; "The rune nj" ;
220 pickup main_nib ;
221 top y1 = h ; bot y2 = 0 ; x1 = x2 = good.x .5w ;
222 bot y3 = .45[y1,y2] ; x3 = x1 ;
223 y4 = y5 = y2 ; x4 = curve_sidebar = w - x5 ;
224 draw_stem(1,2,"tb") ;
225 diag(3,4) ; diag(3,5) ;
226 endchar ;
227
228 beginchar("k",11u#,ex#,0) ; "The rune k" ;
229 pickup main_nib ;
230 top y1 = h ; bot y2 = 0 ; lft x1 = lft x2 = straight_sidebar ;
231 top y3 = .55[y1,y2] ; x3 = x1 ;
232 y4 = y1 ; rt x4 = w - curve_sidebar ;
233 draw_stem(1,2,"tb") ;
234 draw z3{dir 35} .. tension 1 .. {dir 80}z4 -- z4 + 0.03em*left ;
235 endchar ;
236
237 beginchar("g",12u#,ex#,0) ; "The rune g" ;
238 pickup main_nib ;
239 top y1 = h ; bot y2 = 0 ; lft x1 = lft x2 = straight_sidebar ;
240 top y3 = .6[y1,y2] ; x3 = x1 ;
241 y4 = y1 ; rt x4 = w - curve_sidebar ;
242 draw_stem(1,2,"tb") ;
243 draw z3{dir 35} .. tension 1 .. {dir 80}z4 -- z4 + 0.03em*left ;
244 z5 = .55[z1,z3] ; z6 = .5[z1,z4] ;
245 draw z5{dir 40} .. tension 2 .. z6 -- z6 + 0.03em*left ;
246 endchar ;
247
248 beginchar("K",11u#,ex#,0) ; "The rune kh" ;
249 pickup main_nib ;
250 top y1 = h ; bot y2 = 0 ; rt x1 = rt x2 = w - straight_sidebar ;
251 top y3 = .55[y1,y2] ; x3 = x1 ;
252 y4 = y1 ; lft x4 = curve_sidebar ;
253 draw_stem(1,2,"tb") ;
254 draw z3{dir 135} .. tension 1 .. {dir 100}z4 -- z4 + 0.03em*left ;
255 endchar ;
256
257 beginchar("G",12u#,ex#,0) ; "The rune gh" ;
258 pickup main_nib ;
259 top y1 = h ; bot y2 = 0 ; rt x1 = rt x2 = w - straight_sidebar ;
260 top y3 = .6[y1,y2] ; x3 = x1 ;
261 y4 = y1 ; lft x4 = curve_sidebar ;
262 draw_stem(1,2,"tb") ;
263 draw z3{dir 145} .. tension 1 .. {dir 100}z4 -- z4 + 0.03em*left ;
264 z5 = .55[z1,z3] ; z6 = .5[z1,z4] ;
265 draw z5{dir 145} .. tension 1 .. {dir 100}z6 -- z6 + 0.03em*left ;
266 endchar ;
267
268 beginchar("N",16u#,ex#,0) ; "The rune ng" ;
269 pickup main_nib ;
270 top y1 = h ; bot y2 = 0 ; x1 = x2 = good.x .5w ;
271 top y3 = .55[y1,y2] ; x3 = x1 ;
272 y4 = y1 ; lft x4 = curve_sidebar ;
273 draw_stem(1,2,"tb") ;
274 draw z3{dir 145} .. tension 1 .. {dir 100}z4 -- z4 + 0.03em*left ;
275 y5 = y4 ; x5 = w - x4 ;
276 draw z3{dir 35} .. tension 1 .. {dir 80}z5 -- z5 + 0.03em*left ;
277 endchar ;
278
279 beginchar(43,13u#,ex#,0) ; "The rune kw" ;
280 pickup main_nib ;
281 top y1 = h ; bot y2 = 0 ; lft x1 = lft x2 = straight_sidebar ;
282 draw_stem(1,2,"tb") ;
283 rt x4 = w - curve_sidebar ; x3 = .5[x1,x4] ; y4 = y1 ; y3 = .7[y2,y1] ;
284 draw z1 -- z3 ; diag(3,4) ;
285 endchar ;
286
287 beginchar(39,13u#,ex#,0) ; "The rune gw" ;
288 pickup main_nib ;
289 top y1 = h ; bot y2 = 0 ; lft x1 = lft x2 = straight_sidebar ;
290 draw_stem(1,2,"tb") ;
291 rt x4 = w - curve_sidebar ; x3 = .5[x1,x4] ; y4 = y1 ; y3 = .7[y2,y1] ;
292 draw z1 -- z3 ; diag(3,4) ;
293 x5 = x1 ; top y5 = .6[y2,y1] ; z5 - z1 = z6 - z3 = z7 - z4 ;
294 draw z5 -- z6 ; diag(6,7) ;
295 endchar ;
296
297 beginchar(11,13u#,ex#,0) ; "The rune khw" ;
298 pickup main_nib ;
299 top y1 = h ; bot y2 = 0 ; rt x1 = rt x2 = w - straight_sidebar ;
300 draw_stem(1,2,"b") ;
301 lft x4 = curve_sidebar ; x3 = .5[x1,x4] ; y4 = y1 ; y3 = .7[y2,y1] ;
302 draw z1 -- z3 ; diag(3,4) ;
303 endchar ;
304
305 beginchar(7,13u#,ex#,0) ; "The rune ghw" ;
306 pickup main_nib ;
307 top y1 = h ; bot y2 = 0 ; rt x1 = rt x2 = w - straight_sidebar ;
308 draw_stem(1,2,"b") ;
309 lft x4 = curve_sidebar ; x3 = .5[x1,x4] ; y4 = y1 ; y3 = .7[y2,y1] ;
310 draw z1 -- z3 ; diag(3,4) ;
311 x5 = x1 ; top y5 = .6[y2,y1] ; z5 - z1 = z6 - z3 = z7 - z4 ;
312 draw z5 -- z6 ; diag(6,7) ;
313 endchar ;
314
315 beginchar(14,22u#,ex#,0) ; "The rune ngw" ;
316 pickup main_nib ;
317 top y1 = h ; bot y2 = 0 ; x1 = x2 = good.x .5w ;
318 draw_stem(1,2,"b") ;
319 lft x4 = curve_sidebar ; x3 = .5[x1,x4] ; y4 = y1 ; y3 = .7[y2,y1] ;
320 draw z1 -- z3 ; diag(3,4) ;
321 x6 = w - x4 ; y6 = y4 ; y5 = y3 ; x5 = w - x3 ;
322 draw z1 -- z5 ; diag(5,6) ;
323 endchar ;
324
325 beginchar(46,13u#,ex#,0) ; "The rune nw" ;
326 pickup main_nib ;
327 top y1 = h ; bot y2 = 0 ; lft x1 = lft x2 = straight_sidebar ;
328 draw_stem(1,2,"") ;
329 rt x4 = w - curve_sidebar ; x3 = .5[x1,x4] ; y4 = y1 ; y3 = .7[y2,y1] ;
330 draw z1 -- z3 ; diag(3,4) ;
331 x6 = x4 ; y6 = h - y4 ; y5 = h - y3 ; rt x5 = round x3 ;
332 draw z2 -- z5 ; diag(5,6) ;
333 endchar ;
334
335 beginchar("r",10u#,ex#,0) ; "The rune r" ;
336 pickup main_nib ;
337 top y1 = h ; bot y2 = 0 ; lft x1 = lft x2 = straight_sidebar ;
338 y3 = .5[y1,y2] ; x3 = x1 ;
339 y4 = y1 ; rt x4 = w - curve_sidebar ;
340 draw_stem(1,2,"tb") ;
341 draw z3{dir 45} .. tension 2 .. {dir 80}z4 -- z4 + 0.03em*left ;
342 y5 = y2 ; x5 = x4 ;
343 draw z3{dir -20} .. z5{dir -80} ;
344 endchar ;
345
346 beginchar("R",10u#,ex#,0) ; "The rune rh" ;
347 pickup main_nib ;
348 top y1 = h ; bot y2 = 0 ; rt x1 = rt x2 = w - straight_sidebar ;
349 y3 = .5[y1,y2] ; x3 = x1 ;
350 y4 = y1 ; lft x4 = curve_sidebar ;
351 draw_stem(1,2,"tb") ;
352 draw z3{dir 135} .. tension 2 .. {dir 100}z4 -- z4 + 0.03em*left ;
353 y5 = y2 ; x5 = x4 ;
354 draw z3{dir 200} .. z5{dir -100} ;
355 endchar ;
356
357 beginchar("l",12u#,ex#,0) ; "The rune l" ;
358 pickup main_nib ;
359 top y1 = h ; bot y2 = 0 ; x1 = x2 = good.x .5w ;
360 top y3 = round .85h ; rt x3 = w - curve_sidebar ;
361 x4 = w - x3 ; y4 = h - y3 ;
362 draw_stem(1,2,"tb") ;
363 draw z3{dir -100} .. {dir -100}z4 .. z4 + 0.03em*dir -70 ;
364 endchar ;
365
366 beginchar("L",12u#,ex#,0) ; "The rune lh" ;
367 pickup main_nib ;
368 top y1 = h ; bot y2 = 0 ; x1 = x2 = good.x .5w ;
369 top y3 = round .85h ; lft x3 = curve_sidebar ;
370 x4 = w - x3 ; y4 = h - y3 ;
371 draw_stem(1,2,"tb") ;
372 draw z3 + 0.03em*dir70 .. z3{dir -80} .. {dir -100}z4 .. z4 + 0.03em*dir -110 ;
373 endchar ;
374
375 beginchar(1,12u#,ex#,0) ; "The rune ng--nd" ;
376 pickup main_nib ;
377 top y1 = h ; bot y2 = 0 ; x1 = x2 = good.x .5w ;
378 top y3 = round .85h ; lft x3 = curve_sidebar ;
379 x4 = w - x3 ; y4 = h - y3 ;
380 draw_stem(1,2,"tb") ;
381 draw z3 + 0.03em*dir70 .. z3{dir -80} .. {dir -100}z4 .. z4 + 0.03em*dir -110 ;
382 top y5 = round .85h ; rt x5 = w - curve_sidebar ;
383 x6 = w - x5 ; y6 = h - y5 ;
384 draw z5{dir -100} .. {dir -100}z6 .. z6 + 0.03em*dir -70 ;
385 endchar ;
386
387 beginchar("s",10u#,ex#,0) ; "The rune s" ;
388 pickup main_nib ;
389 lft x1 = lft x3 = curve_sidebar = w - rt x2 ;
390 top y1 = h = h - bot y3 ; y2 = .5[y1,y3] ;
391 diag(2,1) ; diag(2,3) ;
392 endchar ;
393
394 beginchar("S",10u#,ex#,0) ; "The rune s---variant" ;
395 pickup main_nib ;
396 rt x1 = rt x3 = w - curve_sidebar = w - lft x2 ;
397 top y1 = h = h - bot y3 ; y2 = .5[y1,y3] ;
398 diag(2,1) ; diag(2,3) ;
399 endchar ;
400
401 beginchar("z",14u#,ex#,0) ; "The rune z" ;
402 pickup main_nib ;
403 lft x1 = curve_sidebar = w - rt x2 = w - rt x4 = lft x3 ;
404 top y1 = top y2 = h = h - bot y3 = h - bot y4 ;
405 z5 = .5[z1,z4] ;
406 diag(5,1) ; diag(5,2) ; diag(5,3) ; diag(5,4) ;
407 endchar ;
408
409 beginchar(2,14u#,ex#,0) ; "The rune ng---variant" ;
410 pickup main_nib ;
411 lft x1 = curve_sidebar = w - rt x2 = w - rt x4 = lft x3 ;
412 top y1 = top y2 = h = h - bot y3 = h - bot y4 ;
413 z5 = .5[z1,z4] ;
414 diag(5,1) ; diag(5,2) ; diag(5,3) ; diag(5,4) ;
415 x1' = x4' = x5 ; y2' = y3' = y5 ;
416 top y1' = round .85h = h - bot y4' ;
417 z2' - z1' = z4' - z3' = whatever*(z4 - z1) ;
418 draw z1' -- z2' -- z4' -- z3' -- cycle ;
419 endchar ;
420
421 beginchar(3,15u#,ex#,0) ; "The rune nd" ;
422 pickup main_nib ;
423 lft x1 = lft x3 = w - rt x2 = w - rt x4 = straight_sidebar ;
424 top y1 = top y2 = h - bot y3 = h - bot y4 = h ;
425 draw z1 -- z4 -- z2 -- z3 -- cycle ;
426 endchar ;
427
428 beginchar(4,14u#,ex#,0) ; "The rune nd---variant" ;
429 pickup main_nib ;
430 lft x1 = lft x3 = w - rt x2 = w - rt x4 = straight_sidebar ;
431 top y1 = top y2 = h - bot y3 = h - bot y4 = h ;
432 draw_stem(1,3,"b") ; draw_stem(2,4,"b") ;
433 x5 = x1 ; x6 = x2 ; y5 = y6 = .45[y1,y3] ;
434 draw z1 -- z6 ; draw z2 -- z5 ;
435 endchar ;
436
437 beginchar("i",4u#,ex#,0) ; "The rune i" ;
438 pickup main_nib ;
439 x1 = x2 = good.x .5w ;
440 top y1 = h ; bot y2 = 0 ;
441 draw_stem(1,2,"tb") ;
442 endchar ;
443
444 beginchar("y", 9u#,ex#,0) ; "The rune y" ;
445 pickup main_nib ;
446 lft x1 = lft x2 = straight_sidebar = w - rt x3 = w - rt x4 ;
447 top y1 = h ; bot y4 = 0 ;
448 y2 = good.y .25h ; y3 = good.y .75h ;
449 draw_stem(1,2,"t") ; draw_stem(3,4,"b") ; draw z2 -- z3 ;
450 endchar ;
451
452 beginchar("H", 9u#,ex#,0) ; "The rune y" ;
453 pickup main_nib ;
454 lft x1 = lft x2 = straight_sidebar = w - rt x3 = w - rt x4 ;
455 bot y1 = 0 ; top y4 = h ;
456 y2 = good.y .75h ; y3 = good.y .25h ;
457 draw_stem(2,1,"b") ; draw_stem(4,3,"t") ; draw z2 -- z3 ;
458 endchar ;
459
460 beginchar("u",14u#,ex#,0) ; "The rune u" ;
461 pickup main_nib ;
462 lft x4 = curve_sidebar = w - rt x2 ;
463 x3 = good.x .5w ;
464 x1 = good.x .3[x4,x3] = w - x5 ;
465 top y3 = h ;
466 bot y1 = bot y5 = 0 ;
467 y2 = y4 = good.y .6h ;
468 diag(2,1) ; diag(4,5) ; draw z2 -- z3 -- z4 ;
469 endchar ;
470
471 beginchar("U",10u#,ex#,0) ; "The rune long u" ;
472 pickup main_nib ;
473 lft x1 = lft x3 = curve_sidebar = w - rt x2 ;
474 top y1 = h = h - bot y3 ; y2 = .5[y1,y3] ;
475 diag(2,1) ; diag(2,3) ;
476 x5 = x1 ; y5 = y2 ; x4 = x6 = x2 ; y4 = y1 ; y6 = y3 ;
477 diag(5,4) ; diag(5,6) ;
478 endchar ;
479
480 beginchar("w",12u#,ex#,0) ; "The rune w" ;
481 pickup main_nib ;
482 lft x1 = curve_sidebar = w - rt x3 ;
483 x2 = x4 = x5 = good.x .5w ;
484 top y2 = h ; bot y5 = 0 ; y4 = good.y .35h ; y1 = y3 = .5[y2,y4] ;
485 draw_stem(4,5,"b") ; draw z1 -- z2 -- z3 -- z4 -- cycle ;
486 endchar ;
487
488 beginchar(21,12u#,ex#,0) ; "The rune ue" ;
489 pickup main_nib ;
490 lft x4 = curve_sidebar = w - rt x2 ;
491 x3 = good.x .5w ;
492 x1 = good.x .3[x4,x3] = w - x5 ;
493 top y3 = h ;
494 y1 = y5 = good.y .3h ;
495 y2 = y4 = good.y .6[y1,y3] ;
496 diag(2,1) ; diag(4,5) ; draw z2 -- z3 -- z4 ;
497 z6 = (z2 -- z1) intersectionpoint (z4--z5) ;
498 x7 = x6 ; bot y7 = 0 ; draw_stem(6,7,"b") ;
499 endchar ;
500
501 beginchar(53,12u#,ex#,0) ; "The rune ue---variant" ;
502 pickup main_nib ;
503 lft x4 = curve_sidebar = w - rt x2 ;
504 x3 = good.x .5w ;
505 x1 = good.x .3[x4,x3] = w - x5 ;
506 top y3 = h ;
507 y1 = y5 = good.y .3h ;
508 y2 = y4 = good.y .6[y1,y3] ;
509 diag(2,1) ; diag(4,5) ; draw z2 -- z3 -- z4 ;
510 z6 = (z2 -- z1) intersectionpoint (z4--z5) ;
511 x7 = x6 ; bot y7 = 0 ; draw_stem(3,7,"b") ;
512 endchar ;
513
514 beginchar("e",10u#,ex#,0) ; "The rune e" ;
515 pickup main_nib ;
516 lft x1 = lft x2 = straight_sidebar = w - rt x3 = w - rt x4 ;
517 top y1 = top y3 = h ; bot y2 = bot y4 = 0 ;
518 draw_stem(1,2,"tb") ; draw_stem(3,4,"tb") ;
519 x5 = x1 ; x6 = x3 ; .5[y5,y6] = vround .52h ;
520 top y5 = vround .67h ; draw z5 -- z6 ;
521 endchar ;
522
523 beginchar("E",10u#,ex#,0) ; "The rune long e" ;
524 pickup main_nib ;
525 lft x1 = lft x2 = straight_sidebar = w - rt x3 = w - rt x4 ;
526 top y1 = top y3 = h ; bot y2 = bot y4 = 0 ;
527 draw_stem(1,2,"tb") ; draw_stem(3,4,"tb") ;
528 x5 = x7 = x1 ; x6 = x8 = x3 ; .5[y5,y8] = vround .52h ;
529 top y5 = vround .8h ;
530 top y6 = vround .67h ; y7 - y8 = y5 - y6 ;
531 draw z5 -- z6 ; draw z7 -- z8 ;
532 endchar ;
533
534 beginchar("a",10u#,ex#,0) ; "The rune a" ;
535 pickup main_nib ;
536 lft x1 = lft x2 = straight_sidebar = w - rt x3 = w - rt x4 ;
537 top y1 = h ; top y3 = vround .75h ; bot y2 = bot y4 = 0 ;
538 draw_stem(1,2,"b") ; draw_stem(3,4,"b") ;
539 draw z1 -- z3 ;
540 endchar ;
541
542 beginchar("A",10u#,ex#,0) ; "The rune long a" ;
543 pickup main_nib ;
544 lft x1 = lft x2 = straight_sidebar = w - rt x3 = w - rt x4 ;
545 top y1 = h ; top y3 = vround .75h ; bot y2 = bot y4 = 0 ;
546 draw_stem(1,2,"b") ; draw_stem(3,4,"b") ;
547 draw z1 -- z3 ;
548 x5 = x1 ; x6 = x3 ; y5 = vround .6h ; y5 - y6 = y1 - y3 ;
549 draw z5 -- z6 ;
550 endchar ;
551
552 beginchar("o",12u#,ex#,0) ; "The rune o" ;
553 pickup main_nib ;
554 lft x1 = curve_sidebar = w - rt x3 ; x2 = good.x .5w ;
555 bot y1 = bot y3 = 0 ; top y2 = h ;
556 diag(2,3) ; diag(2,1) ;
557 endchar ;
558
559 beginchar("O",16u#,ex#,0) ; "The rune long o" ;
560 pickup main_nib ;
561 lft x1 = curve_sidebar = w - rt x6 ;
562 rt x3 = hround .7w = w - lft x4 ;
563 x2 = good.x .5[x1,x3] ; x5 = good.x .5[x4,x6] ;
564 top y2 = top y5 = h ;
565 bot y1 = 0 ; y1 = y3 = y4 = y6 ;
566 diag(2,1) ; diag(2,3) ; diag(5,4) ; diag(5,6) ;
567 endchar ;
568
569 beginchar(15,15u#,ex#,0) ; "The rune long o---variant" ;
570 pickup main_nib ;
571 lft x1 = lft x2 = straight_sidebar = w - rt x4 = w - rt x5 ;
572 x3 = good.x .5[x1,x4] ;
573 top y1 = top y4 = h ; bot y2 = bot y5 = 0 = bot y3 ;
574 draw_stem(1,2,"b") ; draw_stem(4,5,"b") ; draw z1 -- z3 -- z4 ;
575 endchar ;
576
577 beginchar(47,12u#,ex#,0) ; "The rune oe" ;
578 pickup main_nib ;
579 lft x1 = curve_sidebar = w - rt x3 ; x2 = good.x .5w ;
580 bot y1 = bot y3 = 0 ; top y2 = h ;
581 diag(2,3) ; diag(2,1) ;
582 x4 = x2 ; y4 = y1 ; draw_stem(2,4,"b") ;
583 endchar ;
584
585 beginchar("0",12u#,ex#,0) ; "The rune oe---variant" ;
586 pickup main_nib ;
587 lft x1 = curve_sidebar = w - rt x3 ; x2 = good.x .5w ;
588 bot y1 = bot y3 = 0 ; top y2 = h ;
589 diag(2,3) ; diag(2,1) ;
590 x4 = x2 = x5 ; top y4 = vround .4h ; y5 = y1 ; draw z4 -- z5 ;
591 endchar ;
592
593 beginchar(5,12u#,ex#,0) ; "The rune n---another one" ;
594 pickup main_nib ;
595 lft x1 = curve_sidebar = w - rt x3 ;
596 x2 = x4 = good.x .5w ;
597 top y1 = top y3 = h ; bot y4 = 0 ; y2 = good.y .45h ;
598 draw_stem(2,4,"b") ; diag(1,2) ; diag(2,3) ;
599 endchar ;
600
601 beginchar("h",12u#,ex#,0) ; "The rune h" ;
602 pickup main_nib ;
603 lft x1 = curve_sidebar = w - rt x3 ;
604 x2 = x4 = good.x .5w ;
605 bot y1 = bot y3 = 0 ; top y4 = h ; y2 = good.y .55h ;
606 draw_stem(4,2,"t") ; diag(1,2) ; diag(2,3) ;
607 endchar ;
608
609 beginchar(6,8u#,ex#,0) ; "The cup rune" ;
610 pickup main_nib ;
611 lft x1 = lft x2 = lft x3 = straight_sidebar ; rt x4 = w - curve_sidebar ;
612 top y1 = h ; bot y2 = 0 ; .5[y3,y4] = vround .52h ; top y3 = vround .7h ;
613 draw_stem(1,2,"tb") ; diag(3,4) ;
614 endchar ;
615
616 beginchar(8,8u#,ex#,0) ; "The evanescent cup rune" ;
617 pickup main_nib ;
618 lft x3 = curve_sidebar ; rt x4 = w - curve_sidebar ;
619 .5[y3,y4] = vround .52h ; top y3 = vround .7h ;
620 diag(3,4) ; diag(4,3) ;
621 endchar ;
622
623 beginchar(9,8u#,ex#,0) ; "The schwa rune" ;
624 pickup main_nib ;
625 rt x1 = rt x2 = rt x3 = w - straight_sidebar ; lft x4 = curve_sidebar ;
626 top y1 = h ; bot y2 = 0 ; .5[y3,y4] = vround .52h ; top y3 = vround .7h ;
627 draw_stem(1,2,"tb") ; diag(3,4) ;
628 endchar ;
629
630 beginchar(10,8u#,ex#,0) ; "The evanescent schwa rune" ;
631 pickup main_nib ;
632 rt x3 = w - curve_sidebar ; lft x4 = curve_sidebar ;
633 .5[y3,y4] = vround .52h ; top y3 = vround .7h ;
634 diag(3,4) ; diag(4,3) ;
635 endchar ;
636
637 beginchar(16,10u#,ex#,0) ; "The rune ps" ;
638 pickup main_nib ;
639 top y1 = h ; bot y2 = 0 ; lft x1 = lft x2 = straight_sidebar ;
640 draw_stem(1,2,"tb") ;
641 bot y4 = vround 0.2[y2,y1] ; top y5 = vround .8[y2,y1] ;
642 x4 = x1 ; x5 = x2 ;
643 rt x3 = w - curve_sidebar ; y3 = 1/2[y4,y5] ;
644 draw z5 -- z3 -- z4 ;
645 endchar ;
646
647 beginchar(20,10u#,ex#,0) ; "The rune ts" ;
648 pickup main_nib ;
649 top y1 = h ; bot y2 = 0 ; rt x1 = rt x2 = w - straight_sidebar ;
650 draw_stem(1,2,"tb") ;
651 bot y4 = vround 0.2[y2,y1] ; top y5 = vround .8[y2,y1] ;
652 x4 = x5 = x1 ;
653 lft x3 = curve_sidebar ; y3 = 1/2[y4,y5] ;
654 draw z5 -- z3 -- z4 ;
655 endchar ;
656
657 beginchar(12,4u#,ex#,0) ; "The aspiration rune" ;
658 pickup main_nib ;
659 x1 = x2 = good.x .5w ;
660 bot y2 = vround .3h ; top y1 = vround .75h ;
661 draw_stem(1,2,"tb") ;
662 endchar ;
663
664 beginchar("&",8u#,ex#,0) ; "The ampersand rune" ;
665 pickup main_nib ;
666 x1 = x2 = good.x .5w ; lft x3 = curve_sidebar = w - rt x4 ;
667 top y1 = h ; bot y2 = 0 ;
668 bot y3 = vround .7h = h - top y4 ;
669 draw_stem(1,2,"") ; diag(1,3) ; diag(2,4) ;
670 endchar ;
671
672 beginchar(18,11u#,ex#,0) ; "The OE rune wyn" ;
673 pickup main_nib ;
674 top y1 = h ; bot y2 = 0 ; lft x1 = lft x2 = straight_sidebar ;
675 top y3 = .55[y1,y2] ; x3 = x1 ;
676 y4 = y1 ; rt x4 = w - curve_sidebar ;
677 draw_stem(1,2,"tb") ;
678 draw z3 -- z4 -- z1 ;
679 endchar ;
680
681 beginchar(19,15u#,ex#,0) ; "The OE rune daeg---variant" ;
682 pickup main_nib ;
683 lft x1 = lft x3 = w - rt x2 = w - rt x4 = straight_sidebar ;
684 top y1 = top y2 = h - bot y3 = h - bot y4 = h ;
685 draw z1 -- z4 -- z2 -- z3 -- cycle ; draw z1 -- z2 ; draw z3 -- z4 ;
686 endchar ;
687
688 beginchar(22,13u#,ex#,0) ; "The OE rune ac" ;
689 pickup main_nib ;
690 top y1 = h ; bot y2 = 0 ; lft x1 = lft x2 = straight_sidebar ;
691 draw_stem(1,2,"tb") ;
692 rt x4 = w - curve_sidebar ; x3 = .5[x1,x4] ; y4 = y1 ; y3 = .7[y2,y1] ;
693 draw z1 -- z3 ; diag(3,4) ;
694 x5 = x1 ; top y5 = .6[y2,y1] ; z5 - z1 = z6 - z3 = z7 - z4 ;
695 diag(5,6) ;
696 endchar ;
697
698 beginchar(23,14u#,ex#,0) ; "The OE rune yr" ;
699 pickup main_nib ;
700 lft x1 = lft x2 = straight_sidebar = w - rt x3 = w - rt x4 ;
701 top y1 = h ; top y3 = vround .75h ; bot y2 = bot y4 = 0 ;
702 draw_stem(1,2,"b") ; draw_stem(3,4,"b") ;
703 draw z1 -- z3 ;
704 x5 = x1 ; x6 = x3 ; y5 = vround .6h ; y5 - y6 = y1 - y3 ;
705 draw z5 -- z6 ;
706 z7 = .5[z5,z6] ; x7 := good.x x7 ; x8 = x7 ; y8 = y2 ; draw_stem(7,8,"b") ;
707 endchar ;
708
709 beginchar(24,13u#,ex#,0) ; "The OE rune calc" ;
710 pickup main_nib ;
711 lft x1 = lft x2 = straight_sidebar ; top y1 = h ; bot y2 = 0 ;
712 draw_stem(1,2,"tb") ;
713 .5[y3,y4] = vround .52h ; bot y3 = vround .4h ;
714 x3 = x1 ;
715 rt x5 = w - curve_sidebar ; y5 = y2 ; x4 = .5[x3,x5] ;
716 draw z3 -- z4 ; diag(4,5) ;
717 endchar ;
718
719 beginchar(25,12u#,ex#,0) ; "The OE rune feoh" ;
720 pickup main_nib ;
721 top y1 = h ; bot y2 = 0 ; lft x1 = lft x2 = straight_sidebar ;
722 top y3 = .6[y1,y2] ; x3 = x1 ;
723 y4 = y1 ; rt x4 = w - curve_sidebar ;
724 draw_stem(1,2,"tb") ;
725 diag(3,4) ;
726 z5 = .55[z1,z3] ; z6 = .5[z1,z4] ;
727 diag(5,6) ;
728 endchar ;
729
730 beginchar(26,14u#,ex#,0) ; "The Ereborian rune ai" ;
731 pickup main_nib ;
732 lft x1 = lft x2 = straight_sidebar = w - rt x3 = w - rt x4 ;
733 top y1 = h ; top y3 = vround .75h ; bot y2 = bot y4 = 0 ;
734 draw_stem(1,2,"b") ; draw_stem(3,4,"b") ;
735 draw z1 -- z3 ;
736 x5 = x1 ; x6 = x3 ; y5 = vround .6h ; y5 - y6 = y1 - y3 ;
737 z7 = .5[z5,z6] ; x7 := good.x x7 ; x8 = x7 ; y8 = y2 ; draw_stem(7,8,"tb") ;
738 endchar ;
739
740 beginchar(27,14u#,ex#,0) ; "The Ereborian ea rune" ;
741 pickup main_nib ;
742 lft x1 = lft x2 = straight_sidebar = w - rt x3 = w - rt x4 ;
743 bot y2 = bot y4 = 0 ; y1 = y3 = good.y .5h ;
744 draw_stem(1,2,"b") ; draw_stem(3,4,"b") ;
745 x5 = good.x .5w ; top y5 = h ; x6 = x5 ; y6 = y2 ;
746 draw z1 -- z5 -- z3 ; draw_stem(5,6,"b") ;
747 endchar ;
748
749 beginchar(28,13u#,ex#,0) ; "The Ereborian ew rune" ;
750 pickup main_nib ;
751 lft x1 = lft x3 = w - rt x2 = w - rt x4 = straight_sidebar ;
752 top y1 = top y2 = h - bot y3 = h - bot y4 = h ;
753 draw_stem(1,3,"b") ; draw_stem(2,4,"b") ;
754 x5 = x7 = x1 ; x6 = x8 = x2 ; y5 = y6 = .75[y1,y3] = h - y7 = h - y8 ;
755 draw z5 -- z8 ; draw z7 -- z6 ;
756 endchar ;
757
758 beginchar(29,16u#,ex#,0) ; "The rune number 4" ;
759 pickup main_nib ;
760 lft x1 = curve_sidebar = w - rt x6 ;
761 rt x3 = hround .7w = w - lft x4 ;
762 x2 = good.x .5[x1,x3] ; x5 = good.x .5[x4,x6] ;
763 bot y2 = bot y5 = 0 ;
764 top y1 = h ; y1 = y3 = y4 = y6 ;
765 diag(2,1) ; diag(2,3) ; diag(5,4) ; diag(5,6) ;
766 endchar ;
767
768 beginchar(30,16u#,ex#,0) ; "The rune number 5" ;
769 pickup main_nib ;
770 top y1 = h ; bot y2 = 0 ; x1 = x2 = good.x .5w ;
771 top y3 = .55[y1,y2] ; x3 = x1 ;
772 y4 = y1 ; lft x4 = curve_sidebar ;
773 draw_stem(1,2,"tb") ;
774 diag(3,4) ;
775 y5 = y4 ; x5 = w - x4 ;
776 diag(3,5) ;
777 endchar ;
778
779 end.